Context Navigation

traadv_ubs.F90 @ 12340

Last change on this file since 12340 was 12340, checked in by acc, 4 years ago

Branch 2019/dev_r11943_MERGE_2019. This commit introduces basic do loop macro
substitution to the 2019 option 1, merge branch. These changes have been SETTE
tested. The only addition is the do_loop_substitute.h90 file in the OCE directory but
the macros defined therein are used throughout the code to replace identifiable, 2D-
and 3D- nested loop opening and closing statements with single-line alternatives. Code
indents are also adjusted accordingly.

The following explanation is taken from comments in the new header file:

This header file contains preprocessor definitions and macros used in the do-loop
substitutions introduced between version 4.0 and 4.2. The primary aim of these macros
is to assist in future applications of tiling to improve performance. This is expected
to be achieved by alternative versions of these macros in selected locations. The
initial introduction of these macros simply replaces all identifiable nested 2D- and
3D-loops with single line statements (and adjusts indenting accordingly). Do loops
are identifiable if they comform to either:

DO jk = ....

DO jj = .... DO jj = ...

DO ji = .... DO ji = ...
. OR .
. .

END DO END DO

END DO END DO

END DO

and white-space variants thereof.

Additionally, only loops with recognised jj and ji loops limits are treated; these are:
Lower limits of 1, 2 or fs_2
Upper limits of jpi, jpim1 or fs_jpim1 (for ji) or jpj, jpjm1 or fs_jpjm1 (for jj)

The macro naming convention takes the form: DO_2D_BT_LR where:

B is the Bottom offset from the PE's inner domain;
T is the Top offset from the PE's inner domain;
L is the Left offset from the PE's inner domain;
R is the Right offset from the PE's inner domain

So, given an inner domain of 2,jpim1 and 2,jpjm1, a typical example would replace:

DO jj = 2, jpj

DO ji = 1, jpim1
.
.

END DO

END DO

with:

DO_2D_01_10
.
.
END_2D

similar conventions apply to the 3D loops macros. jk loop limits are retained
through macro arguments and are not restricted. This includes the possibility of
strides for which an extra set of DO_3DS macros are defined.

In the example definition below the inner PE domain is defined by start indices of
(kIs, kJs) and end indices of (kIe, KJe)

#define DO_2D_00_00 DO jj = kJs, kJe ; DO ji = kIs, kIe
#define END_2D END DO ; END DO

TO DO:

Only conventional nested loops have been identified and replaced by this step. There are constructs such as:

DO jk = 2, jpkm1

z2d(:,:) = z2d(:,:) + e3w(:,:,jk,Kmm) * z3d(:,:,jk) * wmask(:,:,jk)

END DO

which may need to be considered.

Property svn:keywords set to Id

File size: 18.5 KB

Line
1	MODULE traadv_ubs
2	!!==============================================================================
3	!! * MODULE traadv_ubs *
4	!! Ocean active tracers: horizontal & vertical advective trend
5	!!==============================================================================
6	!! History : 1.0 ! 2006-08 (L. Debreu, R. Benshila) Original code
7	!! 3.3 ! 2010-05 (C. Ethe, G. Madec) merge TRC-TRA + switch from velocity to transport
8	!!----------------------------------------------------------------------
9
10	!!----------------------------------------------------------------------
11	!! tra_adv_ubs : update the tracer trend with the horizontal
12	!! advection trends using a third order biaised scheme
13	!!----------------------------------------------------------------------
14	USE oce ! ocean dynamics and active tracers
15	USE dom_oce ! ocean space and time domain
16	USE trc_oce ! share passive tracers/Ocean variables
17	USE trd_oce ! trends: ocean variables
18	USE traadv_fct ! acces to routine interp_4th_cpt
19	USE trdtra ! trends manager: tracers
20	USE diaptr ! poleward transport diagnostics
21	USE diaar5 ! AR5 diagnostics
22	!
23	USE iom ! I/O library
24	USE in_out_manager ! I/O manager
25	USE lib_mpp ! massively parallel library
26	USE lbclnk ! ocean lateral boundary condition (or mpp link)
27	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
28
29	IMPLICIT NONE
30	PRIVATE
31
32	PUBLIC tra_adv_ubs ! routine called by traadv module
33
34	LOGICAL :: l_trd ! flag to compute trends
35	LOGICAL :: l_ptr ! flag to compute poleward transport
36	LOGICAL :: l_hst ! flag to compute heat transport
37
38
39	!! * Substitutions
40	# include "vectopt_loop_substitute.h90"
41	# include "do_loop_substitute.h90"
42	!!----------------------------------------------------------------------
43	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
44	!! $Id$
45	!! Software governed by the CeCILL license (see ./LICENSE)
46	!!----------------------------------------------------------------------
47	CONTAINS
48
49	SUBROUTINE tra_adv_ubs( kt, kit000, cdtype, p2dt, pU, pV, pW, &
50	& Kbb, Kmm, pt, kjpt, Krhs, kn_ubs_v )
51	!!----------------------------------------------------------------------
52	!! * ROUTINE tra_adv_ubs *
53	!!
54	!! ** Purpose : Compute the now trend due to the advection of tracers
55	!! and add it to the general trend of passive tracer equations.
56	!!
57	!! ** Method : The 3rd order Upstream Biased Scheme (UBS) is based on an
58	!! upstream-biased parabolic interpolation (Shchepetkin and McWilliams 2005)
59	!! It is only used in the horizontal direction.
60	!! For example the i-component of the advective fluxes are given by :
61	!! ! e2u e3u un ( mi(Tn) - zltu(i ) ) if un(i) >= 0
62	!! ztu = ! or
63	!! ! e2u e3u un ( mi(Tn) - zltu(i+1) ) if un(i) < 0
64	!! where zltu is the second derivative of the before temperature field:
65	!! zltu = 1/e3t di[ e2u e3u / e1u di[Tb] ]
66	!! This results in a dissipatively dominant (i.e. hyper-diffusive)
67	!! truncation error. The overall performance of the advection scheme
68	!! is similar to that reported in (Farrow and Stevens, 1995).
69	!! For stability reasons, the first term of the fluxes which corresponds
70	!! to a second order centered scheme is evaluated using the now velocity
71	!! (centered in time) while the second term which is the diffusive part
72	!! of the scheme, is evaluated using the before velocity (forward in time).
73	!! Note that UBS is not positive. Do not use it on passive tracers.
74	!! On the vertical, the advection is evaluated using a FCT scheme,
75	!! as the UBS have been found to be too diffusive.
76	!! kn_ubs_v argument controles whether the FCT is based on
77	!! a 2nd order centrered scheme (kn_ubs_v=2) or on a 4th order compact
78	!! scheme (kn_ubs_v=4).
79	!!
80	!! ** Action : - update pt(:,:,:,:,Krhs) with the now advective tracer trends
81	!! - send trends to trdtra module for further diagnostcs (l_trdtra=T)
82	!! - poleward advective heat and salt transport (ln_diaptr=T)
83	!!
84	!! Reference : Shchepetkin, A. F., J. C. McWilliams, 2005, Ocean Modelling, 9, 347-404.
85	!! Farrow, D.E., Stevens, D.P., 1995, J. Phys. Ocean. 25, 1731Ð1741.
86	!!----------------------------------------------------------------------
87	INTEGER , INTENT(in ) :: kt ! ocean time-step index
88	INTEGER , INTENT(in ) :: Kbb, Kmm, Krhs ! ocean time level indices
89	INTEGER , INTENT(in ) :: kit000 ! first time step index
90	CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator)
91	INTEGER , INTENT(in ) :: kjpt ! number of tracers
92	INTEGER , INTENT(in ) :: kn_ubs_v ! number of tracers
93	REAL(wp) , INTENT(in ) :: p2dt ! tracer time-step
94	REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: pU, pV, pW ! 3 ocean volume transport components
95	REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) :: pt ! tracers and RHS of tracer equation
96	!
97	INTEGER :: ji, jj, jk, jn ! dummy loop indices
98	REAL(wp) :: ztra, zbtr, zcoef ! local scalars
99	REAL(wp) :: zfp_ui, zfm_ui, zcenut, ztak, zfp_wk, zfm_wk ! - -
100	REAL(wp) :: zfp_vj, zfm_vj, zcenvt, zeeu, zeev, z_hdivn ! - -
101	REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztu, ztv, zltu, zltv, zti, ztw ! 3D workspace
102	!!----------------------------------------------------------------------
103	!
104	IF( kt == kit000 ) THEN
105	IF(lwp) WRITE(numout,*)
106	IF(lwp) WRITE(numout,*) 'tra_adv_ubs : horizontal UBS advection scheme on ', cdtype
107	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
108	ENDIF
109	!
110	l_trd = .FALSE.
111	l_hst = .FALSE.
112	l_ptr = .FALSE.
113	IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
114	IF( cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) ) l_ptr = .TRUE.
115	IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
116	& iom_use("uadv_salttr") .OR. iom_use("vadv_salttr") ) ) l_hst = .TRUE.
117	!
118	ztw (:,:, 1 ) = 0._wp ! surface & bottom value : set to zero for all tracers
119	zltu(:,:,jpk) = 0._wp ; zltv(:,:,jpk) = 0._wp
120	ztw (:,:,jpk) = 0._wp ; zti (:,:,jpk) = 0._wp
121	!
122	! ! ===========
123	DO jn = 1, kjpt ! tracer loop
124	! ! ===========
125	!
126	DO jk = 1, jpkm1 !== horizontal laplacian of before tracer ==!
127	DO_2D_10_10
128	zeeu = e2_e1u(ji,jj) * e3u(ji,jj,jk,Kmm) * umask(ji,jj,jk)
129	zeev = e1_e2v(ji,jj) * e3v(ji,jj,jk,Kmm) * vmask(ji,jj,jk)
130	ztu(ji,jj,jk) = zeeu * ( pt(ji+1,jj ,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
131	ztv(ji,jj,jk) = zeev * ( pt(ji ,jj+1,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
132	END_2D
133	DO_2D_00_00
134	zcoef = 1._wp / ( 6._wp * e3t(ji,jj,jk,Kmm) )
135	zltu(ji,jj,jk) = ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zcoef
136	zltv(ji,jj,jk) = ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zcoef
137	END_2D
138	!
139	END DO
140	CALL lbc_lnk( 'traadv_ubs', zltu, 'T', 1. ) ; CALL lbc_lnk( 'traadv_ubs', zltv, 'T', 1. ) ! Lateral boundary cond. (unchanged sgn)
141	!
142	DO_3D_10_10( 1, jpkm1 )
143	zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) ) ! upstream transport (x2)
144	zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
145	zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
146	zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
147	! ! 2nd order centered advective fluxes (x2)
148	zcenut = pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj ,jk,jn,Kmm) )
149	zcenvt = pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji ,jj+1,jk,jn,Kmm) )
150	! ! UBS advective fluxes
151	ztu(ji,jj,jk) = 0.5 * ( zcenut - zfp_ui * zltu(ji,jj,jk) - zfm_ui * zltu(ji+1,jj,jk) )
152	ztv(ji,jj,jk) = 0.5 * ( zcenvt - zfp_vj * zltv(ji,jj,jk) - zfm_vj * zltv(ji,jj+1,jk) )
153	END_3D
154	!
155	zltu(:,:,:) = pt(:,:,:,jn,Krhs) ! store the initial trends before its update
156	!
157	DO jk = 1, jpkm1 !== add the horizontal advective trend ==!
158	DO_2D_00_00
159	pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) &
160	& - ( ztu(ji,jj,jk) - ztu(ji-1,jj ,jk) &
161	& + ztv(ji,jj,jk) - ztv(ji ,jj-1,jk) ) * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
162	END_2D
163	!
164	END DO
165	!
166	zltu(:,:,:) = pt(:,:,:,jn,Krhs) - zltu(:,:,:) ! Horizontal advective trend used in vertical 2nd order FCT case
167	! ! and/or in trend diagnostic (l_trd=T)
168	!
169	IF( l_trd ) THEN ! trend diagnostics
170	CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztu, pU, pt(:,:,:,jn,Kmm) )
171	CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztv, pV, pt(:,:,:,jn,Kmm) )
172	END IF
173	!
174	! ! "Poleward" heat and salt transports (contribution of upstream fluxes)
175	IF( l_ptr ) CALL dia_ptr_hst( jn, 'adv', ztv(:,:,:) )
176	! ! heati/salt transport
177	IF( l_hst ) CALL dia_ar5_hst( jn, 'adv', ztu(:,:,:), ztv(:,:,:) )
178	!
179	!
180	! !== vertical advective trend ==!
181	!
182	SELECT CASE( kn_ubs_v ) ! select the vertical advection scheme
183	!
184	CASE( 2 ) ! 2nd order FCT
185	!
186	IF( l_trd ) zltv(:,:,:) = pt(:,:,:,jn,Krhs) ! store pt(:,:,:,:,Krhs) if trend diag.
187	!
188	! !* upstream advection with initial mass fluxes & intermediate update ==!
189	DO_3D_11_11( 2, jpkm1 )
190	zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
191	zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
192	ztw(ji,jj,jk) = 0.5_wp * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
193	END_3D
194	IF( ln_linssh ) THEN ! top ocean value (only in linear free surface as ztw has been w-masked)
195	IF( ln_isfcav ) THEN ! top of the ice-shelf cavities and at the ocean surface
196	DO_2D_11_11
197	ztw(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb) ! linear free surface
198	END_2D
199	ELSE ! no cavities: only at the ocean surface
200	ztw(:,:,1) = pW(:,:,1) * pt(:,:,1,jn,Kbb)
201	ENDIF
202	ENDIF
203	!
204	DO_3D_00_00( 1, jpkm1 )
205	ztak = - ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
206	pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztak
207	zti(ji,jj,jk) = ( pt(ji,jj,jk,jn,Kbb) + p2dt * ( ztak + zltu(ji,jj,jk) ) ) * tmask(ji,jj,jk)
208	END_3D
209	CALL lbc_lnk( 'traadv_ubs', zti, 'T', 1. ) ! Lateral boundary conditions on zti, zsi (unchanged sign)
210	!
211	! !* anti-diffusive flux : high order minus low order
212	DO_3D_11_11( 2, jpkm1 )
213	ztw(ji,jj,jk) = ( 0.5_wp * pW(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) ) &
214	& - ztw(ji,jj,jk) ) * wmask(ji,jj,jk)
215	END_3D
216	! ! top ocean value: high order == upstream ==>> zwz=0
217	IF( ln_linssh ) ztw(:,:, 1 ) = 0._wp ! only ocean surface as interior zwz values have been w-masked
218	!
219	CALL nonosc_z( Kmm, pt(:,:,:,jn,Kbb), ztw, zti, p2dt ) ! monotonicity algorithm
220	!
221	CASE( 4 ) ! 4th order COMPACT
222	CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw ) ! 4th order compact interpolation of T at w-point
223	DO_3D_00_00( 2, jpkm1 )
224	ztw(ji,jj,jk) = pW(ji,jj,jk) * ztw(ji,jj,jk) * wmask(ji,jj,jk)
225	END_3D
226	IF( ln_linssh ) ztw(:,:, 1 ) = pW(:,:,1) * pt(:,:,1,jn,Kmm) !!gm ISF & 4th COMPACT doesn't work
227	!
228	END SELECT
229	!
230	DO_3D_00_00( 1, jpkm1 )
231	pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
232	END_3D
233	!
234	IF( l_trd ) THEN ! vertical advective trend diagnostics
235	DO_3D_00_00( 1, jpkm1 )
236	zltv(ji,jj,jk) = pt(ji,jj,jk,jn,Krhs) - zltv(ji,jj,jk) &
237	& + pt(ji,jj,jk,jn,Kmm) * ( pW(ji,jj,jk) - pW(ji,jj,jk+1) ) &
238	& * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
239	END_3D
240	CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, zltv )
241	ENDIF
242	!
243	END DO
244	!
245	END SUBROUTINE tra_adv_ubs
246
247
248	SUBROUTINE nonosc_z( Kmm, pbef, pcc, paft, p2dt )
249	!!---------------------------------------------------------------------
250	!! * ROUTINE nonosc_z *
251	!!
252	!! ** Purpose : compute monotonic tracer fluxes from the upstream
253	!! scheme and the before field by a nonoscillatory algorithm
254	!!
255	!! ** Method : ... ???
256	!! warning : pbef and paft must be masked, but the boundaries
257	!! conditions on the fluxes are not necessary zalezak (1979)
258	!! drange (1995) multi-dimensional forward-in-time and upstream-
259	!! in-space based differencing for fluid
260	!!----------------------------------------------------------------------
261	INTEGER , INTENT(in ) :: Kmm ! time level index
262	REAL(wp), INTENT(in ) :: p2dt ! tracer time-step
263	REAL(wp), DIMENSION (jpi,jpj,jpk) :: pbef ! before field
264	REAL(wp), INTENT(inout), DIMENSION (jpi,jpj,jpk) :: paft ! after field
265	REAL(wp), INTENT(inout), DIMENSION (jpi,jpj,jpk) :: pcc ! monotonic flux in the k direction
266	!
267	INTEGER :: ji, jj, jk ! dummy loop indices
268	INTEGER :: ikm1 ! local integer
269	REAL(wp) :: zpos, zneg, zbt, za, zb, zc, zbig, zrtrn ! local scalars
270	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zbetup, zbetdo ! 3D workspace
271	!!----------------------------------------------------------------------
272	!
273	zbig = 1.e+40_wp
274	zrtrn = 1.e-15_wp
275	zbetup(:,:,:) = 0._wp ; zbetdo(:,:,:) = 0._wp
276	!
277	! Search local extrema
278	! --------------------
279	! ! large negative value (-zbig) inside land
280	pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
281	paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
282	!
283	DO jk = 1, jpkm1 ! search maximum in neighbourhood
284	ikm1 = MAX(jk-1,1)
285	DO_2D_00_00
286	zbetup(ji,jj,jk) = MAX( pbef(ji ,jj ,jk ), paft(ji ,jj ,jk ), &
287	& pbef(ji ,jj ,ikm1), pbef(ji ,jj ,jk+1), &
288	& paft(ji ,jj ,ikm1), paft(ji ,jj ,jk+1) )
289	END_2D
290	END DO
291	! ! large positive value (+zbig) inside land
292	pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
293	paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
294	!
295	DO jk = 1, jpkm1 ! search minimum in neighbourhood
296	ikm1 = MAX(jk-1,1)
297	DO_2D_00_00
298	zbetdo(ji,jj,jk) = MIN( pbef(ji ,jj ,jk ), paft(ji ,jj ,jk ), &
299	& pbef(ji ,jj ,ikm1), pbef(ji ,jj ,jk+1), &
300	& paft(ji ,jj ,ikm1), paft(ji ,jj ,jk+1) )
301	END_2D
302	END DO
303	! ! restore masked values to zero
304	pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
305	paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
306	!
307	! Positive and negative part of fluxes and beta terms
308	! ---------------------------------------------------
309	DO_3D_00_00( 1, jpkm1 )
310	! positive & negative part of the flux
311	zpos = MAX( 0., pcc(ji ,jj ,jk+1) ) - MIN( 0., pcc(ji ,jj ,jk ) )
312	zneg = MAX( 0., pcc(ji ,jj ,jk ) ) - MIN( 0., pcc(ji ,jj ,jk+1) )
313	! up & down beta terms
314	zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
315	zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
316	zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
317	END_3D
318	!
319	! monotonic flux in the k direction, i.e. pcc
320	! -------------------------------------------
321	DO_3D_00_00( 2, jpkm1 )
322	za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
323	zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
324	zc = 0.5 * ( 1.e0 + SIGN( 1.e0, pcc(ji,jj,jk) ) )
325	pcc(ji,jj,jk) = pcc(ji,jj,jk) * ( zc * za + ( 1.e0 - zc) * zb )
326	END_3D
327	!
328	END SUBROUTINE nonosc_z
329
330	!!======================================================================
331	END MODULE traadv_ubs

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/TRA/traadv_ubs.F90 @ 12340

Download in other formats: