New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfdrg.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/ZDF – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/ZDF/zdfdrg.F90 @ 11960

Last change on this file since 11960 was 11960, checked in by acc, 4 years ago

Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/dev_r11613_ENHANCE-04_namelists_as_internalfiles. (svn merge -r 11614:11954). Resolved tree conflicts and one actual conflict. Sette tested(these changes alter the ext/AGRIF reference; remember to update). See ticket #2341
  • Property svn:keywords set to Id
File size: 24.8 KB
Line 
1MODULE zdfdrg
2   !!======================================================================
3   !!                       ***  MODULE  zdfdrg  ***
4   !! Ocean physics: top and/or Bottom friction
5   !!======================================================================
6   !! History :  OPA  ! 1997-06  (G. Madec, A.-M. Treguier)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.2  ! 2009-09  (A.C.Coward)  Correction to include barotropic contribution
9   !!            3.3  ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
10   !!            3.4  ! 2011-11  (H. Liu) implementation of semi-implicit bottom friction option
11   !!                 ! 2012-06  (H. Liu) implementation of Log Layer bottom friction option
12   !!            4.0  ! 2017-05  (G. Madec) zdfbfr becomes zdfdrg + variable names change
13   !!                                     + drag defined at t-point + new user interface + top drag (ocean cavities)
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   zdf_drg       : update bottom friction coefficient (non-linear bottom friction only)
18   !!   zdf_drg_exp   : compute the top & bottom friction in explicit case
19   !!   zdf_drg_init  : read in namdrg namelist and control the bottom friction parameters.
20   !!       drg_init  :
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and tracers variables
23   USE phycst  , ONLY : vkarmn
24   USE dom_oce        ! ocean space and time domain variables
25   USE zdf_oce        ! ocean vertical physics variables
26   USE trd_oce        ! trends: ocean variables
27   USE trddyn         ! trend manager: dynamics
28   !
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O module
31   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
32   USE lib_mpp        ! distributed memory computing
33   USE prtctl         ! Print control
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   zdf_drg         ! called by zdf_phy
39   PUBLIC   zdf_drg_exp     ! called by dyn_zdf
40   PUBLIC   zdf_drg_init    ! called by zdf_phy_init
41
42   !                                 !!* Namelist namdrg: nature of drag coefficient namelist *
43   LOGICAL          ::   ln_OFF       ! free-slip       : Cd = 0
44   LOGICAL          ::   ln_lin       !     linear  drag: Cd = Cd0_lin
45   LOGICAL          ::   ln_non_lin   ! non-linear  drag: Cd = Cd0_nl |U|
46   LOGICAL          ::   ln_loglayer  ! logarithmic drag: Cd = vkarmn/log(z/z0)
47   LOGICAL , PUBLIC ::   ln_drgimp    ! implicit top/bottom friction flag
48
49   !                                 !!* Namelist namdrg_top & _bot: TOP or BOTTOM coefficient namelist *
50   REAL(wp)         ::   rn_Cd0       !: drag coefficient                                           [ - ]
51   REAL(wp)         ::   rn_Uc0       !: characteristic velocity (linear case: tau=rho*Cd0*Uc0*u)   [m/s]
52   REAL(wp)         ::   rn_Cdmax     !: drag value maximum (ln_loglayer=T)                         [ - ]
53   REAL(wp)         ::   rn_z0        !: roughness          (ln_loglayer=T)                         [ m ]
54   REAL(wp)         ::   rn_ke0       !: background kinetic energy (non-linear case)                [m2/s2]
55   LOGICAL          ::   ln_boost     !: =T regional boost of Cd0 ; =F Cd0 horizontally uniform
56   REAL(wp)         ::   rn_boost     !: local boost factor                                         [ - ]
57
58   REAL(wp), PUBLIC ::   r_Cdmin_top, r_Cdmax_top, r_z0_top, r_ke0_top   ! set from namdrg_top namelist values
59   REAL(wp), PUBLIC ::   r_Cdmin_bot, r_Cdmax_bot, r_z0_bot, r_ke0_bot   !  -    -  namdrg_bot    -       -
60
61   INTEGER ::              ndrg       ! choice of the type of drag coefficient
62   !                                  ! associated indices:
63   INTEGER, PARAMETER ::   np_OFF      = 0   ! free-slip: drag set to zero
64   INTEGER, PARAMETER ::   np_lin      = 1   !     linear drag: Cd = Cd0_lin
65   INTEGER, PARAMETER ::   np_non_lin  = 2   ! non-linear drag: Cd = Cd0_nl |U|
66   INTEGER, PARAMETER ::   np_loglayer = 3   ! non linear drag (logarithmic formulation): Cd = vkarmn/log(z/z0)
67
68   LOGICAL , PUBLIC ::   l_zdfdrg           !: flag to update at each time step the top/bottom Cd
69   LOGICAL          ::   l_log_not_linssh   !: flag to update at each time step the position ot the velocity point
70   !
71   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::   rCd0_top, rCd0_bot   !: precomputed top/bottom drag coeff. at t-point (>0)
72   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::   rCdU_top, rCdU_bot   !: top/bottom drag coeff. at t-point (<0)  [m/s]
73
74   !! * Substitutions
75#  include "vectopt_loop_substitute.h90"
76   !!----------------------------------------------------------------------
77   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
78   !! $Id$
79   !! Software governed by the CeCILL license (see ./LICENSE)
80   !!----------------------------------------------------------------------
81CONTAINS
82
83   SUBROUTINE zdf_drg( kt, Kmm, k_mk, pCdmin, pCdmax, pz0, pke0, pCd0,   &   ! <<== in
84      &                                                     pCdU )      ! ==>> out : bottom drag [m/s]
85      !!----------------------------------------------------------------------
86      !!                   ***  ROUTINE zdf_drg  ***
87      !!
88      !! ** Purpose :   update the top/bottom drag coefficient (non-linear case only)
89      !!
90      !! ** Method  :   In non linear friction case, the drag coeficient is
91      !!              a function of the velocity:
92      !!                          Cd = cd0 * |U+Ut|   
93      !!              where U is the top or bottom velocity and
94      !!                    Ut a tidal velocity (Ut^2 = Tidal kinetic energy
95      !!                       assumed here here to be constant)
96      !!              Depending on the input variable, the top- or bottom drag is compted
97      !!
98      !! ** Action  :   p_Cd   drag coefficient at t-point
99      !!----------------------------------------------------------------------
100      INTEGER                 , INTENT(in   ) ::   kt       ! ocean time-step index
101      INTEGER                 , INTENT(in   ) ::   Kmm      ! ocean time level index
102      !                       !               !!         !==  top or bottom variables  ==!
103      INTEGER , DIMENSION(:,:), INTENT(in   ) ::   k_mk     ! wet level (1st or last)
104      REAL(wp)                , INTENT(in   ) ::   pCdmin   ! min drag value
105      REAL(wp)                , INTENT(in   ) ::   pCdmax   ! max drag value
106      REAL(wp)                , INTENT(in   ) ::   pz0      ! roughness
107      REAL(wp)                , INTENT(in   ) ::   pke0     ! background tidal KE
108      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   pCd0     ! masked precomputed part of Cd0
109      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   pCdU     ! = - Cd*|U|   (t-points) [m/s]
110      !!
111      INTEGER ::   ji, jj   ! dummy loop indices
112      INTEGER ::   imk      ! local integers
113      REAL(wp)::   zzz, zut, zvt, zcd   ! local scalars
114      !!----------------------------------------------------------------------
115      !
116      IF( l_log_not_linssh ) THEN     !==  "log layer"  ==!   compute Cd and -Cd*|U|
117         DO jj = 2, jpjm1
118            DO ji = 2, jpim1
119               imk = k_mk(ji,jj)          ! ocean bottom level at t-points
120               zut = uu(ji,jj,imk,Kmm) + uu(ji-1,jj,imk,Kmm)     ! 2 x velocity at t-point
121               zvt = vv(ji,jj,imk,Kmm) + vv(ji,jj-1,imk,Kmm)
122               zzz = 0.5_wp * e3t(ji,jj,imk,Kmm)           ! altitude below/above (top/bottom) the boundary
123               !
124!!JC: possible WAD implementation should modify line below if layers vanish
125               zcd = (  vkarmn / LOG( zzz / pz0 )  )**2
126               zcd = pCd0(ji,jj) * MIN(  MAX( pCdmin , zcd ) , pCdmax  )   ! here pCd0 = mask*boost
127               pCdU(ji,jj) = - zcd * SQRT(  0.25 * ( zut*zut + zvt*zvt ) + pke0  )
128            END DO
129         END DO
130      ELSE                                            !==  standard Cd  ==!
131         DO jj = 2, jpjm1
132            DO ji = 2, jpim1
133               imk = k_mk(ji,jj)    ! ocean bottom level at t-points
134               zut = uu(ji,jj,imk,Kmm) + uu(ji-1,jj,imk,Kmm)     ! 2 x velocity at t-point
135               zvt = vv(ji,jj,imk,Kmm) + vv(ji,jj-1,imk,Kmm)
136               !                                                           ! here pCd0 = mask*boost * drag
137               pCdU(ji,jj) = - pCd0(ji,jj) * SQRT(  0.25 * ( zut*zut + zvt*zvt ) + pke0  )
138            END DO
139         END DO
140      ENDIF
141      !
142      IF(ln_ctl)   CALL prt_ctl( tab2d_1=pCdU, clinfo1=' Cd*U ')
143      !
144   END SUBROUTINE zdf_drg
145
146
147   SUBROUTINE zdf_drg_exp( kt, Kmm, pub, pvb, pua, pva )
148      !!----------------------------------------------------------------------
149      !!                  ***  ROUTINE zdf_drg_exp  ***
150      !!
151      !! ** Purpose :   compute and add the explicit top and bottom frictions.
152      !!
153      !! ** Method  :   in explicit case,
154      !!
155      !!              NB: in implicit case the calculation is performed in dynzdf.F90
156      !!
157      !! ** Action  :   (pua,pva)   momentum trend increased by top & bottom friction trend
158      !!---------------------------------------------------------------------
159      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
160      INTEGER                         , INTENT(in   ) ::   Kmm        ! time level indices
161      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pub, pvb   ! the two components of the before velocity
162      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! the two components of the velocity tendency
163      !!
164      INTEGER  ::   ji, jj       ! dummy loop indexes
165      INTEGER  ::   ikbu, ikbv   ! local integers
166      REAL(wp) ::   zm1_2dt      ! local scalar
167      REAL(wp) ::   zCdu, zCdv   !   -      -
168      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdu, ztrdv
169      !!---------------------------------------------------------------------
170      !
171!!gm bug : time step is only rdt (not 2 rdt if euler start !)
172      zm1_2dt = - 1._wp / ( 2._wp * rdt )
173
174      IF( l_trddyn ) THEN      ! trends: store the input trends
175         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
176         ztrdu(:,:,:) = pua(:,:,:)
177         ztrdv(:,:,:) = pva(:,:,:)
178      ENDIF
179
180      DO jj = 2, jpjm1
181         DO ji = 2, jpim1
182            ikbu = mbku(ji,jj)          ! deepest wet ocean u- & v-levels
183            ikbv = mbkv(ji,jj)
184            !
185            ! Apply stability criteria on absolute value  : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt)
186            zCdu = 0.5*( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) / e3u(ji,jj,ikbu,Kmm)
187            zCdv = 0.5*( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) / e3v(ji,jj,ikbv,Kmm)
188            !
189            pua(ji,jj,ikbu) = pua(ji,jj,ikbu) + MAX(  zCdu , zm1_2dt  ) * pub(ji,jj,ikbu)
190            pva(ji,jj,ikbv) = pva(ji,jj,ikbv) + MAX(  zCdv , zm1_2dt  ) * pvb(ji,jj,ikbv)
191         END DO
192      END DO
193      !
194      IF( ln_isfcav ) THEN        ! ocean cavities
195         DO jj = 2, jpjm1
196            DO ji = 2, jpim1
197               ikbu = miku(ji,jj)          ! first wet ocean u- & v-levels
198               ikbv = mikv(ji,jj)
199               !
200               ! Apply stability criteria on absolute value  : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt)
201               zCdu = 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) / e3u(ji,jj,ikbu,Kmm)    ! NB: Cdtop masked
202               zCdv = 0.5*( rCdU_top(ji,jj+1)+rCdU_top(ji,jj) ) / e3v(ji,jj,ikbv,Kmm)
203               !
204               pua(ji,jj,ikbu) = pua(ji,jj,ikbu) + MAX(  zCdu , zm1_2dt  ) * pub(ji,jj,ikbu)
205               pva(ji,jj,ikbv) = pva(ji,jj,ikbv) + MAX(  zCdv , zm1_2dt  ) * pvb(ji,jj,ikbv)
206           END DO
207         END DO
208      ENDIF
209      !
210      IF( l_trddyn ) THEN      ! trends: send trends to trddyn for further diagnostics
211         ztrdu(:,:,:) = pua(:,:,:) - ztrdu(:,:,:)
212         ztrdv(:,:,:) = pva(:,:,:) - ztrdv(:,:,:)
213         CALL trd_dyn( ztrdu(:,:,:), ztrdv(:,:,:), jpdyn_bfr, kt, Kmm )
214         DEALLOCATE( ztrdu, ztrdv )
215      ENDIF
216      !                                          ! print mean trends (used for debugging)
217      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pua, clinfo1=' bfr  - Ua: ', mask1=umask,               &
218         &                       tab3d_2=pva, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
219      !
220   END SUBROUTINE zdf_drg_exp
221
222
223   SUBROUTINE zdf_drg_init
224      !!----------------------------------------------------------------------
225      !!                  ***  ROUTINE zdf_brg_init  ***
226      !!
227      !! ** Purpose :   Initialization of the bottom friction
228      !!
229      !! ** Method  :   Read the namdrg namelist and check their consistency
230      !!                called at the first timestep (nit000)
231      !!----------------------------------------------------------------------
232      INTEGER   ::   ji, jj      ! dummy loop indexes
233      INTEGER   ::   ios, ioptio   ! local integers
234      !!
235      NAMELIST/namdrg/ ln_OFF, ln_lin, ln_non_lin, ln_loglayer, ln_drgimp
236      !!----------------------------------------------------------------------
237      !
238      !                     !==  drag nature  ==!
239      !
240      READ  ( numnam_ref, namdrg, IOSTAT = ios, ERR = 901)
241901   IF( ios /= 0 )   CALL ctl_nam( ios , 'namdrg in reference namelist' )
242      READ  ( numnam_cfg, namdrg, IOSTAT = ios, ERR = 902 )
243902   IF( ios >  0 )   CALL ctl_nam( ios , 'namdrg in configuration namelist' )
244      IF(lwm) WRITE ( numond, namdrg )
245      !
246      IF(lwp) THEN
247         WRITE(numout,*)
248         WRITE(numout,*) 'zdf_drg_init : top and/or bottom drag setting'
249         WRITE(numout,*) '~~~~~~~~~~~~'
250         WRITE(numout,*) '   Namelist namdrg : top/bottom friction choices'
251         WRITE(numout,*) '      free-slip       : Cd = 0                  ln_OFF      = ', ln_OFF 
252         WRITE(numout,*) '      linear  drag    : Cd = Cd0                ln_lin      = ', ln_lin
253         WRITE(numout,*) '      non-linear  drag: Cd = Cd0_nl |U|         ln_non_lin  = ', ln_non_lin
254         WRITE(numout,*) '      logarithmic drag: Cd = vkarmn/log(z/z0)   ln_loglayer = ', ln_loglayer
255         WRITE(numout,*) '      implicit friction                         ln_drgimp   = ', ln_drgimp
256      ENDIF
257      !
258      ioptio = 0                       ! set ndrg and control check
259      IF( ln_OFF      ) THEN   ;   ndrg = np_OFF        ;   ioptio = ioptio + 1   ;   ENDIF
260      IF( ln_lin      ) THEN   ;   ndrg = np_lin        ;   ioptio = ioptio + 1   ;   ENDIF
261      IF( ln_non_lin  ) THEN   ;   ndrg = np_non_lin    ;   ioptio = ioptio + 1   ;   ENDIF
262      IF( ln_loglayer ) THEN   ;   ndrg = np_loglayer   ;   ioptio = ioptio + 1   ;   ENDIF
263      !
264      IF( ioptio /= 1 )   CALL ctl_stop( 'zdf_drg_init: Choose ONE type of drag coef in namdrg' )
265      !
266      !
267      !                     !==  BOTTOM drag setting  ==!   (applied at seafloor)
268      !
269      ALLOCATE( rCd0_bot(jpi,jpj), rCdU_bot(jpi,jpj) )
270      CALL drg_init( 'BOTTOM'   , mbkt       ,                                         &   ! <== in
271         &           r_Cdmin_bot, r_Cdmax_bot, r_z0_bot, r_ke0_bot, rCd0_bot, rCdU_bot )   ! ==> out
272
273      !
274      !                     !==  TOP drag setting  ==!   (applied at the top of ocean cavities)
275      !
276      IF( ln_isfcav ) THEN              ! Ocean cavities: top friction setting
277         ALLOCATE( rCd0_top(jpi,jpj), rCdU_top(jpi,jpj) )
278         CALL drg_init( 'TOP   '   , mikt       ,                                         &   ! <== in
279            &           r_Cdmin_top, r_Cdmax_top, r_z0_top, r_ke0_top, rCd0_top, rCdU_top )   ! ==> out
280      ENDIF
281      !
282   END SUBROUTINE zdf_drg_init
283
284
285   SUBROUTINE drg_init( cd_topbot, k_mk,  &
286      &                 pCdmin, pCdmax, pz0, pke0, pCd0, pCdU ) 
287      !!----------------------------------------------------------------------
288      !!                  ***  ROUTINE drg_init  ***
289      !!
290      !! ** Purpose :   Initialization of the top/bottom friction CdO and Cd
291      !!              from namelist parameters
292      !!----------------------------------------------------------------------
293      CHARACTER(len=6)        , INTENT(in   ) ::   cd_topbot       ! top/ bot indicator
294      INTEGER , DIMENSION(:,:), INTENT(in   ) ::   k_mk            ! 1st/last  wet level
295      REAL(wp)                , INTENT(  out) ::   pCdmin, pCdmax  ! min and max drag coef. [-]
296      REAL(wp)                , INTENT(  out) ::   pz0             ! roughness              [m]
297      REAL(wp)                , INTENT(  out) ::   pke0            ! background KE          [m2/s2]
298      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   pCd0            ! masked precomputed part of the non-linear drag coefficient
299      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   pCdU            ! minus linear drag*|U| at t-points  [m/s]
300      !!
301      CHARACTER(len=40) ::   cl_namdrg, cl_file, cl_varname, cl_namref, cl_namcfg  ! local names
302      INTEGER ::   ji, jj              ! dummy loop indexes
303      LOGICAL ::   ll_top, ll_bot      ! local logical
304      INTEGER ::   ios, inum, imk      ! local integers
305      REAL(wp)::   zmsk, zzz, zcd      ! local scalars
306      REAL(wp), DIMENSION(jpi,jpj) ::   zmsk_boost   ! 2D workspace
307      !!
308      NAMELIST/namdrg_top/ rn_Cd0, rn_Uc0, rn_Cdmax, rn_ke0, rn_z0, ln_boost, rn_boost
309      NAMELIST/namdrg_bot/ rn_Cd0, rn_Uc0, rn_Cdmax, rn_ke0, rn_z0, ln_boost, rn_boost
310      !!----------------------------------------------------------------------
311      !
312      !                          !==  set TOP / BOTTOM specificities  ==!
313      ll_top = .FALSE.
314      ll_bot = .FALSE.
315      !
316      SELECT CASE (cd_topbot)
317      CASE( 'TOP   ' )
318         ll_top = .TRUE.
319         cl_namdrg  = 'namdrg_top'
320         cl_namref  = 'namdrg_top in reference     namelist'
321         cl_namcfg  = 'namdrg_top in configuration namelist'
322         cl_file    = 'tfr_coef.nc'
323         cl_varname = 'tfr_coef'
324      CASE( 'BOTTOM' )
325         ll_bot = .TRUE.
326         cl_namdrg  = 'namdrg_bot'
327         cl_namref  = 'namdrg_bot  in reference     namelist'
328         cl_namcfg  = 'namdrg_bot  in configuration namelist'
329         cl_file    = 'bfr_coef.nc'
330         cl_varname = 'bfr_coef'
331      CASE DEFAULT
332         CALL ctl_stop( 'drg_init: bad value for cd_topbot ' )
333      END SELECT
334      !
335      !                          !==  read namlist  ==!
336      !
337      IF(ll_top)   READ  ( numnam_ref, namdrg_top, IOSTAT = ios, ERR = 901)
338      IF(ll_bot)   READ  ( numnam_ref, namdrg_bot, IOSTAT = ios, ERR = 901)
339901   IF( ios /= 0 )   CALL ctl_nam( ios , TRIM(cl_namref) )
340      IF(ll_top)   READ  ( numnam_cfg, namdrg_top, IOSTAT = ios, ERR = 902 )
341      IF(ll_bot)   READ  ( numnam_cfg, namdrg_bot, IOSTAT = ios, ERR = 902 )
342902   IF( ios >  0 )   CALL ctl_nam( ios , TRIM(cl_namcfg) )
343      IF(lwm .AND. ll_top)   WRITE ( numond, namdrg_top )
344      IF(lwm .AND. ll_bot)   WRITE ( numond, namdrg_bot )
345      !
346      IF(lwp) THEN
347         WRITE(numout,*)
348         WRITE(numout,*) '   Namelist ',TRIM(cl_namdrg),' : set ',TRIM(cd_topbot),' friction parameters'
349         WRITE(numout,*) '      drag coefficient                        rn_Cd0   = ', rn_Cd0
350         WRITE(numout,*) '      characteristic velocity (linear case)   rn_Uc0   = ', rn_Uc0, ' m/s'
351         WRITE(numout,*) '      non-linear drag maximum                 rn_Cdmax = ', rn_Cdmax
352         WRITE(numout,*) '      background kinetic energy  (n-l case)   rn_ke0   = ', rn_ke0
353         WRITE(numout,*) '      bottom roughness           (n-l case)   rn_z0    = ', rn_z0
354         WRITE(numout,*) '      set a regional boost of Cd0             ln_boost = ', ln_boost
355         WRITE(numout,*) '         associated boost factor              rn_boost = ', rn_boost
356      ENDIF
357      !
358      !                          !==  return some namelist parametres  ==!   (used in non_lin and loglayer cases)
359      pCdmin = rn_Cd0
360      pCdmax = rn_Cdmax
361      pz0    = rn_z0
362      pke0   = rn_ke0
363      !
364      !                          !==  mask * boost factor  ==!
365      !
366      IF( ln_boost ) THEN           !* regional boost:   boost factor = 1 + regional boost
367         IF(lwp) WRITE(numout,*)
368         IF(lwp) WRITE(numout,*) '   ==>>>   use a regional boost read in ', TRIM(cl_file), ' file'
369         IF(lwp) WRITE(numout,*) '           using enhancement factor of ', rn_boost
370         ! cl_varname is a coefficient in [0,1] giving where to apply the regional boost
371         CALL iom_open ( TRIM(cl_file), inum )
372         CALL iom_get  ( inum, jpdom_data, TRIM(cl_varname), zmsk_boost, 1 )
373         CALL iom_close( inum)
374         zmsk_boost(:,:) = 1._wp + rn_boost * zmsk_boost(:,:)
375         !
376      ELSE                          !* no boost:   boost factor = 1
377         zmsk_boost(:,:) = 1._wp
378      ENDIF
379      !                             !* mask outside ocean cavities area (top) or land area (bot)
380      IF(ll_top)   zmsk_boost(:,:) = zmsk_boost(:,:) * ssmask(:,:) * (1. - tmask(:,:,1) )  ! none zero in ocean cavities only
381      IF(ll_bot)   zmsk_boost(:,:) = zmsk_boost(:,:) * ssmask(:,:)                         ! x seafloor mask
382      !
383      !
384      SELECT CASE( ndrg )
385      !
386      CASE( np_OFF  )            !==  No top/bottom friction  ==!   (pCdU = 0)
387         IF(lwp) WRITE(numout,*)
388         IF(lwp) WRITE(numout,*) '   ==>>>   ',TRIM(cd_topbot),' free-slip, friction set to zero'
389         !
390         l_zdfdrg = .FALSE.         ! no time variation of the drag: set it one for all
391         !
392         pCdU(:,:) = 0._wp
393         pCd0(:,:) = 0._wp
394         !
395      CASE( np_lin )             !==  linear friction  ==!   (pCdU = Cd0 * Uc0)
396         IF(lwp) WRITE(numout,*)
397         IF(lwp) WRITE(numout,*) '   ==>>>   linear ',TRIM(cd_topbot),' friction (constant coef = Cd0*Uc0 = ', rn_Cd0*rn_Uc0, ')'
398         !
399         l_zdfdrg = .FALSE.         ! no time variation of the Cd*|U| : set it one for all
400         !                     
401         pCd0(:,:) = rn_Cd0 * zmsk_boost(:,:)  !* constant in time drag coefficient (= mask (and boost) Cd0)
402         pCdU(:,:) = - pCd0(:,:) * rn_Uc0      !  using a constant velocity
403         !
404      CASE( np_non_lin )         !== non-linear friction  ==!   (pCd0 = Cd0 )
405         IF(lwp) WRITE(numout,*)
406         IF(lwp) WRITE(numout,*) '   ==>>>   quadratic ',TRIM(cd_topbot),' friction (propotional to module of the velocity)'
407         IF(lwp) WRITE(numout,*) '   with    a drag coefficient Cd0 = ', rn_Cd0, ', and'
408         IF(lwp) WRITE(numout,*) '           a background velocity module of (rn_ke0)^1/2 = ', SQRT(rn_ke0), 'm/s)'
409         !
410         l_zdfdrg = .TRUE.          !* Cd*|U| updated at each time-step (it depends on ocean velocity)
411         !
412         pCd0(:,:) = rn_Cd0 * zmsk_boost(:,:)  !* constant in time proportionality coefficient (= mask (and boost) Cd0)
413         pCdU(:,:) = 0._wp                     ! 
414         !
415      CASE( np_loglayer )       !== logarithmic layer formulation of friction  ==!   (CdU = (vkarman log(z/z0))^2 |U| )
416         IF(lwp) WRITE(numout,*)
417         IF(lwp) WRITE(numout,*) '   ==>>>   quadratic ',TRIM(cd_topbot),' drag (propotional to module of the velocity)'
418         IF(lwp) WRITE(numout,*) '   with   a logarithmic Cd0 formulation Cd0 = ( vkarman log(z/z0) )^2 ,'
419         IF(lwp) WRITE(numout,*) '          a background velocity module of (rn_ke0)^1/2 = ', SQRT(pke0), 'm/s), '
420         IF(lwp) WRITE(numout,*) '          a logarithmic formulation: a roughness of ', pz0, ' meters,   and '
421         IF(lwp) WRITE(numout,*) '          a proportionality factor bounded by min/max values of ', pCdmin, pCdmax
422         !
423         l_zdfdrg = .TRUE.          !* Cd*|U| updated at each time-step (it depends on ocean velocity)
424         !
425         IF( ln_linssh ) THEN       !* pCd0 = (v log(z/z0))^2   as velocity points have a fixed z position
426            IF(lwp) WRITE(numout,*)
427            IF(lwp) WRITE(numout,*) '   N.B.   linear free surface case, Cd0 computed one for all'
428            !
429            l_log_not_linssh = .FALSE.    !- don't update Cd at each time step
430            !
431            DO jj = 1, jpj                   ! pCd0 = mask (and boosted) logarithmic drag coef.
432               DO ji = 1, jpi
433                  zzz =  0.5_wp * e3t_0(ji,jj,k_mk(ji,jj))
434                  zcd = (  vkarmn / LOG( zzz / rn_z0 )  )**2
435                  pCd0(ji,jj) = zmsk_boost(ji,jj) * MIN(  MAX( rn_Cd0 , zcd ) , rn_Cdmax  )  ! rn_Cd0 < Cd0 < rn_Cdmax
436               END DO
437            END DO
438         ELSE                       !* Cd updated at each time-step ==> pCd0 = mask * boost
439            IF(lwp) WRITE(numout,*)
440            IF(lwp) WRITE(numout,*) '   N.B.   non-linear free surface case, Cd0 updated at each time-step '
441            !
442            l_log_not_linssh = .TRUE.     ! compute the drag coef. at each time-step
443            !
444            pCd0(:,:) = zmsk_boost(:,:)
445         ENDIF
446         pCdU(:,:) = 0._wp          ! initialisation to zero (will be updated at each time step)
447         !
448      CASE DEFAULT
449         CALL ctl_stop( 'drg_init: bad flag value for ndrg ' )
450      END SELECT
451      !
452   END SUBROUTINE drg_init
453
454   !!======================================================================
455END MODULE zdfdrg
Note: See TracBrowser for help on using the repository browser.