source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P4Z/p4zmicro.F90 @ 12236

Last change on this file since 12236 was 12236, checked in by acc, 11 months ago

Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/fix_sn_cfctl_ticket2328. Fully SETTE tested

  • Property svn:keywords set to Id
File size: 14.8 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_micro      : Compute the sources/sinks for microzooplankton
11   !!   p4z_micro_init : Initialize and read the appropriate namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zlim          ! Co-limitations
17   USE p4zprod         ! production
18   USE iom             ! I/O manager
19   USE prtctl_trc      ! print control for debugging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_micro         ! called in p4zbio.F90
25   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
26
27   REAL(wp), PUBLIC ::   part        !: part of calcite not dissolved in microzoo guts
28   REAL(wp), PUBLIC ::   xprefc      !: microzoo preference for POC
29   REAL(wp), PUBLIC ::   xprefn      !: microzoo preference for nanophyto
30   REAL(wp), PUBLIC ::   xprefd      !: microzoo preference for diatoms
31   REAL(wp), PUBLIC ::   xthreshdia  !: diatoms feeding threshold for microzooplankton
32   REAL(wp), PUBLIC ::   xthreshphy  !: nanophyto threshold for microzooplankton
33   REAL(wp), PUBLIC ::   xthreshpoc  !: poc threshold for microzooplankton
34   REAL(wp), PUBLIC ::   xthresh     !: feeding threshold for microzooplankton
35   REAL(wp), PUBLIC ::   resrat      !: exsudation rate of microzooplankton
36   REAL(wp), PUBLIC ::   mzrat       !: microzooplankton mortality rate
37   REAL(wp), PUBLIC ::   grazrat     !: maximal microzoo grazing rate
38   REAL(wp), PUBLIC ::   xkgraz      !: Half-saturation constant of assimilation
39   REAL(wp), PUBLIC ::   unass       !: Non-assimilated part of food
40   REAL(wp), PUBLIC ::   sigma1      !: Fraction of microzoo excretion as DOM
41   REAL(wp), PUBLIC ::   epsher      !: growth efficiency for grazing 1
42   REAL(wp), PUBLIC ::   epshermin   !: minimum growth efficiency for grazing 1
43
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p4z_micro( kt, knt, Kbb, Krhs )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_micro  ***
54      !!
55      !! ** Purpose :   Compute the sources/sinks for microzooplankton
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt    ! ocean time step
60      INTEGER, INTENT(in) ::   knt   ! ???
61      INTEGER, INTENT(in) ::   Kbb, Krhs  ! time level indices
62      !
63      INTEGER  :: ji, jj, jk
64      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
65      REAL(wp) :: zgraze  , zdenom, zdenom2
66      REAL(wp) :: zfact   , zfood, zfoodlim, zbeta
67      REAL(wp) :: zepsherf, zepshert, zepsherv, zgrarsig, zgraztotc, zgraztotn, zgraztotf
68      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
69      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
70      REAL(wp) :: zgrazp, zgrazm, zgrazsd
71      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
72      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo
73      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zw3d, zzligprod
74      CHARACTER (len=25) :: charout
75      !!---------------------------------------------------------------------
76      !
77      IF( ln_timing )   CALL timing_start('p4z_micro')
78      !
79      IF (ln_ligand) THEN
80         ALLOCATE( zzligprod(jpi,jpj,jpk) )
81         zzligprod(:,:,:) = 0._wp
82      ENDIF
83      !
84      DO jk = 1, jpkm1
85         DO jj = 1, jpj
86            DO ji = 1, jpi
87               zcompaz = MAX( ( tr(ji,jj,jk,jpzoo,Kbb) - 1.e-9 ), 0.e0 )
88               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
89
90               !  Respiration rates of both zooplankton
91               !  -------------------------------------
92               zrespz = resrat * zfact * tr(ji,jj,jk,jpzoo,Kbb) / ( xkmort + tr(ji,jj,jk,jpzoo,Kbb) )  &
93                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
94
95               !  Zooplankton mortality. A square function has been selected with
96               !  no real reason except that it seems to be more stable and may mimic predation.
97               !  ---------------------------------------------------------------
98               ztortz = mzrat * 1.e6 * zfact * tr(ji,jj,jk,jpzoo,Kbb) * (1. - nitrfac(ji,jj,jk))
99
100               zcompadi  = MIN( MAX( ( tr(ji,jj,jk,jpdia,Kbb) - xthreshdia ), 0.e0 ), xsizedia )
101               zcompaph  = MAX( ( tr(ji,jj,jk,jpphy,Kbb) - xthreshphy ), 0.e0 )
102               zcompapoc = MAX( ( tr(ji,jj,jk,jppoc,Kbb) - xthreshpoc ), 0.e0 )
103               
104               !     Microzooplankton grazing
105               !     ------------------------
106               zfood     = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi
107               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
108               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
109               zdenom2   = zdenom / ( zfood + rtrn )
110               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpzoo,Kbb) * (1. - nitrfac(ji,jj,jk))
111
112               zgrazp    = zgraze  * xprefn * zcompaph  * zdenom2 
113               zgrazm    = zgraze  * xprefc * zcompapoc * zdenom2 
114               zgrazsd   = zgraze  * xprefd * zcompadi  * zdenom2 
115
116               zgrazpf   = zgrazp  * tr(ji,jj,jk,jpnfe,Kbb) / (tr(ji,jj,jk,jpphy,Kbb) + rtrn)
117               zgrazmf   = zgrazm  * tr(ji,jj,jk,jpsfe,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + rtrn)
118               zgrazsf   = zgrazsd * tr(ji,jj,jk,jpdfe,Kbb) / (tr(ji,jj,jk,jpdia,Kbb) + rtrn)
119               !
120               zgraztotc = zgrazp  + zgrazm  + zgrazsd 
121               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
122               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
123
124               ! Grazing by microzooplankton
125               zgrazing(ji,jj,jk) = zgraztotc
126
127               !    Various remineralization and excretion terms
128               !    --------------------------------------------
129               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztotc + rtrn )
130               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztotc + rtrn )
131               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
132               zbeta     = MAX(0., (epsher - epshermin) )
133               zepsherf  = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
134               zepsherv  = zepsherf * zepshert 
135
136               zgrafer   = zgraztotc * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
137               zgrarem   = zgraztotc * ( 1. - zepsherv - unass )
138               zgrapoc   = zgraztotc * unass
139
140               !  Update of the TRA arrays
141               !  ------------------------
142               zgrarsig  = zgrarem * sigma1
143               tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zgrarsig
144               tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zgrarsig
145               tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zgrarem - zgrarsig
146               !
147               IF( ln_ligand ) THEN
148                  tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + (zgrarem - zgrarsig) * ldocz
149                  zzligprod(ji,jj,jk) = (zgrarem - zgrarsig) * ldocz
150               ENDIF
151               !
152               tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2ut * zgrarsig
153               tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + zgrafer
154               zfezoo(ji,jj,jk)    = zgrafer
155               tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zgrapoc
156               prodpoc(ji,jj,jk)   = prodpoc(ji,jj,jk) + zgrapoc
157               tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zgraztotf * unass
158               tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrarsig
159               tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zgrarsig
160               !   Update the arrays TRA which contain the biological sources and sinks
161               !   --------------------------------------------------------------------
162               zmortz = ztortz + zrespz
163               tr(ji,jj,jk,jpzoo,Krhs) = tr(ji,jj,jk,jpzoo,Krhs) - zmortz + zepsherv * zgraztotc 
164               tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) - zgrazp
165               tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) - zgrazsd
166               tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) - zgrazp  * tr(ji,jj,jk,jpnch,Kbb)/(tr(ji,jj,jk,jpphy,Kbb)+rtrn)
167               tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) - zgrazsd * tr(ji,jj,jk,jpdch,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn)
168               tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) - zgrazsd * tr(ji,jj,jk,jpdsi,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn)
169               tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) + zgrazsd * tr(ji,jj,jk,jpdsi,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn)
170               tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) - zgrazpf
171               tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) - zgrazsf
172               tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zmortz - zgrazm
173               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
174               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm
175               tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + ferat3 * zmortz - zgrazmf
176               !
177               ! calcite production
178               zprcaca = xfracal(ji,jj,jk) * zgrazp
179               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
180               !
181               zprcaca = part * zprcaca
182               tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) - zprcaca
183               tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) - 2. * zprcaca
184               tr(ji,jj,jk,jpcal,Krhs) = tr(ji,jj,jk,jpcal,Krhs) + zprcaca
185            END DO
186         END DO
187      END DO
188      !
189      IF( lk_iomput ) THEN
190         IF( knt == nrdttrc ) THEN
191           ALLOCATE( zw3d(jpi,jpj,jpk) )
192           IF( iom_use( "GRAZ1" ) ) THEN
193              zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
194              CALL iom_put( "GRAZ1", zw3d )
195           ENDIF
196           IF( iom_use( "FEZOO" ) ) THEN
197              zw3d(:,:,:) = zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
198              CALL iom_put( "FEZOO", zw3d )
199           ENDIF
200           IF( iom_use( "LPRODZ" ) .AND. ln_ligand )  THEN
201              zw3d(:,:,:) = zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
202              CALL iom_put( "LPRODZ"  , zw3d )
203           ENDIF
204           DEALLOCATE( zw3d )
205         ENDIF
206      ENDIF
207      !
208      IF (ln_ligand)  DEALLOCATE( zzligprod )
209      !
210      IF(sn_cfctl%l_prttrc) THEN      ! print mean trends (used for debugging)
211         WRITE(charout, FMT="('micro')")
212         CALL prt_ctl_trc_info(charout)
213         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
214      ENDIF
215      !
216      IF( ln_timing )   CALL timing_stop('p4z_micro')
217      !
218   END SUBROUTINE p4z_micro
219
220
221   SUBROUTINE p4z_micro_init
222      !!----------------------------------------------------------------------
223      !!                  ***  ROUTINE p4z_micro_init  ***
224      !!
225      !! ** Purpose :   Initialization of microzooplankton parameters
226      !!
227      !! ** Method  :   Read the nampiszoo namelist and check the parameters
228      !!                called at the first timestep (nittrc000)
229      !!
230      !! ** input   :   Namelist nampiszoo
231      !!
232      !!----------------------------------------------------------------------
233      INTEGER ::   ios   ! Local integer
234      !
235      NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xprefn, xprefc, &
236         &                xprefd,  xthreshdia,  xthreshphy,  xthreshpoc, &
237         &                xthresh, xkgraz, epsher, epshermin, sigma1, unass
238      !!----------------------------------------------------------------------
239      !
240      IF(lwp) THEN
241         WRITE(numout,*) 
242         WRITE(numout,*) 'p4z_micro_init : Initialization of microzooplankton parameters'
243         WRITE(numout,*) '~~~~~~~~~~~~~~'
244      ENDIF
245      !
246      READ  ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901)
247901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zzoo in reference namelist' )
248      READ  ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 )
249902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist' )
250      IF(lwm) WRITE( numonp, namp4zzoo )
251      !
252      IF(lwp) THEN                         ! control print
253         WRITE(numout,*) '   Namelist : namp4zzoo'
254         WRITE(numout,*) '      part of calcite not dissolved in microzoo guts  part        =', part
255         WRITE(numout,*) '      microzoo preference for POC                     xprefc      =', xprefc
256         WRITE(numout,*) '      microzoo preference for nano                    xprefn      =', xprefn
257         WRITE(numout,*) '      microzoo preference for diatoms                 xprefd      =', xprefd
258         WRITE(numout,*) '      diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
259         WRITE(numout,*) '      nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
260         WRITE(numout,*) '      poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
261         WRITE(numout,*) '      feeding threshold for microzooplankton          xthresh     =', xthresh
262         WRITE(numout,*) '      exsudation rate of microzooplankton             resrat      =', resrat
263         WRITE(numout,*) '      microzooplankton mortality rate                 mzrat       =', mzrat
264         WRITE(numout,*) '      maximal microzoo grazing rate                   grazrat     =', grazrat
265         WRITE(numout,*) '      non assimilated fraction of P by microzoo       unass       =', unass
266         WRITE(numout,*) '      Efficicency of microzoo growth                  epsher      =', epsher
267         WRITE(numout,*) '      Minimum efficicency of microzoo growth          epshermin   =', epshermin
268         WRITE(numout,*) '      Fraction of microzoo excretion as DOM           sigma1      =', sigma1
269         WRITE(numout,*) '      half sturation constant for grazing 1           xkgraz      =', xkgraz
270      ENDIF
271      !
272   END SUBROUTINE p4z_micro_init
273
274   !!======================================================================
275END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.