New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P4Z/p4zprod.F90 @ 12258

Last change on this file since 12258 was 12258, checked in by cetlod, 4 years ago

dev_r11943_MERGE_2019 : : Cleaning PISCES diagnostics output ; fully sette tested. run.stat and tracer.stat are identical to the ones of dev_r11943_MERGE_2019
  • Property svn:keywords set to Id
File size: 23.3 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10   !!   p4z_prod       : Compute the growth Rate of the two phytoplanktons groups
11   !!   p4z_prod_init  : Initialization of the parameters for growth
12   !!   p4z_prod_alloc : Allocate variables for growth
13   !!----------------------------------------------------------------------
14   USE oce_trc         ! shared variables between ocean and passive tracers
15   USE trc             ! passive tracers common variables
16   USE sms_pisces      ! PISCES Source Minus Sink variables
17   USE p4zlim          ! Co-limitations of differents nutrients
18   USE prtctl_trc      ! print control for debugging
19   USE iom             ! I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_prod         ! called in p4zbio.F90
25   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
26   PUBLIC   p4z_prod_alloc
27
28   REAL(wp), PUBLIC ::   pislopen     !:
29   REAL(wp), PUBLIC ::   pisloped     !:
30   REAL(wp), PUBLIC ::   xadap        !:
31   REAL(wp), PUBLIC ::   excretn      !:
32   REAL(wp), PUBLIC ::   excretd      !:
33   REAL(wp), PUBLIC ::   bresp        !:
34   REAL(wp), PUBLIC ::   chlcnm       !:
35   REAL(wp), PUBLIC ::   chlcdm       !:
36   REAL(wp), PUBLIC ::   chlcmin      !:
37   REAL(wp), PUBLIC ::   fecnm        !:
38   REAL(wp), PUBLIC ::   fecdm        !:
39   REAL(wp), PUBLIC ::   grosip       !:
40
41   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
43   
44   REAL(wp) ::   r1_rday    ! 1 / rday
45   REAL(wp) ::   texcretn   ! 1 - excretn
46   REAL(wp) ::   texcretd   ! 1 - excretd       
47
48   !!----------------------------------------------------------------------
49   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
50   !! $Id$
51   !! Software governed by the CeCILL license (see ./LICENSE)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE p4z_prod( kt , knt, Kbb, Kmm, Krhs )
56      !!---------------------------------------------------------------------
57      !!                     ***  ROUTINE p4z_prod  ***
58      !!
59      !! ** Purpose :   Compute the phytoplankton production depending on
60      !!              light, temperature and nutrient availability
61      !!
62      !! ** Method  : - ???
63      !!---------------------------------------------------------------------
64      INTEGER, INTENT(in) ::   kt, knt   !
65      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
66      !
67      INTEGER  ::   ji, jj, jk
68      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
69      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
70      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
71      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
72      REAL(wp) ::   zmxltst, zmxlday
73      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n
74      REAL(wp) ::   zfact
75      CHARACTER (len=25) :: charout
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zw2d
77      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
78      REAL(wp), DIMENSION(jpi,jpj    ) :: zstrn, zmixnano, zmixdiat
79      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprmaxn,zprmaxd
80      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadd, zysopt 
81      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprdia, zprbio, zprdch, zprnch   
82      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcad, zprofed, zprofen
83      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewd
84      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl
85      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpligprod1, zpligprod2
86      !!---------------------------------------------------------------------
87      !
88      IF( ln_timing )   CALL timing_start('p4z_prod')
89      !
90      !  Allocate temporary workspace
91      !
92      zprorcan  (:,:,jpk) = 0._wp ; zprorcad  (:,:,jpk) = 0._wp ; zprofed (:,:,jpk) = 0._wp
93      zprofen   (:,:,jpk) = 0._wp ; zysopt    (:,:,jpk) = 0._wp
94      zpronewn  (:,:,jpk) = 0._wp ; zpronewd  (:,:,jpk) = 0._wp ; zprdia  (:,:,jpk) = 0._wp
95      zprbio    (:,:,jpk) = 0._wp ; zprdch    (:,:,jpk) = 0._wp ; zprnch  (:,:,jpk) = 0._wp 
96      zmxl_fac  (:,:,jpk) = 0._wp ; zmxl_chl  (:,:,jpk) = 0._wp 
97      zpligprod1(:,:,jpk) = 0._wp ; zpligprod2(:,:,jpk) = 0._wp 
98
99      ! Computation of the optimal production
100      zprmaxn(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:)
101      zprmaxd(:,:,:) = zprmaxn(:,:,:)
102
103      ! compute the day length depending on latitude and the day
104      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
105      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
106
107      ! day length in hours
108      zstrn(:,:) = 0.
109      DO jj = 1, jpj
110         DO ji = 1, jpi
111            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
112            zargu = MAX( -1., MIN(  1., zargu ) )
113            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
114         END DO
115      END DO
116
117      ! Impact of the day duration and light intermittency on phytoplankton growth
118      DO jk = 1, jpkm1
119         DO jj = 1 ,jpj
120            DO ji = 1, jpi
121               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
122                  zval = MAX( 1., zstrn(ji,jj) )
123                  IF( gdept(ji,jj,jk,Kmm) <= hmld(ji,jj) ) THEN
124                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
125                  ENDIF
126                  zmxl_chl(ji,jj,jk) = zval / 24.
127                  zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
128               ENDIF
129            END DO
130         END DO
131      END DO
132
133      zprbio(:,:,:) = zprmaxn(:,:,:) * zmxl_fac(:,:,:)
134      zprdia(:,:,:) = zprmaxd(:,:,:) * zmxl_fac(:,:,:)
135
136      ! Maximum light intensity
137      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
138
139      ! Computation of the P-I slope for nanos and diatoms
140      DO jk = 1, jpkm1
141         DO jj = 1, jpj
142            DO ji = 1, jpi
143               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
144                  ztn         = MAX( 0., ts(ji,jj,jk,jp_tem,Kmm) - 15. )
145                  zadap       = xadap * ztn / ( 2.+ ztn )
146                  zconctemp   = MAX( 0.e0 , tr(ji,jj,jk,jpdia,Kbb) - xsizedia )
147                  zconctemp2  = tr(ji,jj,jk,jpdia,Kbb) - zconctemp
148                  !
149                  zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
150                  &                   * tr(ji,jj,jk,jpnch,Kbb) /( tr(ji,jj,jk,jpphy,Kbb) * 12. + rtrn)
151                  !
152                  zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )   &
153                  &                   * tr(ji,jj,jk,jpdch,Kbb) /( tr(ji,jj,jk,jpdia,Kbb) * 12. + rtrn)
154               ENDIF
155            END DO
156         END DO
157      END DO
158
159      DO jk = 1, jpkm1
160         DO jj = 1, jpj
161            DO ji = 1, jpi
162               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
163                   ! Computation of production function for Carbon
164                   !  ---------------------------------------------
165                   zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
166                   &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
167                   zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
168                   &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
169                   zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
170                   zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
171                   !  Computation of production function for Chlorophyll
172                   !--------------------------------------------------
173                   zpislopen = zpislopeadn(ji,jj,jk) / ( zprmaxn(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
174                   zpisloped = zpislopeadd(ji,jj,jk) / ( zprmaxd(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
175                   zprnch(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) ) )
176                   zprdch(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) ) )
177               ENDIF
178            END DO
179         END DO
180      END DO
181
182      !  Computation of a proxy of the N/C ratio
183      !  ---------------------------------------
184      DO jk = 1, jpkm1
185         DO jj = 1, jpj
186            DO ji = 1, jpi
187                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
188                &      * zprmaxn(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
189                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
190                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
191                &      * zprmaxd(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
192                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
193            END DO
194         END DO
195      END DO
196
197
198      DO jk = 1, jpkm1
199         DO jj = 1, jpj
200            DO ji = 1, jpi
201
202                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
203                   !    Si/C of diatoms
204                   !    ------------------------
205                   !    Si/C increases with iron stress and silicate availability
206                   !    Si/C is arbitrariliy increased for very high Si concentrations
207                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
208                  zlim  = tr(ji,jj,jk,jpsil,Kbb) / ( tr(ji,jj,jk,jpsil,Kbb) + xksi1 )
209                  zsilim = MIN( zprdia(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
210                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
211                  zsiborn = tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb)
212                  IF (gphit(ji,jj) < -30 ) THEN
213                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
214                  ELSE
215                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
216                  ENDIF
217                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
218              ENDIF
219            END DO
220         END DO
221      END DO
222
223      !  Mixed-layer effect on production
224      !  Sea-ice effect on production
225
226      DO jk = 1, jpkm1
227         DO jj = 1, jpj
228            DO ji = 1, jpi
229               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
230               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
231            END DO
232         END DO
233      END DO
234
235      ! Computation of the various production terms
236      DO jk = 1, jpkm1
237         DO jj = 1, jpj
238            DO ji = 1, jpi
239               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
240                  !  production terms for nanophyto. (C)
241                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * tr(ji,jj,jk,jpphy,Kbb) * rfact2
242                  zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
243                  !
244                  zratio = tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) * fecnm + rtrn )
245                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
246                  zprofen(ji,jj,jk) = fecnm * zprmaxn(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
247                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
248                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
249                  &             * zmax * tr(ji,jj,jk,jpphy,Kbb) * rfact2
250                  !  production terms for diatoms (C)
251                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * tr(ji,jj,jk,jpdia,Kbb) * rfact2
252                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
253                  !
254                  zratio = tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) * fecdm + rtrn )
255                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
256                  zprofed(ji,jj,jk) = fecdm * zprmaxd(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
257                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
258                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
259                  &             * zmax * tr(ji,jj,jk,jpdia,Kbb) * rfact2
260               ENDIF
261            END DO
262         END DO
263      END DO
264
265      ! Computation of the chlorophyll production terms
266      DO jk = 1, jpkm1
267         DO jj = 1, jpj
268            DO ji = 1, jpi
269               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
270                  !  production terms for nanophyto. ( chlorophyll )
271                  znanotot = enanom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
272                  zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
273                  zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
274                  chlcnm_n   = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *ts(ji,jj,jk,jp_tem,Kmm))) * (1. - 1.14 / 43.4 * 20.))
275                  zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / &
276                                        & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
277                  !  production terms for diatoms ( chlorophyll )
278                  zdiattot = ediatm(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
279                  zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
280                  zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
281                  chlcdm_n   = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * ts(ji,jj,jk,jp_tem,Kmm))) * (1. - 1.14 / 43.4 * 20.))
282                  zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / &
283                                        & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
284                  !   Update the arrays TRA which contain the Chla sources and sinks
285                  tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) + zprochln * texcretn
286                  tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) + zprochld * texcretd
287               ENDIF
288            END DO
289         END DO
290      END DO
291
292      !   Update the arrays TRA which contain the biological sources and sinks
293      DO jk = 1, jpkm1
294         DO jj = 1, jpj
295           DO ji =1 ,jpi
296              IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
297                 zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
298                 zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
299                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
300                 tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
301                 tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
302                 tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) - zproreg - zproreg2
303                 tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) + zprorcan(ji,jj,jk) * texcretn
304                 tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) + zprofen(ji,jj,jk) * texcretn
305                 tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) + zprorcad(ji,jj,jk) * texcretd
306                 tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) + zprofed(ji,jj,jk) * texcretd
307                 tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
308                 tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zdocprod
309                 tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + o2ut * ( zproreg + zproreg2) &
310                 &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
311                 !
312                 zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
313                 tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zfeup
314                 tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
315                 tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
316                 tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
317                 &                                         - rno3 * ( zproreg + zproreg2 )
318              ENDIF
319           END DO
320        END DO
321     END DO
322     !
323     IF( ln_ligand ) THEN
324         zpligprod1(:,:,jpk) = 0._wp    ;    zpligprod2(:,:,jpk) = 0._wp
325         DO jk = 1, jpkm1
326            DO jj = 1, jpj
327              DO ji =1 ,jpi
328                 IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
329                    zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
330                    zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
331                    tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
332                    zpligprod1(ji,jj,jk) = zdocprod * ldocp
333                    zpligprod2(ji,jj,jk) = zfeup * plig(ji,jj,jk) * lthet
334                 ENDIF
335              END DO
336           END DO
337        END DO
338     ENDIF
339
340
341    ! Total primary production per year
342    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
343         & tpp = glob_sum( 'p4zprod', ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
344
345    IF( lk_iomput .AND.  knt == nrdttrc ) THEN
346       zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
347       !
348       CALL iom_put( "PPPHYN"  , zprorcan(:,:,:) * zfact * tmask(:,:,:) )  ! primary production by nanophyto
349       CALL iom_put( "PPPHYD"  , zprorcad(:,:,:) * zfact * tmask(:,:,:)   ) ! primary production by diatomes
350       CALL iom_put( "PPNEWN"  , zpronewn(:,:,:) * zfact * tmask(:,:,:)    ) ! new primary production by nanophyto
351       CALL iom_put( "PPNEWD"  , zpronewd(:,:,:) * zfact * tmask(:,:,:)   ) ! new primary production by diatomes
352       CALL iom_put( "PBSi"    , zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)  ) ! biogenic silica production
353       CALL iom_put( "PFeN"    , zprofen(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by nanophyto
354       CALL iom_put( "PFeD"    , zprofed(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by  diatomes
355       CALL iom_put( "LPRODP"  , zpligprod1(:,:,:) * 1e9 * zfact * tmask(:,:,:) )
356       CALL iom_put( "LDETP"   , zpligprod2(:,:,:) * 1e9 * zfact * tmask(:,:,:) )
357       CALL iom_put( "Mumax"   , zprmaxn(:,:,:) * tmask(:,:,:)  ) ! Maximum growth rate
358       CALL iom_put( "MuN"     , zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for nanophyto
359       CALL iom_put( "MuD"     , zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for diatoms
360       CALL iom_put( "LNlight" , zprbio (:,:,:) / (zprmaxn(:,:,:) + rtrn) * tmask(:,:,:)  )  ! light limitation term
361       CALL iom_put( "LDlight" , zprdia (:,:,:) / (zprmaxd(:,:,:) + rtrn) * tmask(:,:,:)   )
362       CALL iom_put( "TPP"     , ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  )  ! total primary production
363       CALL iom_put( "TPNEW"   , ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ) ! total new production
364       CALL iom_put( "TPBFE"   , ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  )  ! total biogenic iron production
365       CALL iom_put( "tintpp"  , tpp * zfact )  !  global total integrated primary production molC/s
366     ENDIF
367
368     IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
369         WRITE(charout, FMT="('prod')")
370         CALL prt_ctl_trc_info(charout)
371         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
372     ENDIF
373      !
374      IF( ln_timing )  CALL timing_stop('p4z_prod')
375      !
376   END SUBROUTINE p4z_prod
377
378
379   SUBROUTINE p4z_prod_init
380      !!----------------------------------------------------------------------
381      !!                  ***  ROUTINE p4z_prod_init  ***
382      !!
383      !! ** Purpose :   Initialization of phytoplankton production parameters
384      !!
385      !! ** Method  :   Read the nampisprod namelist and check the parameters
386      !!      called at the first timestep (nittrc000)
387      !!
388      !! ** input   :   Namelist nampisprod
389      !!----------------------------------------------------------------------
390      INTEGER ::   ios   ! Local integer
391      !
392      NAMELIST/namp4zprod/ pislopen, pisloped, xadap, bresp, excretn, excretd,  &
393         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
394      !!----------------------------------------------------------------------
395      !
396      IF(lwp) THEN                         ! control print
397         WRITE(numout,*)
398         WRITE(numout,*) 'p4z_prod_init : phytoplankton growth'
399         WRITE(numout,*) '~~~~~~~~~~~~~'
400      ENDIF
401      !
402      READ  ( numnatp_ref, namp4zprod, IOSTAT = ios, ERR = 901)
403901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zprod in reference namelist' )
404      READ  ( numnatp_cfg, namp4zprod, IOSTAT = ios, ERR = 902 )
405902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zprod in configuration namelist' )
406      IF(lwm) WRITE( numonp, namp4zprod )
407
408      IF(lwp) THEN                         ! control print
409         WRITE(numout,*) '   Namelist : namp4zprod'
410         WRITE(numout,*) '      mean Si/C ratio                           grosip       =', grosip
411         WRITE(numout,*) '      P-I slope                                 pislopen     =', pislopen
412         WRITE(numout,*) '      Acclimation factor to low light           xadap        =', xadap
413         WRITE(numout,*) '      excretion ratio of nanophytoplankton      excretn      =', excretn
414         WRITE(numout,*) '      excretion ratio of diatoms                excretd      =', excretd
415         WRITE(numout,*) '      basal respiration in phytoplankton        bresp        =', bresp
416         WRITE(numout,*) '      Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
417         WRITE(numout,*) '      P-I slope  for diatoms                    pisloped     =', pisloped
418         WRITE(numout,*) '      Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
419         WRITE(numout,*) '      Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
420         WRITE(numout,*) '      Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
421         WRITE(numout,*) '      Minimum Fe/C in diatoms                   fecdm        =', fecdm
422      ENDIF
423      !
424      r1_rday   = 1._wp / rday 
425      texcretn  = 1._wp - excretn
426      texcretd  = 1._wp - excretd
427      tpp       = 0._wp
428      !
429   END SUBROUTINE p4z_prod_init
430
431
432   INTEGER FUNCTION p4z_prod_alloc()
433      !!----------------------------------------------------------------------
434      !!                     ***  ROUTINE p4z_prod_alloc  ***
435      !!----------------------------------------------------------------------
436      ALLOCATE( quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
437      !
438      IF( p4z_prod_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p4z_prod_alloc : failed to allocate arrays.' )
439      !
440   END FUNCTION p4z_prod_alloc
441
442   !!======================================================================
443END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.