New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsms.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P4Z/p4zsms.F90 @ 12236

Last change on this file since 12236 was 12193, checked in by davestorkey, 4 years ago

2019/dev_r11943_MERGE_2019: Merge in dev_r12072_TOP-01_ENHANCE-11_cethe
  • Property svn:keywords set to Id
File size: 27.3 KB
Line 
1MODULE p4zsms
2   !!======================================================================
3   !!                         ***  MODULE p4zsms  ***
4   !! TOP :   PISCES Source Minus Sink manager
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9   !!   p4z_sms        : Time loop of passive tracers sms
10   !!----------------------------------------------------------------------
11   USE oce_trc         ! shared variables between ocean and passive tracers
12   USE trc             ! passive tracers common variables
13   USE trcdta          !
14   USE sms_pisces      ! PISCES Source Minus Sink variables
15   USE p4zbio          ! Biological model
16   USE p4zche          ! Chemical model
17   USE p4zlys          ! Calcite saturation
18   USE p4zflx          ! Gas exchange
19   USE p4zbc           ! External source of nutrients
20   USE p4zsed          ! Sedimentation
21   USE p4zint          ! time interpolation
22   USE p4zrem          ! remineralisation
23   USE iom             ! I/O manager
24   USE trd_oce         ! Ocean trends variables
25   USE trdtrc          ! TOP trends variables
26   USE sedmodel        ! Sediment model
27   USE prtctl_trc      ! print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sms_init   ! called in p4zsms.F90
33   PUBLIC   p4z_sms        ! called in p4zsms.F90
34
35   INTEGER ::    numco2, numnut, numnit      ! logical unit for co2 budget
36   REAL(wp) ::   alkbudget, no3budget, silbudget, ferbudget, po4budget
37   REAL(wp) ::   xfact, xfact1, xfact2, xfact3
38
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xnegtr     ! Array used to indicate negative tracer values
40
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE p4z_sms( kt, Kbb, Kmm, Krhs )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p4z_sms  ***
51      !!
52      !! ** Purpose :   Managment of the call to Biological sources and sinks
53      !!              routines of PISCES bio-model
54      !!
55      !! ** Method  : - at each new day ...
56      !!              - several calls of bio and sed ???
57      !!              - ...
58      !!---------------------------------------------------------------------
59      !
60      INTEGER, INTENT( in ) ::   kt              ! ocean time-step index     
61      INTEGER, INTENT( in ) ::   Kbb, Kmm, Krhs  ! time level index
62      !!
63      INTEGER ::   ji, jj, jk, jnt, jn, jl
64      REAL(wp) ::  ztra
65      CHARACTER (len=25) :: charout
66      REAL(wp), ALLOCATABLE, DIMENSION(:,:    ) :: zw2d
67      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:  ) :: zw3d
68      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrdt   ! 4D workspace
69
70      !!---------------------------------------------------------------------
71      !
72      IF( ln_timing )   CALL timing_start('p4z_sms')
73      !
74      IF( kt == nittrc000 ) THEN
75        !
76        ALLOCATE( xnegtr(jpi,jpj,jpk) )
77        !
78        IF( .NOT. ln_rsttr ) THEN
79            CALL p4z_che( Kbb, Kmm )                  ! initialize the chemical constants
80            CALL ahini_for_at( hi, Kbb )              !  set PH at kt=nit000
81            t_oce_co2_flx_cum = 0._wp
82        ELSE
83            CALL p4z_rst( nittrc000, Kbb, Kmm,  'READ' )  !* read or initialize all required fields
84        ENDIF
85        !
86      ENDIF
87      !
88      IF( ln_pisdmp .AND. MOD( kt - 1, nn_pisdmp ) == 0 )   CALL p4z_dmp( kt, Kbb, Kmm )      ! Relaxation of some tracers
89      !
90      rfact = r2dttrc
91      !
92      ! trends computation initialisation
93      IF( l_trdtrc )  THEN
94         ALLOCATE( ztrdt(jpi,jpj,jpk,jp_pisces) )  !* store now fields before applying the Asselin filter
95         ztrdt(:,:,:,:)  = tr(:,:,:,:,Kmm)
96      ENDIF
97      !
98
99      IF( ( ln_top_euler .AND. kt == nittrc000 )  .OR. ( .NOT.ln_top_euler .AND. kt <= nittrc000 + 1 ) ) THEN
100         rfactr  = 1. / rfact
101         rfact2  = rfact / REAL( nrdttrc, wp )
102         rfact2r = 1. / rfact2
103         xstep = rfact2 / rday         ! Time step duration for biology
104         xfact = 1.e+3 * rfact2r
105         IF(lwp) WRITE(numout,*) 
106         IF(lwp) WRITE(numout,*) '    Passive Tracer  time step    rfact  = ', rfact, ' rdt = ', rdt
107         IF(lwp) write(numout,*) '    PISCES  Biology time step    rfact2 = ', rfact2
108         IF(lwp) WRITE(numout,*)
109      ENDIF
110
111      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN
112         DO jn = jp_pcs0, jp_pcs1              !   SMS on tracer without Asselin time-filter
113            tr(:,:,:,jn,Kbb) = tr(:,:,:,jn,Kmm)
114         END DO
115      ENDIF
116      !
117      IF( ll_bc )    CALL p4z_bc( kt, Kbb, Kmm, Krhs )   ! external sources of nutrients
118      !
119#if ! defined key_sed_off
120      CALL p4z_che(     Kbb, Kmm       ) ! computation of chemical constants
121      CALL p4z_int( kt, Kbb, Kmm       ) ! computation of various rates for biogeochemistry
122      !
123      DO jnt = 1, nrdttrc          ! Potential time splitting if requested
124         !
125         CALL p4z_bio( kt, jnt, Kbb, Kmm, Krhs )   ! Biology
126         CALL p4z_lys( kt, jnt, Kbb,      Krhs )   ! Compute CaCO3 saturation
127         CALL p4z_sed( kt, jnt, Kbb, Kmm, Krhs )   ! Surface and Bottom boundary conditions
128         CALL p4z_flx( kt, jnt, Kbb, Kmm, Krhs )   ! Compute surface fluxes
129         !
130         xnegtr(:,:,:) = 1.e0
131         DO jn = jp_pcs0, jp_pcs1
132            DO jk = 1, jpk
133               DO jj = 1, jpj
134                  DO ji = 1, jpi
135                     IF( ( tr(ji,jj,jk,jn,Kbb) + tr(ji,jj,jk,jn,Krhs) ) < 0.e0 ) THEN
136                        ztra             = ABS( tr(ji,jj,jk,jn,Kbb) ) / ( ABS( tr(ji,jj,jk,jn,Krhs) ) + rtrn )
137                        xnegtr(ji,jj,jk) = MIN( xnegtr(ji,jj,jk),  ztra )
138                     ENDIF
139                 END DO
140               END DO
141            END DO
142         END DO
143         !                                ! where at least 1 tracer concentration becomes negative
144         !                                !
145         DO jn = jp_pcs0, jp_pcs1
146           tr(:,:,:,jn,Kbb) = tr(:,:,:,jn,Kbb) + xnegtr(:,:,:) * tr(:,:,:,jn,Krhs)
147         END DO
148        !
149        IF(  iom_use( 'INTdtAlk' ) .OR. iom_use( 'INTdtDIC' ) .OR. iom_use( 'INTdtFer' ) .OR.  &
150          &  iom_use( 'INTdtDIN' ) .OR. iom_use( 'INTdtDIP' ) .OR. iom_use( 'INTdtSil' ) )  THEN
151          !
152          ALLOCATE( zw3d(jpi,jpj,jpk), zw2d(jpi,jpj) )
153          zw3d(:,:,jpk) = 0.
154          DO jk = 1, jpkm1
155              zw3d(:,:,jk) = xnegtr(:,:,jk) * xfact * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
156          ENDDO
157          !
158          zw2d(:,:) = 0.
159          DO jk = 1, jpkm1
160             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * tr(:,:,jk,jptal,Krhs)
161          ENDDO
162          CALL iom_put( 'INTdtAlk', zw2d )
163          !
164          zw2d(:,:) = 0.
165          DO jk = 1, jpkm1
166             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * tr(:,:,jk,jpdic,Krhs)
167          ENDDO
168          CALL iom_put( 'INTdtDIC', zw2d )
169          !
170          zw2d(:,:) = 0.
171          DO jk = 1, jpkm1
172             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * rno3 * ( tr(:,:,jk,jpno3,Krhs) + tr(:,:,jk,jpnh4,Krhs) )
173          ENDDO
174          CALL iom_put( 'INTdtDIN', zw2d )
175          !
176          zw2d(:,:) = 0.
177          DO jk = 1, jpkm1
178             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * po4r * tr(:,:,jk,jppo4,Krhs)
179          ENDDO
180          CALL iom_put( 'INTdtDIP', zw2d )
181          !
182          zw2d(:,:) = 0.
183          DO jk = 1, jpkm1
184             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * tr(:,:,jk,jpfer,Krhs)
185          ENDDO
186          CALL iom_put( 'INTdtFer', zw2d )
187          !
188          zw2d(:,:) = 0.
189          DO jk = 1, jpkm1
190             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * tr(:,:,jk,jpsil,Krhs)
191          ENDDO
192          CALL iom_put( 'INTdtSil', zw2d )
193          !
194          DEALLOCATE( zw3d, zw2d )
195        ENDIF
196        !
197         DO jn = jp_pcs0, jp_pcs1
198            tr(:,:,:,jn,Krhs) = 0._wp
199         END DO
200         !
201         IF( ln_top_euler ) THEN
202            DO jn = jp_pcs0, jp_pcs1
203               tr(:,:,:,jn,Kmm) = tr(:,:,:,jn,Kbb)
204            END DO
205         ENDIF
206      END DO
207      !
208      IF( l_trdtrc ) THEN
209         DO jn = jp_pcs0, jp_pcs1
210           ztrdt(:,:,:,jn) = ( tr(:,:,:,jn,Kbb) - ztrdt(:,:,:,jn) ) * rfact2r 
211           CALL trd_trc( tr(:,:,:,jn,Krhs), jn, jptra_sms, kt, Kmm )   ! save trends
212         END DO
213         DEALLOCATE( ztrdt ) 
214      END IF
215#endif
216      !
217      IF( ln_sediment ) THEN 
218         !
219         CALL sed_model( kt, Kbb, Kmm, Krhs )     !  Main program of Sediment model
220         !
221         IF( ln_top_euler ) THEN
222            DO jn = jp_pcs0, jp_pcs1
223               tr(:,:,:,jn,Kmm) = tr(:,:,:,jn,Kbb)
224            END DO
225         ENDIF
226         !
227      ENDIF
228      !
229      IF( lrst_trc )  CALL p4z_rst( kt, Kbb, Kmm,  'WRITE' )           !* Write PISCES informations in restart file
230      !
231
232      IF( lk_iomput .OR. ln_check_mass )  CALL p4z_chk_mass( kt, Kmm ) ! Mass conservation checking
233
234      IF( lwm .AND. kt == nittrc000    )  CALL FLUSH( numonp )         ! flush output namelist PISCES
235      !
236      IF( ln_timing )  CALL timing_stop('p4z_sms')
237      !
238   END SUBROUTINE p4z_sms
239
240
241   SUBROUTINE p4z_sms_init
242      !!----------------------------------------------------------------------
243      !!                     ***  p4z_sms_init  *** 
244      !!
245      !! ** Purpose :   read PISCES namelist
246      !!
247      !! ** input   :   file 'namelist.trc.s' containing the following
248      !!             namelist: natext, natbio, natsms
249      !!----------------------------------------------------------------------
250      INTEGER :: ios                 ! Local integer output status for namelist read
251      !!
252      NAMELIST/nampisbio/ nrdttrc, wsbio, xkmort, ferat3, wsbio2, wsbio2max, wsbio2scale,    &
253         &                   ldocp, ldocz, lthet, no3rat3, po4rat3
254         !
255      NAMELIST/nampisdmp/ ln_pisdmp, nn_pisdmp
256      NAMELIST/nampismass/ ln_check_mass
257      !!----------------------------------------------------------------------
258      !
259      IF(lwp) THEN
260         WRITE(numout,*)
261         WRITE(numout,*) 'p4z_sms_init : PISCES initialization'
262         WRITE(numout,*) '~~~~~~~~~~~~'
263      ENDIF
264
265      READ  ( numnatp_ref, nampisbio, IOSTAT = ios, ERR = 901)
266901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisbio in reference namelist' )
267      READ  ( numnatp_cfg, nampisbio, IOSTAT = ios, ERR = 902 )
268902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisbio in configuration namelist' )
269      IF(lwm) WRITE( numonp, nampisbio )
270      !
271      IF(lwp) THEN                         ! control print
272         WRITE(numout,*) '   Namelist : nampisbio'
273         WRITE(numout,*) '      frequency for the biology                 nrdttrc     =', nrdttrc
274         WRITE(numout,*) '      POC sinking speed                         wsbio       =', wsbio
275         WRITE(numout,*) '      half saturation constant for mortality    xkmort      =', xkmort 
276         IF( ln_p5z ) THEN
277            WRITE(numout,*) '      N/C in zooplankton                        no3rat3     =', no3rat3
278            WRITE(numout,*) '      P/C in zooplankton                        po4rat3     =', po4rat3
279         ENDIF
280         WRITE(numout,*) '      Fe/C in zooplankton                       ferat3      =', ferat3
281         WRITE(numout,*) '      Big particles sinking speed               wsbio2      =', wsbio2
282         WRITE(numout,*) '      Big particles maximum sinking speed       wsbio2max   =', wsbio2max
283         WRITE(numout,*) '      Big particles sinking speed length scale  wsbio2scale =', wsbio2scale
284         IF( ln_ligand ) THEN
285            IF( ln_p4z ) THEN
286               WRITE(numout,*) '      Phyto ligand production per unit doc           ldocp  =', ldocp
287               WRITE(numout,*) '      Zoo ligand production per unit doc             ldocz  =', ldocz
288               WRITE(numout,*) '      Proportional loss of ligands due to Fe uptake  lthet  =', lthet
289            ENDIF
290         ENDIF
291      ENDIF
292
293
294      READ  ( numnatp_ref, nampisdmp, IOSTAT = ios, ERR = 905)
295905   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisdmp in reference namelist' )
296      READ  ( numnatp_cfg, nampisdmp, IOSTAT = ios, ERR = 906 )
297906   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisdmp in configuration namelist' )
298      IF(lwm) WRITE( numonp, nampisdmp )
299      !
300      IF(lwp) THEN                         ! control print
301         WRITE(numout,*)
302         WRITE(numout,*) '   Namelist : nampisdmp --- relaxation to GLODAP'
303         WRITE(numout,*) '      Relaxation of tracer to glodap mean value   ln_pisdmp =', ln_pisdmp
304         WRITE(numout,*) '      Frequency of Relaxation                     nn_pisdmp =', nn_pisdmp
305      ENDIF
306
307      READ  ( numnatp_ref, nampismass, IOSTAT = ios, ERR = 907)
308907   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampismass in reference namelist' )
309      READ  ( numnatp_cfg, nampismass, IOSTAT = ios, ERR = 908 )
310908   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampismass in configuration namelist' )
311      IF(lwm) WRITE( numonp, nampismass )
312
313      IF(lwp) THEN                         ! control print
314         WRITE(numout,*)
315         WRITE(numout,*) '   Namelist : nampismass  --- mass conservation checking'
316         WRITE(numout,*) '      Flag to check mass conservation of NO3/Si/TALK   ln_check_mass = ', ln_check_mass
317      ENDIF
318      !
319   END SUBROUTINE p4z_sms_init
320
321
322   SUBROUTINE p4z_rst( kt, Kbb, Kmm, cdrw )
323      !!---------------------------------------------------------------------
324      !!                   ***  ROUTINE p4z_rst  ***
325      !!
326      !!  ** Purpose : Read or write variables in restart file:
327      !!
328      !!  WRITE(READ) mode:
329      !!       kt        : number of time step since the begining of the experiment at the
330      !!                   end of the current(previous) run
331      !!---------------------------------------------------------------------
332      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
333      INTEGER         , INTENT(in) ::   Kbb, Kmm   ! time level indices
334      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
335      !!---------------------------------------------------------------------
336      !
337      IF( TRIM(cdrw) == 'READ' ) THEN
338         !
339         IF(lwp) WRITE(numout,*)
340         IF(lwp) WRITE(numout,*) ' p4z_rst : Read specific variables from pisces model '
341         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
342         !
343         IF( iom_varid( numrtr, 'PH', ldstop = .FALSE. ) > 0 ) THEN
344            CALL iom_get( numrtr, jpdom_autoglo, 'PH' , hi(:,:,:)  )
345         ELSE
346            CALL p4z_che( Kbb, Kmm )                  ! initialize the chemical constants
347            CALL ahini_for_at( hi, Kbb )
348         ENDIF
349         CALL iom_get( numrtr, jpdom_autoglo, 'Silicalim', xksi(:,:) )
350         IF( iom_varid( numrtr, 'Silicamax', ldstop = .FALSE. ) > 0 ) THEN
351            CALL iom_get( numrtr, jpdom_autoglo, 'Silicamax' , xksimax(:,:)  )
352         ELSE
353            xksimax(:,:) = xksi(:,:)
354         ENDIF
355         !
356         IF( iom_varid( numrtr, 'tcflxcum', ldstop = .FALSE. ) > 0 ) THEN  ! cumulative total flux of carbon
357            CALL iom_get( numrtr, 'tcflxcum' , t_oce_co2_flx_cum  )
358         ELSE
359            t_oce_co2_flx_cum = 0._wp
360         ENDIF
361         !
362         IF( ln_p5z ) THEN
363            IF( iom_varid( numrtr, 'sized', ldstop = .FALSE. ) > 0 ) THEN
364               CALL iom_get( numrtr, jpdom_autoglo, 'sizep' , sizep(:,:,:)  )
365               CALL iom_get( numrtr, jpdom_autoglo, 'sizen' , sizen(:,:,:)  )
366               CALL iom_get( numrtr, jpdom_autoglo, 'sized' , sized(:,:,:)  )
367            ELSE
368               sizep(:,:,:) = 1.
369               sizen(:,:,:) = 1.
370               sized(:,:,:) = 1.
371            ENDIF
372        ENDIF
373        !
374      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
375         IF( kt == nitrst ) THEN
376            IF(lwp) WRITE(numout,*)
377            IF(lwp) WRITE(numout,*) 'p4z_rst : write pisces restart file  kt =', kt
378            IF(lwp) WRITE(numout,*) '~~~~~~~'
379         ENDIF
380         CALL iom_rstput( kt, nitrst, numrtw, 'PH', hi(:,:,:) )
381         CALL iom_rstput( kt, nitrst, numrtw, 'Silicalim', xksi(:,:) )
382         CALL iom_rstput( kt, nitrst, numrtw, 'Silicamax', xksimax(:,:) )
383         CALL iom_rstput( kt, nitrst, numrtw, 'tcflxcum', t_oce_co2_flx_cum )
384         IF( ln_p5z ) THEN
385            CALL iom_rstput( kt, nitrst, numrtw, 'sizep', sizep(:,:,:) )
386            CALL iom_rstput( kt, nitrst, numrtw, 'sizen', sizen(:,:,:) )
387            CALL iom_rstput( kt, nitrst, numrtw, 'sized', sized(:,:,:) )
388         ENDIF
389      ENDIF
390      !
391   END SUBROUTINE p4z_rst
392
393
394   SUBROUTINE p4z_dmp( kt, Kbb, Kmm )
395      !!----------------------------------------------------------------------
396      !!                    ***  p4z_dmp  ***
397      !!
398      !! ** purpose  : Relaxation of some tracers
399      !!----------------------------------------------------------------------
400      !
401      INTEGER, INTENT( in )  ::     kt            ! time step
402      INTEGER, INTENT( in )  ::     Kbb, Kmm      ! time level indices
403      !
404      REAL(wp) ::  alkmean = 2426.     ! mean value of alkalinity ( Glodap ; for Goyet 2391. )
405      REAL(wp) ::  po4mean = 2.165     ! mean value of phosphates
406      REAL(wp) ::  no3mean = 30.90     ! mean value of nitrate
407      REAL(wp) ::  silmean = 91.51     ! mean value of silicate
408      !
409      REAL(wp) :: zarea, zalksumn, zpo4sumn, zno3sumn, zsilsumn
410      REAL(wp) :: zalksumb, zpo4sumb, zno3sumb, zsilsumb
411      !!---------------------------------------------------------------------
412
413      IF(lwp)  WRITE(numout,*)
414      IF(lwp)  WRITE(numout,*) ' p4z_dmp : Restoring of nutrients at time-step kt = ', kt
415      IF(lwp)  WRITE(numout,*)
416
417      IF( cn_cfg == "ORCA" .OR. cn_cfg == "orca") THEN
418         IF( .NOT. lk_c1d ) THEN      ! ORCA configuration (not 1D) !
419            !                                                ! --------------------------- !
420            ! set total alkalinity, phosphate, nitrate & silicate
421            zarea          = 1._wp / glob_sum( 'p4zsms', cvol(:,:,:) ) * 1e6             
422
423            zalksumn = glob_sum( 'p4zsms', tr(:,:,:,jptal,Kmm) * cvol(:,:,:)  ) * zarea
424            zpo4sumn = glob_sum( 'p4zsms', tr(:,:,:,jppo4,Kmm) * cvol(:,:,:)  ) * zarea * po4r
425            zno3sumn = glob_sum( 'p4zsms', tr(:,:,:,jpno3,Kmm) * cvol(:,:,:)  ) * zarea * rno3
426            zsilsumn = glob_sum( 'p4zsms', tr(:,:,:,jpsil,Kmm) * cvol(:,:,:)  ) * zarea
427 
428            IF(lwp) WRITE(numout,*) '       TALKN mean : ', zalksumn
429            tr(:,:,:,jptal,Kmm) = tr(:,:,:,jptal,Kmm) * alkmean / zalksumn
430
431            IF(lwp) WRITE(numout,*) '       PO4N  mean : ', zpo4sumn
432            tr(:,:,:,jppo4,Kmm) = tr(:,:,:,jppo4,Kmm) * po4mean / zpo4sumn
433
434            IF(lwp) WRITE(numout,*) '       NO3N  mean : ', zno3sumn
435            tr(:,:,:,jpno3,Kmm) = tr(:,:,:,jpno3,Kmm) * no3mean / zno3sumn
436
437            IF(lwp) WRITE(numout,*) '       SiO3N mean : ', zsilsumn
438            tr(:,:,:,jpsil,Kmm) = MIN( 400.e-6,tr(:,:,:,jpsil,Kmm) * silmean / zsilsumn )
439            !
440            !
441            IF( .NOT. ln_top_euler ) THEN
442               zalksumb = glob_sum( 'p4zsms', tr(:,:,:,jptal,Kbb) * cvol(:,:,:)  ) * zarea
443               zpo4sumb = glob_sum( 'p4zsms', tr(:,:,:,jppo4,Kbb) * cvol(:,:,:)  ) * zarea * po4r
444               zno3sumb = glob_sum( 'p4zsms', tr(:,:,:,jpno3,Kbb) * cvol(:,:,:)  ) * zarea * rno3
445               zsilsumb = glob_sum( 'p4zsms', tr(:,:,:,jpsil,Kbb) * cvol(:,:,:)  ) * zarea
446 
447               IF(lwp) WRITE(numout,*) ' '
448               IF(lwp) WRITE(numout,*) '       TALKB mean : ', zalksumb
449               tr(:,:,:,jptal,Kbb) = tr(:,:,:,jptal,Kbb) * alkmean / zalksumb
450
451               IF(lwp) WRITE(numout,*) '       PO4B  mean : ', zpo4sumb
452               tr(:,:,:,jppo4,Kbb) = tr(:,:,:,jppo4,Kbb) * po4mean / zpo4sumb
453
454               IF(lwp) WRITE(numout,*) '       NO3B  mean : ', zno3sumb
455               tr(:,:,:,jpno3,Kbb) = tr(:,:,:,jpno3,Kbb) * no3mean / zno3sumb
456
457               IF(lwp) WRITE(numout,*) '       SiO3B mean : ', zsilsumb
458               tr(:,:,:,jpsil,Kbb) = MIN( 400.e-6,tr(:,:,:,jpsil,Kbb) * silmean / zsilsumb )
459           ENDIF
460        ENDIF
461        !
462      ENDIF
463        !
464   END SUBROUTINE p4z_dmp
465
466
467   SUBROUTINE p4z_chk_mass( kt, Kmm )
468      !!----------------------------------------------------------------------
469      !!                  ***  ROUTINE p4z_chk_mass  ***
470      !!
471      !! ** Purpose :  Mass conservation check
472      !!
473      !!---------------------------------------------------------------------
474      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
475      INTEGER, INTENT( in ) ::   Kmm     ! time level indices
476      REAL(wp)             ::  zrdenittot, zsdenittot, znitrpottot
477      CHARACTER(LEN=100)   ::   cltxt
478      INTEGER :: jk
479      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwork
480      !!----------------------------------------------------------------------
481      !
482      IF( kt == nittrc000 ) THEN
483         xfact1 = rfact2r * 12. / 1.e15 * ryyss    ! conversion molC/kt --> PgC/yr
484         xfact2 = 1.e+3 * rno3 * 14. / 1.e12 * ryyss   ! conversion molC/l/s ----> TgN/m3/yr
485         xfact3 = 1.e+3 * rfact2r * rno3   ! conversion molC/l/kt ----> molN/m3/s
486         IF( ln_check_mass .AND. lwp) THEN      !   Open budget file of NO3, ALK, Si, Fer
487            CALL ctl_opn( numco2, 'carbon.budget'  , 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
488            CALL ctl_opn( numnut, 'nutrient.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
489            CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
490            cltxt='time-step   Alkalinity        Nitrate        Phosphorus         Silicate           Iron'
491            IF( lwp ) WRITE(numnut,*)  TRIM(cltxt)
492            IF( lwp ) WRITE(numnut,*) 
493         ENDIF
494      ENDIF
495
496      IF( iom_use( "pno3tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
497         !   Compute the budget of NO3, ALK, Si, Fer
498         IF( ln_p4z ) THEN
499            zwork(:,:,:) =    tr(:,:,:,jpno3,Kmm) + tr(:,:,:,jpnh4,Kmm)                      &
500               &          +   tr(:,:,:,jpphy,Kmm) + tr(:,:,:,jpdia,Kmm)                      &
501               &          +   tr(:,:,:,jppoc,Kmm) + tr(:,:,:,jpgoc,Kmm)  + tr(:,:,:,jpdoc,Kmm)  &       
502               &          +   tr(:,:,:,jpzoo,Kmm) + tr(:,:,:,jpmes,Kmm) 
503        ELSE
504            zwork(:,:,:) =    tr(:,:,:,jpno3,Kmm) + tr(:,:,:,jpnh4,Kmm) + tr(:,:,:,jpnph,Kmm)   &
505               &          +   tr(:,:,:,jpndi,Kmm) + tr(:,:,:,jpnpi,Kmm)                      & 
506               &          +   tr(:,:,:,jppon,Kmm) + tr(:,:,:,jpgon,Kmm) + tr(:,:,:,jpdon,Kmm)   &
507               &          + ( tr(:,:,:,jpzoo,Kmm) + tr(:,:,:,jpmes,Kmm) ) * no3rat3 
508        ENDIF
509        !
510        no3budget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
511        no3budget = no3budget / areatot
512        CALL iom_put( "pno3tot", no3budget )
513      ENDIF
514      !
515      IF( iom_use( "ppo4tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
516         IF( ln_p4z ) THEN
517            zwork(:,:,:) =    tr(:,:,:,jppo4,Kmm)                                         &
518               &          +   tr(:,:,:,jpphy,Kmm) + tr(:,:,:,jpdia,Kmm)                      &
519               &          +   tr(:,:,:,jppoc,Kmm) + tr(:,:,:,jpgoc,Kmm)  + tr(:,:,:,jpdoc,Kmm)  &       
520               &          +   tr(:,:,:,jpzoo,Kmm) + tr(:,:,:,jpmes,Kmm) 
521        ELSE
522            zwork(:,:,:) =    tr(:,:,:,jppo4,Kmm) + tr(:,:,:,jppph,Kmm)                      &
523               &          +   tr(:,:,:,jppdi,Kmm) + tr(:,:,:,jpppi,Kmm)                      & 
524               &          +   tr(:,:,:,jppop,Kmm) + tr(:,:,:,jpgop,Kmm) + tr(:,:,:,jpdop,Kmm)   &
525               &          + ( tr(:,:,:,jpzoo,Kmm) + tr(:,:,:,jpmes,Kmm) ) * po4rat3 
526        ENDIF
527        !
528        po4budget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
529        po4budget = po4budget / areatot
530        CALL iom_put( "ppo4tot", po4budget )
531      ENDIF
532      !
533      IF( iom_use( "psiltot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
534         zwork(:,:,:) =  tr(:,:,:,jpsil,Kmm) + tr(:,:,:,jpgsi,Kmm) + tr(:,:,:,jpdsi,Kmm) 
535         !
536         silbudget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
537         silbudget = silbudget / areatot
538         CALL iom_put( "psiltot", silbudget )
539      ENDIF
540      !
541      IF( iom_use( "palktot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
542         zwork(:,:,:) =  tr(:,:,:,jpno3,Kmm) * rno3 + tr(:,:,:,jptal,Kmm) + tr(:,:,:,jpcal,Kmm) * 2.             
543         !
544         alkbudget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  )         !
545         alkbudget = alkbudget / areatot
546         CALL iom_put( "palktot", alkbudget )
547      ENDIF
548      !
549      IF( iom_use( "pfertot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
550         zwork(:,:,:) =   tr(:,:,:,jpfer,Kmm) + tr(:,:,:,jpnfe,Kmm) + tr(:,:,:,jpdfe,Kmm)   &
551            &         +   tr(:,:,:,jpbfe,Kmm) + tr(:,:,:,jpsfe,Kmm)                      &
552            &         + ( tr(:,:,:,jpzoo,Kmm) + tr(:,:,:,jpmes,Kmm) )  * ferat3   
553         !
554         ferbudget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
555         ferbudget = ferbudget / areatot
556         CALL iom_put( "pfertot", ferbudget )
557      ENDIF
558      !
559      ! Global budget of N SMS : denitrification in the water column and in the sediment
560      !                          nitrogen fixation by the diazotrophs
561      ! --------------------------------------------------------------------------------
562      IF( iom_use( "tnfix" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
563         znitrpottot  = glob_sum ( 'p4zsms', nitrpot(:,:,:) * nitrfix * cvol(:,:,:) )
564         CALL iom_put( "tnfix"  , znitrpottot * xfact3 )  ! Global  nitrogen fixation molC/l  to molN/m3
565      ENDIF
566      !
567      IF( iom_use( "tdenit" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
568         zrdenittot = glob_sum ( 'p4zsms', denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
569         zsdenittot = glob_sum ( 'p4zsms', sdenit(:,:) * e1e2t(:,:) * tmask(:,:,1) )
570         CALL iom_put( "tdenit" , ( zrdenittot + zsdenittot ) * xfact3 )  ! Total denitrification molC/l to molN/m3
571      ENDIF
572      !
573      IF( ln_check_mass .AND. kt == nitend ) THEN   ! Compute the budget of NO3, ALK, Si, Fer
574         t_atm_co2_flx  = t_atm_co2_flx / glob_sum( 'p4zsms', e1e2t(:,:) )
575         t_oce_co2_flx  = t_oce_co2_flx         * xfact1 * (-1 )
576         tpp            = tpp           * 1000. * xfact1
577         t_oce_co2_exp  = t_oce_co2_exp * 1000. * xfact1
578         IF( lwp ) WRITE(numco2,9000) ndastp, t_atm_co2_flx, t_oce_co2_flx, tpp, t_oce_co2_exp
579         IF( lwp ) WRITE(numnut,9100) ndastp, alkbudget        * 1.e+06, &
580             &                                no3budget * rno3 * 1.e+06, &
581             &                                po4budget * po4r * 1.e+06, &
582             &                                silbudget        * 1.e+06, &
583             &                                ferbudget        * 1.e+09
584         !
585         IF( lwp ) WRITE(numnit,9200) ndastp, znitrpottot * xfact2  , &
586            &                             zrdenittot  * xfact2  , &
587            &                             zsdenittot  * xfact2
588      ENDIF
589      !
590 9000  FORMAT(i8,f10.5,e18.10,f10.5,f10.5)
591 9100  FORMAT(i8,5e18.10)
592 9200  FORMAT(i8,3f10.5)
593       !
594   END SUBROUTINE p4z_chk_mass
595
596   !!======================================================================
597END MODULE p4zsms 
Note: See TracBrowser for help on using the repository browser.