New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

p5zmeso.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P4Z – NEMO

Context Navigation

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/PISCES/P4Z/p5zmeso.F90 @ 12236

Last change on this file since 12236 was 12236, checked in by acc, 4 years ago
Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/fix_sn_cfctl_ticket2328. Fully SETTE tested
Property svn:keywords set to `Id`
File size: 27.2 KB

Rev	Line
[7162]	1	MODULE p5zmeso
	2	!!======================================================================
	3	!! * MODULE p5zmeso *
	4	!! TOP : PISCES Compute the sources/sinks for mesozooplankton
	5	!!======================================================================
	6	!! History : 1.0 ! 2002 (O. Aumont) Original code
	7	!! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90
	8	!! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Quota model for iron
	9	!! 3.6 ! 2015-05 (O. Aumont) PISCES quota
	10	!!----------------------------------------------------------------------
	11	!! p5z_meso : Compute the sources/sinks for mesozooplankton
	12	!! p5z_meso_init : Initialization of the parameters for mesozooplankton
	13	!!----------------------------------------------------------------------
	14	USE oce_trc ! shared variables between ocean and passive tracers
	15	USE trc ! passive tracers common variables
	16	USE sms_pisces ! PISCES Source Minus Sink variables
	17	USE prtctl_trc ! print control for debugging
	18	USE iom ! I/O manager
	19
	20	IMPLICIT NONE
	21	PRIVATE
	22
	23	PUBLIC p5z_meso ! called in p5zbio.F90
	24	PUBLIC p5z_meso_init ! called in trcsms_pisces.F90
	25
	26	!! * Shared module variables
	27	REAL(wp), PUBLIC :: part2 !: part of calcite not dissolved in mesozoo guts
	28	REAL(wp), PUBLIC :: xpref2c !: mesozoo preference for POC
[10362]	29	REAL(wp), PUBLIC :: xpref2n !: mesozoo preference for nanophyto
[7162]	30	REAL(wp), PUBLIC :: xpref2z !: mesozoo preference for zooplankton
	31	REAL(wp), PUBLIC :: xpref2d !: mesozoo preference for Diatoms
	32	REAL(wp), PUBLIC :: xpref2m !: mesozoo preference for mesozoo
	33	REAL(wp), PUBLIC :: xthresh2zoo !: zoo feeding threshold for mesozooplankton
	34	REAL(wp), PUBLIC :: xthresh2dia !: diatoms feeding threshold for mesozooplankton
	35	REAL(wp), PUBLIC :: xthresh2phy !: nanophyto feeding threshold for mesozooplankton
	36	REAL(wp), PUBLIC :: xthresh2poc !: poc feeding threshold for mesozooplankton
	37	REAL(wp), PUBLIC :: xthresh2mes !: mesozoo feeding threshold for mesozooplankton
	38	REAL(wp), PUBLIC :: xthresh2 !: feeding threshold for mesozooplankton
	39	REAL(wp), PUBLIC :: resrat2 !: exsudation rate of mesozooplankton
	40	REAL(wp), PUBLIC :: mzrat2 !: microzooplankton mortality rate
	41	REAL(wp), PUBLIC :: grazrat2 !: maximal mesozoo grazing rate
[10362]	42	REAL(wp), PUBLIC :: xkgraz2 !: Half-saturation constant of assimilation
	43	REAL(wp), PUBLIC :: unass2c !: Non-assimilated fraction of food
	44	REAL(wp), PUBLIC :: unass2n !: Non-assimilated fraction of food
	45	REAL(wp), PUBLIC :: unass2p !: Non-assimilated fraction of food
	46	REAL(wp), PUBLIC :: epsher2 !: Growth efficiency of mesozoo
	47	REAL(wp), PUBLIC :: epsher2min !: Minimum growth efficiency of mesozoo
[7162]	48	REAL(wp), PUBLIC :: ssigma2 !: Fraction excreted as semi-labile DOM
	49	REAL(wp), PUBLIC :: srespir2 !: Active respiration
	50	REAL(wp), PUBLIC :: grazflux !: mesozoo flux feeding rate
	51	LOGICAL, PUBLIC :: bmetexc2 !: Use of excess carbon for respiration
	52
	53	!!----------------------------------------------------------------------
[10067]	54	!! NEMO/TOP 4.0 , NEMO Consortium (2018)
[10068]	55	!! $Id$
	56	!! Software governed by the CeCILL license (see ./LICENSE)
[7162]	57	!!----------------------------------------------------------------------
	58
	59	CONTAINS
	60
[11949]	61	SUBROUTINE p5z_meso( kt, knt, Kbb, Krhs )
[7162]	62	!!---------------------------------------------------------------------
	63	!! * ROUTINE p5z_meso *
	64	!!
	65	!! ** Purpose : Compute the sources/sinks for mesozooplankton
	66	!!
	67	!! ** Method : - ???
	68	!!---------------------------------------------------------------------
[11949]	69	INTEGER, INTENT(in) :: kt, knt ! ocean time step
	70	INTEGER, INTENT(in) :: Kbb, Krhs ! time level indices
[7162]	71	INTEGER :: ji, jj, jk
	72	REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam, zcompames
	73	REAL(wp) :: zgraze2, zdenom, zfact, zfood, zfoodlim, zproport
	74	REAL(wp) :: zmortzgoc, zfracc, zfracn, zfracp, zfracfe, zratio, zratio2
	75	REAL(wp) :: zepsherf, zepshert, zepsherv, zrespirc, zrespirn, zrespirp, zbasresb, zbasresi
	76	REAL(wp) :: zgraztotc, zgraztotn, zgraztotp, zgraztotf, zbasresn, zbasresp, zbasresf
	77	REAL(wp) :: zgradoc, zgradon, zgradop, zgratmp, zgradoct, zgradont, zgrareft, zgradopt
	78	REAL(wp) :: zgrapoc, zgrapon, zgrapop, zgrapof, zprcaca, zmortz
	79	REAL(wp) :: zexcess, zgrarem, zgraren, zgrarep, zgraref
	80	REAL(wp) :: zbeta, zrespz, ztortz, zgrasratp, zgrasratn, zgrasratf
	81	REAL(wp) :: ztmp1, ztmp2, ztmp3, ztmp4, ztmp5, ztmptot
	82	REAL(wp) :: zgrazdc, zgrazz, zgrazm, zgrazpof, zgrazcal, zfracal
	83	REAL(wp) :: zgraznc, zgrazpoc, zgrazpon, zgrazpop, zgraznf, zgrazdf
	84	REAL(wp) :: zgraznp, zgraznn, zgrazdn, zgrazdp
	85	REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
	86	REAL(wp) :: zgrazffnp, zgrazffng, zgrazffpp, zgrazffpg
	87	CHARACTER (len=25) :: charout
	88	REAL(wp) :: zrfact2, zmetexcess
[10362]	89	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo2
	90	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d, zz2ligprod
[7162]	91
	92	!!---------------------------------------------------------------------
	93	!
[9124]	94	IF( ln_timing ) CALL timing_start('p5z_meso')
[7162]	95	!
[10362]	96
[7162]	97	zgrazing(:,:,:) = 0._wp
[10362]	98	zfezoo2 (:,:,:) = 0._wp
	99	!
	100	IF (ln_ligand) THEN
	101	ALLOCATE( zz2ligprod(jpi,jpj,jpk) )
	102	zz2ligprod(:,:,:) = 0._wp
	103	ENDIF
[7162]	104
	105	zmetexcess = 0.0
	106	IF ( bmetexc2 ) zmetexcess = 1.0
	107
	108	DO jk = 1, jpkm1
	109	DO jj = 1, jpj
	110	DO ji = 1, jpi
[11949]	111	zcompam = MAX( ( tr(ji,jj,jk,jpmes,Kbb) - 1.e-9 ), 0.e0 )
[7162]	112	zfact = xstep * tgfunc2(ji,jj,jk) * zcompam
	113
	114	! Michaelis-Menten mortality rates of mesozooplankton
	115	! ---------------------------------------------------
[11949]	116	zrespz = resrat2 * zfact * ( tr(ji,jj,jk,jpmes,Kbb) / ( xkmort + tr(ji,jj,jk,jpmes,Kbb) ) &
[7162]	117	& + 3. * nitrfac(ji,jj,jk) )
	118
	119	! Zooplankton mortality. A square function has been selected with
	120	! no real reason except that it seems to be more stable and may mimic predation
	121	! ---------------------------------------------------------------
[11949]	122	ztortz = mzrat2 * 1.e6 * zfact * tr(ji,jj,jk,jpmes,Kbb) * (1. - nitrfac(ji,jj,jk))
[7162]	123
	124	! Computation of the abundance of the preys
	125	! A threshold can be specified in the namelist
	126	! --------------------------------------------
[11949]	127	zcompadi = MAX( ( tr(ji,jj,jk,jpdia,Kbb) - xthresh2dia ), 0.e0 )
	128	zcompaz = MAX( ( tr(ji,jj,jk,jpzoo,Kbb) - xthresh2zoo ), 0.e0 )
	129	zcompaph = MAX( ( tr(ji,jj,jk,jpphy,Kbb) - xthresh2phy ), 0.e0 )
	130	zcompapoc = MAX( ( tr(ji,jj,jk,jppoc,Kbb) - xthresh2poc ), 0.e0 )
	131	zcompames = MAX( ( tr(ji,jj,jk,jpmes,Kbb) - xthresh2mes ), 0.e0 )
[7162]	132
	133	! Mesozooplankton grazing
	134	! ------------------------
[10362]	135	zfood = xpref2d * zcompadi + xpref2z * zcompaz + xpref2n * zcompaph + xpref2c * zcompapoc &
[7162]	136	& + xpref2m * zcompames
	137	zfoodlim = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
	138	zdenom = zfoodlim / ( xkgraz2 + zfoodlim )
[11949]	139	zgraze2 = grazrat2 * xstep * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpmes,Kbb) * (1. - nitrfac(ji,jj,jk))
[7162]	140
	141	! An active switching parameterization is used here.
	142	! We don't use the KTW parameterization proposed by
	143	! Vallina et al. because it tends to produce to steady biomass
	144	! composition and the variance of Chl is too low as it grazes
	145	! too strongly on winning organisms. Thus, instead of a square
	146	! a 1.5 power value is used which decreases the pressure on the
	147	! most abundant species
	148	! ------------------------------------------------------------
[10362]	149	ztmp1 = xpref2n * zcompaph**1.5
[7162]	150	ztmp2 = xpref2m * zcompames**1.5
	151	ztmp3 = xpref2c * zcompapoc**1.5
	152	ztmp4 = xpref2d * zcompadi**1.5
	153	ztmp5 = xpref2z * zcompaz**1.5
	154	ztmptot = ztmp1 + ztmp2 + ztmp3 + ztmp4 + ztmp5 + rtrn
	155	ztmp1 = ztmp1 / ztmptot
	156	ztmp2 = ztmp2 / ztmptot
	157	ztmp3 = ztmp3 / ztmptot
	158	ztmp4 = ztmp4 / ztmptot
	159	ztmp5 = ztmp5 / ztmptot
	160
	161	! Mesozooplankton regular grazing on the different preys
	162	! ------------------------------------------------------
	163	zgrazdc = zgraze2 * ztmp4 * zdenom
[11949]	164	zgrazdn = zgrazdc * tr(ji,jj,jk,jpndi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn)
	165	zgrazdp = zgrazdc * tr(ji,jj,jk,jppdi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn)
	166	zgrazdf = zgrazdc * tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn)
[7162]	167	zgrazz = zgraze2 * ztmp5 * zdenom
	168	zgrazm = zgraze2 * ztmp2 * zdenom
	169	zgraznc = zgraze2 * ztmp1 * zdenom
[11949]	170	zgraznn = zgraznc * tr(ji,jj,jk,jpnph,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn)
	171	zgraznp = zgraznc * tr(ji,jj,jk,jppph,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn)
	172	zgraznf = zgraznc * tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn)
[7162]	173	zgrazpoc = zgraze2 * ztmp3 * zdenom
[11949]	174	zgrazpon = zgrazpoc * tr(ji,jj,jk,jppon,Kbb) / ( tr(ji,jj,jk,jppoc,Kbb) + rtrn)
	175	zgrazpop = zgrazpoc * tr(ji,jj,jk,jppop,Kbb) / ( tr(ji,jj,jk,jppoc,Kbb) + rtrn)
	176	zgrazpof = zgrazpoc * tr(ji,jj,jk,jpsfe,Kbb) / ( tr(ji,jj,jk,jppoc,Kbb) + rtrn)
[7162]	177
	178	! Mesozooplankton flux feeding on GOC
	179	! ----------------------------------
	180	zgrazffeg = grazflux * xstep * wsbio4(ji,jj,jk) &
[11949]	181	& * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpgoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb) &
[10362]	182	& * (1. - nitrfac(ji,jj,jk))
[11949]	183	zgrazfffg = zgrazffeg * tr(ji,jj,jk,jpbfe,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn)
	184	zgrazffng = zgrazffeg * tr(ji,jj,jk,jpgon,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn)
	185	zgrazffpg = zgrazffeg * tr(ji,jj,jk,jpgop,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn)
[7162]	186	zgrazffep = grazflux * xstep * wsbio3(ji,jj,jk) &
[11949]	187	& * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jppoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb) &
[10362]	188	& * (1. - nitrfac(ji,jj,jk))
[11949]	189	zgrazfffp = zgrazffep * tr(ji,jj,jk,jpsfe,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + rtrn)
	190	zgrazffnp = zgrazffep * tr(ji,jj,jk,jppon,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + rtrn)
	191	zgrazffpp = zgrazffep * tr(ji,jj,jk,jppop,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + rtrn)
[7162]	192	!
	193	zgraztotc = zgrazdc + zgrazz + zgraznc + zgrazm + zgrazpoc + zgrazffep + zgrazffeg
	194
	195	! Compute the proportion of filter feeders
	196	! ----------------------------------------
	197	zproport = (zgrazffep + zgrazffeg)/(rtrn + zgraztotc)
	198
	199	! Compute fractionation of aggregates. It is assumed that
	200	! diatoms based aggregates are more prone to fractionation
	201	! since they are more porous (marine snow instead of fecal pellets)
	202	! ----------------------------------------------------------------
[11949]	203	zratio = tr(ji,jj,jk,jpgsi,Kbb) / ( tr(ji,jj,jk,jpgoc,Kbb) + rtrn )
[7162]	204	zratio2 = zratio * zratio
	205	zfracc = zproport * grazflux * xstep * wsbio4(ji,jj,jk) &
[11949]	206	& * tr(ji,jj,jk,jpgoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb) &
[7162]	207	& * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
[11949]	208	zfracfe = zfracc * tr(ji,jj,jk,jpbfe,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn)
	209	zfracn = zfracc * tr(ji,jj,jk,jpgon,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn)
	210	zfracp = zfracc * tr(ji,jj,jk,jpgop,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn)
[7162]	211
	212	zgrazffep = zproport * zgrazffep ; zgrazffeg = zproport * zgrazffeg
	213	zgrazfffp = zproport * zgrazfffp ; zgrazfffg = zproport * zgrazfffg
	214	zgrazffnp = zproport * zgrazffnp ; zgrazffng = zproport * zgrazffng
	215	zgrazffpp = zproport * zgrazffpp ; zgrazffpg = zproport * zgrazffpg
	216
	217	zgraztotc = zgrazdc + zgrazz + zgraznc + zgrazm + zgrazpoc + zgrazffep + zgrazffeg
	218	zgraztotf = zgrazdf + zgraznf + ( zgrazz + zgrazm ) * ferat3 + zgrazpof &
	219	& + zgrazfffp + zgrazfffg
	220	zgraztotn = zgrazdn + (zgrazm + zgrazz) * no3rat3 + zgraznn + zgrazpon &
	221	& + zgrazffnp + zgrazffng
	222	zgraztotp = zgrazdp + (zgrazz + zgrazm) * po4rat3 + zgraznp + zgrazpop &
	223	& + zgrazffpp + zgrazffpg
	224
	225
	226	! Total grazing ( grazing by microzoo is already computed in p5zmicro )
	227	zgrazing(ji,jj,jk) = zgraztotc
	228
	229	! Stoichiometruc ratios of the food ingested by zooplanton
	230	! --------------------------------------------------------
	231	zgrasratf = (zgraztotf + rtrn) / ( zgraztotc + rtrn )
	232	zgrasratn = (zgraztotn + rtrn) / ( zgraztotc + rtrn )
	233	zgrasratp = (zgraztotp + rtrn) / ( zgraztotc + rtrn )
	234
	235	! Growth efficiency is made a function of the quality
	236	! and the quantity of the preys
	237	! ---------------------------------------------------
	238	zepshert = MIN( 1., zgrasratn/ no3rat3, zgrasratp/ po4rat3, zgrasratf / ferat3)
[10362]	239	zbeta = MAX(0., (epsher2 - epsher2min) )
	240	zepsherf = epsher2min + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
[7162]	241	zepsherv = zepsherf * zepshert
	242
	243	! Respiration of mesozooplankton
	244	! Excess carbon in the food is used preferentially
	245	! ---------------- ------------------------------
	246	zexcess = zgraztotc * zepsherf * (1.0 - zepshert) * zmetexcess
	247	zbasresb = MAX(0., zrespz - zexcess)
	248	zbasresi = zexcess + MIN(0., zrespz - zexcess)
	249	zrespirc = srespir2 * zepsherv * zgraztotc + zbasresb
	250
	251	! When excess carbon is used, the other elements in excess
	252	! are also used proportionally to their abundance
	253	! --------------------------------------------------------
	254	zexcess = ( zgrasratn/ no3rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
	255	zbasresn = zbasresi * zexcess * zgrasratn
	256	zexcess = ( zgrasratp/ po4rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
	257	zbasresp = zbasresi * zexcess * zgrasratp
	258	zexcess = ( zgrasratf/ ferat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
	259	zbasresf = zbasresi * zexcess * zgrasratf
	260
	261	! Voiding of the excessive elements as organic matter
	262	! --------------------------------------------------------
	263	zgradoct = (1. - unass2c - zepsherv) * zgraztotc - zbasresi
	264	zgradont = (1. - unass2n) * zgraztotn - zepsherv * no3rat3 * zgraztotc - zbasresn
	265	zgradopt = (1. - unass2p) * zgraztotp - zepsherv * po4rat3 * zgraztotc - zbasresp
	266	zgrareft = (1. - unass2c) * zgraztotf - zepsherv * ferat3 * zgraztotc - zbasresf
	267	ztmp1 = ( 1. - epsher2 - unass2c ) /( 1. - 0.8 * epsher2 ) * ztortz
	268	zgradoc = (zgradoct + ztmp1) * ssigma2
	269	zgradon = (zgradont + no3rat3 * ztmp1) * ssigma2
	270	zgradop = (zgradopt + po4rat3 * ztmp1) * ssigma2
	271	zgratmp = 0.2 * epsher2 /( 1. - 0.8 * epsher2 ) * ztortz
	272
	273	! Since only semilabile DOM is represented in PISCES
	274	! part of DOM is in fact labile and is then released
	275	! as dissolved inorganic compounds (ssigma2)
	276	! --------------------------------------------------
	277	zgrarem = zgratmp + ( zgradoct + ztmp1 ) * (1.0 - ssigma2)
	278	zgraren = no3rat3 * zgratmp + ( zgradont + no3rat3 * ztmp1 ) * (1.0 - ssigma2)
	279	zgrarep = po4rat3 * zgratmp + ( zgradopt + po4rat3 * ztmp1 ) * (1.0 - ssigma2)
	280	zgraref = zgrareft + ferat3 * ( ztmp1 + zgratmp )
	281
	282	! Defecation as a result of non assimilated products
	283	! --------------------------------------------------
	284	zgrapoc = zgraztotc * unass2c + unass2c / ( 1. - 0.8 * epsher2 ) * ztortz
	285	zgrapon = zgraztotn * unass2n + no3rat3 * unass2n / ( 1. - 0.8 * epsher2 ) * ztortz
	286	zgrapop = zgraztotp * unass2p + po4rat3 * unass2p / ( 1. - 0.8 * epsher2 ) * ztortz
	287	zgrapof = zgraztotf * unass2c + ferat3 * unass2c / ( 1. - 0.8 * epsher2 ) * ztortz
	288
	289	! Addition of respiration to the release of inorganic nutrients
	290	! -------------------------------------------------------------
	291	zgrarem = zgrarem + zbasresi + zrespirc
	292	zgraren = zgraren + zbasresn + zrespirc * no3rat3
	293	zgrarep = zgrarep + zbasresp + zrespirc * po4rat3
	294	zgraref = zgraref + zbasresf + zrespirc * ferat3
	295
	296	! Update the arrays TRA which contain the biological sources and
	297	! sinks
	298	! --------------------------------------------------------------
[11949]	299	tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zgrarep
	300	tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zgraren
	301	tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zgradoc
[7162]	302	!
[10362]	303	IF( ln_ligand ) THEN
[11949]	304	tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + zgradoc * ldocz
[10362]	305	zz2ligprod(ji,jj,jk) = zgradoc * ldocz
	306	ENDIF
[7162]	307	!
[11949]	308	tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) + zgradon
	309	tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) + zgradop
	310	tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2ut * zgrarem
	311	tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + zgraref
[10362]	312	zfezoo2(ji,jj,jk) = zgraref
[11949]	313	tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrarem
	314	tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zgraren
	315	tr(ji,jj,jk,jpmes,Krhs) = tr(ji,jj,jk,jpmes,Krhs) + zepsherv * zgraztotc - zrespirc &
[7162]	316	& - ztortz - zgrazm
[11949]	317	tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) - zgrazdc
	318	tr(ji,jj,jk,jpndi,Krhs) = tr(ji,jj,jk,jpndi,Krhs) - zgrazdn
	319	tr(ji,jj,jk,jppdi,Krhs) = tr(ji,jj,jk,jppdi,Krhs) - zgrazdp
	320	tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) - zgrazdf
	321	tr(ji,jj,jk,jpzoo,Krhs) = tr(ji,jj,jk,jpzoo,Krhs) - zgrazz
	322	tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) - zgraznc
	323	tr(ji,jj,jk,jpnph,Krhs) = tr(ji,jj,jk,jpnph,Krhs) - zgraznn
	324	tr(ji,jj,jk,jppph,Krhs) = tr(ji,jj,jk,jppph,Krhs) - zgraznp
	325	tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) - zgraznf
	326	tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) - zgraznc * tr(ji,jj,jk,jpnch,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
	327	tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) - zgrazdc * tr(ji,jj,jk,jpdch,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
	328	tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) - zgrazdc * tr(ji,jj,jk,jpdsi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
	329	tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) + zgrazdc * tr(ji,jj,jk,jpdsi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
[7162]	330
[11949]	331	tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) - zgrazpoc - zgrazffep + zfracc
[7162]	332	prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfracc
	333	conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep
[11949]	334	tr(ji,jj,jk,jppon,Krhs) = tr(ji,jj,jk,jppon,Krhs) - zgrazpon - zgrazffnp + zfracn
	335	tr(ji,jj,jk,jppop,Krhs) = tr(ji,jj,jk,jppop,Krhs) - zgrazpop - zgrazffpp + zfracp
	336	tr(ji,jj,jk,jpgoc,Krhs) = tr(ji,jj,jk,jpgoc,Krhs) - zgrazffeg + zgrapoc - zfracc
[7162]	337	prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zgrapoc
	338	consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfracc
[11949]	339	tr(ji,jj,jk,jpgon,Krhs) = tr(ji,jj,jk,jpgon,Krhs) - zgrazffng + zgrapon - zfracn
	340	tr(ji,jj,jk,jpgop,Krhs) = tr(ji,jj,jk,jpgop,Krhs) - zgrazffpg + zgrapop - zfracp
	341	tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) - zgrazpof - zgrazfffp + zfracfe
	342	tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) - zgrazfffg + zgrapof - zfracfe
	343	zfracal = tr(ji,jj,jk,jpcal,Kbb) / ( tr(ji,jj,jk,jpgoc,Kbb) + rtrn )
[7162]	344	zgrazcal = zgrazffeg * (1. - part2) * zfracal
	345
	346	! calcite production
	347	! ------------------
	348	zprcaca = xfracal(ji,jj,jk) * zgraznc
	349	prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
	350	zprcaca = part2 * zprcaca
[11949]	351	tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrazcal - zprcaca
	352	tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + 2. * ( zgrazcal - zprcaca )
	353	tr(ji,jj,jk,jpcal,Krhs) = tr(ji,jj,jk,jpcal,Krhs) - zgrazcal + zprcaca
[7162]	354	END DO
	355	END DO
	356	END DO
	357	!
	358	IF( lk_iomput .AND. knt == nrdttrc ) THEN
[9125]	359	ALLOCATE( zw3d(jpi,jpj,jpk) )
[7162]	360	IF( iom_use( "GRAZ2" ) ) THEN
	361	zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) ! Total grazing of phyto by zooplankton
	362	CALL iom_put( "GRAZ2", zw3d )
	363	ENDIF
	364	IF( iom_use( "PCAL" ) ) THEN
	365	zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) ! Calcite production
	366	CALL iom_put( "PCAL", zw3d )
	367	ENDIF
[10362]	368	IF( iom_use( "FEZOO2" ) ) THEN
	369	zw3d(:,:,:) = zfezoo2(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) !
	370	CALL iom_put( "FEZOO2", zw3d )
	371	ENDIF
	372	IF( iom_use( "LPRODZ2" ) .AND. ln_ligand ) THEN
	373	zw3d(:,:,:) = zz2ligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
	374	CALL iom_put( "LPRODZ2" , zw3d )
	375	ENDIF
[9125]	376	DEALLOCATE( zw3d )
[7162]	377	ENDIF
	378	!
[12236]	379	IF(sn_cfctl%l_prttrc) THEN ! print mean trends (used for debugging)
[7162]	380	WRITE(charout, FMT="('meso')")
	381	CALL prt_ctl_trc_info(charout)
[11949]	382	CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
[7162]	383	ENDIF
	384	!
[9124]	385	IF( ln_timing ) CALL timing_stop('p5z_meso')
[7162]	386	!
	387	END SUBROUTINE p5z_meso
	388
[9124]	389
[7162]	390	SUBROUTINE p5z_meso_init
	391	!!----------------------------------------------------------------------
	392	!! * ROUTINE p5z_meso_init *
	393	!!
	394	!! ** Purpose : Initialization of mesozooplankton parameters
	395	!!
	396	!! ** Method : Read the nampismes namelist and check the parameters
	397	!! called at the first timestep (nittrc000)
	398	!!
	399	!! ** input : Namelist nampismes
	400	!!
	401	!!----------------------------------------------------------------------
[9124]	402	INTEGER :: ios ! Local integer output status for namelist read
	403	!!
[10362]	404	NAMELIST/namp5zmes/part2, bmetexc2, grazrat2, resrat2, mzrat2, xpref2c, xpref2n, xpref2z, &
[7162]	405	& xpref2m, xpref2d, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
[10362]	406	& xthresh2mes, xthresh2, xkgraz2, epsher2, epsher2min, ssigma2, unass2c, &
[9124]	407	& unass2n, unass2p, srespir2, grazflux
	408	!!----------------------------------------------------------------------
	409	!
[7162]	410	READ ( numnatp_ref, namp5zmes, IOSTAT = ios, ERR = 901)
[11536]	411	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in reference namelist' )
[9124]	412	!
[7162]	413	READ ( numnatp_cfg, namp5zmes, IOSTAT = ios, ERR = 902 )
[11536]	414	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'nampismes in configuration namelist' )
[7162]	415	IF(lwm) WRITE ( numonp, namp5zmes )
[9124]	416	!
[7162]	417	IF(lwp) THEN ! control print
	418	WRITE(numout,*) ' '
	419	WRITE(numout,*) ' Namelist parameters for mesozooplankton, namp5zmes'
	420	WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
	421	WRITE(numout,*) ' part of calcite not dissolved in mesozoo guts part2 = ', part2
[10362]	422	WRITE(numout,*) ' mesozoo preference for nano. xpref2n = ', xpref2n
[7162]	423	WRITE(numout,*) ' mesozoo preference for diatoms xpref2d = ', xpref2d
	424	WRITE(numout,*) ' mesozoo preference for zoo xpref2z = ', xpref2z
	425	WRITE(numout,*) ' mesozoo preference for mesozoo xpref2m = ', xpref2m
	426	WRITE(numout,*) ' mesozoo preference for poc xpref2c = ', xpref2c
	427	WRITE(numout,*) ' microzoo feeding threshold for mesozoo xthresh2zoo = ', xthresh2zoo
	428	WRITE(numout,*) ' diatoms feeding threshold for mesozoo xthresh2dia = ', xthresh2dia
	429	WRITE(numout,*) ' nanophyto feeding threshold for mesozoo xthresh2phy = ', xthresh2phy
	430	WRITE(numout,*) ' poc feeding threshold for mesozoo xthresh2poc = ', xthresh2poc
	431	WRITE(numout,*) ' mesozoo feeding threshold for mesozoo xthresh2mes = ', xthresh2mes
	432	WRITE(numout,*) ' feeding threshold for mesozooplankton xthresh2 = ', xthresh2
	433	WRITE(numout,*) ' exsudation rate of mesozooplankton resrat2 = ', resrat2
	434	WRITE(numout,*) ' mesozooplankton mortality rate mzrat2 = ', mzrat2
	435	WRITE(numout,*) ' maximal mesozoo grazing rate grazrat2 = ', grazrat2
	436	WRITE(numout,*) ' mesozoo flux feeding rate grazflux = ', grazflux
	437	WRITE(numout,*) ' C egested fraction of food by mesozoo unass2c = ', unass2c
[10362]	438	WRITE(numout,*) ' N egested fraction of food by mesozoo unass2n = ', unass2n
	439	WRITE(numout,*) ' P egested fraction of food by mesozoo unass2p = ', unass2p
[7162]	440	WRITE(numout,*) ' Efficicency of Mesozoo growth epsher2 = ', epsher2
[10362]	441	WRITE(numout,*) ' Minimum Efficiency of Mesozoo growth epsher2min =', epsher2min
[7162]	442	WRITE(numout,*) ' Fraction excreted as semi-labile DOM ssigma2 = ', ssigma2
	443	WRITE(numout,*) ' Active respiration srespir2 = ', srespir2
	444	WRITE(numout,*) ' half sturation constant for grazing 2 xkgraz2 = ', xkgraz2
	445	WRITE(numout,*) ' Use excess carbon for respiration bmetexc2 = ', bmetexc2
	446	ENDIF
[9124]	447	!
[7162]	448	END SUBROUTINE p5z_meso_init
	449
	450	!!======================================================================
[9788]	451	END MODULE p5zmeso

Note: See TracBrowser for help on using the repository browser.

Download in other formats: