source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/TOP/trcstp.F90 @ 12236

Last change on this file since 12236 was 12236, checked in by acc, 11 months ago

Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/fix_sn_cfctl_ticket2328. Fully SETTE tested

  • Property svn:keywords set to Id
File size: 11.8 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   trc_stp       : passive tracer system time-stepping
12   !!----------------------------------------------------------------------
13   USE oce_trc        ! ocean dynamics and active tracers variables
14   USE sbc_oce
15   USE trc
16   USE trctrp         ! passive tracers transport
17   USE trcsms         ! passive tracers sources and sinks
18   USE trcwri
19   USE trcrst
20   USE trdtrc_oce
21   USE trdmxl_trc
22   USE sms_pisces,  ONLY : ln_check_mass
23   !
24   USE prtctl_trc     ! Print control for debbuging
25   USE iom            !
26   USE in_out_manager !
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   trc_stp    ! called by step
32
33   LOGICAL  ::   llnew                   ! ???
34   REAL(wp) ::   rdt_sampl               ! ???
35   INTEGER  ::   nb_rec_per_day, ktdcy   ! ???
36   REAL(wp) ::   rsecfst, rseclast       ! ???
37   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr   ! save qsr during TOP time-step
38
39   !!----------------------------------------------------------------------
40   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE trc_stp( kt, Kbb, Kmm, Krhs, Kaa )
47      !!-------------------------------------------------------------------
48      !!                     ***  ROUTINE trc_stp  ***
49      !!                     
50      !! ** Purpose :   Time loop of opa for passive tracer
51      !!
52      !! ** Method  :   Compute the passive tracers trends
53      !!                Update the passive tracers
54      !!-------------------------------------------------------------------
55      INTEGER, INTENT( in ) :: kt                  ! ocean time-step index
56      INTEGER, INTENT( in ) :: Kbb, Kmm, Krhs, Kaa ! time level indices
57      !
58      INTEGER ::   jk, jn   ! dummy loop indices
59      REAL(wp)::   ztrai    ! local scalar
60      LOGICAL ::   ll_trcstat ! local logical
61      CHARACTER (len=25) ::   charout   !
62      !!-------------------------------------------------------------------
63      !
64      IF( ln_timing )   CALL timing_start('trc_stp')
65      !
66      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
67         r2dttrc =  rdttrc           ! = rdttrc (use or restarting with Euler time stepping)
68      ELSEIF( kt <= nittrc000 + 1 ) THEN                                     ! at nittrc000 or nittrc000+1
69         r2dttrc = 2. * rdttrc       ! = 2 rdttrc (leapfrog)
70      ENDIF
71      !
72      ll_trcstat  = ( sn_cfctl%l_trcstat ) .AND. &
73     &              ( ( MOD( kt, sn_cfctl%ptimincr ) == 0 ) .OR. ( kt == nitend ) )
74      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
75      !
76      IF( .NOT.ln_linssh ) THEN                                           ! update ocean volume due to ssh temporal evolution
77         DO jk = 1, jpk
78            cvol(:,:,jk) = e1e2t(:,:) * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
79         END DO
80         IF ( ll_trcstat .OR. kt == nitrst .OR. ( ln_check_mass .AND. kt == nitend )   &
81            & .OR. iom_use( "pno3tot" ) .OR. iom_use( "ppo4tot" ) .OR. iom_use( "psiltot" )   &
82            & .OR. iom_use( "palktot" ) .OR. iom_use( "pfertot" ) )                           &
83            &     areatot = glob_sum( 'trcstp', cvol(:,:,:) )
84      ENDIF
85      !
86      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
87      !   
88      !
89      IF(sn_cfctl%l_prttrc) THEN
90         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
91         CALL prt_ctl_trc_info(charout)
92      ENDIF
93      !
94      tr(:,:,:,:,Krhs) = 0._wp
95      !
96      CALL trc_rst_opn  ( kt )                            ! Open tracer restart file
97      IF( lrst_trc )  CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
98      CALL trc_wri      ( kt,      Kmm            )       ! output of passive tracers with iom I/O manager
99      CALL trc_sms      ( kt, Kbb, Kmm, Krhs      )       ! tracers: sinks and sources
100      CALL trc_trp      ( kt, Kbb, Kmm, Krhs, Kaa )       ! transport of passive tracers
101           !
102           ! Note passive tracers have been time-filtered in trc_trp but the time level
103           ! indices will not be swapped until after tra_atf/dyn_atf/ssh_atf in stp. Subsequent calls here
104           ! anticipate this update which will be: Nrhs= Nbb ; Nbb = Nnn ; Nnn = Naa ; Naa = Nrhs
105           ! and use the filtered levels explicitly.
106           !
107      IF( kt == nittrc000 ) THEN
108         CALL iom_close( numrtr )                         ! close input tracer restart file
109         IF(lwm) CALL FLUSH( numont )                     ! flush namelist output
110      ENDIF
111      IF( lrst_trc )            CALL trc_rst_wri  ( kt, Kmm, Kaa, Kbb  )       ! write tracer restart file
112      IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt,      Kaa       )       ! trends: Mixed-layer
113      !
114      IF( ln_top_euler ) THEN 
115         ! For Euler timestepping for TOP we need to copy the "after" to the "now" fields
116         ! here then after the (leapfrog) swapping of the time-level indices in OCE/step.F90 we have
117         ! "before" fields = "now" fields.
118         tr(:,:,:,:,Kmm) = tr(:,:,:,:,Kaa)
119      ENDIF
120      !
121      IF (ll_trcstat) THEN
122         ztrai = 0._wp                                                   !  content of all tracers
123         DO jn = 1, jptra
124            ztrai = ztrai + glob_sum( 'trcstp', tr(:,:,:,jn,Kaa) * cvol(:,:,:)   )
125         END DO
126         IF( lwm ) WRITE(numstr,9300) kt,  ztrai / areatot
127      ENDIF
1289300  FORMAT(i10,D23.16)
129      !
130      IF( ln_timing )   CALL timing_stop('trc_stp')
131      !
132   END SUBROUTINE trc_stp
133
134   SUBROUTINE trc_mean_qsr( kt )
135      !!----------------------------------------------------------------------
136      !!             ***  ROUTINE trc_mean_qsr  ***
137      !!
138      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
139      !!               of diurnal cycle
140      !!
141      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
142      !!              is greater than 1 hour ) and then, compute the  mean with
143      !!              a moving average over 24 hours.
144      !!              In coupled mode, the sampling is done at every coupling frequency
145      !!----------------------------------------------------------------------
146      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
147      !
148      INTEGER  ::   jn   ! dummy loop indices
149      REAL(wp) ::   zkt, zrec     ! local scalars
150      CHARACTER(len=1) ::   cl1   ! 1 character
151      CHARACTER(len=2) ::   cl2   ! 2 characters
152      !!----------------------------------------------------------------------
153      !
154      IF( ln_timing )   CALL timing_start('trc_mean_qsr')
155      !
156      IF( kt == nittrc000 ) THEN
157         IF( ln_cpl )  THEN 
158            rdt_sampl = rday / ncpl_qsr_freq
159            nb_rec_per_day = ncpl_qsr_freq
160         ELSE 
161            rdt_sampl = MAX( 3600., rdttrc )
162            nb_rec_per_day = INT( rday / rdt_sampl )
163         ENDIF
164         !
165         IF(lwp) THEN
166            WRITE(numout,*) 
167            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
168            WRITE(numout,*) 
169         ENDIF
170         !
171         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
172         !
173         !                                            !* Restart: read in restart file
174         IF( ln_rsttr .AND. nn_rsttr /= 0 .AND. iom_varid( numrtr, 'qsr_mean' , ldstop = .FALSE. ) > 0  &
175           &                              .AND. iom_varid( numrtr, 'qsr_arr_1', ldstop = .FALSE. ) > 0  &
176           &                              .AND. iom_varid( numrtr, 'ktdcy'    , ldstop = .FALSE. ) > 0  &
177           &                              .AND. iom_varid( numrtr, 'nrdcy'    , ldstop = .FALSE. ) > 0  ) THEN
178
179            CALL iom_get( numrtr, 'ktdcy', zkt ) 
180            rsecfst = INT( zkt ) * rdttrc
181            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file at time-step rsecfst =', rsecfst, ' s '
182            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
183            CALL iom_get( numrtr, 'nrdcy', zrec )   !  Number of record per days
184            IF( INT( zrec ) == nb_rec_per_day ) THEN
185               DO jn = 1, nb_rec_per_day 
186                  IF( jn <= 9 )  THEN
187                    WRITE(cl1,'(i1)') jn
188                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )   !  A mean of qsr
189                  ELSE
190                    WRITE(cl2,'(i2.2)') jn
191                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )   !  A mean of qsr
192                  ENDIF
193              END DO
194            ELSE
195               DO jn = 1, nb_rec_per_day
196                  qsr_arr(:,:,jn) = qsr_mean(:,:)
197               ENDDO
198            ENDIF
199         ELSE                                         !* no restart: set from nit000 values
200            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
201            rsecfst  = kt * rdttrc
202            !
203            qsr_mean(:,:) = qsr(:,:)
204            DO jn = 1, nb_rec_per_day
205               qsr_arr(:,:,jn) = qsr_mean(:,:)
206            END DO
207         ENDIF
208         !
209      ENDIF
210      !
211      rseclast = kt * rdttrc
212      !
213      llnew   = ( rseclast - rsecfst ) .ge.  rdt_sampl    !   new shortwave to store
214      IF( llnew ) THEN
215          ktdcy = kt
216          IF( lwp .AND. kt < nittrc000 + 100 ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', ktdcy, &
217             &                      ' time = ', rseclast/3600.,'hours '
218          rsecfst = rseclast
219          DO jn = 1, nb_rec_per_day - 1
220             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
221          ENDDO
222          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
223          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
224      ENDIF
225      !
226      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
227         IF(lwp) WRITE(numout,*)
228         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
229         IF(lwp) WRITE(numout,*) '~~~~~~~'
230         zkt  = REAL( ktdcy, wp )
231         zrec = REAL( nb_rec_per_day, wp )
232         CALL iom_rstput( kt, nitrst, numrtw, 'ktdcy', zkt  )
233         CALL iom_rstput( kt, nitrst, numrtw, 'nrdcy', zrec )
234          DO jn = 1, nb_rec_per_day 
235             IF( jn <= 9 )  THEN
236               WRITE(cl1,'(i1)') jn
237               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )
238             ELSE
239               WRITE(cl2,'(i2.2)') jn
240               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )
241             ENDIF
242         END DO
243         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
244      ENDIF
245      !
246      IF( ln_timing )   CALL timing_stop('trc_mean_qsr')
247      !
248   END SUBROUTINE trc_mean_qsr
249
250#else
251   !!----------------------------------------------------------------------
252   !!   Default key                                     NO passive tracers
253   !!----------------------------------------------------------------------
254CONTAINS
255   SUBROUTINE trc_stp( kt )        ! Empty routine
256      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
257   END SUBROUTINE trc_stp
258#endif
259
260   !!======================================================================
261END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.