New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/DYN – NEMO

source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/DYN/dynhpg.F90 @ 12251

Last change on this file since 12251 was 12210, checked in by cetlod, 4 years ago

dev_merge_option2 : merge in fix_sn_cfctl_ticket2328 branch
  • Property svn:keywords set to Id
File size: 70.1 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE isf_oce , ONLY : risfload  ! ice shelf  (risfload variable)
34   USE isfload , ONLY : isf_load  ! ice shelf  (isf_load routine )
35   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
36   USE dom_oce         ! ocean space and time domain
37   USE wet_dry         ! wetting and drying
38   USE phycst          ! physical constants
39   USE trd_oce         ! trends: ocean variables
40   USE trddyn          ! trend manager: dynamics
41   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE prtctl          ! Print control
45   USE lbclnk          ! lateral boundary condition
46   USE lib_mpp         ! MPP library
47   USE eosbn2          ! compute density
48   USE timing          ! Timing
49   USE iom
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   dyn_hpg        ! routine called by step module
55   PUBLIC   dyn_hpg_init   ! routine called by opa module
56
57   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
58   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
59   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
60   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
61   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
62   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
63   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
64
65   !                                !! Flag to control the type of hydrostatic pressure gradient
66   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
67   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
68   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
69   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
70   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
71   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
72   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
73   !
74   INTEGER, PUBLIC ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
75
76   !! * Substitutions
77#  include "vectopt_loop_substitute.h90"
78   !!----------------------------------------------------------------------
79   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
80   !! $Id$
81   !! Software governed by the CeCILL license (see ./LICENSE)
82   !!----------------------------------------------------------------------
83CONTAINS
84
85   SUBROUTINE dyn_hpg( kt )
86      !!---------------------------------------------------------------------
87      !!                  ***  ROUTINE dyn_hpg  ***
88      !!
89      !! ** Method  :   Call the hydrostatic pressure gradient routine
90      !!              using the scheme defined in the namelist
91      !!
92      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
93      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
94      !!----------------------------------------------------------------------
95      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
96      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
97      !!----------------------------------------------------------------------
98      !
99      IF( ln_timing )   CALL timing_start('dyn_hpg')
100      !
101      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
102         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
103         ztrdu(:,:,:) = ua(:,:,:)
104         ztrdv(:,:,:) = va(:,:,:)
105      ENDIF
106      !
107      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
108      CASE ( np_zco )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
109      CASE ( np_zps )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
110      CASE ( np_sco )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
111      CASE ( np_djc )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
112      CASE ( np_prj )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
113      CASE ( np_isf )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
114      END SELECT
115      !
116      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
117         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
118         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
119         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
120         DEALLOCATE( ztrdu , ztrdv )
121      ENDIF
122      !
123      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
124         &                                  tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
125      !
126      IF( ln_timing )   CALL timing_stop('dyn_hpg')
127      !
128   END SUBROUTINE dyn_hpg
129
130
131   SUBROUTINE dyn_hpg_init
132      !!----------------------------------------------------------------------
133      !!                 ***  ROUTINE dyn_hpg_init  ***
134      !!
135      !! ** Purpose :   initializations for the hydrostatic pressure gradient
136      !!              computation and consistency control
137      !!
138      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
139      !!      with the type of vertical coordinate used (zco, zps, sco)
140      !!----------------------------------------------------------------------
141      INTEGER ::   ioptio = 0      ! temporary integer
142      INTEGER ::   ios             ! Local integer output status for namelist read
143      !!
144      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
145      REAL(wp) ::   znad
146      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
147      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
148      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
149      !!
150      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
151         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
152      !!----------------------------------------------------------------------
153      !
154      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
155901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
156      !
157      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
158902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
159      IF(lwm) WRITE ( numond, namdyn_hpg )
160      !
161      IF(lwp) THEN                   ! Control print
162         WRITE(numout,*)
163         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
164         WRITE(numout,*) '~~~~~~~~~~~~'
165         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
166         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
167         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
168         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
169         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
170         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
171         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
172      ENDIF
173      !
174      IF( ln_hpg_djc )   &
175         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method',   &
176         &                 '   currently disabled (bugs under investigation).'        ,   &
177         &                 '   Please select either  ln_hpg_sco or  ln_hpg_prj instead' )
178         !
179      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )          &
180         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ',   &
181         &                 '   the standard jacobian formulation hpg_sco    or '    ,   &
182         &                 '   the pressure jacobian formulation hpg_prj'             )
183         !
184      IF( ln_hpg_isf ) THEN
185         IF( .NOT. ln_isfcav )   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
186       ELSE
187         IF(       ln_isfcav )   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
188      ENDIF
189      !
190      !                               ! Set nhpg from ln_hpg_... flags & consistency check
191      nhpg   = np_ERROR
192      ioptio = 0
193      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
194      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
195      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
196      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
197      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
198      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
199      !
200      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
201      !
202      IF(lwp) THEN
203         WRITE(numout,*)
204         SELECT CASE( nhpg )
205         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
206         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
207         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
208         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
209         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
210         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
211         END SELECT
212         WRITE(numout,*)
213      ENDIF
214      !                         
215   END SUBROUTINE dyn_hpg_init
216
217   SUBROUTINE hpg_zco( kt )
218      !!---------------------------------------------------------------------
219      !!                  ***  ROUTINE hpg_zco  ***
220      !!
221      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
222      !!      The now hydrostatic pressure gradient at a given level, jk,
223      !!      is computed by taking the vertical integral of the in-situ
224      !!      density gradient along the model level from the suface to that
225      !!      level:    zhpi = grav .....
226      !!                zhpj = grav .....
227      !!      add it to the general momentum trend (ua,va).
228      !!            ua = ua - 1/e1u * zhpi
229      !!            va = va - 1/e2v * zhpj
230      !!
231      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
232      !!----------------------------------------------------------------------
233      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
234      !
235      INTEGER  ::   ji, jj, jk       ! dummy loop indices
236      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
237      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
238      !!----------------------------------------------------------------------
239      !
240      IF( kt == nit000 ) THEN
241         IF(lwp) WRITE(numout,*)
242         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
243         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
244      ENDIF
245
246      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
247
248      ! Surface value
249      DO jj = 2, jpjm1
250         DO ji = fs_2, fs_jpim1   ! vector opt.
251            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
252            ! hydrostatic pressure gradient
253            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
254            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
255            ! add to the general momentum trend
256            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
257            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
258         END DO
259      END DO
260
261      !
262      ! interior value (2=<jk=<jpkm1)
263      DO jk = 2, jpkm1
264         DO jj = 2, jpjm1
265            DO ji = fs_2, fs_jpim1   ! vector opt.
266               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
267               ! hydrostatic pressure gradient
268               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
269                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
270                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
271
272               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
273                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
274                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
275               ! add to the general momentum trend
276               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
277               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
278            END DO
279         END DO
280      END DO
281      !
282   END SUBROUTINE hpg_zco
283
284
285   SUBROUTINE hpg_zps( kt )
286      !!---------------------------------------------------------------------
287      !!                 ***  ROUTINE hpg_zps  ***
288      !!
289      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
290      !!
291      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
292      !!----------------------------------------------------------------------
293      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
294      !!
295      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
296      INTEGER  ::   iku, ikv                         ! temporary integers
297      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
298      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
299      REAL(wp), DIMENSION(jpi,jpj) :: zgtsu, zgtsv, zgru, zgrv
300      !!----------------------------------------------------------------------
301      !
302      IF( kt == nit000 ) THEN
303         IF(lwp) WRITE(numout,*)
304         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
305         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
306      ENDIF
307
308      ! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
309      CALL zps_hde( kt, jpts, tsn, zgtsu, zgtsv, rhd, zgru , zgrv )
310
311      ! Local constant initialization
312      zcoef0 = - grav * 0.5_wp
313
314      !  Surface value (also valid in partial step case)
315      DO jj = 2, jpjm1
316         DO ji = fs_2, fs_jpim1   ! vector opt.
317            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
318            ! hydrostatic pressure gradient
319            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
320            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
321            ! add to the general momentum trend
322            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
323            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
324         END DO
325      END DO
326
327      ! interior value (2=<jk=<jpkm1)
328      DO jk = 2, jpkm1
329         DO jj = 2, jpjm1
330            DO ji = fs_2, fs_jpim1   ! vector opt.
331               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
332               ! hydrostatic pressure gradient
333               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
334                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
335                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
336
337               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
338                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
339                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
340               ! add to the general momentum trend
341               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
342               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
343            END DO
344         END DO
345      END DO
346
347      ! partial steps correction at the last level  (use zgru & zgrv computed in zpshde.F90)
348      DO jj = 2, jpjm1
349         DO ji = 2, jpim1
350            iku = mbku(ji,jj)
351            ikv = mbkv(ji,jj)
352            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
353            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
354            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
355               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
356               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
357                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
358               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
359            ENDIF
360            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
361               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
362               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
363                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
364               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
365            ENDIF
366         END DO
367      END DO
368      !
369   END SUBROUTINE hpg_zps
370
371
372   SUBROUTINE hpg_sco( kt )
373      !!---------------------------------------------------------------------
374      !!                  ***  ROUTINE hpg_sco  ***
375      !!
376      !! ** Method  :   s-coordinate case. Jacobian scheme.
377      !!      The now hydrostatic pressure gradient at a given level, jk,
378      !!      is computed by taking the vertical integral of the in-situ
379      !!      density gradient along the model level from the suface to that
380      !!      level. s-coordinates (ln_sco): a corrective term is added
381      !!      to the horizontal pressure gradient :
382      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
383      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
384      !!      add it to the general momentum trend (ua,va).
385      !!         ua = ua - 1/e1u * zhpi
386      !!         va = va - 1/e2v * zhpj
387      !!
388      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
389      !!----------------------------------------------------------------------
390      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
391      !!
392      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
393      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
394      LOGICAL  ::   ll_tmp1, ll_tmp2                     ! local logical variables
395      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
396      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
397      !!----------------------------------------------------------------------
398      !
399      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
400      !
401      IF( kt == nit000 ) THEN
402         IF(lwp) WRITE(numout,*)
403         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
404         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
405      ENDIF
406      !
407      zcoef0 = - grav * 0.5_wp
408      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
409      ELSE                    ;   znad = 1._wp         ! Variable volume: density
410      ENDIF
411      !
412      IF( ln_wd_il ) THEN
413        DO jj = 2, jpjm1
414           DO ji = 2, jpim1 
415             ll_tmp1 = MIN(  sshn(ji,jj)               ,  sshn(ji+1,jj) ) >                &
416                  &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
417                  &    MAX(  sshn(ji,jj) +  ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
418                  &                                                       > rn_wdmin1 + rn_wdmin2
419             ll_tmp2 = ( ABS( sshn(ji,jj)              -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (       &
420                  &    MAX(   sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
421                  &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
422
423             IF(ll_tmp1) THEN
424               zcpx(ji,jj) = 1.0_wp
425             ELSE IF(ll_tmp2) THEN
426               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
427               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
428                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
429             ELSE
430               zcpx(ji,jj) = 0._wp
431             END IF
432     
433             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
434                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
435                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
436                  &                                                      > rn_wdmin1 + rn_wdmin2
437             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
438                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
439                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
440
441             IF(ll_tmp1) THEN
442               zcpy(ji,jj) = 1.0_wp
443             ELSE IF(ll_tmp2) THEN
444               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
445               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
446                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
447             ELSE
448               zcpy(ji,jj) = 0._wp
449             END IF
450           END DO
451        END DO
452        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
453      END IF
454
455      ! Surface value
456      DO jj = 2, jpjm1
457         DO ji = fs_2, fs_jpim1   ! vector opt.
458            ! hydrostatic pressure gradient along s-surfaces
459            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
460               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
461            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
462               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
463            ! s-coordinate pressure gradient correction
464            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
465               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
466            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
467               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
468            !
469            IF( ln_wd_il ) THEN
470               zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
471               zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
472               zuap = zuap * zcpx(ji,jj)
473               zvap = zvap * zcpy(ji,jj)
474            ENDIF
475            !
476            ! add to the general momentum trend
477            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
478            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
479         END DO
480      END DO
481
482      ! interior value (2=<jk=<jpkm1)
483      DO jk = 2, jpkm1
484         DO jj = 2, jpjm1
485            DO ji = fs_2, fs_jpim1   ! vector opt.
486               ! hydrostatic pressure gradient along s-surfaces
487               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
488                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
489                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
490               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
491                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
492                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
493               ! s-coordinate pressure gradient correction
494               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
495                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
496               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
497                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
498               !
499               IF( ln_wd_il ) THEN
500                  zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
501                  zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
502                  zuap = zuap * zcpx(ji,jj)
503                  zvap = zvap * zcpy(ji,jj)
504               ENDIF
505               !
506               ! add to the general momentum trend
507               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
508               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
509            END DO
510         END DO
511      END DO
512      !
513      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
514      !
515   END SUBROUTINE hpg_sco
516
517
518   SUBROUTINE hpg_isf( kt )
519      !!---------------------------------------------------------------------
520      !!                  ***  ROUTINE hpg_isf  ***
521      !!
522      !! ** Method  :   s-coordinate case. Jacobian scheme.
523      !!      The now hydrostatic pressure gradient at a given level, jk,
524      !!      is computed by taking the vertical integral of the in-situ
525      !!      density gradient along the model level from the suface to that
526      !!      level. s-coordinates (ln_sco): a corrective term is added
527      !!      to the horizontal pressure gradient :
528      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
529      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
530      !!      add it to the general momentum trend (ua,va).
531      !!         ua = ua - 1/e1u * zhpi
532      !!         va = va - 1/e2v * zhpj
533      !!      iceload is added
534      !!     
535      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
536      !!----------------------------------------------------------------------
537      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
538      !!
539      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
540      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
541      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
542      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
543      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
544      !!----------------------------------------------------------------------
545      !
546      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
547      !
548      znad=1._wp                 ! To use density and not density anomaly
549      !
550      !                          ! iniitialised to 0. zhpi zhpi
551      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
552
553      ! compute rhd at the ice/oce interface (ocean side)
554      ! usefull to reduce residual current in the test case ISOMIP with no melting
555      DO ji = 1, jpi
556        DO jj = 1, jpj
557          ikt = mikt(ji,jj)
558          zts_top(ji,jj,1) = tsn(ji,jj,ikt,1)
559          zts_top(ji,jj,2) = tsn(ji,jj,ikt,2)
560        END DO
561      END DO
562      CALL eos( zts_top, risfdep, zrhdtop_oce )
563
564!==================================================================================     
565!===== Compute surface value =====================================================
566!==================================================================================
567      DO jj = 2, jpjm1
568         DO ji = fs_2, fs_jpim1   ! vector opt.
569            ikt    = mikt(ji,jj)
570            iktp1i = mikt(ji+1,jj)
571            iktp1j = mikt(ji,jj+1)
572            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
573            ! we assume ISF is in isostatic equilibrium
574            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
575               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
576               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
577               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
578               &                                  + ( risfload(ji+1,jj) - risfload(ji,jj))                            ) 
579            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
580               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
581               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
582               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
583               &                                  + ( risfload(ji,jj+1) - risfload(ji,jj))                            ) 
584            ! s-coordinate pressure gradient correction (=0 if z coordinate)
585            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
586               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
587            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
588               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
589            ! add to the general momentum trend
590            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
591            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
592         END DO
593      END DO
594!==================================================================================     
595!===== Compute interior value =====================================================
596!==================================================================================
597      ! interior value (2=<jk=<jpkm1)
598      DO jk = 2, jpkm1
599         DO jj = 2, jpjm1
600            DO ji = fs_2, fs_jpim1   ! vector opt.
601               ! hydrostatic pressure gradient along s-surfaces
602               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
603                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
604                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
605               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
606                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
607                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
608               ! s-coordinate pressure gradient correction
609               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
610                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
611               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
612                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
613               ! add to the general momentum trend
614               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
615               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
616            END DO
617         END DO
618      END DO
619      !
620   END SUBROUTINE hpg_isf
621
622
623   SUBROUTINE hpg_djc( kt )
624      !!---------------------------------------------------------------------
625      !!                  ***  ROUTINE hpg_djc  ***
626      !!
627      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
628      !!
629      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
630      !!----------------------------------------------------------------------
631      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
632      !!
633      INTEGER  ::   ji, jj, jk          ! dummy loop indices
634      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
635      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
636      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
637      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
638      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
639      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   dzx, dzy, dzz, dzu, dzv, dzw
640      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, drhoy, drhoz, drhou, drhov, drhow
641      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   rho_i, rho_j, rho_k
642      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
643      !!----------------------------------------------------------------------
644      !
645      IF( ln_wd_il ) THEN
646         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
647        DO jj = 2, jpjm1
648           DO ji = 2, jpim1 
649             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
650                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
651                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
652                  &                                                      > rn_wdmin1 + rn_wdmin2
653             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (        &
654                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
655                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
656             IF(ll_tmp1) THEN
657               zcpx(ji,jj) = 1.0_wp
658             ELSE IF(ll_tmp2) THEN
659               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
660               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
661                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
662             ELSE
663               zcpx(ji,jj) = 0._wp
664             END IF
665     
666             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
667                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
668                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
669                  &                                                      > rn_wdmin1 + rn_wdmin2
670             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
671                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
672                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
673
674             IF(ll_tmp1) THEN
675               zcpy(ji,jj) = 1.0_wp
676             ELSE IF(ll_tmp2) THEN
677               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
678               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
679                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
680             ELSE
681               zcpy(ji,jj) = 0._wp
682             END IF
683           END DO
684        END DO
685        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
686      END IF
687
688      IF( kt == nit000 ) THEN
689         IF(lwp) WRITE(numout,*)
690         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
691         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
692      ENDIF
693
694      ! Local constant initialization
695      zcoef0 = - grav * 0.5_wp
696      z1_10  = 1._wp / 10._wp
697      z1_12  = 1._wp / 12._wp
698
699      !----------------------------------------------------------------------------------------
700      !  compute and store in provisional arrays elementary vertical and horizontal differences
701      !----------------------------------------------------------------------------------------
702
703!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
704
705      DO jk = 2, jpkm1
706         DO jj = 2, jpjm1
707            DO ji = fs_2, fs_jpim1   ! vector opt.
708               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
709               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
710               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
711               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
712               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
713               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
714            END DO
715         END DO
716      END DO
717
718      !-------------------------------------------------------------------------
719      ! compute harmonic averages using eq. 5.18
720      !-------------------------------------------------------------------------
721      zep = 1.e-15
722
723!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
724!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
725
726      DO jk = 2, jpkm1
727         DO jj = 2, jpjm1
728            DO ji = fs_2, fs_jpim1   ! vector opt.
729               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
730
731               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
732               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
733
734               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
735               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
736
737               IF( cffw > zep) THEN
738                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
739                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
740               ELSE
741                  drhow(ji,jj,jk) = 0._wp
742               ENDIF
743
744               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
745                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
746
747               IF( cffu > zep ) THEN
748                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
749                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
750               ELSE
751                  drhou(ji,jj,jk ) = 0._wp
752               ENDIF
753
754               IF( cffx > zep ) THEN
755                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
756                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
757               ELSE
758                  dzu(ji,jj,jk) = 0._wp
759               ENDIF
760
761               IF( cffv > zep ) THEN
762                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
763                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
764               ELSE
765                  drhov(ji,jj,jk) = 0._wp
766               ENDIF
767
768               IF( cffy > zep ) THEN
769                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
770                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
771               ELSE
772                  dzv(ji,jj,jk) = 0._wp
773               ENDIF
774
775            END DO
776         END DO
777      END DO
778
779      !----------------------------------------------------------------------------------
780      ! apply boundary conditions at top and bottom using 5.36-5.37
781      !----------------------------------------------------------------------------------
782      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
783      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
784      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
785
786      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
787      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
788      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
789
790
791      !--------------------------------------------------------------
792      ! Upper half of top-most grid box, compute and store
793      !-------------------------------------------------------------
794
795!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
796!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
797
798      DO jj = 2, jpjm1
799         DO ji = fs_2, fs_jpim1   ! vector opt.
800            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
801               &                   * (  rhd(ji,jj,1)                                     &
802               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
803               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
804               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
805         END DO
806      END DO
807
808!!bug gm    : here also, simplification is possible
809!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
810
811      DO jk = 2, jpkm1
812         DO jj = 2, jpjm1
813            DO ji = fs_2, fs_jpim1   ! vector opt.
814
815               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
816                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
817                  &            - grav * z1_10 * (                                                                   &
818                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
819                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
820                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
821                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
822                  &                             )
823
824               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
825                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
826                  &            - grav* z1_10 * (                                                                    &
827                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
828                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
829                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
830                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
831                  &                            )
832
833               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
834                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
835                  &            - grav* z1_10 * (                                                                    &
836                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
837                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
838                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
839                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
840                  &                            )
841
842            END DO
843         END DO
844      END DO
845      CALL lbc_lnk_multi( 'dynhpg', rho_k, 'W', 1., rho_i, 'U', 1., rho_j, 'V', 1. )
846
847      ! ---------------
848      !  Surface value
849      ! ---------------
850      DO jj = 2, jpjm1
851         DO ji = fs_2, fs_jpim1   ! vector opt.
852            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
853            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
854            IF( ln_wd_il ) THEN
855              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
856              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
857            ENDIF
858            ! add to the general momentum trend
859            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
860            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
861         END DO
862      END DO
863
864      ! ----------------
865      !  interior value   (2=<jk=<jpkm1)
866      ! ----------------
867      DO jk = 2, jpkm1
868         DO jj = 2, jpjm1
869            DO ji = fs_2, fs_jpim1   ! vector opt.
870               ! hydrostatic pressure gradient along s-surfaces
871               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
872                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
873                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
874               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
875                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
876                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
877               IF( ln_wd_il ) THEN
878                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
879                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
880               ENDIF
881               ! add to the general momentum trend
882               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
883               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
884            END DO
885         END DO
886      END DO
887      !
888      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
889      !
890   END SUBROUTINE hpg_djc
891
892
893   SUBROUTINE hpg_prj( kt )
894      !!---------------------------------------------------------------------
895      !!                  ***  ROUTINE hpg_prj  ***
896      !!
897      !! ** Method  :   s-coordinate case.
898      !!      A Pressure-Jacobian horizontal pressure gradient method
899      !!      based on the constrained cubic-spline interpolation for
900      !!      all vertical coordinate systems
901      !!
902      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
903      !!----------------------------------------------------------------------
904      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
905      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
906      !!
907      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
908      REAL(wp) ::   zcoef0, znad                    ! local scalars
909      !
910      !! The local variables for the correction term
911      INTEGER  :: jk1, jis, jid, jjs, jjd
912      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
913      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
914      REAL(wp) :: zrhdt1
915      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
916      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
917      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
918      REAL(wp), DIMENSION(jpi,jpj)   ::   zsshu_n, zsshv_n
919      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
920      !!----------------------------------------------------------------------
921      !
922      IF( kt == nit000 ) THEN
923         IF(lwp) WRITE(numout,*)
924         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
925         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
926      ENDIF
927
928      ! Local constant initialization
929      zcoef0 = - grav
930      znad = 1._wp
931      IF( ln_linssh )   znad = 0._wp
932
933      IF( ln_wd_il ) THEN
934         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
935         DO jj = 2, jpjm1
936           DO ji = 2, jpim1 
937             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
938                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
939                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
940                  &                                                      > rn_wdmin1 + rn_wdmin2
941             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (         &
942                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
943                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
944
945             IF(ll_tmp1) THEN
946               zcpx(ji,jj) = 1.0_wp
947             ELSE IF(ll_tmp2) THEN
948               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
949               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
950                           &    / (sshn(ji+1,jj) -  sshn(ji  ,jj)) )
951             
952                zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
953             ELSE
954               zcpx(ji,jj) = 0._wp
955             END IF
956     
957             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
958                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
959                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
960                  &                                                      > rn_wdmin1 + rn_wdmin2
961             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (      &
962                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
963                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
964
965             IF(ll_tmp1) THEN
966               zcpy(ji,jj) = 1.0_wp
967             ELSE IF(ll_tmp2) THEN
968               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
969               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
970                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
971                zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
972
973               ELSE
974                  zcpy(ji,jj) = 0._wp
975               ENDIF
976            END DO
977         END DO
978         CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
979      ENDIF
980
981      ! Clean 3-D work arrays
982      zhpi(:,:,:) = 0._wp
983      zrhh(:,:,:) = rhd(:,:,:)
984
985      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
986      DO jj = 1, jpj
987        DO ji = 1, jpi
988          jk = mbkt(ji,jj)+1
989          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
990          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
991          ELSEIF( jk < jpkm1 ) THEN
992             DO jkk = jk+1, jpk
993                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
994                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
995             END DO
996          ENDIF
997        END DO
998      END DO
999
1000      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1001      DO jj = 1, jpj
1002         DO ji = 1, jpi
1003            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1004         END DO
1005      END DO
1006
1007      DO jk = 2, jpk
1008         DO jj = 1, jpj
1009            DO ji = 1, jpi
1010               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1011            END DO
1012         END DO
1013      END DO
1014
1015      fsp(:,:,:) = zrhh (:,:,:)
1016      xsp(:,:,:) = zdept(:,:,:)
1017
1018      ! Construct the vertical density profile with the
1019      ! constrained cubic spline interpolation
1020      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1021      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1022
1023      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1024      DO jj = 2, jpj
1025        DO ji = 2, jpi
1026          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1027             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1028
1029          ! assuming linear profile across the top half surface layer
1030          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1031        END DO
1032      END DO
1033
1034      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1035      DO jk = 2, jpkm1
1036        DO jj = 2, jpj
1037          DO ji = 2, jpi
1038            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1039               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1040               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1041               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1042          END DO
1043        END DO
1044      END DO
1045
1046      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1047
1048      ! Prepare zsshu_n and zsshv_n
1049      DO jj = 2, jpjm1
1050        DO ji = 2, jpim1
1051!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1052!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1053!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1054!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1055!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1056!!gm not this:
1057          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1058                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1059          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1060                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1061        END DO
1062      END DO
1063
1064      CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1., zsshv_n, 'V', 1. )
1065
1066      DO jj = 2, jpjm1
1067        DO ji = 2, jpim1
1068          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1069          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1070        END DO
1071      END DO
1072
1073      DO jk = 2, jpkm1
1074        DO jj = 2, jpjm1
1075          DO ji = 2, jpim1
1076            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1077            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1078          END DO
1079        END DO
1080      END DO
1081
1082      DO jk = 1, jpkm1
1083        DO jj = 2, jpjm1
1084          DO ji = 2, jpim1
1085            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1086            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1087          END DO
1088        END DO
1089      END DO
1090
1091      DO jk = 1, jpkm1
1092        DO jj = 2, jpjm1
1093          DO ji = 2, jpim1
1094            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1095            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1096            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1097            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1098          END DO
1099        END DO
1100      END DO
1101
1102
1103      DO jk = 1, jpkm1
1104        DO jj = 2, jpjm1
1105          DO ji = 2, jpim1
1106            zpwes = 0._wp; zpwed = 0._wp
1107            zpnss = 0._wp; zpnsd = 0._wp
1108            zuijk = zu(ji,jj,jk)
1109            zvijk = zv(ji,jj,jk)
1110
1111            !!!!!     for u equation
1112            IF( jk <= mbku(ji,jj) ) THEN
1113               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1114                 jis = ji + 1; jid = ji
1115               ELSE
1116                 jis = ji;     jid = ji +1
1117               ENDIF
1118
1119               ! integrate the pressure on the shallow side
1120               jk1 = jk
1121               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1122                 IF( jk1 == mbku(ji,jj) ) THEN
1123                   zuijk = -zdept(jis,jj,jk1)
1124                   EXIT
1125                 ENDIF
1126                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1127                 zpwes = zpwes +                                    &
1128                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1129                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1130                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1131                 jk1 = jk1 + 1
1132               END DO
1133
1134               ! integrate the pressure on the deep side
1135               jk1 = jk
1136               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1137                 IF( jk1 == 1 ) THEN
1138                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1139                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1140                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1141                                                     dsp(jid,jj,1)) * zdeps
1142                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1143                   EXIT
1144                 ENDIF
1145                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1146                 zpwed = zpwed +                                        &
1147                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1148                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1149                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1150                 jk1 = jk1 - 1
1151               END DO
1152
1153               ! update the momentum trends in u direction
1154
1155               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1156               IF( .NOT.ln_linssh ) THEN
1157                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1158                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1159                ELSE
1160                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1161               ENDIF
1162               IF( ln_wd_il ) THEN
1163                  zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1164                  zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1165               ENDIF
1166               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1167            ENDIF
1168
1169            !!!!!     for v equation
1170            IF( jk <= mbkv(ji,jj) ) THEN
1171               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1172                 jjs = jj + 1; jjd = jj
1173               ELSE
1174                 jjs = jj    ; jjd = jj + 1
1175               ENDIF
1176
1177               ! integrate the pressure on the shallow side
1178               jk1 = jk
1179               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1180                 IF( jk1 == mbkv(ji,jj) ) THEN
1181                   zvijk = -zdept(ji,jjs,jk1)
1182                   EXIT
1183                 ENDIF
1184                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1185                 zpnss = zpnss +                                      &
1186                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1187                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1188                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1189                 jk1 = jk1 + 1
1190               END DO
1191
1192               ! integrate the pressure on the deep side
1193               jk1 = jk
1194               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1195                 IF( jk1 == 1 ) THEN
1196                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1197                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1198                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1199                                                     dsp(ji,jjd,1) ) * zdeps
1200                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1201                   EXIT
1202                 ENDIF
1203                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1204                 zpnsd = zpnsd +                                        &
1205                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1206                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1207                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1208                 jk1 = jk1 - 1
1209               END DO
1210
1211
1212               ! update the momentum trends in v direction
1213
1214               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1215               IF( .NOT.ln_linssh ) THEN
1216                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1217                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1218               ELSE
1219                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1220               ENDIF
1221               IF( ln_wd_il ) THEN
1222                  zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1223                  zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1224               ENDIF
1225
1226               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1227            ENDIF
1228               !
1229            END DO
1230         END DO
1231      END DO
1232      !
1233      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1234      !
1235   END SUBROUTINE hpg_prj
1236
1237
1238   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1239      !!----------------------------------------------------------------------
1240      !!                 ***  ROUTINE cspline  ***
1241      !!
1242      !! ** Purpose :   constrained cubic spline interpolation
1243      !!
1244      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1245      !!
1246      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1247      !!----------------------------------------------------------------------
1248      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1249      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1250      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1251      !
1252      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1253      INTEGER  ::   jpi, jpj, jpkm1
1254      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1255      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1256      REAL(wp) ::   zdf(size(fsp,3))
1257      !!----------------------------------------------------------------------
1258      !
1259!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1260      jpi   = size(fsp,1)
1261      jpj   = size(fsp,2)
1262      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1263      !
1264      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1265         DO ji = 1, jpi
1266            DO jj = 1, jpj
1267           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1268           !    DO jk = 2, jpkm1-1
1269           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1270           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1271           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1272           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1273           !
1274           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1275           !
1276           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1277           !           zdf(jk) = 0._wp
1278           !       ELSE
1279           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1280           !       ENDIF
1281           !    END DO
1282
1283           !!Simply geometric average
1284               DO jk = 2, jpkm1-1
1285                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1286                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1287
1288                  IF(zdf1 * zdf2 <= 0._wp) THEN
1289                     zdf(jk) = 0._wp
1290                  ELSE
1291                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1292                  ENDIF
1293               END DO
1294
1295               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1296                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1297               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1298                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1299
1300               DO jk = 1, jpkm1 - 1
1301                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1302                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1303                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1304                 zddf1  = -2._wp * ztmp1 + ztmp2
1305                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1306                 zddf2  =  2._wp * ztmp1 - ztmp2
1307
1308                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1309                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1310                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1311                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1312                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1313                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1314                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1315                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1316                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1317               END DO
1318            END DO
1319         END DO
1320
1321      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1322         DO ji = 1, jpi
1323            DO jj = 1, jpj
1324               DO jk = 1, jpkm1-1
1325                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1326                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1327
1328                  dsp(ji,jj,jk) = 0._wp
1329                  csp(ji,jj,jk) = 0._wp
1330                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1331                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1332               END DO
1333            END DO
1334         END DO
1335         !
1336      ELSE
1337         CALL ctl_stop( 'invalid polynomial type in cspline' )
1338      ENDIF
1339      !
1340   END SUBROUTINE cspline
1341
1342
1343   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1344      !!----------------------------------------------------------------------
1345      !!                 ***  ROUTINE interp1  ***
1346      !!
1347      !! ** Purpose :   1-d linear interpolation
1348      !!
1349      !! ** Method  :   interpolation is straight forward
1350      !!                extrapolation is also permitted (no value limit)
1351      !!----------------------------------------------------------------------
1352      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1353      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1354      REAL(wp)             ::  zdeltx
1355      !!----------------------------------------------------------------------
1356      !
1357      zdeltx = xr - xl
1358      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1359         f = 0.5_wp * (fl + fr)
1360      ELSE
1361         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1362      ENDIF
1363      !
1364   END FUNCTION interp1
1365
1366
1367   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1368      !!----------------------------------------------------------------------
1369      !!                 ***  ROUTINE interp1  ***
1370      !!
1371      !! ** Purpose :   1-d constrained cubic spline interpolation
1372      !!
1373      !! ** Method  :  cubic spline interpolation
1374      !!
1375      !!----------------------------------------------------------------------
1376      REAL(wp), INTENT(in) ::  x, a, b, c, d
1377      REAL(wp)             ::  f ! value from the interpolation
1378      !!----------------------------------------------------------------------
1379      !
1380      f = a + x* ( b + x * ( c + d * x ) )
1381      !
1382   END FUNCTION interp2
1383
1384
1385   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1386      !!----------------------------------------------------------------------
1387      !!                 ***  ROUTINE interp1  ***
1388      !!
1389      !! ** Purpose :   Calculate the first order of derivative of
1390      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1391      !!
1392      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1393      !!
1394      !!----------------------------------------------------------------------
1395      REAL(wp), INTENT(in) ::  x, a, b, c, d
1396      REAL(wp)             ::  f ! value from the interpolation
1397      !!----------------------------------------------------------------------
1398      !
1399      f = b + x * ( 2._wp * c + 3._wp * d * x)
1400      !
1401   END FUNCTION interp3
1402
1403
1404   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1405      !!----------------------------------------------------------------------
1406      !!                 ***  ROUTINE interp1  ***
1407      !!
1408      !! ** Purpose :   1-d constrained cubic spline integration
1409      !!
1410      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1411      !!
1412      !!----------------------------------------------------------------------
1413      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1414      REAL(wp)             ::  za1, za2, za3
1415      REAL(wp)             ::  f                   ! integration result
1416      !!----------------------------------------------------------------------
1417      !
1418      za1 = 0.5_wp * b
1419      za2 = c / 3.0_wp
1420      za3 = 0.25_wp * d
1421      !
1422      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1423         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1424      !
1425   END FUNCTION integ_spline
1426
1427   !!======================================================================
1428END MODULE dynhpg
1429
Note: See TracBrowser for help on using the repository browser.