source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/OCE/SBC/sbcmod.F90 @ 12169

Last change on this file since 12169 was 12169, checked in by cetlod, 10 months ago

Bugfixes

  • Property svn:keywords set to Id
File size: 35.3 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!            4.0  ! 2019-03  (F. Lemarié & G. Samson)  add ABL compatibility (ln_abl=TRUE)
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   sbc_init      : read namsbc namelist
22   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
23   !!   sbc_final     : Finalize CICE ice model (if used)
24   !!----------------------------------------------------------------------
25   USE oce            ! ocean dynamics and tracers
26   USE dom_oce        ! ocean space and time domain
27   USE phycst         ! physical constants
28   USE sbc_oce        ! Surface boundary condition: ocean fields
29   USE trc_oce        ! shared ocean-passive tracers variables
30   USE sbc_ice        ! Surface boundary condition: ice fields
31   USE sbcdcy         ! surface boundary condition: diurnal cycle
32   USE sbcssm         ! surface boundary condition: sea-surface mean variables
33   USE sbcflx         ! surface boundary condition: flux formulation
34   USE sbcblk         ! surface boundary condition: bulk formulation
35   USE sbcabl         ! atmospheric boundary layer
36   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
37#if defined key_si3
38   USE icestp         ! surface boundary condition: SI3 sea-ice model
39#endif
40   USE sbcice_cice    ! surface boundary condition: CICE sea-ice model
41   USE sbccpl         ! surface boundary condition: coupled formulation
42   USE cpl_oasis3     ! OASIS routines for coupling
43   USE sbcssr         ! surface boundary condition: sea surface restoring
44   USE sbcrnf         ! surface boundary condition: runoffs
45   USE sbcapr         ! surface boundary condition: atmo pressure
46   USE sbcfwb         ! surface boundary condition: freshwater budget
47   USE icbstp         ! Icebergs
48   USE icb_oce  , ONLY : ln_passive_mode      ! iceberg interaction mode
49   USE traqsr         ! active tracers: light penetration
50   USE sbcwave        ! Wave module
51   USE bdy_oce   , ONLY: ln_bdy
52   USE usrdef_sbc     ! user defined: surface boundary condition
53   USE closea         ! closed sea
54   !
55   USE prtctl         ! Print control                    (prt_ctl routine)
56   USE iom            ! IOM library
57   USE in_out_manager ! I/O manager
58   USE lib_mpp        ! MPP library
59   USE timing         ! Timing
60   USE wet_dry
61   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
62
63   IMPLICIT NONE
64   PRIVATE
65
66   PUBLIC   sbc        ! routine called by step.F90
67   PUBLIC   sbc_init   ! routine called by opa.F90
68
69   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
70
71   !!----------------------------------------------------------------------
72   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
73   !! $Id$
74   !! Software governed by the CeCILL license (see ./LICENSE)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   SUBROUTINE sbc_init
79      !!---------------------------------------------------------------------
80      !!                    ***  ROUTINE sbc_init ***
81      !!
82      !! ** Purpose :   Initialisation of the ocean surface boundary computation
83      !!
84      !! ** Method  :   Read the namsbc namelist and set derived parameters
85      !!                Call init routines for all other SBC modules that have one
86      !!
87      !! ** Action  : - read namsbc parameters
88      !!              - nsbc: type of sbc
89      !!----------------------------------------------------------------------
90      INTEGER ::   ios, icpt                         ! local integer
91      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
92      !!
93      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
94         &             ln_usr   , ln_flx   , ln_blk   , ln_abl,                      &
95         &             ln_cpl   , ln_mixcpl, nn_components,                          &
96         &             nn_ice   , ln_ice_embd,                                       &
97         &             ln_traqsr, ln_dm2dc ,                                         &
98         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_apr_dyn ,     &
99         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauwoc  , ln_stcor  ,     &
100         &             ln_tauw  , nn_lsm, nn_sdrift
101      !!----------------------------------------------------------------------
102      !
103      IF(lwp) THEN
104         WRITE(numout,*)
105         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
106         WRITE(numout,*) '~~~~~~~~ '
107      ENDIF
108      !
109      !                       !**  read Surface Module namelist
110      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
111      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
112901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
113      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
114      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
115902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
116      IF(lwm) WRITE( numond, namsbc )
117      !
118#if defined key_mpp_mpi
119      ncom_fsbc = nn_fsbc    ! make nn_fsbc available for lib_mpp
120#endif
121      !                             !* overwrite namelist parameter using CPP key information
122#if defined key_agrif
123      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
124         IF( lk_si3  )   nn_ice      = 2
125         IF( lk_cice )   nn_ice      = 3
126      ENDIF
127!!GS: TBD
128!#else
129!      IF( lk_si3  )   nn_ice      = 2
130!      IF( lk_cice )   nn_ice      = 3
131#endif
132      !
133      IF(lwp) THEN                  !* Control print
134         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
135         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
136         WRITE(numout,*) '      Type of air-sea fluxes : '
137         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
138         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
139         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
140         WRITE(numout,*) '         ABL          formulation                   ln_abl        = ', ln_abl
141         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
142         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
143         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
144!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
145         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
146         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
147         WRITE(numout,*) '      Sea-ice : '
148         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
149         WRITE(numout,*) '         ice embedded into ocean                    ln_ice_embd   = ', ln_ice_embd
150         WRITE(numout,*) '      Misc. options of sbc : '
151         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
152         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
153         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
154         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
155         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
156         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
157         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
158         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
159         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
160         WRITE(numout,*) '                  vertical parametrization          nn_sdrift     = ', nn_sdrift
161         WRITE(numout,*) '               wave modified ocean stress           ln_tauwoc     = ', ln_tauwoc
162         WRITE(numout,*) '               wave modified ocean stress component ln_tauw       = ', ln_tauw
163         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
164         WRITE(numout,*) '               neutral drag coefficient (CORE,NCAR) ln_cdgw       = ', ln_cdgw
165      ENDIF
166      !
167      IF( .NOT.ln_wave ) THEN
168         ln_sdw = .false. ; ln_cdgw = .false. ; ln_tauwoc = .false. ; ln_tauw = .false. ; ln_stcor = .false.
169      ENDIF
170      IF( ln_sdw ) THEN
171         IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) &
172            CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' )
173      ENDIF
174      ll_st_bv2014  = ( nn_sdrift==jp_breivik_2014 )
175      ll_st_li2017  = ( nn_sdrift==jp_li_2017 )
176      ll_st_bv_li   = ( ll_st_bv2014 .OR. ll_st_li2017 )
177      ll_st_peakfr  = ( nn_sdrift==jp_peakfr )
178      IF( ln_tauwoc .AND. ln_tauw ) &
179         CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', &
180                                  '(ln_tauwoc=.true. and ln_tauw=.true.)' )
181      IF( ln_tauwoc ) &
182         CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' )
183      IF( ln_tauw ) &
184         CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', &
185                              'This will override any other specification of the ocean stress' )
186      !
187      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
188         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
189         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
190         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
191      ENDIF
192      !                       !**  check option consistency
193      !
194      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
195      SELECT CASE( nn_components )
196      CASE( jp_iam_nemo )
197         IF(lwp) WRITE(numout,*) '   ==>>>   NEMO configured as a single executable (i.e. including both OPA and Surface module)'
198      CASE( jp_iam_opa  )
199         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, OPA component'
200         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
201         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
202         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
203      CASE( jp_iam_sas  )
204         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, SAS component'
205         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
206         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
207      CASE DEFAULT
208         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
209      END SELECT
210      !                             !* coupled options
211      IF( ln_cpl ) THEN
212         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
213            &                                  '           required to defined key_oasis3' )
214      ENDIF
215      IF( ln_mixcpl ) THEN
216         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
217            &                                  '           required to defined key_oasis3' )
218         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
219         IF( nn_components /= jp_iam_nemo )    &
220            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
221            &                                   '          not yet working with sas-opa coupling via oasis' )
222      ENDIF
223      !                             !* sea-ice
224      SELECT CASE( nn_ice )
225      CASE( 0 )                        !- no ice in the domain
226      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
227      CASE( 2 )                        !- SI3  ice model
228         IF( .NOT.( ln_blk .OR. ln_cpl .OR. ln_abl .OR. ln_usr ) )   &
229            &                   CALL ctl_stop( 'sbc_init : SI3 sea-ice model requires ln_blk or ln_cpl or ln_abl or ln_usr = T' )
230      CASE( 3 )                        !- CICE ice model
231         IF( .NOT.( ln_blk .OR. ln_cpl .OR. ln_abl .OR. ln_usr ) )   &
232            &                   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl or ln_abl or ln_usr = T' )
233         IF( lk_agrif                                )   &
234            &                   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
235      CASE DEFAULT                     !- not supported
236      END SELECT
237      !
238      !                       !**  allocate and set required variables
239      !
240      !                             !* allocate sbc arrays
241      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
242#if ! defined key_si3 && ! defined key_cice
243      IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' )
244#endif
245      !
246      IF( sbc_ssr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_ssr arrays' )
247      IF( .NOT.ln_ssr ) THEN               !* Initialize qrp and erp if no restoring
248         qrp(:,:) = 0._wp
249         erp(:,:) = 0._wp
250      ENDIF
251      !
252      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
253         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
254      ENDIF
255      !
256      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
257      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
258
259      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
260
261      !                          ! Choice of the Surface Boudary Condition (set nsbc)
262      nday_qsr = -1   ! allow initialization at the 1st call !LB: now warm-layer of COARE* calls "sbc_dcy_param" of sbcdcy.F90!
263      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
264         !LB:nday_qsr = -1   ! allow initialization at the 1st call
265         IF( .NOT.( ln_flx .OR. ln_blk .OR. ln_abl ) .AND. nn_components /= jp_iam_opa )   &
266            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires flux, bulk or abl formulation' )
267      ENDIF
268      !                             !* Choice of the Surface Boudary Condition
269      !                             (set nsbc)
270      !
271      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
272      ll_opa      = nn_components == jp_iam_opa
273      ll_not_nemo = nn_components /= jp_iam_nemo
274      icpt = 0
275      !
276      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
277      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
278      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
279      IF( ln_abl          ) THEN   ;   nsbc = jp_abl     ; icpt = icpt + 1   ;   ENDIF       ! ABL                  formulation
280      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
281      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
282      !
283      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
284      !
285      IF(lwp) THEN                     !- print the choice of surface flux formulation
286         WRITE(numout,*)
287         SELECT CASE( nsbc )
288         CASE( jp_usr     )   ;   WRITE(numout,*) '   ==>>>   user defined forcing formulation'
289         CASE( jp_flx     )   ;   WRITE(numout,*) '   ==>>>   flux formulation'
290         CASE( jp_blk     )   ;   WRITE(numout,*) '   ==>>>   bulk formulation'
291         CASE( jp_abl     )   ;   WRITE(numout,*) '   ==>>>   ABL  formulation'
292         CASE( jp_purecpl )   ;   WRITE(numout,*) '   ==>>>   pure coupled formulation'
293!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
294         CASE( jp_none    )   ;   WRITE(numout,*) '   ==>>>   OPA coupled to SAS via oasis'
295            IF( ln_mixcpl )       WRITE(numout,*) '               + forced-coupled mixed formulation'
296         END SELECT
297         IF( ll_not_nemo  )       WRITE(numout,*) '               + OASIS coupled SAS'
298      ENDIF
299      !
300      !                             !* OASIS initialization
301      !
302      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
303      !                                              !                      (2) the use of nn_fsbc
304      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
305      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
306      IF( nn_components /= jp_iam_nemo ) THEN
307         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
308         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
309         !
310         IF(lwp)THEN
311            WRITE(numout,*)
312            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
313            WRITE(numout,*)
314         ENDIF
315      ENDIF
316      !
317      !                             !* check consistency between model timeline and nn_fsbc
318      IF( ln_rst_list .OR. nn_stock /= -1 ) THEN   ! we will do restart files
319         IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 ) THEN
320            WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
321            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
322         ENDIF
323         IF( .NOT. ln_rst_list .AND. MOD( nn_stock, nn_fsbc) /= 0 ) THEN   ! we don't use nn_stock if ln_rst_list
324            WRITE(ctmp1,*) 'sbc_init : nn_stock (', nn_stock, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
325            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
326         ENDIF
327      ENDIF
328      !
329      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
330         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
331      !
332      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
333         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
334      !
335   
336      !                       !**  associated modules : initialization
337      !
338                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
339      !
340      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
341
342      IF( ln_abl      )   CALL sbc_abl_init            ! Atmospheric Boundary Layer (ABL)
343
344      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
345      !
346                          CALL sbc_rnf_init            ! Runof initialization
347      !
348      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
349      !
350#if defined key_si3
351      IF( lk_agrif .AND. nn_ice == 0 ) THEN            ! allocate ice arrays in case agrif + ice-model + no-ice in child grid
352                          IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' )
353      ELSEIF( nn_ice == 2 ) THEN
354                          CALL ice_init                ! ICE initialization
355      ENDIF
356#endif
357      IF( nn_ice == 3 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
358      !
359      IF( ln_wave     )   CALL sbc_wave_init           ! surface wave initialisation
360      !
361      IF( lwxios ) THEN
362         CALL iom_set_rstw_var_active('utau_b')
363         CALL iom_set_rstw_var_active('vtau_b')
364         CALL iom_set_rstw_var_active('qns_b')
365         ! The 3D heat content due to qsr forcing is treated in traqsr
366         ! CALL iom_set_rstw_var_active('qsr_b')
367         CALL iom_set_rstw_var_active('emp_b')
368         CALL iom_set_rstw_var_active('sfx_b')
369      ENDIF
370
371   END SUBROUTINE sbc_init
372
373
374   SUBROUTINE sbc( kt )
375      !!---------------------------------------------------------------------
376      !!                    ***  ROUTINE sbc  ***
377      !!
378      !! ** Purpose :   provide at each time-step the ocean surface boundary
379      !!                condition (momentum, heat and freshwater fluxes)
380      !!
381      !! ** Method  :   blah blah  to be written ?????????
382      !!                CAUTION : never mask the surface stress field (tke sbc)
383      !!
384      !! ** Action  : - set the ocean surface boundary condition at before and now
385      !!                time step, i.e.
386      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
387      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
388      !!              - updte the ice fraction : fr_i
389      !!----------------------------------------------------------------------
390      INTEGER, INTENT(in) ::   kt   ! ocean time step
391      !
392      LOGICAL ::   ll_sas, ll_opa   ! local logical
393      !
394      REAL(wp) ::     zthscl        ! wd  tanh scale
395      REAL(wp), DIMENSION(jpi,jpj) ::  zwdht, zwght  ! wd dep over wd limit, wgt 
396
397      !!---------------------------------------------------------------------
398      !
399      IF( ln_timing )   CALL timing_start('sbc')
400      !
401      !                                            ! ---------------------------------------- !
402      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
403         !                                         ! ---------------------------------------- !
404         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
405         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
406         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
407         emp_b (:,:) = emp (:,:)
408         sfx_b (:,:) = sfx (:,:)
409         IF( ln_rnf ) THEN
410            rnf_b    (:,:  ) = rnf    (:,:  )
411            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
412         ENDIF
413        !
414      ENDIF
415      !                                            ! ---------------------------------------- !
416      !                                            !        forcing field computation         !
417      !                                            ! ---------------------------------------- !
418      !
419      ll_sas = nn_components == jp_iam_sas               ! component flags
420      ll_opa = nn_components == jp_iam_opa
421      !
422      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
423      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
424
425      !
426      !                                            !==  sbc formulation  ==!
427      !                                                   
428      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
429      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
430      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
431      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
432      CASE( jp_blk     )
433         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
434                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
435                               !
436      CASE( jp_abl     )
437         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
438                               CALL sbc_abl       ( kt )                    ! ABL  formulation for the ocean
439                               !
440      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
441      CASE( jp_none    )
442         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
443      END SELECT
444      !
445      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
446      !
447      IF( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( )      ! Wind stress provided by waves
448      !
449      !                                            !==  Misc. Options  ==!
450      !
451      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
452      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )             ! Ice-cover climatology ("Ice-if" model)
453#if defined key_si3
454      CASE(  2 )   ;         CALL ice_stp  ( kt, nsbc )           ! SI3 ice model
455#endif
456      CASE(  3 )   ;         CALL sbc_ice_cice ( kt, nsbc )       ! CICE ice model
457      END SELECT
458
459      IF( ln_icebergs    )   THEN
460                                     CALL icb_stp( kt )           ! compute icebergs
461         ! icebergs may advect into haloes during the icb step and alter emp.
462         ! A lbc_lnk is necessary here to ensure restartability (#2113)
463         IF( .NOT. ln_passive_mode ) CALL lbc_lnk( 'sbcmod', emp, 'T', 1. ) ! ensure restartability with icebergs
464      ENDIF
465
466      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
467
468      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
469
470      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
471
472      ! Special treatment of freshwater fluxes over closed seas in the model domain
473      ! Should not be run if ln_diurnal_only
474      IF( l_sbc_clo .AND. (.NOT. ln_diurnal_only) )   CALL sbc_clo( kt )   
475
476!!$!RBbug do not understand why see ticket 667
477!!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
478!!$      CALL lbc_lnk( 'sbcmod', emp, 'T', 1. )
479      IF( ll_wd ) THEN     ! If near WAD point limit the flux for now
480         zthscl = atanh(rn_wd_sbcfra)                     ! taper frac default is .999
481         zwdht(:,:) = sshn(:,:) + ht_0(:,:) - rn_wdmin1   ! do this calc of water
482                                                     ! depth above wd limit once
483         WHERE( zwdht(:,:) <= 0.0 )
484            taum(:,:) = 0.0
485            utau(:,:) = 0.0
486            vtau(:,:) = 0.0
487            qns (:,:) = 0.0
488            qsr (:,:) = 0.0
489            emp (:,:) = min(emp(:,:),0.0) !can allow puddles to grow but not shrink
490            sfx (:,:) = 0.0
491         END WHERE
492         zwght(:,:) = tanh(zthscl*zwdht(:,:))
493         WHERE( zwdht(:,:) > 0.0  .and. zwdht(:,:) < rn_wd_sbcdep ) !  5 m hard limit here is arbitrary
494            qsr  (:,:) =  qsr(:,:)  * zwght(:,:)
495            qns  (:,:) =  qns(:,:)  * zwght(:,:)
496            taum (:,:) =  taum(:,:) * zwght(:,:)
497            utau (:,:) =  utau(:,:) * zwght(:,:)
498            vtau (:,:) =  vtau(:,:) * zwght(:,:)
499            sfx  (:,:) =  sfx(:,:)  * zwght(:,:)
500            emp  (:,:) =  emp(:,:)  * zwght(:,:)
501         END WHERE
502      ENDIF
503      !
504      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
505         !                                             ! ---------------------------------------- !
506         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
507            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
508            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
509            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, ldxios = lrxios )   ! before i-stress  (U-point)
510            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, ldxios = lrxios )   ! before j-stress  (V-point)
511            CALL iom_get( numror, jpdom_autoglo,  'qns_b',  qns_b, ldxios = lrxios )   ! before non solar heat flux (T-point)
512            ! The 3D heat content due to qsr forcing is treated in traqsr
513            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, ldxios = lrxios  ) ! before     solar heat flux (T-point)
514            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, ldxios = lrxios  )    ! before     freshwater flux (T-point)
515            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
516            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
517               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, ldxios = lrxios )  ! before salt flux (T-point)
518            ELSE
519               sfx_b (:,:) = sfx(:,:)
520            ENDIF
521         ELSE                                                   !* no restart: set from nit000 values
522            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
523            utau_b(:,:) = utau(:,:)
524            vtau_b(:,:) = vtau(:,:)
525            qns_b (:,:) = qns (:,:)
526            emp_b (:,:) = emp (:,:)
527            sfx_b (:,:) = sfx (:,:)
528         ENDIF
529      ENDIF
530      !                                                ! ---------------------------------------- !
531      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
532         !                                             ! ---------------------------------------- !
533         IF(lwp) WRITE(numout,*)
534         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
535            &                    'at it= ', kt,' date= ', ndastp
536         IF(lwp) WRITE(numout,*) '~~~~'
537         IF( lwxios ) CALL iom_swap(      cwxios_context          )
538         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios )
539         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios )
540         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns, ldxios = lwxios  )
541         ! The 3D heat content due to qsr forcing is treated in traqsr
542         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
543         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp, ldxios = lwxios  )
544         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx, ldxios = lwxios  )
545         IF( lwxios ) CALL iom_swap(      cxios_context          )
546      ENDIF
547      !                                                ! ---------------------------------------- !
548      !                                                !        Outputs and control print         !
549      !                                                ! ---------------------------------------- !
550      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
551         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
552         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
553         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
554         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
555         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
556         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
557         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
558         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
559         CALL iom_put( "taum"  , taum       )                   ! wind stress module
560         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
561         CALL iom_put( "qrp", qrp )                             ! heat flux damping
562         CALL iom_put( "erp", erp )                             ! freshwater flux damping
563      ENDIF
564      !
565      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
566      CALL iom_put( "vtau", vtau )   ! j-wind stress
567      !
568      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
569         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i     - : ', mask1=tmask )
570         CALL prt_ctl(tab2d_1=(emp-rnf)        , clinfo1=' emp-rnf  - : ', mask1=tmask )
571         CALL prt_ctl(tab2d_1=(sfx-rnf)        , clinfo1=' sfx-rnf  - : ', mask1=tmask )
572         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask )
573         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask )
574         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, kdim=jpk )
575         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, kdim=1   )
576         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, kdim=1   )
577         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
578            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask )
579      ENDIF
580
581      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
582      !
583      IF( ln_timing )   CALL timing_stop('sbc')
584      !
585   END SUBROUTINE sbc
586
587
588   SUBROUTINE sbc_final
589      !!---------------------------------------------------------------------
590      !!                    ***  ROUTINE sbc_final  ***
591      !!
592      !! ** Purpose :   Finalize CICE (if used)
593      !!---------------------------------------------------------------------
594      !
595      IF( nn_ice == 3 )   CALL cice_sbc_final
596      !
597   END SUBROUTINE sbc_final
598
599   !!======================================================================
600END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.