source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/TOP/PISCES/P4Z/p4zmeso.F90 @ 12251

Last change on this file since 12251 was 12251, checked in by smasson, 11 months ago

rev12232_dev_r12072_MERGE_OPTION2_2019: merge trunk 12072:12248, all sette tests ok, GYRE_PISCES, AMM12, ISOMIP, VORTEX intentical to 12210

  • Property svn:keywords set to Id
File size: 17.8 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_meso       : Compute the sources/sinks for mesozooplankton
11   !!   p4z_meso_init  : Initialization of the parameters for mesozooplankton
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zprod         ! production
17   USE prtctl_trc      ! print control for debugging
18   USE iom             ! I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p4z_meso              ! called in p4zbio.F90
24   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
25
26   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
27   REAL(wp), PUBLIC ::  xpref2d      !: mesozoo preference for diatoms
28   REAL(wp), PUBLIC ::  xpref2n      !: mesozoo preference for nanophyto
29   REAL(wp), PUBLIC ::  xpref2z      !: mesozoo preference for microzooplankton
30   REAL(wp), PUBLIC ::  xpref2c      !: mesozoo preference for POC
31   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
32   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
33   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
34   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
35   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
36   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
37   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
38   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
39   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
40   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
41   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
42   REAL(wp), PUBLIC ::  epsher2      !: growth efficiency
43   REAL(wp), PUBLIC ::  epsher2min   !: minimum growth efficiency at high food for grazing 2
44   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
45
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL license (see ./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE p4z_meso( kt, knt )
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE p4z_meso  ***
56      !!
57      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step and ???
62      !
63      INTEGER  :: ji, jj, jk
64      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
65      REAL(wp) :: zgraze2 , zdenom, zdenom2
66      REAL(wp) :: zfact   , zfood, zfoodlim, zproport, zbeta
67      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2, zfracal, zgrazcal
68      REAL(wp) :: zepsherf, zepshert, zepsherv, zgrarsig, zgraztotc, zgraztotn, zgraztotf
69      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz, zgrasrat, zgrasratn
70      REAL(wp) :: zrespz, ztortz, zgrazd, zgrazz, zgrazpof
71      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
72      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
73      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing2, zfezoo2, zz2ligprod
74      CHARACTER (len=25) :: charout
75      !!---------------------------------------------------------------------
76      !
77      IF( ln_timing )   CALL timing_start('p4z_meso')
78      !
79      DO jk = 1, jpkm1
80         DO jj = 1, jpj
81            DO ji = 1, jpi
82               zcompam   = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
83               zfact     = xstep * tgfunc2(ji,jj,jk) * zcompam
84
85               !  Respiration rates of both zooplankton
86               !  -------------------------------------
87               zrespz    = resrat2 * zfact * ( trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) )  &
88               &           + 3. * nitrfac(ji,jj,jk) )
89
90               !  Zooplankton mortality. A square function has been selected with
91               !  no real reason except that it seems to be more stable and may mimic predation
92               !  ---------------------------------------------------------------
93               ztortz    = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes)  * (1. - nitrfac(ji,jj,jk) )
94               !
95               zcompadi  = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
96               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
97               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
98               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
99               ! it is to predation by mesozooplankton
100               ! -------------------------------------------------------------------------------
101               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) &
102                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
103
104               !   Mesozooplankton grazing
105               !   ------------------------
106               zfood     = xpref2d * zcompadi + xpref2z * zcompaz + xpref2n * zcompaph + xpref2c * zcompapoc 
107               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
108               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
109               zdenom2   = zdenom / ( zfood + rtrn )
110               zgraze2   = grazrat2 * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) * (1. - nitrfac(ji,jj,jk)) 
111
112               zgrazd    = zgraze2  * xpref2d  * zcompadi  * zdenom2 
113               zgrazz    = zgraze2  * xpref2z  * zcompaz   * zdenom2 
114               zgrazn    = zgraze2  * xpref2n  * zcompaph  * zdenom2 
115               zgrazpoc  = zgraze2  * xpref2c  * zcompapoc * zdenom2 
116
117               zgraznf   = zgrazn   * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn)
118               zgrazf    = zgrazd   * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn)
119               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn)
120
121               !  Mesozooplankton flux feeding on GOC
122               !  ----------------------------------
123               zgrazffeg = grazflux  * xstep * wsbio4(ji,jj,jk)      &
124               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes) &
125               &           * (1. - nitrfac(ji,jj,jk))
126               zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
127               zgrazffep = grazflux  * xstep *  wsbio3(ji,jj,jk)     &
128               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes) &
129               &           * (1. - nitrfac(ji,jj,jk))
130               zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
131               !
132               zgraztotc = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
133               ! Compute the proportion of filter feeders
134               zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztotc)
135               ! Compute fractionation of aggregates. It is assumed that
136               ! diatoms based aggregates are more prone to fractionation
137               ! since they are more porous (marine snow instead of fecal pellets)
138               zratio    = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn )
139               zratio2   = zratio * zratio
140               zfrac     = zproport * grazflux  * xstep * wsbio4(ji,jj,jk)      &
141               &          * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)          &
142               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
143               zfracfe   = zfrac * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
144
145               zgrazffep = zproport * zgrazffep
146               zgrazffeg = zproport * zgrazffeg
147               zgrazfffp = zproport * zgrazfffp
148               zgrazfffg = zproport * zgrazfffg
149               zgraztotc = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
150               zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
151               &   + zgrazpoc + zgrazffep + zgrazffeg
152               zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
153
154               ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
155               zgrazing2(ji,jj,jk) = zgraztotc
156
157               !    Mesozooplankton efficiency
158               !    --------------------------
159               zgrasrat  =  ( zgraztotf + rtrn )/ ( zgraztotc + rtrn )
160               zgrasratn =  ( zgraztotn + rtrn )/ ( zgraztotc + rtrn )
161               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
162               zbeta     = MAX(0., (epsher2 - epsher2min) )
163               zepsherf  = epsher2min + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta ) 
164               zepsherv  = zepsherf * zepshert 
165
166               zgrarem2  = zgraztotc * ( 1. - zepsherv - unass2 ) &
167               &         + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz
168               zgrafer2  = zgraztotc * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
169               &         + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz )
170               zgrapoc2  = zgraztotc * unass2
171
172               !   Update the arrays TRA which contain the biological sources and sinks
173               zgrarsig  = zgrarem2 * sigma2
174               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
175               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
176               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
177               !
178               IF( ln_ligand ) THEN
179                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem2 - zgrarsig) * ldocz
180                  zz2ligprod(ji,jj,jk) = (zgrarem2 - zgrarsig) * ldocz
181               ENDIF
182               !
183               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
184               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
185               zfezoo2(ji,jj,jk)   = zgrafer2
186               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
187               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
188
189               zmortz = ztortz + zrespz
190               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz + zrespz
191               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz + zepsherv * zgraztotc 
192               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
193               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
194               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
195               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn )
196               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
197               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
198               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
199               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
200               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
201
202               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfrac
203               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfrac
204               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep
205               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
206               prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zmortzgoc + zgrapoc2
207               consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfrac
208               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
209               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg     &
210                 &                + zgraztotf * unass2 - zfracfe
211               zfracal = trb(ji,jj,jk,jpcal) / (trb(ji,jj,jk,jppoc) + trb(ji,jj,jk,jpgoc) + rtrn )
212               zgrazcal = (zgrazffeg + zgrazpoc) * (1. - part2) * zfracal
213               ! calcite production
214               zprcaca = xfracal(ji,jj,jk) * zgrazn
215               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
216               !
217               zprcaca = part2 * zprcaca
218               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrazcal - zprcaca
219               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * ( zgrazcal + zprcaca )
220               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) - zgrazcal + zprcaca
221            END DO
222         END DO
223      END DO
224      !
225      IF( lk_iomput .AND. knt == nrdttrc ) THEN
226         zgrazing2(:,:,jpk) = 0._wp
227         zfezoo2 (:,:,jpk) = 0._wp
228         CALL iom_put( "GRAZ2" , zgrazing2(:,:,:) * 1.e+3       * rfact2r * tmask(:,:,:) )  !   Total grazing of phyto by zooplankton
229         CALL iom_put( "PCAL"  , prodcal  (:,:,:) * 1.e+3       * rfact2r * tmask(:,:,:) )  !  Calcite production
230         CALL iom_put( "FEZOO2", zfezoo2  (:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) )
231         IF( ln_ligand )  THEN
232            zz2ligprod(:,:,jpk) = 0._wp
233            CALL iom_put( "LPRODZ2", zz2ligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)  )
234         ENDIF
235      ENDIF
236      !
237      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
238        WRITE(charout, FMT="('meso')")
239        CALL prt_ctl_trc_info(charout)
240        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
241      ENDIF
242      !
243      IF( ln_timing )   CALL timing_stop('p4z_meso')
244      !
245   END SUBROUTINE p4z_meso
246
247
248   SUBROUTINE p4z_meso_init
249      !!----------------------------------------------------------------------
250      !!                  ***  ROUTINE p4z_meso_init  ***
251      !!
252      !! ** Purpose :   Initialization of mesozooplankton parameters
253      !!
254      !! ** Method  :   Read the nampismes namelist and check the parameters
255      !!      called at the first timestep (nittrc000)
256      !!
257      !! ** input   :   Namelist nampismes
258      !!----------------------------------------------------------------------
259      INTEGER ::   ios   ! Local integer
260      !
261      NAMELIST/namp4zmes/ part2, grazrat2, resrat2, mzrat2, xpref2n, xpref2d, xpref2z,   &
262         &                xpref2c, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
263         &                xthresh2, xkgraz2, epsher2, epsher2min, sigma2, unass2, grazflux
264      !!----------------------------------------------------------------------
265      !
266      IF(lwp) THEN
267         WRITE(numout,*) 
268         WRITE(numout,*) 'p4z_meso_init : Initialization of mesozooplankton parameters'
269         WRITE(numout,*) '~~~~~~~~~~~~~'
270      ENDIF
271      !
272      READ  ( numnatp_ref, namp4zmes, IOSTAT = ios, ERR = 901)
273901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zmes in reference namelist' )
274      READ  ( numnatp_cfg, namp4zmes, IOSTAT = ios, ERR = 902 )
275902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zmes in configuration namelist' )
276      IF(lwm) WRITE( numonp, namp4zmes )
277      !
278      IF(lwp) THEN                         ! control print
279         WRITE(numout,*) '   Namelist : namp4zmes'
280         WRITE(numout,*) '      part of calcite not dissolved in mesozoo guts  part2        =', part2
281         WRITE(numout,*) '      mesozoo preference for phyto                   xpref2n      =', xpref2n
282         WRITE(numout,*) '      mesozoo preference for diatoms                 xpref2d      =', xpref2d
283         WRITE(numout,*) '      mesozoo preference for zoo                     xpref2z      =', xpref2z
284         WRITE(numout,*) '      mesozoo preference for poc                     xpref2c      =', xpref2c
285         WRITE(numout,*) '      microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
286         WRITE(numout,*) '      diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
287         WRITE(numout,*) '      nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
288         WRITE(numout,*) '      poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
289         WRITE(numout,*) '      feeding threshold for mesozooplankton          xthresh2     =', xthresh2
290         WRITE(numout,*) '      exsudation rate of mesozooplankton             resrat2      =', resrat2
291         WRITE(numout,*) '      mesozooplankton mortality rate                 mzrat2       =', mzrat2
292         WRITE(numout,*) '      maximal mesozoo grazing rate                   grazrat2     =', grazrat2
293         WRITE(numout,*) '      mesozoo flux feeding rate                      grazflux     =', grazflux
294         WRITE(numout,*) '      non assimilated fraction of P by mesozoo       unass2       =', unass2
295         WRITE(numout,*) '      Efficiency of Mesozoo growth                   epsher2      =', epsher2
296         WRITE(numout,*) '      Minimum Efficiency of Mesozoo growth           epsher2min  =', epsher2min
297         WRITE(numout,*) '      Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
298         WRITE(numout,*) '      half sturation constant for grazing 2          xkgraz2      =', xkgraz2
299      ENDIF
300      !
301   END SUBROUTINE p4z_meso_init
302
303   !!======================================================================
304END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.