1 | MODULE icedyn |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE icedyn *** |
---|
4 | !! Sea-Ice dynamics : master routine for sea ice dynamics |
---|
5 | !!====================================================================== |
---|
6 | !! history : 4.0 ! 2018 (C. Rousset) original code SI3 [aka Sea Ice cube] |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | #if defined key_si3 |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! 'key_si3' SI3 sea-ice model |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! ice_dyn : dynamics of sea ice |
---|
13 | !! ice_dyn_init : initialization and namelist read |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | USE phycst ! physical constants |
---|
16 | USE dom_oce ! ocean space and time domain |
---|
17 | USE ice ! sea-ice: variables |
---|
18 | USE icedyn_rhg ! sea-ice: rheology |
---|
19 | USE icedyn_adv ! sea-ice: advection |
---|
20 | USE icedyn_rdgrft ! sea-ice: ridging/rafting |
---|
21 | USE icecor ! sea-ice: corrections |
---|
22 | USE icevar ! sea-ice: operations |
---|
23 | USE icectl ! sea-ice: control prints |
---|
24 | ! |
---|
25 | USE in_out_manager ! I/O manager |
---|
26 | USE iom ! I/O manager library |
---|
27 | USE lib_mpp ! MPP library |
---|
28 | USE lib_fortran ! fortran utilities (glob_sum + no signed zero) |
---|
29 | USE lbclnk ! lateral boundary conditions (or mpp links) |
---|
30 | USE timing ! Timing |
---|
31 | |
---|
32 | IMPLICIT NONE |
---|
33 | PRIVATE |
---|
34 | |
---|
35 | PUBLIC ice_dyn ! called by icestp.F90 |
---|
36 | PUBLIC ice_dyn_init ! called by icestp.F90 |
---|
37 | |
---|
38 | INTEGER :: nice_dyn ! choice of the type of dynamics |
---|
39 | ! ! associated indices: |
---|
40 | INTEGER, PARAMETER :: np_dynALL = 1 ! full ice dynamics (rheology + advection + ridging/rafting + correction) |
---|
41 | INTEGER, PARAMETER :: np_dynRHGADV = 2 ! pure dynamics (rheology + advection) |
---|
42 | INTEGER, PARAMETER :: np_dynADV1D = 3 ! only advection 1D - test case from Schar & Smolarkiewicz 1996 |
---|
43 | INTEGER, PARAMETER :: np_dynADV2D = 4 ! only advection 2D w prescribed vel.(rn_uvice + advection) |
---|
44 | ! |
---|
45 | ! ** namelist (namdyn) ** |
---|
46 | LOGICAL :: ln_dynALL ! full ice dynamics (rheology + advection + ridging/rafting + correction) |
---|
47 | LOGICAL :: ln_dynRHGADV ! no ridge/raft & no corrections (rheology + advection) |
---|
48 | LOGICAL :: ln_dynADV1D ! only advection in 1D w ice convergence (test case from Schar & Smolarkiewicz 1996) |
---|
49 | LOGICAL :: ln_dynADV2D ! only advection in 2D w prescribed vel. (rn_uvice + advection) |
---|
50 | REAL(wp) :: rn_uice ! prescribed u-vel (case np_dynADV1D & np_dynADV2D) |
---|
51 | REAL(wp) :: rn_vice ! prescribed v-vel (case np_dynADV1D & np_dynADV2D) |
---|
52 | |
---|
53 | !! * Substitutions |
---|
54 | # include "vectopt_loop_substitute.h90" |
---|
55 | !!---------------------------------------------------------------------- |
---|
56 | !! NEMO/ICE 4.0 , NEMO Consortium (2018) |
---|
57 | !! $Id$ |
---|
58 | !! Software governed by the CeCILL licence (./LICENSE) |
---|
59 | !!---------------------------------------------------------------------- |
---|
60 | CONTAINS |
---|
61 | |
---|
62 | SUBROUTINE ice_dyn( kt ) |
---|
63 | !!------------------------------------------------------------------- |
---|
64 | !! *** ROUTINE ice_dyn *** |
---|
65 | !! |
---|
66 | !! ** Purpose : this routine manages sea ice dynamics |
---|
67 | !! |
---|
68 | !! ** Action : - calculation of friction in case of landfast ice |
---|
69 | !! - call ice_dyn_rhg = rheology |
---|
70 | !! - call ice_dyn_adv = advection |
---|
71 | !! - call ice_dyn_rdgrft = ridging/rafting |
---|
72 | !! - call ice_cor = corrections if fields are out of bounds |
---|
73 | !!-------------------------------------------------------------------- |
---|
74 | INTEGER, INTENT(in) :: kt ! ice time step |
---|
75 | !! |
---|
76 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
77 | REAL(wp) :: zcoefu, zcoefv |
---|
78 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zhi_max, zhs_max, zhip_max |
---|
79 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zdivu_i |
---|
80 | !!-------------------------------------------------------------------- |
---|
81 | ! |
---|
82 | ! controls |
---|
83 | IF( ln_timing ) CALL timing_start('icedyn') |
---|
84 | ! |
---|
85 | IF( kt == nit000 .AND. lwp ) THEN |
---|
86 | WRITE(numout,*) |
---|
87 | WRITE(numout,*)'ice_dyn: sea-ice dynamics' |
---|
88 | WRITE(numout,*)'~~~~~~~' |
---|
89 | ENDIF |
---|
90 | ! |
---|
91 | IF( ln_landfast_home ) THEN !-- Landfast ice parameterization |
---|
92 | tau_icebfr(:,:) = 0._wp |
---|
93 | DO jl = 1, jpl |
---|
94 | WHERE( h_i_b(:,:,jl) > ht_n(:,:) * rn_depfra ) tau_icebfr(:,:) = tau_icebfr(:,:) + a_i(:,:,jl) * rn_icebfr |
---|
95 | END DO |
---|
96 | ENDIF |
---|
97 | ! |
---|
98 | ! !-- Record max of the surrounding 9-pts ice thick. (for CALL Hbig) |
---|
99 | DO jl = 1, jpl |
---|
100 | DO jj = 2, jpjm1 |
---|
101 | DO ji = fs_2, fs_jpim1 |
---|
102 | zhip_max(ji,jj,jl) = MAX( epsi20, h_ip_b(ji,jj,jl), h_ip_b(ji+1,jj ,jl), h_ip_b(ji ,jj+1,jl), & |
---|
103 | & h_ip_b(ji-1,jj ,jl), h_ip_b(ji ,jj-1,jl), & |
---|
104 | & h_ip_b(ji+1,jj+1,jl), h_ip_b(ji-1,jj-1,jl), & |
---|
105 | & h_ip_b(ji+1,jj-1,jl), h_ip_b(ji-1,jj+1,jl) ) |
---|
106 | zhi_max (ji,jj,jl) = MAX( epsi20, h_i_b (ji,jj,jl), h_i_b (ji+1,jj ,jl), h_i_b (ji ,jj+1,jl), & |
---|
107 | & h_i_b (ji-1,jj ,jl), h_i_b (ji ,jj-1,jl), & |
---|
108 | & h_i_b (ji+1,jj+1,jl), h_i_b (ji-1,jj-1,jl), & |
---|
109 | & h_i_b (ji+1,jj-1,jl), h_i_b (ji-1,jj+1,jl) ) |
---|
110 | zhs_max (ji,jj,jl) = MAX( epsi20, h_s_b (ji,jj,jl), h_s_b (ji+1,jj ,jl), h_s_b (ji ,jj+1,jl), & |
---|
111 | & h_s_b (ji-1,jj ,jl), h_s_b (ji ,jj-1,jl), & |
---|
112 | & h_s_b (ji+1,jj+1,jl), h_s_b (ji-1,jj-1,jl), & |
---|
113 | & h_s_b (ji+1,jj-1,jl), h_s_b (ji-1,jj+1,jl) ) |
---|
114 | END DO |
---|
115 | END DO |
---|
116 | END DO |
---|
117 | CALL lbc_lnk_multi( 'icedyn', zhi_max(:,:,:), 'T', 1., zhs_max(:,:,:), 'T', 1., zhip_max(:,:,:), 'T', 1. ) |
---|
118 | ! |
---|
119 | ! |
---|
120 | SELECT CASE( nice_dyn ) !-- Set which dynamics is running |
---|
121 | |
---|
122 | CASE ( np_dynALL ) !== all dynamical processes ==! |
---|
123 | CALL ice_dyn_rhg ( kt ) ! -- rheology |
---|
124 | CALL ice_dyn_adv ( kt ) ; CALL Hbig( zhi_max, zhs_max, zhip_max ) ! -- advection of ice + correction on ice thickness |
---|
125 | CALL ice_dyn_rdgrft( kt ) ! -- ridging/rafting |
---|
126 | CALL ice_cor ( kt , 1 ) ! -- Corrections |
---|
127 | |
---|
128 | CASE ( np_dynRHGADV ) !== no ridge/raft & no corrections ==! |
---|
129 | CALL ice_dyn_rhg ( kt ) ! -- rheology |
---|
130 | CALL ice_dyn_adv ( kt ) ; CALL Hbig( zhi_max, zhs_max, zhip_max ) ! -- advection of ice + correction on ice thickness |
---|
131 | CALL Hpiling ! -- simple pile-up (replaces ridging/rafting) |
---|
132 | |
---|
133 | CASE ( np_dynADV1D ) !== pure advection ==! (1D) |
---|
134 | ALLOCATE( zdivu_i(jpi,jpj) ) |
---|
135 | ! --- monotonicity test from Schar & Smolarkiewicz 1996 --- ! |
---|
136 | ! CFL = 0.5 at a distance from the bound of 1/6 of the basin length |
---|
137 | ! Then for dx = 2m and dt = 1s => rn_uice = u (1/6th) = 1m/s |
---|
138 | DO jj = 1, jpj |
---|
139 | DO ji = 1, jpi |
---|
140 | zcoefu = ( REAL(jpiglo+1)*0.5 - REAL(ji+nimpp-1) ) / ( REAL(jpiglo+1)*0.5 - 1. ) |
---|
141 | zcoefv = ( REAL(jpjglo+1)*0.5 - REAL(jj+njmpp-1) ) / ( REAL(jpjglo+1)*0.5 - 1. ) |
---|
142 | u_ice(ji,jj) = rn_uice * 1.5 * SIGN( 1., zcoefu ) * ABS( zcoefu ) * umask(ji,jj,1) |
---|
143 | v_ice(ji,jj) = rn_vice * 1.5 * SIGN( 1., zcoefv ) * ABS( zcoefv ) * vmask(ji,jj,1) |
---|
144 | END DO |
---|
145 | END DO |
---|
146 | ! --- |
---|
147 | CALL ice_dyn_adv ( kt ) ! -- advection of ice |
---|
148 | |
---|
149 | ! diagnostics: divergence at T points |
---|
150 | DO jj = 2, jpjm1 |
---|
151 | DO ji = 2, jpim1 |
---|
152 | zdivu_i(ji,jj) = ( e2u(ji,jj) * u_ice(ji,jj) - e2u(ji-1,jj) * u_ice(ji-1,jj) & |
---|
153 | & + e1v(ji,jj) * v_ice(ji,jj) - e1v(ji,jj-1) * v_ice(ji,jj-1) ) * r1_e1e2t(ji,jj) |
---|
154 | END DO |
---|
155 | END DO |
---|
156 | CALL lbc_lnk( 'icedyn', zdivu_i, 'T', 1. ) |
---|
157 | IF( iom_use('icediv') ) CALL iom_put( "icediv" , zdivu_i(:,:) ) |
---|
158 | |
---|
159 | DEALLOCATE( zdivu_i ) |
---|
160 | |
---|
161 | CASE ( np_dynADV2D ) !== pure advection ==! (2D w prescribed velocities) |
---|
162 | ALLOCATE( zdivu_i(jpi,jpj) ) |
---|
163 | u_ice(:,:) = rn_uice * umask(:,:,1) |
---|
164 | v_ice(:,:) = rn_vice * vmask(:,:,1) |
---|
165 | !CALL RANDOM_NUMBER(u_ice(:,:)) ; u_ice(:,:) = u_ice(:,:) * 0.1 + rn_uice * 0.9 * umask(:,:,1) |
---|
166 | !CALL RANDOM_NUMBER(v_ice(:,:)) ; v_ice(:,:) = v_ice(:,:) * 0.1 + rn_vice * 0.9 * vmask(:,:,1) |
---|
167 | ! --- |
---|
168 | CALL ice_dyn_adv ( kt ) ! -- advection of ice |
---|
169 | |
---|
170 | ! diagnostics: divergence at T points |
---|
171 | DO jj = 2, jpjm1 |
---|
172 | DO ji = 2, jpim1 |
---|
173 | zdivu_i(ji,jj) = ( e2u(ji,jj) * u_ice(ji,jj) - e2u(ji-1,jj) * u_ice(ji-1,jj) & |
---|
174 | & + e1v(ji,jj) * v_ice(ji,jj) - e1v(ji,jj-1) * v_ice(ji,jj-1) ) * r1_e1e2t(ji,jj) |
---|
175 | END DO |
---|
176 | END DO |
---|
177 | CALL lbc_lnk( 'icedyn', zdivu_i, 'T', 1. ) |
---|
178 | IF( iom_use('icediv') ) CALL iom_put( "icediv" , zdivu_i(:,:) ) |
---|
179 | |
---|
180 | DEALLOCATE( zdivu_i ) |
---|
181 | |
---|
182 | END SELECT |
---|
183 | ! |
---|
184 | ! controls |
---|
185 | IF( ln_timing ) CALL timing_stop ('icedyn') |
---|
186 | ! |
---|
187 | END SUBROUTINE ice_dyn |
---|
188 | |
---|
189 | |
---|
190 | SUBROUTINE Hbig( phi_max, phs_max, phip_max ) |
---|
191 | !!------------------------------------------------------------------- |
---|
192 | !! *** ROUTINE Hbig *** |
---|
193 | !! |
---|
194 | !! ** Purpose : Thickness correction in case advection scheme creates |
---|
195 | !! abnormally tick ice or snow |
---|
196 | !! |
---|
197 | !! ** Method : 1- check whether ice thickness is larger than the surrounding 9-points |
---|
198 | !! (before advection) and reduce it by adapting ice concentration |
---|
199 | !! 2- check whether snow thickness is larger than the surrounding 9-points |
---|
200 | !! (before advection) and reduce it by sending the excess in the ocean |
---|
201 | !! 3- check whether snow load deplets the snow-ice interface below sea level$ |
---|
202 | !! and reduce it by sending the excess in the ocean |
---|
203 | !! 4- correct pond fraction to avoid a_ip > a_i |
---|
204 | !! |
---|
205 | !! ** input : Max thickness of the surrounding 9-points |
---|
206 | !!------------------------------------------------------------------- |
---|
207 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: phi_max, phs_max, phip_max ! max ice thick from surrounding 9-pts |
---|
208 | ! |
---|
209 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
210 | REAL(wp) :: zhip, zhi, zhs, zvs_excess, zfra |
---|
211 | !!------------------------------------------------------------------- |
---|
212 | ! controls |
---|
213 | IF( ln_icediachk ) CALL ice_cons_hsm(0, 'Hbig', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation |
---|
214 | ! |
---|
215 | CALL ice_var_zapsmall !-- zap small areas |
---|
216 | ! |
---|
217 | DO jl = 1, jpl |
---|
218 | DO jj = 1, jpj |
---|
219 | DO ji = 1, jpi |
---|
220 | IF ( v_i(ji,jj,jl) > 0._wp ) THEN |
---|
221 | ! |
---|
222 | ! ! -- check h_ip -- ! |
---|
223 | ! if h_ip is larger than the surrounding 9 pts => reduce h_ip and increase a_ip |
---|
224 | IF( ln_pnd_H12 .AND. v_ip(ji,jj,jl) > 0._wp ) THEN |
---|
225 | zhip = v_ip(ji,jj,jl) / MAX( epsi20, a_ip(ji,jj,jl) ) |
---|
226 | IF( zhip > phip_max(ji,jj,jl) .AND. a_ip(ji,jj,jl) < 0.15 ) THEN |
---|
227 | a_ip(ji,jj,jl) = v_ip(ji,jj,jl) / phip_max(ji,jj,jl) |
---|
228 | ENDIF |
---|
229 | ENDIF |
---|
230 | ! |
---|
231 | ! ! -- check h_i -- ! |
---|
232 | ! if h_i is larger than the surrounding 9 pts => reduce h_i and increase a_i |
---|
233 | zhi = v_i(ji,jj,jl) / a_i(ji,jj,jl) |
---|
234 | IF( zhi > phi_max(ji,jj,jl) .AND. a_i(ji,jj,jl) < 0.15 ) THEN |
---|
235 | a_i(ji,jj,jl) = v_i(ji,jj,jl) / MIN( phi_max(ji,jj,jl), hi_max(jpl) ) !-- bound h_i to hi_max (99 m) |
---|
236 | ENDIF |
---|
237 | ! |
---|
238 | ! ! -- check h_s -- ! |
---|
239 | ! if h_s is larger than the surrounding 9 pts => put the snow excess in the ocean |
---|
240 | zhs = v_s(ji,jj,jl) / a_i(ji,jj,jl) |
---|
241 | IF( v_s(ji,jj,jl) > 0._wp .AND. zhs > phs_max(ji,jj,jl) .AND. a_i(ji,jj,jl) < 0.15 ) THEN |
---|
242 | zfra = phs_max(ji,jj,jl) / MAX( zhs, epsi20 ) |
---|
243 | ! |
---|
244 | wfx_res(ji,jj) = wfx_res(ji,jj) + ( v_s(ji,jj,jl) - a_i(ji,jj,jl) * phs_max(ji,jj,jl) ) * rhos * r1_rdtice |
---|
245 | hfx_res(ji,jj) = hfx_res(ji,jj) - SUM( e_s(ji,jj,1:nlay_s,jl) ) * ( 1._wp - zfra ) * r1_rdtice ! W.m-2 <0 |
---|
246 | ! |
---|
247 | e_s(ji,jj,1:nlay_s,jl) = e_s(ji,jj,1:nlay_s,jl) * zfra |
---|
248 | v_s(ji,jj,jl) = a_i(ji,jj,jl) * phs_max(ji,jj,jl) |
---|
249 | ENDIF |
---|
250 | ! |
---|
251 | ! ! -- check snow load -- ! |
---|
252 | ! if snow load makes snow-ice interface to deplet below the ocean surface => put the snow excess in the ocean |
---|
253 | ! this correction is crucial because of the call to routine icecor afterwards which imposes a mini of ice thick. (rn_himin) |
---|
254 | ! this imposed mini can artificially make the snow very thick (if concentration decreases drastically) |
---|
255 | zvs_excess = MAX( 0._wp, v_s(ji,jj,jl) - v_i(ji,jj,jl) * (rau0-rhoi) * r1_rhos ) |
---|
256 | IF( zvs_excess > 0._wp ) THEN |
---|
257 | zfra = ( v_s(ji,jj,jl) - zvs_excess ) / MAX( v_s(ji,jj,jl), epsi20 ) |
---|
258 | wfx_res(ji,jj) = wfx_res(ji,jj) + zvs_excess * rhos * r1_rdtice |
---|
259 | hfx_res(ji,jj) = hfx_res(ji,jj) - SUM( e_s(ji,jj,1:nlay_s,jl) ) * ( 1._wp - zfra ) * r1_rdtice ! W.m-2 <0 |
---|
260 | ! |
---|
261 | e_s(ji,jj,1:nlay_s,jl) = e_s(ji,jj,1:nlay_s,jl) * zfra |
---|
262 | v_s(ji,jj,jl) = v_s(ji,jj,jl) - zvs_excess |
---|
263 | ENDIF |
---|
264 | |
---|
265 | ENDIF |
---|
266 | END DO |
---|
267 | END DO |
---|
268 | END DO |
---|
269 | ! !-- correct pond fraction to avoid a_ip > a_i |
---|
270 | WHERE( a_ip(:,:,:) > a_i(:,:,:) ) a_ip(:,:,:) = a_i(:,:,:) |
---|
271 | ! |
---|
272 | ! controls |
---|
273 | IF( ln_icediachk ) CALL ice_cons_hsm(1, 'Hbig', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation |
---|
274 | ! |
---|
275 | END SUBROUTINE Hbig |
---|
276 | |
---|
277 | |
---|
278 | SUBROUTINE Hpiling |
---|
279 | !!------------------------------------------------------------------- |
---|
280 | !! *** ROUTINE Hpiling *** |
---|
281 | !! |
---|
282 | !! ** Purpose : Simple conservative piling comparable with 1-cat models |
---|
283 | !! |
---|
284 | !! ** Method : pile-up ice when no ridging/rafting |
---|
285 | !! |
---|
286 | !! ** input : a_i |
---|
287 | !!------------------------------------------------------------------- |
---|
288 | INTEGER :: jl ! dummy loop indices |
---|
289 | !!------------------------------------------------------------------- |
---|
290 | ! controls |
---|
291 | IF( ln_icediachk ) CALL ice_cons_hsm(0, 'Hpiling', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation |
---|
292 | ! |
---|
293 | CALL ice_var_zapsmall !-- zap small areas |
---|
294 | ! |
---|
295 | at_i(:,:) = SUM( a_i(:,:,:), dim=3 ) |
---|
296 | DO jl = 1, jpl |
---|
297 | WHERE( at_i(:,:) > epsi20 ) |
---|
298 | a_i(:,:,jl) = a_i(:,:,jl) * ( 1._wp + MIN( rn_amax_2d(:,:) - at_i(:,:) , 0._wp ) / at_i(:,:) ) |
---|
299 | END WHERE |
---|
300 | END DO |
---|
301 | ! controls |
---|
302 | IF( ln_icediachk ) CALL ice_cons_hsm(1, 'Hpiling', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation |
---|
303 | ! |
---|
304 | END SUBROUTINE Hpiling |
---|
305 | |
---|
306 | |
---|
307 | SUBROUTINE ice_dyn_init |
---|
308 | !!------------------------------------------------------------------- |
---|
309 | !! *** ROUTINE ice_dyn_init *** |
---|
310 | !! |
---|
311 | !! ** Purpose : Physical constants and parameters linked to the ice |
---|
312 | !! dynamics |
---|
313 | !! |
---|
314 | !! ** Method : Read the namdyn namelist and check the ice-dynamic |
---|
315 | !! parameter values called at the first timestep (nit000) |
---|
316 | !! |
---|
317 | !! ** input : Namelist namdyn |
---|
318 | !!------------------------------------------------------------------- |
---|
319 | INTEGER :: ios, ioptio ! Local integer output status for namelist read |
---|
320 | !! |
---|
321 | NAMELIST/namdyn/ ln_dynALL, ln_dynRHGADV, ln_dynADV1D, ln_dynADV2D, rn_uice, rn_vice, & |
---|
322 | & rn_ishlat , & |
---|
323 | & ln_landfast_L16, ln_landfast_home, rn_depfra, rn_icebfr, rn_lfrelax, rn_tensile |
---|
324 | !!------------------------------------------------------------------- |
---|
325 | ! |
---|
326 | REWIND( numnam_ice_ref ) ! Namelist namdyn in reference namelist : Ice dynamics |
---|
327 | READ ( numnam_ice_ref, namdyn, IOSTAT = ios, ERR = 901) |
---|
328 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn in reference namelist', lwp ) |
---|
329 | REWIND( numnam_ice_cfg ) ! Namelist namdyn in configuration namelist : Ice dynamics |
---|
330 | READ ( numnam_ice_cfg, namdyn, IOSTAT = ios, ERR = 902 ) |
---|
331 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namdyn in configuration namelist', lwp ) |
---|
332 | IF(lwm) WRITE( numoni, namdyn ) |
---|
333 | ! |
---|
334 | IF(lwp) THEN ! control print |
---|
335 | WRITE(numout,*) |
---|
336 | WRITE(numout,*) 'ice_dyn_init: ice parameters for ice dynamics ' |
---|
337 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
338 | WRITE(numout,*) ' Namelist namdyn:' |
---|
339 | WRITE(numout,*) ' Full ice dynamics (rhg + adv + ridge/raft + corr) ln_dynALL = ', ln_dynALL |
---|
340 | WRITE(numout,*) ' No ridge/raft & No cor (rhg + adv) ln_dynRHGADV = ', ln_dynRHGADV |
---|
341 | WRITE(numout,*) ' Advection 1D only (Schar & Smolarkiewicz 1996) ln_dynADV1D = ', ln_dynADV1D |
---|
342 | WRITE(numout,*) ' Advection 2D only (rn_uvice + adv) ln_dynADV2D = ', ln_dynADV2D |
---|
343 | WRITE(numout,*) ' with prescribed velocity given by (u,v)_ice = (rn_uice,rn_vice) = (', rn_uice,',', rn_vice,')' |
---|
344 | WRITE(numout,*) ' lateral boundary condition for sea ice dynamics rn_ishlat = ', rn_ishlat |
---|
345 | WRITE(numout,*) ' Landfast: param from Lemieux 2016 ln_landfast_L16 = ', ln_landfast_L16 |
---|
346 | WRITE(numout,*) ' Landfast: param from home made ln_landfast_home= ', ln_landfast_home |
---|
347 | WRITE(numout,*) ' fraction of ocean depth that ice must reach rn_depfra = ', rn_depfra |
---|
348 | WRITE(numout,*) ' maximum bottom stress per unit area of contact rn_icebfr = ', rn_icebfr |
---|
349 | WRITE(numout,*) ' relax time scale (s-1) to reach static friction rn_lfrelax = ', rn_lfrelax |
---|
350 | WRITE(numout,*) ' isotropic tensile strength rn_tensile = ', rn_tensile |
---|
351 | WRITE(numout,*) |
---|
352 | ENDIF |
---|
353 | ! !== set the choice of ice dynamics ==! |
---|
354 | ioptio = 0 |
---|
355 | ! !--- full dynamics (rheology + advection + ridging/rafting + correction) |
---|
356 | IF( ln_dynALL ) THEN ; ioptio = ioptio + 1 ; nice_dyn = np_dynALL ; ENDIF |
---|
357 | ! !--- dynamics without ridging/rafting and corr (rheology + advection) |
---|
358 | IF( ln_dynRHGADV ) THEN ; ioptio = ioptio + 1 ; nice_dyn = np_dynRHGADV ; ENDIF |
---|
359 | ! !--- advection 1D only - test case from Schar & Smolarkiewicz 1996 |
---|
360 | IF( ln_dynADV1D ) THEN ; ioptio = ioptio + 1 ; nice_dyn = np_dynADV1D ; ENDIF |
---|
361 | ! !--- advection 2D only with prescribed ice velocities (from namelist) |
---|
362 | IF( ln_dynADV2D ) THEN ; ioptio = ioptio + 1 ; nice_dyn = np_dynADV2D ; ENDIF |
---|
363 | ! |
---|
364 | IF( ioptio /= 1 ) CALL ctl_stop( 'ice_dyn_init: one and only one ice dynamics option has to be defined ' ) |
---|
365 | ! |
---|
366 | ! !--- Lateral boundary conditions |
---|
367 | IF ( rn_ishlat == 0. ) THEN ; IF(lwp) WRITE(numout,*) ' ===>>> ice lateral free-slip' |
---|
368 | ELSEIF ( rn_ishlat == 2. ) THEN ; IF(lwp) WRITE(numout,*) ' ===>>> ice lateral no-slip' |
---|
369 | ELSEIF ( 0. < rn_ishlat .AND. rn_ishlat < 2. ) THEN ; IF(lwp) WRITE(numout,*) ' ===>>> ice lateral partial-slip' |
---|
370 | ELSEIF ( 2. < rn_ishlat ) THEN ; IF(lwp) WRITE(numout,*) ' ===>>> ice lateral strong-slip' |
---|
371 | ENDIF |
---|
372 | ! !--- Landfast ice |
---|
373 | IF( .NOT.ln_landfast_L16 .AND. .NOT.ln_landfast_home ) tau_icebfr(:,:) = 0._wp |
---|
374 | ! |
---|
375 | IF ( ln_landfast_L16 .AND. ln_landfast_home ) THEN |
---|
376 | CALL ctl_stop( 'ice_dyn_init: choose one and only one landfast parameterization (ln_landfast_L16 or ln_landfast_home)' ) |
---|
377 | ENDIF |
---|
378 | ! |
---|
379 | CALL ice_dyn_rdgrft_init ! set ice ridging/rafting parameters |
---|
380 | CALL ice_dyn_rhg_init ! set ice rheology parameters |
---|
381 | CALL ice_dyn_adv_init ! set ice advection parameters |
---|
382 | ! |
---|
383 | END SUBROUTINE ice_dyn_init |
---|
384 | |
---|
385 | #else |
---|
386 | !!---------------------------------------------------------------------- |
---|
387 | !! Default option Empty module NO SI3 sea-ice model |
---|
388 | !!---------------------------------------------------------------------- |
---|
389 | #endif |
---|
390 | |
---|
391 | !!====================================================================== |
---|
392 | END MODULE icedyn |
---|