New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in NEMO/branches/2020/dev_12905_xios_restart/src/OCE/SBC – NEMO

source: NEMO/branches/2020/dev_12905_xios_restart/src/OCE/SBC/sbcrnf.F90 @ 12950

Last change on this file since 12950 was 12950, checked in by andmirek, 4 years ago

Ticket #2462: new XIOS restart read/write interfaces
  • Property svn:keywords set to Id
File size: 29.9 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf       : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init  : runoffs initialisation
16   !!   rnf_mouth     : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce        ! ocean space and time domain
19   USE phycst         ! physical constants
20   USE sbc_oce        ! surface boundary condition variables
21   USE eosbn2         ! Equation Of State
22   USE closea, ONLY: l_clo_rnf, clo_rnf ! closed seas
23   !
24   USE in_out_manager ! I/O manager
25   USE fldread        ! read input field at current time step
26   USE iom            ! I/O module
27   USE lib_mpp        ! MPP library
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_rnf       ! called in sbcmod module
33   PUBLIC   sbc_rnf_div   ! called in divhor module
34   PUBLIC   sbc_rnf_alloc ! called in sbcmod module
35   PUBLIC   sbc_rnf_init  ! called in sbcmod module
36   
37   !                                                !!* namsbc_rnf namelist *
38   CHARACTER(len=100)         ::   cn_dir            !: Root directory for location of rnf files
39   LOGICAL           , PUBLIC ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
40   LOGICAL                    ::      ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
41   REAL(wp)                   ::      rn_rnf_max        !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
42   REAL(wp)                   ::      rn_dep_max        !: depth over which runoffs is spread       (ln_rnf_depth_ini =T)
43   INTEGER                    ::      nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44   LOGICAL                    ::   ln_rnf_icb        !: iceberg flux is specified in a file
45   LOGICAL                    ::   ln_rnf_tem        !: temperature river runoffs attribute specified in a file
46   LOGICAL           , PUBLIC ::   ln_rnf_sal        !: salinity    river runoffs attribute specified in a file
47   TYPE(FLD_N)       , PUBLIC ::   sn_rnf            !: information about the runoff file to be read
48   TYPE(FLD_N)                ::   sn_cnf            !: information about the runoff mouth file to be read
49   TYPE(FLD_N)                ::   sn_i_rnf        !: information about the iceberg flux file to be read
50   TYPE(FLD_N)                ::   sn_s_rnf          !: information about the salinities of runoff file to be read
51   TYPE(FLD_N)                ::   sn_t_rnf          !: information about the temperatures of runoff file to be read
52   TYPE(FLD_N)                ::   sn_dep_rnf        !: information about the depth which river inflow affects
53   LOGICAL           , PUBLIC ::   ln_rnf_mouth      !: specific treatment in mouths vicinity
54   REAL(wp)                   ::   rn_hrnf           !: runoffs, depth over which enhanced vertical mixing is used
55   REAL(wp)          , PUBLIC ::   rn_avt_rnf        !: runoffs, value of the additional vertical mixing coef. [m2/s]
56   REAL(wp)          , PUBLIC ::   rn_rfact          !: multiplicative factor for runoff
57
58   LOGICAL , PUBLIC ::   l_rnfcpl = .false.   !: runoffs recieved from oasis
59   INTEGER , PUBLIC ::   nkrnf = 0            !: nb of levels over which Kz is increased at river mouths
60   
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
63   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
64   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
65   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
66
67   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
68   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_i_rnf     ! structure: iceberg flux (file information, fields read)
69   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
70   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
71 
72   !! * Substitutions
73#  include "do_loop_substitute.h90"
74   !!----------------------------------------------------------------------
75   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
76   !! $Id$
77   !! Software governed by the CeCILL license (see ./LICENSE)
78   !!----------------------------------------------------------------------
79CONTAINS
80
81   INTEGER FUNCTION sbc_rnf_alloc()
82      !!----------------------------------------------------------------------
83      !!                ***  ROUTINE sbc_rnf_alloc  ***
84      !!----------------------------------------------------------------------
85      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
86         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
87         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
88         !
89      CALL mpp_sum ( 'sbcrnf', sbc_rnf_alloc )
90      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
91   END FUNCTION sbc_rnf_alloc
92
93
94   SUBROUTINE sbc_rnf( kt )
95      !!----------------------------------------------------------------------
96      !!                  ***  ROUTINE sbc_rnf  ***
97      !!
98      !! ** Purpose :   Introduce a climatological run off forcing
99      !!
100      !! ** Method  :   Set each river mouth with a monthly climatology
101      !!                provided from different data.
102      !!                CAUTION : upward water flux, runoff forced to be < 0
103      !!
104      !! ** Action  :   runoff updated runoff field at time-step kt
105      !!----------------------------------------------------------------------
106      INTEGER, INTENT(in) ::   kt          ! ocean time step
107      !
108      INTEGER  ::   ji, jj    ! dummy loop indices
109      INTEGER  ::   z_err = 0 ! dummy integer for error handling
110      !!----------------------------------------------------------------------
111      REAL(wp), DIMENSION(jpi,jpj) ::   ztfrz   ! freezing point used for temperature correction
112      !
113      !
114      !                                            !-------------------!
115      !                                            !   Update runoff   !
116      !                                            !-------------------!
117      !
118      !
119      IF( .NOT. l_rnfcpl )  THEN
120                            CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt ( runoffs + iceberg )
121         IF( ln_rnf_icb )   CALL fld_read ( kt, nn_fsbc, sf_i_rnf )    ! idem for iceberg flux if required
122      ENDIF
123      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
124      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
125      !
126      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
127         !
128         IF( .NOT. l_rnfcpl ) THEN
129             rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
130             IF( ln_rnf_icb ) THEN
131                fwficb(:,:) = rn_rfact * ( sf_i_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
132                CALL iom_put( 'iceberg_cea'  , fwficb(:,:)  )         ! output iceberg flux
133                CALL iom_put( 'hflx_icb_cea' , fwficb(:,:) * rLfus )   ! output Heat Flux into Sea Water due to Iceberg Thermodynamics -->
134             ENDIF
135         ENDIF
136         !
137         !                                                           ! set temperature & salinity content of runoffs
138         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
139            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
140            CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
141            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
142               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rho0
143            END WHERE
144         ELSE                                                        ! use SST as runoffs temperature
145            !CEOD River is fresh water so must at least be 0 unless we consider ice
146            rnf_tsc(:,:,jp_tem) = MAX( sst_m(:,:), 0.0_wp ) * rnf(:,:) * r1_rho0
147         ENDIF
148         !                                                           ! use runoffs salinity data
149         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
150         !                                                           ! else use S=0 for runoffs (done one for all in the init)
151                                         CALL iom_put( 'runoffs'     , rnf(:,:)                         )   ! output runoff mass flux
152         IF( iom_use('hflx_rnf_cea') )   CALL iom_put( 'hflx_rnf_cea', rnf_tsc(:,:,jp_tem) * rho0 * rcp )   ! output runoff sensible heat (W/m2)
153      ENDIF
154      !
155      !                                                ! ---------------------------------------- !
156      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
157         !                                             ! ---------------------------------------- !
158         IF( lrxios ) CALL iom_swap( TRIM(crxios_context) )
159         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
160            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
161            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file', lrxios
162            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b, ldxios = lrxios )     ! before runoff
163            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem), ldxios = lrxios )   ! before heat content of runoff
164            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal), ldxios = lrxios )   ! before salinity content of runoff
165         ELSE                                                   !* no restart: set from nit000 values
166            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
167            rnf_b    (:,:  ) = rnf    (:,:  )
168            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
169         ENDIF
170         IF( lrxios ) CALL iom_swap( TRIM(cxios_context) )
171      ENDIF
172      !                                                ! ---------------------------------------- !
173      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
174         !                                             ! ---------------------------------------- !
175         IF(lwp) WRITE(numout,*)
176         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
177            &                    'at it= ', kt,' date= ', ndastp
178         IF(lwp) WRITE(numout,*) '~~~~'
179         IF( lwxios ) CALL iom_swap(      cwxios_context          )
180         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf, ldxios = lwxios )
181         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem), ldxios = lwxios )
182         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal), ldxios = lwxios )
183         IF( lwxios ) CALL iom_swap(      cxios_context          )
184      ENDIF
185      !
186   END SUBROUTINE sbc_rnf
187
188
189   SUBROUTINE sbc_rnf_div( phdivn, Kmm )
190      !!----------------------------------------------------------------------
191      !!                  ***  ROUTINE sbc_rnf  ***
192      !!
193      !! ** Purpose :   update the horizontal divergence with the runoff inflow
194      !!
195      !! ** Method  :
196      !!                CAUTION : rnf is positive (inflow) decreasing the
197      !!                          divergence and expressed in m/s
198      !!
199      !! ** Action  :   phdivn   decreased by the runoff inflow
200      !!----------------------------------------------------------------------
201      INTEGER                   , INTENT(in   ) ::   Kmm      ! ocean time level index
202      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
203      !!
204      INTEGER  ::   ji, jj, jk   ! dummy loop indices
205      REAL(wp) ::   zfact     ! local scalar
206      !!----------------------------------------------------------------------
207      !
208      zfact = 0.5_wp
209      !
210      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
211         IF( ln_linssh ) THEN    !* constant volume case : just apply the runoff input flow
212            DO_2D_11_11
213               DO jk = 1, nk_rnf(ji,jj)
214                  phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
215               END DO
216            END_2D
217         ELSE                    !* variable volume case
218            DO_2D_11_11
219               h_rnf(ji,jj) = 0._wp
220               DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
221                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)   ! to the bottom of the relevant grid box
222               END DO
223               !                          ! apply the runoff input flow
224               DO jk = 1, nk_rnf(ji,jj)
225                  phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
226               END DO
227            END_2D
228         ENDIF
229      ELSE                       !==   runoff put only at the surface   ==!
230         h_rnf (:,:)   = e3t (:,:,1,Kmm)        ! update h_rnf to be depth of top box
231         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rho0 / e3t(:,:,1,Kmm)
232      ENDIF
233      !
234   END SUBROUTINE sbc_rnf_div
235
236
237   SUBROUTINE sbc_rnf_init( Kmm )
238      !!----------------------------------------------------------------------
239      !!                  ***  ROUTINE sbc_rnf_init  ***
240      !!
241      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
242      !!
243      !! ** Method  : - read the runoff namsbc_rnf namelist
244      !!
245      !! ** Action  : - read parameters
246      !!----------------------------------------------------------------------
247      INTEGER, INTENT(in) :: Kmm           ! ocean time level index
248      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
249      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
250      INTEGER           ::   ierror, inum  ! temporary integer
251      INTEGER           ::   ios           ! Local integer output status for namelist read
252      INTEGER           ::   nbrec         ! temporary integer
253      REAL(wp)          ::   zacoef 
254      REAL(wp), DIMENSION(jpi,jpj,2) :: zrnfcl   
255      !!
256      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, ln_rnf_icb,   &
257         &                 sn_rnf, sn_cnf    , sn_i_rnf, sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
258         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
259         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
260      !!----------------------------------------------------------------------
261      !
262      !                                         !==  allocate runoff arrays
263      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
264      !
265      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
266         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
267         nkrnf         = 0
268         rnf     (:,:) = 0.0_wp
269         rnf_b   (:,:) = 0.0_wp
270         rnfmsk  (:,:) = 0.0_wp
271         rnfmsk_z(:)   = 0.0_wp
272         RETURN
273      ENDIF
274      !
275      !                                   ! ============
276      !                                   !   Namelist
277      !                                   ! ============
278      !
279      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
280901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist' )
281
282      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
283902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist' )
284      IF(lwm) WRITE ( numond, namsbc_rnf )
285      !
286      !                                         ! Control print
287      IF(lwp) THEN
288         WRITE(numout,*)
289         WRITE(numout,*) 'sbc_rnf_init : runoff '
290         WRITE(numout,*) '~~~~~~~~~~~~ '
291         WRITE(numout,*) '   Namelist namsbc_rnf'
292         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
293         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
294         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
295         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
296      ENDIF
297      !                                   ! ==================
298      !                                   !   Type of runoff
299      !                                   ! ==================
300      !
301      IF( .NOT. l_rnfcpl ) THEN                   
302         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
303         IF(lwp) WRITE(numout,*)
304         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs inflow read in a file'
305         IF( ierror > 0 ) THEN
306            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_rnf structure' )   ;   RETURN
307         ENDIF
308         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
309         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
310         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf', no_print )
311         !
312         IF( ln_rnf_icb ) THEN                      ! Create (if required) sf_i_rnf structure
313            IF(lwp) WRITE(numout,*)
314            IF(lwp) WRITE(numout,*) '          iceberg flux read in a file'
315            ALLOCATE( sf_i_rnf(1), STAT=ierror  )
316            IF( ierror > 0 ) THEN
317               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_i_rnf structure' )   ;   RETURN
318            ENDIF
319            ALLOCATE( sf_i_rnf(1)%fnow(jpi,jpj,1)   )
320            IF( sn_i_rnf%ln_tint ) ALLOCATE( sf_i_rnf(1)%fdta(jpi,jpj,1,2) )
321            CALL fld_fill (sf_i_rnf, (/ sn_i_rnf /), cn_dir, 'sbc_rnf_init', 'read iceberg flux data', 'namsbc_rnf' )
322         ELSE
323            fwficb(:,:) = 0._wp
324         ENDIF
325
326      ENDIF
327      !
328      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
329         IF(lwp) WRITE(numout,*)
330         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs temperatures read in a file'
331         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
332         IF( ierror > 0 ) THEN
333            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
334         ENDIF
335         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
336         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
337         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf', no_print )
338      ENDIF
339      !
340      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
341         IF(lwp) WRITE(numout,*)
342         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs salinities read in a file'
343         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
344         IF( ierror > 0 ) THEN
345            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
346         ENDIF
347         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
348         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
349         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf', no_print )
350      ENDIF
351      !
352      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
353         IF(lwp) WRITE(numout,*)
354         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs depth read in a file'
355         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
356         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
357            IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
358         ENDIF
359         CALL iom_open ( rn_dep_file, inum )                           ! open file
360         CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
361         CALL iom_close( inum )                                        ! close file
362         !
363         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
364         DO_2D_11_11
365            IF( h_rnf(ji,jj) > 0._wp ) THEN
366               jk = 2
367               DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
368               END DO
369               nk_rnf(ji,jj) = jk
370            ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
371            ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
372            ELSE
373               CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
374               WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
375            ENDIF
376         END_2D
377         DO_2D_11_11
378            h_rnf(ji,jj) = 0._wp
379            DO jk = 1, nk_rnf(ji,jj)
380               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
381            END DO
382         END_2D
383         !
384      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
385         !
386         IF(lwp) WRITE(numout,*)
387         IF(lwp) WRITE(numout,*) '   ==>>>   depth of runoff computed once from max value of runoff'
388         IF(lwp) WRITE(numout,*) '        max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
389         IF(lwp) WRITE(numout,*) '        depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
390         IF(lwp) WRITE(numout,*) '        create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
391
392         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
393         nbrec = iom_getszuld( inum )
394         zrnfcl(:,:,1) = 0._wp                                                          ! init the max to 0. in 1
395         DO jm = 1, nbrec
396            CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,2), jm )   ! read the value in 2
397            zrnfcl(:,:,1) = MAXVAL( zrnfcl(:,:,:), DIM=3 )                              ! store the maximum value in time in 1
398         END DO
399         CALL iom_close( inum )
400         !
401         h_rnf(:,:) = 1.
402         !
403         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
404         !
405         WHERE( zrnfcl(:,:,1) > 0._wp )  h_rnf(:,:) = zacoef * zrnfcl(:,:,1)   ! compute depth for all runoffs
406         !
407         DO_2D_11_11
408            IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
409               jk = mbkt(ji,jj)
410               h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
411            ENDIF
412         END_2D
413         !
414         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
415         DO_2D_11_11
416            IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
417               jk = 2
418               DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
419               END DO
420               nk_rnf(ji,jj) = jk
421            ELSE
422               nk_rnf(ji,jj) = 1
423            ENDIF
424         END_2D
425         !
426         DO_2D_11_11
427            h_rnf(ji,jj) = 0._wp
428            DO jk = 1, nk_rnf(ji,jj)
429               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
430            END DO
431         END_2D
432         !
433         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
434            IF(lwp) WRITE(numout,*) '   ==>>>   create runoff depht file'
435            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE. )
436            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
437            CALL iom_close ( inum )
438         ENDIF
439      ELSE                                       ! runoffs applied at the surface
440         nk_rnf(:,:) = 1
441         h_rnf (:,:) = e3t(:,:,1,Kmm)
442      ENDIF
443      !
444      rnf(:,:) =  0._wp                         ! runoff initialisation
445      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
446      !
447      !                                   ! ========================
448      !                                   !   River mouth vicinity
449      !                                   ! ========================
450      !
451      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
452         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
453         !                                      !    - set to zero SSS damping (ln_ssr=T)
454         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
455         !
456         IF( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
457            &                                              'be spread through depth by ln_rnf_depth'               )
458         !
459         nkrnf = 0                                  ! Number of level over which Kz increase
460         IF( rn_hrnf > 0._wp ) THEN
461            nkrnf = 2
462            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
463            END DO
464            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf_init: number of levels over which Kz is increased is computed for zco...' )
465         ENDIF
466         IF(lwp) WRITE(numout,*)
467         IF(lwp) WRITE(numout,*) '   ==>>>   Specific treatment used in vicinity of river mouths :'
468         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
469         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
470         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
471         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
472         !
473         CALL rnf_mouth                             ! set river mouth mask
474         !
475      ELSE                                      ! No treatment at river mouths
476         IF(lwp) WRITE(numout,*)
477         IF(lwp) WRITE(numout,*) '   ==>>>   No specific treatment at river mouths'
478         rnfmsk  (:,:) = 0._wp
479         rnfmsk_z(:)   = 0._wp
480         nkrnf = 0
481      ENDIF
482      !
483   END SUBROUTINE sbc_rnf_init
484
485
486   SUBROUTINE rnf_mouth
487      !!----------------------------------------------------------------------
488      !!                  ***  ROUTINE rnf_mouth  ***
489      !!
490      !! ** Purpose :   define the river mouths mask
491      !!
492      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
493      !!                climatological file. Defined a given vertical structure.
494      !!                CAUTION, the vertical structure is hard coded on the
495      !!                first 5 levels.
496      !!                This fields can be used to:
497      !!                 - set an upstream advection scheme
498      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
499      !!                 - increase vertical on the top nn_krnf vertical levels
500      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
501      !!                 - set to zero SSS restoring flux at river mouth grid points
502      !!
503      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
504      !!                rnfmsk_z vertical structure
505      !!----------------------------------------------------------------------
506      INTEGER            ::   inum        ! temporary integers
507      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
508      !!----------------------------------------------------------------------
509      !
510      IF(lwp) WRITE(numout,*)
511      IF(lwp) WRITE(numout,*) '   rnf_mouth : river mouth mask'
512      IF(lwp) WRITE(numout,*) '   ~~~~~~~~~ '
513      !
514      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
515      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
516         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
517      ENDIF
518      !
519      ! horizontal mask (read in NetCDF file)
520      CALL iom_open ( cl_rnfile, inum )                           ! open file
521      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
522      CALL iom_close( inum )                                      ! close file
523      !
524      IF( l_clo_rnf )   CALL clo_rnf( rnfmsk )   ! closed sea inflow set as river mouth
525      !
526      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
527      rnfmsk_z(1)   = 1.0
528      rnfmsk_z(2)   = 1.0                                         ! **********
529      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
530      rnfmsk_z(4)   = 0.25                                        ! **********
531      rnfmsk_z(5)   = 0.125
532      !
533   END SUBROUTINE rnf_mouth
534
535   !!======================================================================
536END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.