New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsms.F90 in NEMO/branches/2020/dev_12905_xios_restart/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2020/dev_12905_xios_restart/src/TOP/PISCES/P4Z/p4zsms.F90 @ 13871

Last change on this file since 13871 was 13871, checked in by andmirek, 4 years ago

Ticket #2462: Addressing reviewr comments stage 1
  • Property svn:keywords set to Id
File size: 27.5 KB
Line 
1MODULE p4zsms
2   !!======================================================================
3   !!                         ***  MODULE p4zsms  ***
4   !! TOP :   PISCES Source Minus Sink manager
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9   !!   p4z_sms        : Time loop of passive tracers sms
10   !!----------------------------------------------------------------------
11   USE oce_trc         ! shared variables between ocean and passive tracers
12   USE trc             ! passive tracers common variables
13   USE trcdta          !
14   USE sms_pisces      ! PISCES Source Minus Sink variables
15   USE p4zbio          ! Biological model
16   USE p4zche          ! Chemical model
17   USE p4zlys          ! Calcite saturation
18   USE p4zflx          ! Gas exchange
19   USE p4zbc           ! External source of nutrients
20   USE p4zsed          ! Sedimentation
21   USE p4zint          ! time interpolation
22   USE p4zrem          ! remineralisation
23   USE iom             ! I/O manager
24   USE trd_oce         ! Ocean trends variables
25   USE trdtrc          ! TOP trends variables
26   USE sedmodel        ! Sediment model
27   USE prtctl          ! print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sms_init   ! called in p4zsms.F90
33   PUBLIC   p4z_sms        ! called in p4zsms.F90
34
35   INTEGER ::    numco2, numnut, numnit      ! logical unit for co2 budget
36   REAL(wp) ::   alkbudget, no3budget, silbudget, ferbudget, po4budget
37   REAL(wp) ::   xfact, xfact1, xfact2, xfact3
38
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xnegtr     ! Array used to indicate negative tracer values
40
41   !! * Substitutions
42#  include "do_loop_substitute.h90"
43#  include "domzgr_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p4z_sms( kt, Kbb, Kmm, Krhs )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_sms  ***
54      !!
55      !! ** Purpose :   Managment of the call to Biological sources and sinks
56      !!              routines of PISCES bio-model
57      !!
58      !! ** Method  : - at each new day ...
59      !!              - several calls of bio and sed ???
60      !!              - ...
61      !!---------------------------------------------------------------------
62      !
63      INTEGER, INTENT( in ) ::   kt              ! ocean time-step index     
64      INTEGER, INTENT( in ) ::   Kbb, Kmm, Krhs  ! time level index
65      !!
66      INTEGER ::   ji, jj, jk, jnt, jn, jl
67      REAL(wp) ::  ztra
68      CHARACTER (len=25) :: charout
69      REAL(wp), ALLOCATABLE, DIMENSION(:,:    ) :: zw2d
70      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:  ) :: zw3d
71      REAL(wp), DIMENSION(jpi,jpj,jpk,jp_pisces) :: ztrbbio
72
73      !!---------------------------------------------------------------------
74      !
75      IF( ln_timing )   CALL timing_start('p4z_sms')
76      !
77      IF( kt == nittrc000 ) THEN
78        !
79        ALLOCATE( xnegtr(jpi,jpj,jpk) )
80        !
81        IF( .NOT. ln_rsttr ) THEN
82            CALL p4z_che( Kbb, Kmm )                  ! initialize the chemical constants
83            CALL ahini_for_at( hi, Kbb )              !  set PH at kt=nit000
84            t_oce_co2_flx_cum = 0._wp
85        ELSE
86            CALL p4z_rst( nittrc000, Kbb, Kmm,  'READ' )  !* read or initialize all required fields
87        ENDIF
88        !
89      ENDIF
90      !
91      IF( ln_pisdmp .AND. MOD( kt - 1, nn_pisdmp ) == 0 )   CALL p4z_dmp( kt, Kbb, Kmm )      ! Relaxation of some tracers
92      !
93      rfact = rDt_trc
94      !
95      IF( ( ln_top_euler .AND. kt == nittrc000 )  .OR. ( .NOT.ln_top_euler .AND. kt <= nittrc000 + 1 ) ) THEN
96         rfactr  = 1. / rfact
97         rfact2  = rfact / REAL( nrdttrc, wp )
98         rfact2r = 1. / rfact2
99         xstep = rfact2 / rday         ! Time step duration for biology
100         xfact = 1.e+3 * rfact2r
101         IF(lwp) WRITE(numout,*) 
102         IF(lwp) WRITE(numout,*) '    Passive Tracer  time step    rfact  = ', rfact, ' rn_Dt = ', rn_Dt
103         IF(lwp) write(numout,*) '    PISCES  Biology time step    rfact2 = ', rfact2
104         IF(lwp) WRITE(numout,*)
105      ENDIF
106
107      IF( l_1st_euler .OR. ln_top_euler ) THEN
108         DO jn = jp_pcs0, jp_pcs1              !   SMS on tracer without Asselin time-filter
109            tr(:,:,:,jn,Kbb) = tr(:,:,:,jn,Kmm)
110         END DO
111      ENDIF
112
113      DO jn = jp_pcs0, jp_pcs1              !   Store the tracer concentrations before entering PISCES
114         ztrbbio(:,:,:,jn) = tr(:,:,:,jn,Kbb)
115      END DO
116
117      !
118      IF( ll_bc )    CALL p4z_bc( kt, Kbb, Kmm, Krhs )   ! external sources of nutrients
119      !
120#if ! defined key_sed_off
121      CALL p4z_che(     Kbb, Kmm       ) ! computation of chemical constants
122      CALL p4z_int( kt, Kbb, Kmm       ) ! computation of various rates for biogeochemistry
123      !
124      DO jnt = 1, nrdttrc          ! Potential time splitting if requested
125         !
126         CALL p4z_bio( kt, jnt, Kbb, Kmm, Krhs )   ! Biology
127         CALL p4z_lys( kt, jnt, Kbb,      Krhs )   ! Compute CaCO3 saturation
128         CALL p4z_sed( kt, jnt, Kbb, Kmm, Krhs )   ! Surface and Bottom boundary conditions
129         CALL p4z_flx( kt, jnt, Kbb, Kmm, Krhs )   ! Compute surface fluxes
130         !
131         xnegtr(:,:,:) = 1.e0
132         DO jn = jp_pcs0, jp_pcs1
133            DO_3D( 1, 1, 1, 1, 1, jpk )
134               IF( ( tr(ji,jj,jk,jn,Kbb) + tr(ji,jj,jk,jn,Krhs) ) < 0.e0 ) THEN
135                  ztra             = ABS( tr(ji,jj,jk,jn,Kbb) ) / ( ABS( tr(ji,jj,jk,jn,Krhs) ) + rtrn )
136                  xnegtr(ji,jj,jk) = MIN( xnegtr(ji,jj,jk),  ztra )
137               ENDIF
138            END_3D
139         END DO
140         !                                ! where at least 1 tracer concentration becomes negative
141         !                                !
142         DO jn = jp_pcs0, jp_pcs1
143           tr(:,:,:,jn,Kbb) = tr(:,:,:,jn,Kbb) + xnegtr(:,:,:) * tr(:,:,:,jn,Krhs)
144         END DO
145        !
146        IF(  iom_use( 'INTdtAlk' ) .OR. iom_use( 'INTdtDIC' ) .OR. iom_use( 'INTdtFer' ) .OR.  &
147          &  iom_use( 'INTdtDIN' ) .OR. iom_use( 'INTdtDIP' ) .OR. iom_use( 'INTdtSil' ) )  THEN
148          !
149          ALLOCATE( zw3d(jpi,jpj,jpk), zw2d(jpi,jpj) )
150          zw3d(:,:,jpk) = 0.
151          DO jk = 1, jpkm1
152              zw3d(:,:,jk) = xnegtr(:,:,jk) * xfact * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
153          ENDDO
154          !
155          zw2d(:,:) = 0.
156          DO jk = 1, jpkm1
157             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * tr(:,:,jk,jptal,Krhs)
158          ENDDO
159          CALL iom_put( 'INTdtAlk', zw2d )
160          !
161          zw2d(:,:) = 0.
162          DO jk = 1, jpkm1
163             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * tr(:,:,jk,jpdic,Krhs)
164          ENDDO
165          CALL iom_put( 'INTdtDIC', zw2d )
166          !
167          zw2d(:,:) = 0.
168          DO jk = 1, jpkm1
169             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * rno3 * ( tr(:,:,jk,jpno3,Krhs) + tr(:,:,jk,jpnh4,Krhs) )
170          ENDDO
171          CALL iom_put( 'INTdtDIN', zw2d )
172          !
173          zw2d(:,:) = 0.
174          DO jk = 1, jpkm1
175             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * po4r * tr(:,:,jk,jppo4,Krhs)
176          ENDDO
177          CALL iom_put( 'INTdtDIP', zw2d )
178          !
179          zw2d(:,:) = 0.
180          DO jk = 1, jpkm1
181             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * tr(:,:,jk,jpfer,Krhs)
182          ENDDO
183          CALL iom_put( 'INTdtFer', zw2d )
184          !
185          zw2d(:,:) = 0.
186          DO jk = 1, jpkm1
187             zw2d(:,:) = zw2d(:,:) + zw3d(:,:,jk) * tr(:,:,jk,jpsil,Krhs)
188          ENDDO
189          CALL iom_put( 'INTdtSil', zw2d )
190          !
191          DEALLOCATE( zw3d, zw2d )
192        ENDIF
193        !
194         DO jn = jp_pcs0, jp_pcs1
195            tr(:,:,:,jn,Krhs) = 0._wp
196         END DO
197         !
198      END DO
199      !
200#endif
201      !
202      IF( ln_sediment ) THEN 
203         !
204         CALL sed_model( kt, Kbb, Kmm, Krhs )     !  Main program of Sediment model
205         !
206      ENDIF
207      !
208      DO jn = jp_pcs0, jp_pcs1
209         tr(:,:,:,jn,Krhs) = ( tr(:,:,:,jn,Kbb) - ztrbbio(:,:,:,jn) ) * rfactr
210         tr(:,:,:,jn,Kbb ) = ztrbbio(:,:,:,jn)
211         ztrbbio(:,:,:,jn) = 0._wp
212      END DO
213      !
214      IF( l_trdtrc ) THEN
215         DO jn = jp_pcs0, jp_pcs1
216           CALL trd_trc( tr(:,:,:,jn,Krhs), jn, jptra_sms, kt, Kmm )   ! save trends
217         END DO
218      END IF
219      ! 
220      IF( lrst_trc )  CALL p4z_rst( kt, Kbb, Kmm,  'WRITE' )           !* Write PISCES informations in restart file
221      !
222
223      IF( lk_iomput .OR. ln_check_mass )  CALL p4z_chk_mass( kt, Kmm ) ! Mass conservation checking
224
225      IF( lwm .AND. kt == nittrc000    )  CALL FLUSH( numonp )         ! flush output namelist PISCES
226      !
227      IF( ln_timing )  CALL timing_stop('p4z_sms')
228      !
229   END SUBROUTINE p4z_sms
230
231
232   SUBROUTINE p4z_sms_init
233      !!----------------------------------------------------------------------
234      !!                     ***  p4z_sms_init  *** 
235      !!
236      !! ** Purpose :   read PISCES namelist
237      !!
238      !! ** input   :   file 'namelist.trc.s' containing the following
239      !!             namelist: natext, natbio, natsms
240      !!----------------------------------------------------------------------
241      INTEGER :: ios                 ! Local integer output status for namelist read
242      !!
243      NAMELIST/nampisbio/ nrdttrc, wsbio, xkmort, ferat3, wsbio2, wsbio2max, wsbio2scale,    &
244         &                   ldocp, ldocz, lthet, no3rat3, po4rat3
245         !
246      NAMELIST/nampisdmp/ ln_pisdmp, nn_pisdmp
247      NAMELIST/nampismass/ ln_check_mass
248      !!----------------------------------------------------------------------
249      !
250      IF(lwp) THEN
251         WRITE(numout,*)
252         WRITE(numout,*) 'p4z_sms_init : PISCES initialization'
253         WRITE(numout,*) '~~~~~~~~~~~~'
254      ENDIF
255
256      READ  ( numnatp_ref, nampisbio, IOSTAT = ios, ERR = 901)
257901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisbio in reference namelist' )
258      READ  ( numnatp_cfg, nampisbio, IOSTAT = ios, ERR = 902 )
259902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisbio in configuration namelist' )
260      IF(lwm) WRITE( numonp, nampisbio )
261      !
262      IF(lwp) THEN                         ! control print
263         WRITE(numout,*) '   Namelist : nampisbio'
264         WRITE(numout,*) '      frequency for the biology                 nrdttrc     =', nrdttrc
265         WRITE(numout,*) '      POC sinking speed                         wsbio       =', wsbio
266         WRITE(numout,*) '      half saturation constant for mortality    xkmort      =', xkmort 
267         IF( ln_p5z ) THEN
268            WRITE(numout,*) '      N/C in zooplankton                        no3rat3     =', no3rat3
269            WRITE(numout,*) '      P/C in zooplankton                        po4rat3     =', po4rat3
270         ENDIF
271         WRITE(numout,*) '      Fe/C in zooplankton                       ferat3      =', ferat3
272         WRITE(numout,*) '      Big particles sinking speed               wsbio2      =', wsbio2
273         WRITE(numout,*) '      Big particles maximum sinking speed       wsbio2max   =', wsbio2max
274         WRITE(numout,*) '      Big particles sinking speed length scale  wsbio2scale =', wsbio2scale
275         IF( ln_ligand ) THEN
276            IF( ln_p4z ) THEN
277               WRITE(numout,*) '      Phyto ligand production per unit doc           ldocp  =', ldocp
278               WRITE(numout,*) '      Zoo ligand production per unit doc             ldocz  =', ldocz
279               WRITE(numout,*) '      Proportional loss of ligands due to Fe uptake  lthet  =', lthet
280            ENDIF
281         ENDIF
282      ENDIF
283
284
285      READ  ( numnatp_ref, nampisdmp, IOSTAT = ios, ERR = 905)
286905   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisdmp in reference namelist' )
287      READ  ( numnatp_cfg, nampisdmp, IOSTAT = ios, ERR = 906 )
288906   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisdmp in configuration namelist' )
289      IF(lwm) WRITE( numonp, nampisdmp )
290      !
291      IF(lwp) THEN                         ! control print
292         WRITE(numout,*)
293         WRITE(numout,*) '   Namelist : nampisdmp --- relaxation to GLODAP'
294         WRITE(numout,*) '      Relaxation of tracer to glodap mean value   ln_pisdmp =', ln_pisdmp
295         WRITE(numout,*) '      Frequency of Relaxation                     nn_pisdmp =', nn_pisdmp
296      ENDIF
297
298      READ  ( numnatp_ref, nampismass, IOSTAT = ios, ERR = 907)
299907   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampismass in reference namelist' )
300      READ  ( numnatp_cfg, nampismass, IOSTAT = ios, ERR = 908 )
301908   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampismass in configuration namelist' )
302      IF(lwm) WRITE( numonp, nampismass )
303
304      IF(lwp) THEN                         ! control print
305         WRITE(numout,*)
306         WRITE(numout,*) '   Namelist : nampismass  --- mass conservation checking'
307         WRITE(numout,*) '      Flag to check mass conservation of NO3/Si/TALK   ln_check_mass = ', ln_check_mass
308      ENDIF
309      !
310   END SUBROUTINE p4z_sms_init
311
312
313   SUBROUTINE p4z_rst( kt, Kbb, Kmm, cdrw )
314      !!---------------------------------------------------------------------
315      !!                   ***  ROUTINE p4z_rst  ***
316      !!
317      !!  ** Purpose : Read or write variables in restart file:
318      !!
319      !!  WRITE(READ) mode:
320      !!       kt        : number of time step since the begining of the experiment at the
321      !!                   end of the current(previous) run
322      !!---------------------------------------------------------------------
323      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
324      INTEGER         , INTENT(in) ::   Kbb, Kmm   ! time level indices
325      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
326      !!---------------------------------------------------------------------
327      !
328      IF( TRIM(cdrw) == 'READ' ) THEN
329         !
330         IF(lwp) WRITE(numout,*)
331         IF(lwp) WRITE(numout,*) ' p4z_rst : Read specific variables from pisces model '
332         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
333         !
334         IF(lrxios) CALL iom_swap(cr_toprst_cxt)
335         IF( iom_varid( numrtr, 'PH', ldstop = .FALSE. ) > 0 ) THEN
336            CALL iom_get( numrtr, jpdom_auto, 'PH' , hi(:,:,:), ldxios = lrxios  )
337         ELSE
338            CALL p4z_che( Kbb, Kmm )                  ! initialize the chemical constants
339            CALL ahini_for_at( hi, Kbb )
340         ENDIF
341         CALL iom_get( numrtr, jpdom_auto, 'Silicalim', xksi(:,:), ldxios = lrxios )
342         IF( iom_varid( numrtr, 'Silicamax', ldstop = .FALSE. ) > 0 ) THEN
343            CALL iom_get( numrtr, jpdom_auto, 'Silicamax' , xksimax(:,:), ldxios = lrxios  )
344         ELSE
345            xksimax(:,:) = xksi(:,:)
346         ENDIF
347         !
348         IF( iom_varid( numrtr, 'tcflxcum', ldstop = .FALSE. ) > 0 ) THEN  ! cumulative total flux of carbon
349            CALL iom_get( numrtr, 'tcflxcum' , t_oce_co2_flx_cum, ldxios = lrxios  )
350         ELSE
351            t_oce_co2_flx_cum = 0._wp
352         ENDIF
353         !
354         IF( ln_p5z ) THEN
355            IF( iom_varid( numrtr, 'sized', ldstop = .FALSE. ) > 0 ) THEN
356               CALL iom_get( numrtr, jpdom_auto, 'sizep' , sizep(:,:,:), ldxios = lrxios  )
357               CALL iom_get( numrtr, jpdom_auto, 'sizen' , sizen(:,:,:), ldxios = lrxios  )
358               CALL iom_get( numrtr, jpdom_auto, 'sized' , sized(:,:,:), ldxios = lrxios  )
359            ELSE
360               sizep(:,:,:) = 1.
361               sizen(:,:,:) = 1.
362               sized(:,:,:) = 1.
363            ENDIF
364        ENDIF
365        IF(lrxios) CALL iom_swap(cxios_context)
366        !
367      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
368         IF( kt == nitrst ) THEN
369            IF(lwp) WRITE(numout,*)
370            IF(lwp) WRITE(numout,*) 'p4z_rst : write pisces restart file  kt =', kt
371            IF(lwp) WRITE(numout,*) '~~~~~~~'
372         ENDIF
373         IF( lwxios ) CALL iom_swap(      cw_toprst_cxt         )
374         CALL iom_rstput( kt, nitrst, numrtw, 'PH', hi(:,:,:),               ldxios = lwxios )
375         CALL iom_rstput( kt, nitrst, numrtw, 'Silicalim', xksi(:,:),        ldxios = lwxios )
376         CALL iom_rstput( kt, nitrst, numrtw, 'Silicamax', xksimax(:,:),     ldxios = lwxios )
377         CALL iom_rstput( kt, nitrst, numrtw, 'tcflxcum', t_oce_co2_flx_cum, ldxios = lwxios )
378         IF( ln_p5z ) THEN
379            CALL iom_rstput( kt, nitrst, numrtw, 'sizep', sizep(:,:,:), ldxios = lwxios )
380            CALL iom_rstput( kt, nitrst, numrtw, 'sizen', sizen(:,:,:), ldxios = lwxios )
381            CALL iom_rstput( kt, nitrst, numrtw, 'sized', sized(:,:,:), ldxios = lwxios )
382         ENDIF
383         IF( lwxios ) CALL iom_swap(      cxios_context         )
384      ENDIF
385      !
386   END SUBROUTINE p4z_rst
387
388
389   SUBROUTINE p4z_dmp( kt, Kbb, Kmm )
390      !!----------------------------------------------------------------------
391      !!                    ***  p4z_dmp  ***
392      !!
393      !! ** purpose  : Relaxation of some tracers
394      !!----------------------------------------------------------------------
395      !
396      INTEGER, INTENT( in )  ::     kt            ! time step
397      INTEGER, INTENT( in )  ::     Kbb, Kmm      ! time level indices
398      !
399      REAL(wp) ::  alkmean = 2426.     ! mean value of alkalinity ( Glodap ; for Goyet 2391. )
400      REAL(wp) ::  po4mean = 2.165     ! mean value of phosphates
401      REAL(wp) ::  no3mean = 30.90     ! mean value of nitrate
402      REAL(wp) ::  silmean = 91.51     ! mean value of silicate
403      !
404      REAL(wp) :: zarea, zalksumn, zpo4sumn, zno3sumn, zsilsumn
405      REAL(wp) :: zalksumb, zpo4sumb, zno3sumb, zsilsumb
406      !!---------------------------------------------------------------------
407
408      IF(lwp)  WRITE(numout,*)
409      IF(lwp)  WRITE(numout,*) ' p4z_dmp : Restoring of nutrients at time-step kt = ', kt
410      IF(lwp)  WRITE(numout,*)
411
412      IF( cn_cfg == "ORCA" .OR. cn_cfg == "orca") THEN
413         IF( .NOT. lk_c1d ) THEN      ! ORCA configuration (not 1D) !
414            !                                                ! --------------------------- !
415            ! set total alkalinity, phosphate, nitrate & silicate
416            zarea          = 1._wp / glob_sum( 'p4zsms', cvol(:,:,:) ) * 1e6             
417
418            zalksumn = glob_sum( 'p4zsms', tr(:,:,:,jptal,Kmm) * cvol(:,:,:)  ) * zarea
419            zpo4sumn = glob_sum( 'p4zsms', tr(:,:,:,jppo4,Kmm) * cvol(:,:,:)  ) * zarea * po4r
420            zno3sumn = glob_sum( 'p4zsms', tr(:,:,:,jpno3,Kmm) * cvol(:,:,:)  ) * zarea * rno3
421            zsilsumn = glob_sum( 'p4zsms', tr(:,:,:,jpsil,Kmm) * cvol(:,:,:)  ) * zarea
422 
423            IF(lwp) WRITE(numout,*) '       TALKN mean : ', zalksumn
424            tr(:,:,:,jptal,Kmm) = tr(:,:,:,jptal,Kmm) * alkmean / zalksumn
425
426            IF(lwp) WRITE(numout,*) '       PO4N  mean : ', zpo4sumn
427            tr(:,:,:,jppo4,Kmm) = tr(:,:,:,jppo4,Kmm) * po4mean / zpo4sumn
428
429            IF(lwp) WRITE(numout,*) '       NO3N  mean : ', zno3sumn
430            tr(:,:,:,jpno3,Kmm) = tr(:,:,:,jpno3,Kmm) * no3mean / zno3sumn
431
432            IF(lwp) WRITE(numout,*) '       SiO3N mean : ', zsilsumn
433            tr(:,:,:,jpsil,Kmm) = MIN( 400.e-6,tr(:,:,:,jpsil,Kmm) * silmean / zsilsumn )
434            !
435            !
436            IF( .NOT. ln_top_euler ) THEN
437               zalksumb = glob_sum( 'p4zsms', tr(:,:,:,jptal,Kbb) * cvol(:,:,:)  ) * zarea
438               zpo4sumb = glob_sum( 'p4zsms', tr(:,:,:,jppo4,Kbb) * cvol(:,:,:)  ) * zarea * po4r
439               zno3sumb = glob_sum( 'p4zsms', tr(:,:,:,jpno3,Kbb) * cvol(:,:,:)  ) * zarea * rno3
440               zsilsumb = glob_sum( 'p4zsms', tr(:,:,:,jpsil,Kbb) * cvol(:,:,:)  ) * zarea
441 
442               IF(lwp) WRITE(numout,*) ' '
443               IF(lwp) WRITE(numout,*) '       TALKB mean : ', zalksumb
444               tr(:,:,:,jptal,Kbb) = tr(:,:,:,jptal,Kbb) * alkmean / zalksumb
445
446               IF(lwp) WRITE(numout,*) '       PO4B  mean : ', zpo4sumb
447               tr(:,:,:,jppo4,Kbb) = tr(:,:,:,jppo4,Kbb) * po4mean / zpo4sumb
448
449               IF(lwp) WRITE(numout,*) '       NO3B  mean : ', zno3sumb
450               tr(:,:,:,jpno3,Kbb) = tr(:,:,:,jpno3,Kbb) * no3mean / zno3sumb
451
452               IF(lwp) WRITE(numout,*) '       SiO3B mean : ', zsilsumb
453               tr(:,:,:,jpsil,Kbb) = MIN( 400.e-6,tr(:,:,:,jpsil,Kbb) * silmean / zsilsumb )
454           ENDIF
455        ENDIF
456        !
457      ENDIF
458        !
459   END SUBROUTINE p4z_dmp
460
461
462   SUBROUTINE p4z_chk_mass( kt, Kmm )
463      !!----------------------------------------------------------------------
464      !!                  ***  ROUTINE p4z_chk_mass  ***
465      !!
466      !! ** Purpose :  Mass conservation check
467      !!
468      !!---------------------------------------------------------------------
469      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
470      INTEGER, INTENT( in ) ::   Kmm     ! time level indices
471      REAL(wp)             ::  zrdenittot, zsdenittot, znitrpottot
472      CHARACTER(LEN=100)   ::   cltxt
473      INTEGER :: jk
474      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwork
475      !!----------------------------------------------------------------------
476      !
477      IF( kt == nittrc000 ) THEN
478         xfact1 = rfact2r * 12. / 1.e15 * ryyss    ! conversion molC/kt --> PgC/yr
479         xfact2 = 1.e+3 * rno3 * 14. / 1.e12 * ryyss   ! conversion molC/l/s ----> TgN/m3/yr
480         xfact3 = 1.e+3 * rfact2r * rno3   ! conversion molC/l/kt ----> molN/m3/s
481         IF( ln_check_mass .AND. lwp) THEN      !   Open budget file of NO3, ALK, Si, Fer
482            CALL ctl_opn( numco2, 'carbon.budget'  , 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
483            CALL ctl_opn( numnut, 'nutrient.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
484            CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
485            cltxt='time-step   Alkalinity        Nitrate        Phosphorus         Silicate           Iron'
486            IF( lwp ) WRITE(numnut,*)  TRIM(cltxt)
487            IF( lwp ) WRITE(numnut,*) 
488         ENDIF
489      ENDIF
490
491      IF( iom_use( "pno3tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
492         !   Compute the budget of NO3, ALK, Si, Fer
493         IF( ln_p4z ) THEN
494            zwork(:,:,:) =    tr(:,:,:,jpno3,Kmm) + tr(:,:,:,jpnh4,Kmm)                      &
495               &          +   tr(:,:,:,jpphy,Kmm) + tr(:,:,:,jpdia,Kmm)                      &
496               &          +   tr(:,:,:,jppoc,Kmm) + tr(:,:,:,jpgoc,Kmm)  + tr(:,:,:,jpdoc,Kmm)  &       
497               &          +   tr(:,:,:,jpzoo,Kmm) + tr(:,:,:,jpmes,Kmm) 
498        ELSE
499            zwork(:,:,:) =    tr(:,:,:,jpno3,Kmm) + tr(:,:,:,jpnh4,Kmm) + tr(:,:,:,jpnph,Kmm)   &
500               &          +   tr(:,:,:,jpndi,Kmm) + tr(:,:,:,jpnpi,Kmm)                      & 
501               &          +   tr(:,:,:,jppon,Kmm) + tr(:,:,:,jpgon,Kmm) + tr(:,:,:,jpdon,Kmm)   &
502               &          + ( tr(:,:,:,jpzoo,Kmm) + tr(:,:,:,jpmes,Kmm) ) * no3rat3 
503        ENDIF
504        !
505        no3budget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
506        no3budget = no3budget / areatot
507        CALL iom_put( "pno3tot", no3budget )
508      ENDIF
509      !
510      IF( iom_use( "ppo4tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
511         IF( ln_p4z ) THEN
512            zwork(:,:,:) =    tr(:,:,:,jppo4,Kmm)                                         &
513               &          +   tr(:,:,:,jpphy,Kmm) + tr(:,:,:,jpdia,Kmm)                      &
514               &          +   tr(:,:,:,jppoc,Kmm) + tr(:,:,:,jpgoc,Kmm)  + tr(:,:,:,jpdoc,Kmm)  &       
515               &          +   tr(:,:,:,jpzoo,Kmm) + tr(:,:,:,jpmes,Kmm) 
516        ELSE
517            zwork(:,:,:) =    tr(:,:,:,jppo4,Kmm) + tr(:,:,:,jppph,Kmm)                      &
518               &          +   tr(:,:,:,jppdi,Kmm) + tr(:,:,:,jpppi,Kmm)                      & 
519               &          +   tr(:,:,:,jppop,Kmm) + tr(:,:,:,jpgop,Kmm) + tr(:,:,:,jpdop,Kmm)   &
520               &          + ( tr(:,:,:,jpzoo,Kmm) + tr(:,:,:,jpmes,Kmm) ) * po4rat3 
521        ENDIF
522        !
523        po4budget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
524        po4budget = po4budget / areatot
525        CALL iom_put( "ppo4tot", po4budget )
526      ENDIF
527      !
528      IF( iom_use( "psiltot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
529         zwork(:,:,:) =  tr(:,:,:,jpsil,Kmm) + tr(:,:,:,jpgsi,Kmm) + tr(:,:,:,jpdsi,Kmm) 
530         !
531         silbudget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
532         silbudget = silbudget / areatot
533         CALL iom_put( "psiltot", silbudget )
534      ENDIF
535      !
536      IF( iom_use( "palktot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
537         zwork(:,:,:) =  tr(:,:,:,jpno3,Kmm) * rno3 + tr(:,:,:,jptal,Kmm) + tr(:,:,:,jpcal,Kmm) * 2.             
538         !
539         alkbudget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  )         !
540         alkbudget = alkbudget / areatot
541         CALL iom_put( "palktot", alkbudget )
542      ENDIF
543      !
544      IF( iom_use( "pfertot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
545         zwork(:,:,:) =   tr(:,:,:,jpfer,Kmm) + tr(:,:,:,jpnfe,Kmm) + tr(:,:,:,jpdfe,Kmm)   &
546            &         +   tr(:,:,:,jpbfe,Kmm) + tr(:,:,:,jpsfe,Kmm)                      &
547            &         + ( tr(:,:,:,jpzoo,Kmm) + tr(:,:,:,jpmes,Kmm) )  * ferat3   
548         !
549         ferbudget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
550         ferbudget = ferbudget / areatot
551         CALL iom_put( "pfertot", ferbudget )
552      ENDIF
553      !
554      ! Global budget of N SMS : denitrification in the water column and in the sediment
555      !                          nitrogen fixation by the diazotrophs
556      ! --------------------------------------------------------------------------------
557      IF( iom_use( "tnfix" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
558         znitrpottot  = glob_sum ( 'p4zsms', nitrpot(:,:,:) * nitrfix * cvol(:,:,:) )
559         CALL iom_put( "tnfix"  , znitrpottot * xfact3 )  ! Global  nitrogen fixation molC/l  to molN/m3
560      ENDIF
561      !
562      IF( iom_use( "tdenit" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
563         zrdenittot = glob_sum ( 'p4zsms', denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
564         zsdenittot = glob_sum ( 'p4zsms', sdenit(:,:) * e1e2t(:,:) * tmask(:,:,1) )
565         CALL iom_put( "tdenit" , ( zrdenittot + zsdenittot ) * xfact3 )  ! Total denitrification molC/l to molN/m3
566      ENDIF
567      !
568      IF( ln_check_mass .AND. kt == nitend ) THEN   ! Compute the budget of NO3, ALK, Si, Fer
569         t_atm_co2_flx  = t_atm_co2_flx / glob_sum( 'p4zsms', e1e2t(:,:) )
570         t_oce_co2_flx  = t_oce_co2_flx         * xfact1 * (-1 )
571         tpp            = tpp           * 1000. * xfact1
572         t_oce_co2_exp  = t_oce_co2_exp * 1000. * xfact1
573         IF( lwp ) WRITE(numco2,9000) ndastp, t_atm_co2_flx, t_oce_co2_flx, tpp, t_oce_co2_exp
574         IF( lwp ) WRITE(numnut,9100) ndastp, alkbudget        * 1.e+06, &
575             &                                no3budget * rno3 * 1.e+06, &
576             &                                po4budget * po4r * 1.e+06, &
577             &                                silbudget        * 1.e+06, &
578             &                                ferbudget        * 1.e+09
579         !
580         IF( lwp ) WRITE(numnit,9200) ndastp, znitrpottot * xfact2  , &
581            &                             zrdenittot  * xfact2  , &
582            &                             zsdenittot  * xfact2
583      ENDIF
584      !
585 9000  FORMAT(i8,f10.5,e18.10,f10.5,f10.5)
586 9100  FORMAT(i8,5e18.10)
587 9200  FORMAT(i8,3f10.5)
588       !
589   END SUBROUTINE p4z_chk_mass
590
591   !!======================================================================
592END MODULE p4zsms 
Note: See TracBrowser for help on using the repository browser.