New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaar5.F90 in NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/DIA – NEMO

source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/DIA/diaar5.F90 @ 13156

Last change on this file since 13156 was 13156, checked in by techene, 4 years ago

some bug correction (zgdept allocation, empty step qco module when key_qco is not activated)
  • Property svn:keywords set to Id
File size: 18.8 KB
Line 
1MODULE diaar5
2   !!======================================================================
3   !!                       ***  MODULE  diaar5  ***
4   !! AR5 diagnostics
5   !!======================================================================
6   !! History :  3.2  !  2009-11  (S. Masson)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
8   !!----------------------------------------------------------------------
9   !!   dia_ar5       : AR5 diagnostics
10   !!   dia_ar5_init  : initialisation of AR5 diagnostics
11   !!----------------------------------------------------------------------
12   USE oce            ! ocean dynamics and active tracers
13   USE dom_oce        ! ocean space and time domain
14   USE eosbn2         ! equation of state                (eos_bn2 routine)
15   USE phycst         ! physical constant
16   USE in_out_manager  ! I/O manager
17   USE zdfddm
18   USE zdf_oce
19   !
20   USE lib_mpp        ! distribued memory computing library
21   USE iom            ! I/O manager library
22   USE fldread        ! type FLD_N
23   USE timing         ! preformance summary
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   dia_ar5        ! routine called in step.F90 module
29   PUBLIC   dia_ar5_alloc  ! routine called in nemogcm.F90 module
30   PUBLIC   dia_ar5_hst    ! heat/salt transport
31
32   REAL(wp)                         ::   vol0         ! ocean volume (interior domain)
33   REAL(wp)                         ::   area_tot     ! total ocean surface (interior domain)
34   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   thick0       ! ocean thickness (interior domain)
35   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sn0          ! initial salinity
36
37   LOGICAL  :: l_ar5
38     
39   !! * Substitutions
40#  include "do_loop_substitute.h90"
41#  include "domzgr_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   FUNCTION dia_ar5_alloc()
50      !!----------------------------------------------------------------------
51      !!                    ***  ROUTINE dia_ar5_alloc  ***
52      !!----------------------------------------------------------------------
53      INTEGER :: dia_ar5_alloc
54      !!----------------------------------------------------------------------
55      !
56      ALLOCATE( thick0(jpi,jpj) , sn0(jpi,jpj,jpk) , STAT=dia_ar5_alloc )
57      !
58      CALL mpp_sum ( 'diaar5', dia_ar5_alloc )
59      IF( dia_ar5_alloc /= 0 )   CALL ctl_stop( 'STOP', 'dia_ar5_alloc: failed to allocate arrays' )
60      !
61   END FUNCTION dia_ar5_alloc
62
63
64   SUBROUTINE dia_ar5( kt, Kmm )
65      !!----------------------------------------------------------------------
66      !!                    ***  ROUTINE dia_ar5  ***
67      !!
68      !! ** Purpose :   compute and output some AR5 diagnostics
69      !!----------------------------------------------------------------------
70      !
71      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
72      INTEGER, INTENT( in ) ::   Kmm  ! ocean time level index
73      !
74      INTEGER  ::   ji, jj, jk, iks, ikb                      ! dummy loop arguments
75      REAL(wp) ::   zvolssh, zvol, zssh_steric, zztmp, zarho, ztemp, zsal, zmass, zsst
76      REAL(wp) ::   zaw, zbw, zrw
77      !
78      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     :: zarea_ssh , zbotpres       ! 2D workspace
79      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     :: z2d, zpe                   ! 2D workspace
80      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   :: z3d, zrhd , zrhop, ztpot, zgdept   ! 3D workspace (zgdept: needed to use the substitute)
81      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) :: ztsn                       ! 4D workspace
82
83      !!--------------------------------------------------------------------
84      IF( ln_timing )   CALL timing_start('dia_ar5')
85 
86      IF( kt == nit000 )     CALL dia_ar5_init
87
88      IF( l_ar5 ) THEN
89         ALLOCATE( zarea_ssh(jpi,jpj), zbotpres(jpi,jpj), z2d(jpi,jpj) )
90         ALLOCATE( zrhd(jpi,jpj,jpk) , zrhop(jpi,jpj,jpk) )
91         ALLOCATE( ztsn(jpi,jpj,jpk,jpts) )
92         zarea_ssh(:,:) = e1e2t(:,:) * ssh(:,:,Kmm)
93      ENDIF
94      !
95      CALL iom_put( 'e2u'      , e2u  (:,:) )
96      CALL iom_put( 'e1v'      , e1v  (:,:) )
97      CALL iom_put( 'areacello', e1e2t(:,:) )
98      !
99      IF( iom_use( 'volcello' ) .OR. iom_use( 'masscello' )  ) THEN 
100         zrhd(:,:,jpk) = 0._wp        ! ocean volume ; rhd is used as workspace
101         DO jk = 1, jpkm1
102            zrhd(:,:,jk) = e1e2t(:,:) * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
103         END DO
104         DO jk = 1, jpk
105            z3d(:,:,jk) =  rho0 * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
106         END DO
107         CALL iom_put( 'volcello'  , zrhd(:,:,:)  )  ! WARNING not consistent with CMIP DR where volcello is at ca. 2000
108         CALL iom_put( 'masscello' , z3d (:,:,:) )   ! ocean mass
109      ENDIF 
110      !
111      IF( iom_use( 'e3tb' ) )  THEN    ! bottom layer thickness
112         DO_2D_11_11
113            ikb = mbkt(ji,jj)
114            z2d(ji,jj) = e3t(ji,jj,ikb,Kmm)
115         END_2D
116         CALL iom_put( 'e3tb', z2d )
117      ENDIF 
118      !
119      IF( iom_use( 'voltot' ) .OR. iom_use( 'sshtot' )  .OR. iom_use( 'sshdyn' )  ) THEN   
120         !                                         ! total volume of liquid seawater
121         zvolssh = glob_sum( 'diaar5', zarea_ssh(:,:) ) 
122         zvol    = vol0 + zvolssh
123     
124         CALL iom_put( 'voltot', zvol               )
125         CALL iom_put( 'sshtot', zvolssh / area_tot )
126         CALL iom_put( 'sshdyn', ssh(:,:,Kmm) - (zvolssh / area_tot) )
127         !
128      ENDIF
129
130      IF( iom_use( 'botpres' ) .OR. iom_use( 'sshthster' )  .OR. iom_use( 'sshsteric' )  ) THEN   
131         !                     
132         ztsn(:,:,:,jp_tem) = ts(:,:,:,jp_tem,Kmm)                    ! thermosteric ssh
133         ztsn(:,:,:,jp_sal) = sn0(:,:,:)
134         ALLOCATE( zgdept(jpi,jpj,jpk) )
135         DO jk = 1, jpk
136            zgdept(:,:,jk) = gdept(:,:,jk,Kmm)
137         END DO
138         CALL eos( ztsn, zrhd, zgdept)                       ! now in situ density using initial salinity
139         !
140         zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
141         DO jk = 1, jpkm1
142            zbotpres(:,:) = zbotpres(:,:) + e3t(:,:,jk,Kmm) * zrhd(:,:,jk)
143         END DO
144         IF( ln_linssh ) THEN
145            IF( ln_isfcav ) THEN
146               DO ji = 1, jpi
147                  DO jj = 1, jpj
148                     iks = mikt(ji,jj)
149                     zbotpres(ji,jj) = zbotpres(ji,jj) + ssh(ji,jj,Kmm) * zrhd(ji,jj,iks) + riceload(ji,jj)
150                  END DO
151               END DO
152            ELSE
153               zbotpres(:,:) = zbotpres(:,:) + ssh(:,:,Kmm) * zrhd(:,:,1)
154            END IF
155!!gm
156!!gm   riceload should be added in both ln_linssh=T or F, no?
157!!gm
158         END IF
159         !                                         
160         zarho = glob_sum( 'diaar5', e1e2t(:,:) * zbotpres(:,:) ) 
161         zssh_steric = - zarho / area_tot
162         CALL iom_put( 'sshthster', zssh_steric )
163     
164         !                                         ! steric sea surface height
165         CALL eos( ts(:,:,:,:,Kmm), zrhd, zrhop, zgdept )                 ! now in situ and potential density
166         zrhop(:,:,jpk) = 0._wp
167         CALL iom_put( 'rhop', zrhop )
168         !
169         zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
170         DO jk = 1, jpkm1
171            zbotpres(:,:) = zbotpres(:,:) + e3t(:,:,jk,Kmm) * zrhd(:,:,jk)
172         END DO
173         IF( ln_linssh ) THEN
174            IF ( ln_isfcav ) THEN
175               DO ji = 1,jpi
176                  DO jj = 1,jpj
177                     iks = mikt(ji,jj)
178                     zbotpres(ji,jj) = zbotpres(ji,jj) + ssh(ji,jj,Kmm) * zrhd(ji,jj,iks) + riceload(ji,jj)
179                  END DO
180               END DO
181            ELSE
182               zbotpres(:,:) = zbotpres(:,:) + ssh(:,:,Kmm) * zrhd(:,:,1)
183            END IF
184         END IF
185         !   
186         zarho = glob_sum( 'diaar5', e1e2t(:,:) * zbotpres(:,:) ) 
187         zssh_steric = - zarho / area_tot
188         CALL iom_put( 'sshsteric', zssh_steric )
189         !                                         ! ocean bottom pressure
190         zztmp = rho0 * grav * 1.e-4_wp               ! recover pressure from pressure anomaly and cover to dbar = 1.e4 Pa
191         zbotpres(:,:) = zztmp * ( zbotpres(:,:) + ssh(:,:,Kmm) + thick0(:,:) )
192         CALL iom_put( 'botpres', zbotpres )
193         !
194         DEALLOCATE( zgdept )
195         !
196      ENDIF
197
198      IF( iom_use( 'masstot' ) .OR. iom_use( 'temptot' )  .OR. iom_use( 'saltot' )  ) THEN   
199          !                                         ! Mean density anomalie, temperature and salinity
200          ztsn(:,:,:,:) = 0._wp                    ! ztsn(:,:,1,jp_tem/sal) is used here as 2D Workspace for temperature & salinity
201          DO_3D_11_11( 1, jpkm1 )
202             zztmp = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm)
203             ztsn(ji,jj,1,jp_tem) = ztsn(ji,jj,1,jp_tem) + zztmp * ts(ji,jj,jk,jp_tem,Kmm)
204             ztsn(ji,jj,1,jp_sal) = ztsn(ji,jj,1,jp_sal) + zztmp * ts(ji,jj,jk,jp_sal,Kmm)
205          END_3D
206
207          IF( ln_linssh ) THEN
208            IF( ln_isfcav ) THEN
209               DO ji = 1, jpi
210                  DO jj = 1, jpj
211                     iks = mikt(ji,jj)
212                     ztsn(ji,jj,1,jp_tem) = ztsn(ji,jj,1,jp_tem) + zarea_ssh(ji,jj) * ts(ji,jj,iks,jp_tem,Kmm) 
213                     ztsn(ji,jj,1,jp_sal) = ztsn(ji,jj,1,jp_sal) + zarea_ssh(ji,jj) * ts(ji,jj,iks,jp_sal,Kmm) 
214                  END DO
215               END DO
216            ELSE
217               ztsn(:,:,1,jp_tem) = ztsn(:,:,1,jp_tem) + zarea_ssh(:,:) * ts(:,:,1,jp_tem,Kmm) 
218               ztsn(:,:,1,jp_sal) = ztsn(:,:,1,jp_sal) + zarea_ssh(:,:) * ts(:,:,1,jp_sal,Kmm) 
219            END IF
220         ENDIF
221         !
222         ztemp = glob_sum( 'diaar5', ztsn(:,:,1,jp_tem) )
223         zsal  = glob_sum( 'diaar5', ztsn(:,:,1,jp_sal) )
224         zmass = rho0 * ( zarho + zvol )     
225         !
226         CALL iom_put( 'masstot', zmass )
227         CALL iom_put( 'temptot', ztemp / zvol )
228         CALL iom_put( 'saltot' , zsal  / zvol )
229         !
230      ENDIF     
231
232      IF( ln_teos10 ) THEN        ! ! potential temperature (TEOS-10 case)
233         IF( iom_use( 'toce_pot') .OR. iom_use( 'temptot_pot' ) .OR. iom_use( 'sst_pot' )  &
234                                  .OR. iom_use( 'ssttot' ) .OR.  iom_use( 'tosmint_pot' ) ) THEN
235            !
236            ALLOCATE( ztpot(jpi,jpj,jpk) )
237            ztpot(:,:,jpk) = 0._wp
238            DO jk = 1, jpkm1
239               ztpot(:,:,jk) = eos_pt_from_ct( ts(:,:,jk,jp_tem,Kmm), ts(:,:,jk,jp_sal,Kmm) )
240            END DO
241            !
242            CALL iom_put( 'toce_pot', ztpot(:,:,:) )  ! potential temperature (TEOS-10 case)
243            CALL iom_put( 'sst_pot' , ztpot(:,:,1) )  ! surface temperature
244            !
245            IF( iom_use( 'temptot_pot' ) ) THEN   ! Output potential temperature in case we use TEOS-10
246               z2d(:,:) = 0._wp
247               DO jk = 1, jpkm1
248                 z2d(:,:) = z2d(:,:) + e1e2t(:,:) * e3t(:,:,jk,Kmm) * ztpot(:,:,jk)
249               END DO
250               ztemp = glob_sum( 'diaar5', z2d(:,:)  ) 
251               CALL iom_put( 'temptot_pot', ztemp / zvol )
252             ENDIF
253             !
254             IF( iom_use( 'ssttot' ) ) THEN   ! Output potential temperature in case we use TEOS-10
255               zsst = glob_sum( 'diaar5',  e1e2t(:,:) * ztpot(:,:,1)  ) 
256               CALL iom_put( 'ssttot', zsst / area_tot )
257             ENDIF
258             ! Vertical integral of temperature
259             IF( iom_use( 'tosmint_pot') ) THEN
260               z2d(:,:) = 0._wp
261               DO_3D_11_11( 1, jpkm1 )
262                  z2d(ji,jj) = z2d(ji,jj) + rho0 * e3t(ji,jj,jk,Kmm) *  ztpot(ji,jj,jk)
263               END_3D
264               CALL iom_put( 'tosmint_pot', z2d ) 
265            ENDIF
266            DEALLOCATE( ztpot )
267        ENDIF
268      ELSE       
269         IF( iom_use('ssttot') ) THEN   ! Output sst in case we use EOS-80
270            zsst  = glob_sum( 'diaar5', e1e2t(:,:) * ts(:,:,1,jp_tem,Kmm) )
271            CALL iom_put('ssttot', zsst / area_tot )
272         ENDIF
273      ENDIF
274
275      IF( iom_use( 'tnpeo' )) THEN   
276        ! Work done against stratification by vertical mixing
277        ! Exclude points where rn2 is negative as convection kicks in here and
278        ! work is not being done against stratification
279         ALLOCATE( zpe(jpi,jpj) )
280         zpe(:,:) = 0._wp
281         IF( ln_zdfddm ) THEN
282            DO_3D_11_11( 2, jpk )
283               IF( rn2(ji,jj,jk) > 0._wp ) THEN
284                  zrw = ( gdept(ji,jj,jk,Kmm) - gdepw(ji,jj,jk,Kmm) ) / e3w(ji,jj,jk,Kmm)
285                  !
286                  zaw = rab_n(ji,jj,jk,jp_tem) * (1. - zrw) + rab_n(ji,jj,jk-1,jp_tem)* zrw
287                  zbw = rab_n(ji,jj,jk,jp_sal) * (1. - zrw) + rab_n(ji,jj,jk-1,jp_sal)* zrw
288                  !
289                  zpe(ji, jj) = zpe(ji,jj)   &
290                     &        -  grav * (  avt(ji,jj,jk) * zaw * (ts(ji,jj,jk-1,jp_tem,Kmm) - ts(ji,jj,jk,jp_tem,Kmm) )  &
291                     &                   - avs(ji,jj,jk) * zbw * (ts(ji,jj,jk-1,jp_sal,Kmm) - ts(ji,jj,jk,jp_sal,Kmm) ) )
292               ENDIF
293            END_3D
294          ELSE
295            DO_3D_11_11( 1, jpk )
296               zpe(ji,jj) = zpe(ji,jj) + avt(ji,jj,jk) * MIN(0._wp,rn2(ji,jj,jk)) * rho0 * e3w(ji,jj,jk,Kmm)
297            END_3D
298         ENDIF
299          CALL iom_put( 'tnpeo', zpe )
300          DEALLOCATE( zpe )
301      ENDIF
302
303      IF( l_ar5 ) THEN
304        DEALLOCATE( zarea_ssh , zbotpres, z2d )
305        DEALLOCATE( zrhd      , zrhop    )
306        DEALLOCATE( ztsn                 )
307      ENDIF
308      !
309      IF( ln_timing )   CALL timing_stop('dia_ar5')
310      !
311   END SUBROUTINE dia_ar5
312
313
314   SUBROUTINE dia_ar5_hst( ktra, cptr, puflx, pvflx ) 
315      !!----------------------------------------------------------------------
316      !!                    ***  ROUTINE dia_ar5_htr ***
317      !!----------------------------------------------------------------------
318      !! Wrapper for heat transport calculations
319      !! Called from all advection and/or diffusion routines
320      !!----------------------------------------------------------------------
321      INTEGER                         , INTENT(in )  :: ktra  ! tracer index
322      CHARACTER(len=3)                , INTENT(in)   :: cptr  ! transport type  'adv'/'ldf'
323      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in)   :: puflx  ! u-flux of advection/diffusion
324      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in)   :: pvflx  ! v-flux of advection/diffusion
325      !
326      INTEGER    ::  ji, jj, jk
327      REAL(wp), DIMENSION(jpi,jpj)  :: z2d
328
329   
330      z2d(:,:) = puflx(:,:,1) 
331      DO_3D_00_00( 1, jpkm1 )
332         z2d(ji,jj) = z2d(ji,jj) + puflx(ji,jj,jk) 
333      END_3D
334       CALL lbc_lnk( 'diaar5', z2d, 'U', -1. )
335       IF( cptr == 'adv' ) THEN
336          IF( ktra == jp_tem ) CALL iom_put( 'uadv_heattr' , rho0_rcp * z2d )  ! advective heat transport in i-direction
337          IF( ktra == jp_sal ) CALL iom_put( 'uadv_salttr' , rho0     * z2d )  ! advective salt transport in i-direction
338       ENDIF
339       IF( cptr == 'ldf' ) THEN
340          IF( ktra == jp_tem ) CALL iom_put( 'udiff_heattr' , rho0_rcp * z2d ) ! diffusive heat transport in i-direction
341          IF( ktra == jp_sal ) CALL iom_put( 'udiff_salttr' , rho0     * z2d ) ! diffusive salt transport in i-direction
342       ENDIF
343       !
344       z2d(:,:) = pvflx(:,:,1) 
345       DO_3D_00_00( 1, jpkm1 )
346          z2d(ji,jj) = z2d(ji,jj) + pvflx(ji,jj,jk) 
347       END_3D
348       CALL lbc_lnk( 'diaar5', z2d, 'V', -1. )
349       IF( cptr == 'adv' ) THEN
350          IF( ktra == jp_tem ) CALL iom_put( 'vadv_heattr' , rho0_rcp * z2d )  ! advective heat transport in j-direction
351          IF( ktra == jp_sal ) CALL iom_put( 'vadv_salttr' , rho0     * z2d )  ! advective salt transport in j-direction
352       ENDIF
353       IF( cptr == 'ldf' ) THEN
354          IF( ktra == jp_tem ) CALL iom_put( 'vdiff_heattr' , rho0_rcp * z2d ) ! diffusive heat transport in j-direction
355          IF( ktra == jp_sal ) CALL iom_put( 'vdiff_salttr' , rho0     * z2d ) ! diffusive salt transport in j-direction
356       ENDIF
357         
358   END SUBROUTINE dia_ar5_hst
359
360
361   SUBROUTINE dia_ar5_init
362      !!----------------------------------------------------------------------
363      !!                  ***  ROUTINE dia_ar5_init  ***
364      !!                   
365      !! ** Purpose :   initialization for AR5 diagnostic computation
366      !!----------------------------------------------------------------------
367      INTEGER  ::   inum
368      INTEGER  ::   ik, idep
369      INTEGER  ::   ji, jj, jk  ! dummy loop indices
370      REAL(wp) ::   zztmp 
371      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   zsaldta   ! Jan/Dec levitus salinity
372      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     ::   zvol0     
373      !
374      !!----------------------------------------------------------------------
375      !
376      l_ar5 = .FALSE.
377      IF(   iom_use( 'voltot'  ) .OR. iom_use( 'sshtot'    )  .OR. iom_use( 'sshdyn' )  .OR.  & 
378         &  iom_use( 'masstot' ) .OR. iom_use( 'temptot'   )  .OR. iom_use( 'saltot' ) .OR.  &   
379         &  iom_use( 'botpres' ) .OR. iom_use( 'sshthster' )  .OR. iom_use( 'sshsteric' )  ) L_ar5 = .TRUE.
380 
381      IF( l_ar5 ) THEN
382         !
383         !                                      ! allocate dia_ar5 arrays
384         IF( dia_ar5_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'dia_ar5_init : unable to allocate arrays' )
385
386         area_tot  = glob_sum( 'diaar5', e1e2t(:,:) )
387
388         ALLOCATE( zvol0(jpi,jpj) )
389         zvol0 (:,:) = 0._wp
390         thick0(:,:) = 0._wp
391         DO_3D_11_11( 1, jpkm1 )
392            idep = tmask(ji,jj,jk) * e3t_0(ji,jj,jk)
393            zvol0 (ji,jj) = zvol0 (ji,jj) +  idep * e1e2t(ji,jj)
394            thick0(ji,jj) = thick0(ji,jj) +  idep   
395         END_3D
396         vol0 = glob_sum( 'diaar5', zvol0 )
397         DEALLOCATE( zvol0 )
398
399         IF( iom_use( 'sshthster' ) ) THEN
400            ALLOCATE( zsaldta(jpi,jpj,jpk,jpts) )
401            CALL iom_open ( 'sali_ref_clim_monthly', inum )
402            CALL iom_get  ( inum, jpdom_data, 'vosaline' , zsaldta(:,:,:,1), 1  )
403            CALL iom_get  ( inum, jpdom_data, 'vosaline' , zsaldta(:,:,:,2), 12 )
404            CALL iom_close( inum )
405
406            sn0(:,:,:) = 0.5_wp * ( zsaldta(:,:,:,1) + zsaldta(:,:,:,2) )       
407            sn0(:,:,:) = sn0(:,:,:) * tmask(:,:,:)
408            IF( ln_zps ) THEN               ! z-coord. partial steps
409               DO_2D_11_11
410                  ik = mbkt(ji,jj)
411                  IF( ik > 1 ) THEN
412                     zztmp = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
413                     sn0(ji,jj,ik) = ( 1._wp - zztmp ) * sn0(ji,jj,ik) + zztmp * sn0(ji,jj,ik-1)
414                  ENDIF
415               END_2D
416            ENDIF
417            !
418            DEALLOCATE( zsaldta )
419         ENDIF
420         !
421      ENDIF
422      !
423   END SUBROUTINE dia_ar5_init
424
425   !!======================================================================
426END MODULE diaar5
Note: See TracBrowser for help on using the repository browser.