| 1 | MODULE traldf_triad |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traldf_triad *** |
|---|
| 4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) Griffies operator (original code) |
|---|
| 7 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) triad operator (Griffies) + Method of Stabilizing Correction |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and active tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | USE phycst ! physical constants |
|---|
| 16 | USE trc_oce ! share passive tracers/Ocean variables |
|---|
| 17 | USE zdf_oce ! ocean vertical physics |
|---|
| 18 | USE ldftra ! lateral physics: eddy diffusivity |
|---|
| 19 | USE ldfslp ! lateral physics: iso-neutral slopes |
|---|
| 20 | USE traldf_iso ! lateral diffusion (Madec operator) (tra_ldf_iso routine) |
|---|
| 21 | USE diaptr ! poleward transport diagnostics |
|---|
| 22 | USE diaar5 ! AR5 diagnostics |
|---|
| 23 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 24 | ! |
|---|
| 25 | USE in_out_manager ! I/O manager |
|---|
| 26 | USE iom ! I/O library |
|---|
| 27 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 28 | USE lib_mpp ! MPP library |
|---|
| 29 | |
|---|
| 30 | IMPLICIT NONE |
|---|
| 31 | PRIVATE |
|---|
| 32 | |
|---|
| 33 | PUBLIC tra_ldf_triad ! routine called by traldf.F90 |
|---|
| 34 | |
|---|
| 35 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: zdkt3d !: vertical tracer gradient at 2 levels |
|---|
| 36 | |
|---|
| 37 | LOGICAL :: l_ptr ! flag to compute poleward transport |
|---|
| 38 | LOGICAL :: l_hst ! flag to compute heat transport |
|---|
| 39 | |
|---|
| 40 | |
|---|
| 41 | !! * Substitutions |
|---|
| 42 | # include "do_loop_substitute.h90" |
|---|
| 43 | # include "domzgr_substitute.h90" |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 46 | !! $Id$ |
|---|
| 47 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | CONTAINS |
|---|
| 50 | |
|---|
| 51 | SUBROUTINE tra_ldf_triad( kt, Kmm, kit000, cdtype, pahu, pahv, & |
|---|
| 52 | & pgu , pgv , pgui, pgvi , & |
|---|
| 53 | & pt , pt2, pt_rhs, kjpt, kpass ) |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | !! *** ROUTINE tra_ldf_triad *** |
|---|
| 56 | !! |
|---|
| 57 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
|---|
| 58 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
|---|
| 59 | !! add it to the general trend of tracer equation. |
|---|
| 60 | !! |
|---|
| 61 | !! ** Method : The horizontal component of the lateral diffusive trends |
|---|
| 62 | !! is provided by a 2nd order operator rotated along neural or geopo- |
|---|
| 63 | !! tential surfaces to which an eddy induced advection can be added |
|---|
| 64 | !! It is computed using before fields (forward in time) and isopyc- |
|---|
| 65 | !! nal or geopotential slopes computed in routine ldfslp. |
|---|
| 66 | !! |
|---|
| 67 | !! see documentation for the desciption |
|---|
| 68 | !! |
|---|
| 69 | !! ** Action : pt_rhs updated with the before rotated diffusion |
|---|
| 70 | !! ah_wslp2 .... |
|---|
| 71 | !! akz stabilizing vertical diffusivity coefficient (used in trazdf_imp) |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 74 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 75 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 76 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 77 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 78 | INTEGER , INTENT(in) :: Kmm ! ocean time level indices |
|---|
| 79 | REAL(wp), DIMENSION(jpi,jpj,jpk) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 80 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 81 | REAL(wp), DIMENSION(jpi,jpj, kjpt), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 82 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: pt ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 83 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: pt2 ! tracer (only used in kpass=2) |
|---|
| 84 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pt_rhs ! tracer trend |
|---|
| 85 | ! |
|---|
| 86 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 87 | INTEGER :: ip,jp,kp ! dummy loop indices |
|---|
| 88 | INTEGER :: ierr ! local integer |
|---|
| 89 | REAL(wp) :: zmsku, zabe1, zcof1, zcoef3 ! local scalars |
|---|
| 90 | REAL(wp) :: zmskv, zabe2, zcof2, zcoef4 ! - - |
|---|
| 91 | REAL(wp) :: zcoef0, ze3w_2, zsign, z2dt, z1_2dt ! - - |
|---|
| 92 | ! |
|---|
| 93 | REAL(wp) :: zslope_skew, zslope_iso, zslope2, zbu, zbv |
|---|
| 94 | REAL(wp) :: ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt |
|---|
| 95 | REAL(wp) :: zah, zah_slp, zaei_slp |
|---|
| 96 | REAL(wp), DIMENSION(jpi,jpj ) :: z2d ! 2D workspace |
|---|
| 97 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ! 3D - |
|---|
| 98 | !!---------------------------------------------------------------------- |
|---|
| 99 | ! |
|---|
| 100 | IF( .NOT.ALLOCATED(zdkt3d) ) THEN |
|---|
| 101 | ALLOCATE( zdkt3d(jpi,jpj,0:1) , STAT=ierr ) |
|---|
| 102 | CALL mpp_sum ( 'traldf_triad', ierr ) |
|---|
| 103 | IF( ierr > 0 ) CALL ctl_stop('STOP', 'tra_ldf_triad: unable to allocate arrays') |
|---|
| 104 | ENDIF |
|---|
| 105 | ! |
|---|
| 106 | IF( kpass == 1 .AND. kt == kit000 ) THEN |
|---|
| 107 | IF(lwp) WRITE(numout,*) |
|---|
| 108 | IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype |
|---|
| 109 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~' |
|---|
| 110 | ENDIF |
|---|
| 111 | ! |
|---|
| 112 | l_hst = .FALSE. |
|---|
| 113 | l_ptr = .FALSE. |
|---|
| 114 | IF( cdtype == 'TRA' .AND. ( iom_use( 'sophtldf' ) .OR. iom_use( 'sopstldf' ) ) ) l_ptr = .TRUE. |
|---|
| 115 | IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. & |
|---|
| 116 | & iom_use("uadv_salttr") .OR. iom_use("vadv_salttr") ) ) l_hst = .TRUE. |
|---|
| 117 | ! |
|---|
| 118 | ! ! set time step size (Euler/Leapfrog) |
|---|
| 119 | IF( neuler == 0 .AND. kt == kit000 ) THEN ; z2dt = rdt ! at nit000 (Euler) |
|---|
| 120 | ELSE ; z2dt = 2.* rdt ! (Leapfrog) |
|---|
| 121 | ENDIF |
|---|
| 122 | z1_2dt = 1._wp / z2dt |
|---|
| 123 | ! |
|---|
| 124 | IF( kpass == 1 ) THEN ; zsign = 1._wp ! bilaplacian operator require a minus sign (eddy diffusivity >0) |
|---|
| 125 | ELSE ; zsign = -1._wp |
|---|
| 126 | ENDIF |
|---|
| 127 | ! |
|---|
| 128 | !!---------------------------------------------------------------------- |
|---|
| 129 | !! 0 - calculate ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw |
|---|
| 130 | !!---------------------------------------------------------------------- |
|---|
| 131 | ! |
|---|
| 132 | IF( kpass == 1 ) THEN !== first pass only and whatever the tracer is ==! |
|---|
| 133 | ! |
|---|
| 134 | akz (:,:,:) = 0._wp |
|---|
| 135 | ah_wslp2(:,:,:) = 0._wp |
|---|
| 136 | IF( ln_ldfeiv_dia ) THEN |
|---|
| 137 | zpsi_uw(:,:,:) = 0._wp |
|---|
| 138 | zpsi_vw(:,:,:) = 0._wp |
|---|
| 139 | ENDIF |
|---|
| 140 | ! |
|---|
| 141 | DO ip = 0, 1 ! i-k triads |
|---|
| 142 | DO kp = 0, 1 |
|---|
| 143 | DO_3D_10_10( 1, jpkm1 ) |
|---|
| 144 | ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm) |
|---|
| 145 | zbu = e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 146 | zah = 0.25_wp * pahu(ji,jj,jk) |
|---|
| 147 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 148 | ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth) |
|---|
| 149 | zslope2 = zslope_skew + ( gdept(ji+1,jj,jk,Kmm) - gdept(ji,jj,jk,Kmm) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 150 | zslope2 = zslope2 *zslope2 |
|---|
| 151 | ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji+ip,jj) * zslope2 |
|---|
| 152 | akz (ji+ip,jj,jk+kp) = akz (ji+ip,jj,jk+kp) + zah * r1_e1u(ji,jj) & |
|---|
| 153 | & * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 154 | ! |
|---|
| 155 | IF( ln_ldfeiv_dia ) zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp) & |
|---|
| 156 | & + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * zslope_skew |
|---|
| 157 | END_3D |
|---|
| 158 | END DO |
|---|
| 159 | END DO |
|---|
| 160 | ! |
|---|
| 161 | DO jp = 0, 1 ! j-k triads |
|---|
| 162 | DO kp = 0, 1 |
|---|
| 163 | DO_3D_10_10( 1, jpkm1 ) |
|---|
| 164 | ze3wr = 1.0_wp / e3w(ji,jj+jp,jk+kp,Kmm) |
|---|
| 165 | zbv = e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 166 | zah = 0.25_wp * pahv(ji,jj,jk) |
|---|
| 167 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 168 | ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces |
|---|
| 169 | ! (do this by *adding* gradient of depth) |
|---|
| 170 | zslope2 = zslope_skew + ( gdept(ji,jj+1,jk,Kmm) - gdept(ji,jj,jk,Kmm) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 171 | zslope2 = zslope2 * zslope2 |
|---|
| 172 | ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj+jp) * zslope2 |
|---|
| 173 | akz (ji,jj+jp,jk+kp) = akz (ji,jj+jp,jk+kp) + zah * r1_e2v(ji,jj) & |
|---|
| 174 | & * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 175 | ! |
|---|
| 176 | IF( ln_ldfeiv_dia ) zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp) & |
|---|
| 177 | & + 0.25 * aeiv(ji,jj,jk) * e1v(ji,jj) * zslope_skew |
|---|
| 178 | END_3D |
|---|
| 179 | END DO |
|---|
| 180 | END DO |
|---|
| 181 | ! |
|---|
| 182 | IF( ln_traldf_msc ) THEN ! stabilizing vertical diffusivity coefficient |
|---|
| 183 | ! |
|---|
| 184 | IF( ln_traldf_blp ) THEN ! bilaplacian operator |
|---|
| 185 | DO_3D_10_10( 2, jpkm1 ) |
|---|
| 186 | akz(ji,jj,jk) = & |
|---|
| 187 | & 16._wp * ah_wslp2(ji,jj,jk) & |
|---|
| 188 | & * ( akz(ji,jj,jk) & |
|---|
| 189 | & + ah_wslp2(ji,jj,jk) / ( e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) ) ) |
|---|
| 190 | END_3D |
|---|
| 191 | ELSEIF( ln_traldf_lap ) THEN ! laplacian operator |
|---|
| 192 | DO_3D_10_10( 2, jpkm1 ) |
|---|
| 193 | ze3w_2 = e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) |
|---|
| 194 | zcoef0 = z2dt * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2 ) |
|---|
| 195 | akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt |
|---|
| 196 | END_3D |
|---|
| 197 | ENDIF |
|---|
| 198 | ! |
|---|
| 199 | ELSE ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit |
|---|
| 200 | akz(:,:,:) = ah_wslp2(:,:,:) |
|---|
| 201 | ENDIF |
|---|
| 202 | ! |
|---|
| 203 | IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) CALL ldf_eiv_dia( zpsi_uw, zpsi_vw, Kmm ) |
|---|
| 204 | ! |
|---|
| 205 | ENDIF !== end 1st pass only ==! |
|---|
| 206 | ! |
|---|
| 207 | ! ! =========== |
|---|
| 208 | DO jn = 1, kjpt ! tracer loop |
|---|
| 209 | ! ! =========== |
|---|
| 210 | ! Zero fluxes for each tracer |
|---|
| 211 | !!gm this should probably be done outside the jn loop |
|---|
| 212 | ztfw(:,:,:) = 0._wp |
|---|
| 213 | zftu(:,:,:) = 0._wp |
|---|
| 214 | zftv(:,:,:) = 0._wp |
|---|
| 215 | ! |
|---|
| 216 | DO_3D_10_10( 1, jpkm1 ) |
|---|
| 217 | zdit(ji,jj,jk) = ( pt(ji+1,jj ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
|---|
| 218 | zdjt(ji,jj,jk) = ( pt(ji ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
|---|
| 219 | END_3D |
|---|
| 220 | IF( ln_zps .AND. l_grad_zps ) THEN ! partial steps: correction at top/bottom ocean level |
|---|
| 221 | DO_2D_10_10 |
|---|
| 222 | zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn) |
|---|
| 223 | zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn) |
|---|
| 224 | END_2D |
|---|
| 225 | IF( ln_isfcav ) THEN ! top level (ocean cavities only) |
|---|
| 226 | DO_2D_10_10 |
|---|
| 227 | IF( miku(ji,jj) > 1 ) zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) |
|---|
| 228 | IF( mikv(ji,jj) > 1 ) zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) |
|---|
| 229 | END_2D |
|---|
| 230 | ENDIF |
|---|
| 231 | ENDIF |
|---|
| 232 | ! |
|---|
| 233 | !!---------------------------------------------------------------------- |
|---|
| 234 | !! II - horizontal trend (full) |
|---|
| 235 | !!---------------------------------------------------------------------- |
|---|
| 236 | ! |
|---|
| 237 | DO jk = 1, jpkm1 |
|---|
| 238 | ! !== Vertical tracer gradient at level jk and jk+1 |
|---|
| 239 | zdkt3d(:,:,1) = ( pt(:,:,jk,jn) - pt(:,:,jk+1,jn) ) * tmask(:,:,jk+1) |
|---|
| 240 | ! |
|---|
| 241 | ! ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1) |
|---|
| 242 | IF( jk == 1 ) THEN ; zdkt3d(:,:,0) = zdkt3d(:,:,1) |
|---|
| 243 | ELSE ; zdkt3d(:,:,0) = ( pt(:,:,jk-1,jn) - pt(:,:,jk,jn) ) * tmask(:,:,jk) |
|---|
| 244 | ENDIF |
|---|
| 245 | ! |
|---|
| 246 | zaei_slp = 0._wp |
|---|
| 247 | ! |
|---|
| 248 | IF( ln_botmix_triad ) THEN |
|---|
| 249 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 250 | DO kp = 0, 1 |
|---|
| 251 | DO_2D_10_10 |
|---|
| 252 | ze1ur = r1_e1u(ji,jj) |
|---|
| 253 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 254 | ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm) |
|---|
| 255 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 256 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 257 | zslope_iso = triadi (ji+ip,jj,jk,1-ip,kp) |
|---|
| 258 | ! |
|---|
| 259 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 260 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahu is masked.... |
|---|
| 261 | zah = pahu(ji,jj,jk) |
|---|
| 262 | zah_slp = zah * zslope_iso |
|---|
| 263 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew |
|---|
| 264 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 265 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 266 | END_2D |
|---|
| 267 | END DO |
|---|
| 268 | END DO |
|---|
| 269 | ! |
|---|
| 270 | DO jp = 0, 1 |
|---|
| 271 | DO kp = 0, 1 |
|---|
| 272 | DO_2D_10_10 |
|---|
| 273 | ze2vr = r1_e2v(ji,jj) |
|---|
| 274 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 275 | ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,Kmm) |
|---|
| 276 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 277 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 278 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 279 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 280 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahv is masked... |
|---|
| 281 | zah = pahv(ji,jj,jk) |
|---|
| 282 | zah_slp = zah * zslope_iso |
|---|
| 283 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew |
|---|
| 284 | zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 285 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt * zbv * ze3wr |
|---|
| 286 | END_2D |
|---|
| 287 | END DO |
|---|
| 288 | END DO |
|---|
| 289 | ! |
|---|
| 290 | ELSE |
|---|
| 291 | ! |
|---|
| 292 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 293 | DO kp = 0, 1 |
|---|
| 294 | DO_2D_10_10 |
|---|
| 295 | ze1ur = r1_e1u(ji,jj) |
|---|
| 296 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 297 | ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm) |
|---|
| 298 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 299 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 300 | zslope_iso = triadi(ji+ip,jj,jk,1-ip,kp) |
|---|
| 301 | ! |
|---|
| 302 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 303 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 304 | zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp) ! pahu(ji+ip,jj,jk) ===>> ???? |
|---|
| 305 | zah_slp = zah * zslope_iso |
|---|
| 306 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew ! aeit(ji+ip,jj,jk)*zslope_skew |
|---|
| 307 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 308 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 309 | END_2D |
|---|
| 310 | END DO |
|---|
| 311 | END DO |
|---|
| 312 | ! |
|---|
| 313 | DO jp = 0, 1 |
|---|
| 314 | DO kp = 0, 1 |
|---|
| 315 | DO_2D_10_10 |
|---|
| 316 | ze2vr = r1_e2v(ji,jj) |
|---|
| 317 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 318 | ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,Kmm) |
|---|
| 319 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 320 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 321 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 322 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 323 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 324 | zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp) ! pahv(ji,jj+jp,jk) ???? |
|---|
| 325 | zah_slp = zah * zslope_iso |
|---|
| 326 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew ! aeit(ji,jj+jp,jk)*zslope_skew |
|---|
| 327 | zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 328 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr |
|---|
| 329 | END_2D |
|---|
| 330 | END DO |
|---|
| 331 | END DO |
|---|
| 332 | ENDIF |
|---|
| 333 | ! !== horizontal divergence and add to the general trend ==! |
|---|
| 334 | DO_2D_00_00 |
|---|
| 335 | pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) & |
|---|
| 336 | & + zsign * ( zftu(ji-1,jj ,jk) - zftu(ji,jj,jk) & |
|---|
| 337 | & + zftv(ji ,jj-1,jk) - zftv(ji,jj,jk) ) & |
|---|
| 338 | & / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) ) |
|---|
| 339 | END_2D |
|---|
| 340 | ! |
|---|
| 341 | END DO |
|---|
| 342 | ! |
|---|
| 343 | ! !== add the vertical 33 flux ==! |
|---|
| 344 | IF( ln_traldf_lap ) THEN ! laplacian case: eddy coef = ah_wslp2 - akz |
|---|
| 345 | DO_3D_10_00( 2, jpkm1 ) |
|---|
| 346 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 347 | & * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) ) & |
|---|
| 348 | & * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) |
|---|
| 349 | END_3D |
|---|
| 350 | ELSE ! bilaplacian |
|---|
| 351 | SELECT CASE( kpass ) |
|---|
| 352 | CASE( 1 ) ! 1st pass : eddy coef = ah_wslp2 |
|---|
| 353 | DO_3D_10_00( 2, jpkm1 ) |
|---|
| 354 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 355 | & * ah_wslp2(ji,jj,jk) * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) |
|---|
| 356 | END_3D |
|---|
| 357 | CASE( 2 ) ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt and pt2 gradients, resp. |
|---|
| 358 | DO_3D_10_00( 2, jpkm1 ) |
|---|
| 359 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 360 | & * ( ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) ) & |
|---|
| 361 | & + akz (ji,jj,jk) * ( pt2(ji,jj,jk-1,jn) - pt2(ji,jj,jk,jn) ) ) |
|---|
| 362 | END_3D |
|---|
| 363 | END SELECT |
|---|
| 364 | ENDIF |
|---|
| 365 | ! |
|---|
| 366 | DO_3D_00_00( 1, jpkm1 ) |
|---|
| 367 | pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) & |
|---|
| 368 | & + zsign * ( ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk) ) & |
|---|
| 369 | & / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) ) |
|---|
| 370 | END_3D |
|---|
| 371 | ! |
|---|
| 372 | IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR. & !== first pass only ( laplacian) ==! |
|---|
| 373 | ( kpass == 2 .AND. ln_traldf_blp ) ) THEN !== 2nd pass (bilaplacian) ==! |
|---|
| 374 | ! |
|---|
| 375 | ! ! "Poleward" diffusive heat or salt transports (T-S case only) |
|---|
| 376 | IF( l_ptr ) CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:) ) |
|---|
| 377 | ! ! Diffusive heat transports |
|---|
| 378 | IF( l_hst ) CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) ) |
|---|
| 379 | ! |
|---|
| 380 | ENDIF !== end pass selection ==! |
|---|
| 381 | ! |
|---|
| 382 | ! ! =============== |
|---|
| 383 | END DO ! end tracer loop |
|---|
| 384 | ! ! =============== |
|---|
| 385 | END SUBROUTINE tra_ldf_triad |
|---|
| 386 | |
|---|
| 387 | !!============================================================================== |
|---|
| 388 | END MODULE traldf_triad |
|---|
