| 1 | MODULE zdfiwm |
|---|
| 2 | !!======================================================================== |
|---|
| 3 | !! *** MODULE zdfiwm *** |
|---|
| 4 | !! Ocean physics: Internal gravity wave-driven vertical mixing |
|---|
| 5 | !!======================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
|---|
| 7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
|---|
| 8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 9 | !! 3.6 ! 2016-03 (C. de Lavergne) New param: internal wave-driven mixing |
|---|
| 10 | !! 4.0 ! 2017-04 (G. Madec) renamed module, remove the old param. and the CPP keys |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! zdf_iwm : global momentum & tracer Kz with wave induced Kz |
|---|
| 15 | !! zdf_iwm_init : global momentum & tracer Kz with wave induced Kz |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers variables |
|---|
| 18 | USE dom_oce ! ocean space and time domain variables |
|---|
| 19 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 20 | USE zdfddm ! ocean vertical physics: double diffusive mixing |
|---|
| 21 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 22 | USE eosbn2 ! ocean equation of state |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | ! |
|---|
| 25 | USE prtctl ! Print control |
|---|
| 26 | USE in_out_manager ! I/O manager |
|---|
| 27 | USE iom ! I/O Manager |
|---|
| 28 | USE lib_mpp ! MPP library |
|---|
| 29 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC zdf_iwm ! called in step module |
|---|
| 35 | PUBLIC zdf_iwm_init ! called in nemogcm module |
|---|
| 36 | |
|---|
| 37 | ! !!* Namelist namzdf_iwm : internal wave-driven mixing * |
|---|
| 38 | INTEGER :: nn_zpyc ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2) |
|---|
| 39 | LOGICAL :: ln_mevar ! variable (=T) or constant (=F) mixing efficiency |
|---|
| 40 | LOGICAL :: ln_tsdiff ! account for differential T/S wave-driven mixing (=T) or not (=F) |
|---|
| 41 | |
|---|
| 42 | REAL(wp):: r1_6 = 1._wp / 6._wp |
|---|
| 43 | |
|---|
| 44 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ebot_iwm ! power available from high-mode wave breaking (W/m2) |
|---|
| 45 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: epyc_iwm ! power available from low-mode, pycnocline-intensified wave breaking (W/m2) |
|---|
| 46 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ecri_iwm ! power available from low-mode, critical slope wave breaking (W/m2) |
|---|
| 47 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hbot_iwm ! WKB decay scale for high-mode energy dissipation (m) |
|---|
| 48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hcri_iwm ! decay scale for low-mode critical slope dissipation (m) |
|---|
| 49 | |
|---|
| 50 | !! * Substitutions |
|---|
| 51 | # include "do_loop_substitute.h90" |
|---|
| 52 | # include "domzgr_substitute.h90" |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 55 | !! $Id$ |
|---|
| 56 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 57 | !!---------------------------------------------------------------------- |
|---|
| 58 | CONTAINS |
|---|
| 59 | |
|---|
| 60 | INTEGER FUNCTION zdf_iwm_alloc() |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! *** FUNCTION zdf_iwm_alloc *** |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | ALLOCATE( ebot_iwm(jpi,jpj), epyc_iwm(jpi,jpj), ecri_iwm(jpi,jpj) , & |
|---|
| 65 | & hbot_iwm(jpi,jpj), hcri_iwm(jpi,jpj) , STAT=zdf_iwm_alloc ) |
|---|
| 66 | ! |
|---|
| 67 | CALL mpp_sum ( 'zdfiwm', zdf_iwm_alloc ) |
|---|
| 68 | IF( zdf_iwm_alloc /= 0 ) CALL ctl_stop( 'STOP', 'zdf_iwm_alloc: failed to allocate arrays' ) |
|---|
| 69 | END FUNCTION zdf_iwm_alloc |
|---|
| 70 | |
|---|
| 71 | |
|---|
| 72 | SUBROUTINE zdf_iwm( kt, Kmm, p_avm, p_avt, p_avs ) |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | !! *** ROUTINE zdf_iwm *** |
|---|
| 75 | !! |
|---|
| 76 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 77 | !! breaking internal waves. |
|---|
| 78 | !! |
|---|
| 79 | !! ** Method : - internal wave-driven vertical mixing is given by: |
|---|
| 80 | !! Kz_wave = min( 100 cm2/s, f( Reb = zemx_iwm /( Nu * N^2 ) ) |
|---|
| 81 | !! where zemx_iwm is the 3D space distribution of the wave-breaking |
|---|
| 82 | !! energy and Nu the molecular kinematic viscosity. |
|---|
| 83 | !! The function f(Reb) is linear (constant mixing efficiency) |
|---|
| 84 | !! if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T. |
|---|
| 85 | !! |
|---|
| 86 | !! - Compute zemx_iwm, the 3D power density that allows to compute |
|---|
| 87 | !! Reb and therefrom the wave-induced vertical diffusivity. |
|---|
| 88 | !! This is divided into three components: |
|---|
| 89 | !! 1. Bottom-intensified low-mode dissipation at critical slopes |
|---|
| 90 | !! zemx_iwm(z) = ( ecri_iwm / rau0 ) * EXP( -(H-z)/hcri_iwm ) |
|---|
| 91 | !! / ( 1. - EXP( - H/hcri_iwm ) ) * hcri_iwm |
|---|
| 92 | !! where hcri_iwm is the characteristic length scale of the bottom |
|---|
| 93 | !! intensification, ecri_iwm a map of available power, and H the ocean depth. |
|---|
| 94 | !! 2. Pycnocline-intensified low-mode dissipation |
|---|
| 95 | !! zemx_iwm(z) = ( epyc_iwm / rau0 ) * ( sqrt(rn2(z))^nn_zpyc ) |
|---|
| 96 | !! / SUM( sqrt(rn2(z))^nn_zpyc * e3w[z) ) |
|---|
| 97 | !! where epyc_iwm is a map of available power, and nn_zpyc |
|---|
| 98 | !! is the chosen stratification-dependence of the internal wave |
|---|
| 99 | !! energy dissipation. |
|---|
| 100 | !! 3. WKB-height dependent high mode dissipation |
|---|
| 101 | !! zemx_iwm(z) = ( ebot_iwm / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_iwm) |
|---|
| 102 | !! / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_iwm) * e3w[z) ) |
|---|
| 103 | !! where hbot_iwm is the characteristic length scale of the WKB bottom |
|---|
| 104 | !! intensification, ebot_iwm is a map of available power, and z_wkb is the |
|---|
| 105 | !! WKB-stretched height above bottom defined as |
|---|
| 106 | !! z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w[z'>=z) ) |
|---|
| 107 | !! / SUM( sqrt(rn2(z')) * e3w[z') ) |
|---|
| 108 | !! |
|---|
| 109 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 110 | !! avt = avt + av_wave |
|---|
| 111 | !! avm = avm + av_wave |
|---|
| 112 | !! |
|---|
| 113 | !! - if namelist parameter ln_tsdiff = T, account for differential mixing: |
|---|
| 114 | !! avs = avt + av_wave * diffusivity_ratio(Reb) |
|---|
| 115 | !! |
|---|
| 116 | !! ** Action : - avt, avs, avm, increased by tide internal wave-driven mixing |
|---|
| 117 | !! |
|---|
| 118 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
|---|
| 119 | !!---------------------------------------------------------------------- |
|---|
| 120 | INTEGER , INTENT(in ) :: kt ! ocean time step |
|---|
| 121 | INTEGER , INTENT(in ) :: Kmm ! time level index |
|---|
| 122 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: p_avm ! momentum Kz (w-points) |
|---|
| 123 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: p_avt, p_avs ! tracer Kz (w-points) |
|---|
| 124 | ! |
|---|
| 125 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 126 | REAL(wp) :: zztmp, ztmp1, ztmp2 ! scalar workspace |
|---|
| 127 | REAL(wp), DIMENSION(jpi,jpj) :: zfact ! Used for vertical structure |
|---|
| 128 | REAL(wp), DIMENSION(jpi,jpj) :: zhdep ! Ocean depth |
|---|
| 129 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwkb ! WKB-stretched height above bottom |
|---|
| 130 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zweight ! Weight for high mode vertical distribution |
|---|
| 131 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: znu_t ! Molecular kinematic viscosity (T grid) |
|---|
| 132 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: znu_w ! Molecular kinematic viscosity (W grid) |
|---|
| 133 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zReb ! Turbulence intensity parameter |
|---|
| 134 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zemx_iwm ! local energy density available for mixing (W/kg) |
|---|
| 135 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zav_ratio ! S/T diffusivity ratio (only for ln_tsdiff=T) |
|---|
| 136 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zav_wave ! Internal wave-induced diffusivity |
|---|
| 137 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: z3d ! 3D workspace used for iom_put |
|---|
| 138 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z2d ! 2D - - - - |
|---|
| 139 | !!---------------------------------------------------------------------- |
|---|
| 140 | ! |
|---|
| 141 | ! !* Set to zero the 1st and last vertical levels of appropriate variables |
|---|
| 142 | zemx_iwm (:,:,1) = 0._wp ; zemx_iwm (:,:,jpk) = 0._wp |
|---|
| 143 | zav_ratio(:,:,1) = 0._wp ; zav_ratio(:,:,jpk) = 0._wp |
|---|
| 144 | zav_wave (:,:,1) = 0._wp ; zav_wave (:,:,jpk) = 0._wp |
|---|
| 145 | ! |
|---|
| 146 | ! ! ----------------------------- ! |
|---|
| 147 | ! ! Internal wave-driven mixing ! (compute zav_wave) |
|---|
| 148 | ! ! ----------------------------- ! |
|---|
| 149 | ! |
|---|
| 150 | ! !* Critical slope mixing: distribute energy over the time-varying ocean depth, |
|---|
| 151 | ! using an exponential decay from the seafloor. |
|---|
| 152 | DO_2D_11_11 |
|---|
| 153 | zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 154 | zfact(ji,jj) = rau0 * ( 1._wp - EXP( -zhdep(ji,jj) / hcri_iwm(ji,jj) ) ) |
|---|
| 155 | IF( zfact(ji,jj) /= 0._wp ) zfact(ji,jj) = ecri_iwm(ji,jj) / zfact(ji,jj) |
|---|
| 156 | END_2D |
|---|
| 157 | !!gm gde3w ==>>> check for ssh taken into account.... seem OK gde3w_n=gdept(:,:,:,Kmm) - ssh(:,:,Kmm) |
|---|
| 158 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 159 | IF ( zfact(ji,jj) == 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN ! optimization |
|---|
| 160 | zemx_iwm(ji,jj,jk) = 0._wp |
|---|
| 161 | ELSE |
|---|
| 162 | zemx_iwm(ji,jj,jk) = zfact(ji,jj) * ( EXP( ( gde3w(ji,jj,jk ) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) ) & |
|---|
| 163 | & - EXP( ( gde3w(ji,jj,jk-1) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) ) ) & |
|---|
| 164 | & / ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) ) |
|---|
| 165 | ENDIF |
|---|
| 166 | END_3D |
|---|
| 167 | !!gm delta(gde3w) = e3t(:,:,:,Kmm) !! Please verify the grid-point position w versus t-point |
|---|
| 168 | !!gm it seems to me that only 1/hcri_iwm is used ==> compute it one for all |
|---|
| 169 | |
|---|
| 170 | |
|---|
| 171 | ! !* Pycnocline-intensified mixing: distribute energy over the time-varying |
|---|
| 172 | ! !* ocean depth as proportional to sqrt(rn2)^nn_zpyc |
|---|
| 173 | ! ! (NB: N2 is masked, so no use of wmask here) |
|---|
| 174 | SELECT CASE ( nn_zpyc ) |
|---|
| 175 | ! |
|---|
| 176 | CASE ( 1 ) ! Dissipation scales as N (recommended) |
|---|
| 177 | ! |
|---|
| 178 | zfact(:,:) = 0._wp |
|---|
| 179 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 180 | zfact(:,:) = & |
|---|
| 181 | & zfact(:,:) + & |
|---|
| 182 | & e3w(:,:,jk,Kmm) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 183 | END DO |
|---|
| 184 | ! |
|---|
| 185 | DO_2D_11_11 |
|---|
| 186 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_iwm(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 187 | END_2D |
|---|
| 188 | ! |
|---|
| 189 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 190 | zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zfact(:,:) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 191 | END DO |
|---|
| 192 | ! |
|---|
| 193 | CASE ( 2 ) ! Dissipation scales as N^2 |
|---|
| 194 | ! |
|---|
| 195 | zfact(:,:) = 0._wp |
|---|
| 196 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 197 | zfact(:,:) = zfact(:,:) + e3w(:,:,jk,Kmm) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 198 | END DO |
|---|
| 199 | ! |
|---|
| 200 | DO_2D_11_11 |
|---|
| 201 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_iwm(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 202 | END_2D |
|---|
| 203 | ! |
|---|
| 204 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 205 | zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 206 | END DO |
|---|
| 207 | ! |
|---|
| 208 | END SELECT |
|---|
| 209 | |
|---|
| 210 | ! !* WKB-height dependent mixing: distribute energy over the time-varying |
|---|
| 211 | ! !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot) |
|---|
| 212 | ! |
|---|
| 213 | zwkb (:,:,:) = 0._wp |
|---|
| 214 | zfact(:,:) = 0._wp |
|---|
| 215 | DO jk = 2, jpkm1 |
|---|
| 216 | zfact(:,:) = zfact(:,:) + e3w(:,:,jk,Kmm) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 217 | zwkb(:,:,jk) = zfact(:,:) |
|---|
| 218 | END DO |
|---|
| 219 | !!gm even better: |
|---|
| 220 | ! DO jk = 2, jpkm1 |
|---|
| 221 | ! zwkb(:,:) = zwkb(:,:) + e3w(:,:,jk,Kmm) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) |
|---|
| 222 | ! END DO |
|---|
| 223 | ! zfact(:,:) = zwkb(:,:,jpkm1) |
|---|
| 224 | !!gm or just use zwkb(k=jpk-1) instead of zfact... |
|---|
| 225 | !!gm |
|---|
| 226 | ! |
|---|
| 227 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 228 | IF( zfact(ji,jj) /= 0 ) zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) ) & |
|---|
| 229 | & * wmask(ji,jj,jk) / zfact(ji,jj) |
|---|
| 230 | END_3D |
|---|
| 231 | zwkb(:,:,1) = zhdep(:,:) * wmask(:,:,1) |
|---|
| 232 | ! |
|---|
| 233 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 234 | IF ( rn2(ji,jj,jk) <= 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN ! optimization |
|---|
| 235 | zweight(ji,jj,jk) = 0._wp |
|---|
| 236 | ELSE |
|---|
| 237 | zweight(ji,jj,jk) = rn2(ji,jj,jk) * hbot_iwm(ji,jj) & |
|---|
| 238 | & * ( EXP( -zwkb(ji,jj,jk) / hbot_iwm(ji,jj) ) - EXP( -zwkb(ji,jj,jk-1) / hbot_iwm(ji,jj) ) ) |
|---|
| 239 | ENDIF |
|---|
| 240 | END_3D |
|---|
| 241 | ! |
|---|
| 242 | zfact(:,:) = 0._wp |
|---|
| 243 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 244 | zfact(:,:) = zfact(:,:) + zweight(:,:,jk) |
|---|
| 245 | END DO |
|---|
| 246 | ! |
|---|
| 247 | DO_2D_11_11 |
|---|
| 248 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ebot_iwm(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 249 | END_2D |
|---|
| 250 | ! |
|---|
| 251 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 252 | zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk) & |
|---|
| 253 | & / ( gde3w(:,:,jk) - gde3w(:,:,jk-1) ) |
|---|
| 254 | !!gm use of e3t(:,:,:,Kmm) just above? |
|---|
| 255 | END DO |
|---|
| 256 | ! |
|---|
| 257 | !!gm this is to be replaced by just a constant value znu=1.e-6 m2/s |
|---|
| 258 | ! Calculate molecular kinematic viscosity |
|---|
| 259 | znu_t(:,:,:) = 1.e-4_wp * ( 17.91_wp - 0.53810_wp * ts(:,:,:,jp_tem,Kmm) + 0.00694_wp * ts(:,:,:,jp_tem,Kmm) * ts(:,:,:,jp_tem,Kmm) & |
|---|
| 260 | & + 0.02305_wp * ts(:,:,:,jp_sal,Kmm) ) * tmask(:,:,:) * r1_rau0 |
|---|
| 261 | DO jk = 2, jpkm1 |
|---|
| 262 | znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 263 | END DO |
|---|
| 264 | !!gm end |
|---|
| 265 | ! |
|---|
| 266 | ! Calculate turbulence intensity parameter Reb |
|---|
| 267 | DO jk = 2, jpkm1 |
|---|
| 268 | zReb(:,:,jk) = zemx_iwm(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) ) |
|---|
| 269 | END DO |
|---|
| 270 | ! |
|---|
| 271 | ! Define internal wave-induced diffusivity |
|---|
| 272 | DO jk = 2, jpkm1 |
|---|
| 273 | zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6 ! This corresponds to a constant mixing efficiency of 1/6 |
|---|
| 274 | END DO |
|---|
| 275 | ! |
|---|
| 276 | IF( ln_mevar ) THEN ! Variable mixing efficiency case : modify zav_wave in the |
|---|
| 277 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 278 | IF( zReb(ji,jj,jk) > 480.00_wp ) THEN |
|---|
| 279 | zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 280 | ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN |
|---|
| 281 | zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 282 | ENDIF |
|---|
| 283 | END_3D |
|---|
| 284 | ENDIF |
|---|
| 285 | ! |
|---|
| 286 | DO jk = 2, jpkm1 ! Bound diffusivity by molecular value and 100 cm2/s |
|---|
| 287 | zav_wave(:,:,jk) = MIN( MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp ) * wmask(:,:,jk) |
|---|
| 288 | END DO |
|---|
| 289 | ! |
|---|
| 290 | IF( kt == nit000 ) THEN !* Control print at first time-step: diagnose the energy consumed by zav_wave |
|---|
| 291 | zztmp = 0._wp |
|---|
| 292 | !!gm used of glosum 3D.... |
|---|
| 293 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 294 | zztmp = zztmp + e3w(ji,jj,jk,Kmm) * e1e2t(ji,jj) & |
|---|
| 295 | & * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 296 | END_3D |
|---|
| 297 | CALL mpp_sum( 'zdfiwm', zztmp ) |
|---|
| 298 | zztmp = rau0 * zztmp ! Global integral of rauo * Kz * N^2 = power contributing to mixing |
|---|
| 299 | ! |
|---|
| 300 | IF(lwp) THEN |
|---|
| 301 | WRITE(numout,*) |
|---|
| 302 | WRITE(numout,*) 'zdf_iwm : Internal wave-driven mixing (iwm)' |
|---|
| 303 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 304 | WRITE(numout,*) |
|---|
| 305 | WRITE(numout,*) ' Total power consumption by av_wave = ', zztmp * 1.e-12_wp, 'TW' |
|---|
| 306 | ENDIF |
|---|
| 307 | ENDIF |
|---|
| 308 | |
|---|
| 309 | ! ! ----------------------- ! |
|---|
| 310 | ! ! Update mixing coefs ! |
|---|
| 311 | ! ! ----------------------- ! |
|---|
| 312 | ! |
|---|
| 313 | IF( ln_tsdiff ) THEN !* Option for differential mixing of salinity and temperature |
|---|
| 314 | ztmp1 = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10( 1.e-20_wp ) - 0.60_wp ) ) |
|---|
| 315 | DO_3D_11_11( 2, jpkm1 ) |
|---|
| 316 | ztmp2 = zReb(ji,jj,jk) * 5._wp * r1_6 |
|---|
| 317 | IF ( ztmp2 > 1.e-20_wp .AND. wmask(ji,jj,jk) == 1._wp ) THEN |
|---|
| 318 | zav_ratio(ji,jj,jk) = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10(ztmp2) - 0.60_wp ) ) |
|---|
| 319 | ELSE |
|---|
| 320 | zav_ratio(ji,jj,jk) = ztmp1 * wmask(ji,jj,jk) |
|---|
| 321 | ENDIF |
|---|
| 322 | END_3D |
|---|
| 323 | CALL iom_put( "av_ratio", zav_ratio ) |
|---|
| 324 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 325 | p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk) |
|---|
| 326 | p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 327 | p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 328 | END DO |
|---|
| 329 | ! |
|---|
| 330 | ELSE !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 331 | DO jk = 2, jpkm1 |
|---|
| 332 | p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 333 | p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 334 | p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 335 | END DO |
|---|
| 336 | ENDIF |
|---|
| 337 | |
|---|
| 338 | ! !* output internal wave-driven mixing coefficient |
|---|
| 339 | CALL iom_put( "av_wave", zav_wave ) |
|---|
| 340 | !* output useful diagnostics: Kz*N^2 , |
|---|
| 341 | !!gm Kz*N2 should take into account the ratio avs/avt if it is used.... (see diaar5) |
|---|
| 342 | ! vertical integral of rau0 * Kz * N^2 , energy density (zemx_iwm) |
|---|
| 343 | IF( iom_use("bflx_iwm") .OR. iom_use("pcmap_iwm") ) THEN |
|---|
| 344 | ALLOCATE( z2d(jpi,jpj) , z3d(jpi,jpj,jpk) ) |
|---|
| 345 | z3d(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:) |
|---|
| 346 | z2d(:,:) = 0._wp |
|---|
| 347 | DO jk = 2, jpkm1 |
|---|
| 348 | z2d(:,:) = z2d(:,:) + e3w(:,:,jk,Kmm) * z3d(:,:,jk) * wmask(:,:,jk) |
|---|
| 349 | END DO |
|---|
| 350 | z2d(:,:) = rau0 * z2d(:,:) |
|---|
| 351 | CALL iom_put( "bflx_iwm", z3d ) |
|---|
| 352 | CALL iom_put( "pcmap_iwm", z2d ) |
|---|
| 353 | DEALLOCATE( z2d , z3d ) |
|---|
| 354 | ENDIF |
|---|
| 355 | CALL iom_put( "emix_iwm", zemx_iwm ) |
|---|
| 356 | |
|---|
| 357 | IF(sn_cfctl%l_prtctl) CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' iwm - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', kdim=jpk) |
|---|
| 358 | ! |
|---|
| 359 | END SUBROUTINE zdf_iwm |
|---|
| 360 | |
|---|
| 361 | |
|---|
| 362 | SUBROUTINE zdf_iwm_init |
|---|
| 363 | !!---------------------------------------------------------------------- |
|---|
| 364 | !! *** ROUTINE zdf_iwm_init *** |
|---|
| 365 | !! |
|---|
| 366 | !! ** Purpose : Initialization of the wave-driven vertical mixing, reading |
|---|
| 367 | !! of input power maps and decay length scales in netcdf files. |
|---|
| 368 | !! |
|---|
| 369 | !! ** Method : - Read the namzdf_iwm namelist and check the parameters |
|---|
| 370 | !! |
|---|
| 371 | !! - Read the input data in NetCDF files : |
|---|
| 372 | !! power available from high-mode wave breaking (mixing_power_bot.nc) |
|---|
| 373 | !! power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc) |
|---|
| 374 | !! power available from critical slope wave-breaking (mixing_power_cri.nc) |
|---|
| 375 | !! WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc) |
|---|
| 376 | !! decay scale for critical slope wave-breaking (decay_scale_cri.nc) |
|---|
| 377 | !! |
|---|
| 378 | !! ** input : - Namlist namzdf_iwm |
|---|
| 379 | !! - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc, |
|---|
| 380 | !! decay_scale_bot.nc decay_scale_cri.nc |
|---|
| 381 | !! |
|---|
| 382 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 383 | !! - Define ebot_iwm, epyc_iwm, ecri_iwm, hbot_iwm, hcri_iwm |
|---|
| 384 | !! |
|---|
| 385 | !! References : de Lavergne et al. JPO, 2015 ; de Lavergne PhD 2016 |
|---|
| 386 | !! de Lavergne et al. in prep., 2017 |
|---|
| 387 | !!---------------------------------------------------------------------- |
|---|
| 388 | INTEGER :: inum ! local integer |
|---|
| 389 | INTEGER :: ios |
|---|
| 390 | REAL(wp) :: zbot, zpyc, zcri ! local scalars |
|---|
| 391 | !! |
|---|
| 392 | NAMELIST/namzdf_iwm/ nn_zpyc, ln_mevar, ln_tsdiff |
|---|
| 393 | !!---------------------------------------------------------------------- |
|---|
| 394 | ! |
|---|
| 395 | READ ( numnam_ref, namzdf_iwm, IOSTAT = ios, ERR = 901) |
|---|
| 396 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in reference namelist' ) |
|---|
| 397 | ! |
|---|
| 398 | READ ( numnam_cfg, namzdf_iwm, IOSTAT = ios, ERR = 902 ) |
|---|
| 399 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in configuration namelist' ) |
|---|
| 400 | IF(lwm) WRITE ( numond, namzdf_iwm ) |
|---|
| 401 | ! |
|---|
| 402 | IF(lwp) THEN ! Control print |
|---|
| 403 | WRITE(numout,*) |
|---|
| 404 | WRITE(numout,*) 'zdf_iwm_init : internal wave-driven mixing' |
|---|
| 405 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 406 | WRITE(numout,*) ' Namelist namzdf_iwm : set wave-driven mixing parameters' |
|---|
| 407 | WRITE(numout,*) ' Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc |
|---|
| 408 | WRITE(numout,*) ' Variable (T) or constant (F) mixing efficiency = ', ln_mevar |
|---|
| 409 | WRITE(numout,*) ' Differential internal wave-driven mixing (T) or not (F) = ', ln_tsdiff |
|---|
| 410 | ENDIF |
|---|
| 411 | |
|---|
| 412 | ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and |
|---|
| 413 | ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should |
|---|
| 414 | ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6). |
|---|
| 415 | avmb(:) = 1.4e-6_wp ! viscous molecular value |
|---|
| 416 | avtb(:) = 1.e-10_wp ! very small diffusive minimum (background avt is specified in zdf_iwm) |
|---|
| 417 | avtb_2d(:,:) = 1.e0_wp ! uniform |
|---|
| 418 | IF(lwp) THEN ! Control print |
|---|
| 419 | WRITE(numout,*) |
|---|
| 420 | WRITE(numout,*) ' Force the background value applied to avm & avt in TKE to be everywhere ', & |
|---|
| 421 | & 'the viscous molecular value & a very small diffusive value, resp.' |
|---|
| 422 | ENDIF |
|---|
| 423 | |
|---|
| 424 | ! ! allocate iwm arrays |
|---|
| 425 | IF( zdf_iwm_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_iwm_init : unable to allocate iwm arrays' ) |
|---|
| 426 | ! |
|---|
| 427 | ! ! read necessary fields |
|---|
| 428 | CALL iom_open('mixing_power_bot',inum) ! energy flux for high-mode wave breaking [W/m2] |
|---|
| 429 | CALL iom_get (inum, jpdom_data, 'field', ebot_iwm, 1 ) |
|---|
| 430 | CALL iom_close(inum) |
|---|
| 431 | ! |
|---|
| 432 | CALL iom_open('mixing_power_pyc',inum) ! energy flux for pynocline-intensified wave breaking [W/m2] |
|---|
| 433 | CALL iom_get (inum, jpdom_data, 'field', epyc_iwm, 1 ) |
|---|
| 434 | CALL iom_close(inum) |
|---|
| 435 | ! |
|---|
| 436 | CALL iom_open('mixing_power_cri',inum) ! energy flux for critical slope wave breaking [W/m2] |
|---|
| 437 | CALL iom_get (inum, jpdom_data, 'field', ecri_iwm, 1 ) |
|---|
| 438 | CALL iom_close(inum) |
|---|
| 439 | ! |
|---|
| 440 | CALL iom_open('decay_scale_bot',inum) ! spatially variable decay scale for high-mode wave breaking [m] |
|---|
| 441 | CALL iom_get (inum, jpdom_data, 'field', hbot_iwm, 1 ) |
|---|
| 442 | CALL iom_close(inum) |
|---|
| 443 | ! |
|---|
| 444 | CALL iom_open('decay_scale_cri',inum) ! spatially variable decay scale for critical slope wave breaking [m] |
|---|
| 445 | CALL iom_get (inum, jpdom_data, 'field', hcri_iwm, 1 ) |
|---|
| 446 | CALL iom_close(inum) |
|---|
| 447 | |
|---|
| 448 | ebot_iwm(:,:) = ebot_iwm(:,:) * ssmask(:,:) |
|---|
| 449 | epyc_iwm(:,:) = epyc_iwm(:,:) * ssmask(:,:) |
|---|
| 450 | ecri_iwm(:,:) = ecri_iwm(:,:) * ssmask(:,:) |
|---|
| 451 | |
|---|
| 452 | zbot = glob_sum( 'zdfiwm', e1e2t(:,:) * ebot_iwm(:,:) ) |
|---|
| 453 | zpyc = glob_sum( 'zdfiwm', e1e2t(:,:) * epyc_iwm(:,:) ) |
|---|
| 454 | zcri = glob_sum( 'zdfiwm', e1e2t(:,:) * ecri_iwm(:,:) ) |
|---|
| 455 | IF(lwp) THEN |
|---|
| 456 | WRITE(numout,*) ' High-mode wave-breaking energy: ', zbot * 1.e-12_wp, 'TW' |
|---|
| 457 | WRITE(numout,*) ' Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW' |
|---|
| 458 | WRITE(numout,*) ' Critical slope wave-breaking energy: ', zcri * 1.e-12_wp, 'TW' |
|---|
| 459 | ENDIF |
|---|
| 460 | ! |
|---|
| 461 | END SUBROUTINE zdf_iwm_init |
|---|
| 462 | |
|---|
| 463 | !!====================================================================== |
|---|
| 464 | END MODULE zdfiwm |
|---|
