1 | MODULE p4zrem |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4zrem *** |
---|
4 | !! TOP : PISCES Compute remineralization/dissolution of organic compounds |
---|
5 | !!========================================================================= |
---|
6 | !! History : 1.0 ! 2004 (O. Aumont) Original code |
---|
7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
8 | !! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Quota model for iron |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! p4z_rem : Compute remineralization/dissolution of organic compounds |
---|
11 | !! p4z_rem_init : Initialisation of parameters for remineralisation |
---|
12 | !! p4z_rem_alloc : Allocate remineralisation variables |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | USE oce_trc ! shared variables between ocean and passive tracers |
---|
15 | USE trc ! passive tracers common variables |
---|
16 | USE sms_pisces ! PISCES Source Minus Sink variables |
---|
17 | USE p4zche ! chemical model |
---|
18 | USE p4zprod ! Growth rate of the 2 phyto groups |
---|
19 | USE p4zlim |
---|
20 | USE prtctl_trc ! print control for debugging |
---|
21 | USE iom ! I/O manager |
---|
22 | |
---|
23 | |
---|
24 | IMPLICIT NONE |
---|
25 | PRIVATE |
---|
26 | |
---|
27 | PUBLIC p4z_rem ! called in p4zbio.F90 |
---|
28 | PUBLIC p4z_rem_init ! called in trcsms_pisces.F90 |
---|
29 | PUBLIC p4z_rem_alloc |
---|
30 | |
---|
31 | REAL(wp), PUBLIC :: xremikc !: remineralisation rate of DOC |
---|
32 | REAL(wp), PUBLIC :: xremikn !: remineralisation rate of DON |
---|
33 | REAL(wp), PUBLIC :: xremikp !: remineralisation rate of DOP |
---|
34 | REAL(wp), PUBLIC :: xremik !: remineralisation rate of POC |
---|
35 | REAL(wp), PUBLIC :: nitrif !: NH4 nitrification rate |
---|
36 | REAL(wp), PUBLIC :: xsirem !: remineralisation rate of POC |
---|
37 | REAL(wp), PUBLIC :: xsiremlab !: fast remineralisation rate of POC |
---|
38 | REAL(wp), PUBLIC :: xsilab !: fraction of labile biogenic silica |
---|
39 | REAL(wp), PUBLIC :: feratb !: Fe/C quota in bacteria |
---|
40 | REAL(wp), PUBLIC :: xkferb !: Half-saturation constant for bacteria Fe/C |
---|
41 | |
---|
42 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: denitr !: denitrification array |
---|
43 | |
---|
44 | !! * Substitutions |
---|
45 | # include "do_loop_substitute.h90" |
---|
46 | # include "domzgr_substitute.h90" |
---|
47 | !!---------------------------------------------------------------------- |
---|
48 | !! NEMO/TOP 4.0 , NEMO Consortium (2018) |
---|
49 | !! $Id$ |
---|
50 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
51 | !!---------------------------------------------------------------------- |
---|
52 | CONTAINS |
---|
53 | |
---|
54 | SUBROUTINE p4z_rem( kt, knt, Kbb, Kmm, Krhs ) |
---|
55 | !!--------------------------------------------------------------------- |
---|
56 | !! *** ROUTINE p4z_rem *** |
---|
57 | !! |
---|
58 | !! ** Purpose : Compute remineralization/scavenging of organic compounds |
---|
59 | !! |
---|
60 | !! ** Method : - ??? |
---|
61 | !!--------------------------------------------------------------------- |
---|
62 | INTEGER, INTENT(in) :: kt, knt ! ocean time step |
---|
63 | INTEGER, INTENT(in) :: Kbb, Kmm, Krhs ! time level indices |
---|
64 | ! |
---|
65 | INTEGER :: ji, jj, jk |
---|
66 | REAL(wp) :: zremik, zremikc, zremikn, zremikp, zsiremin, zfact |
---|
67 | REAL(wp) :: zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep |
---|
68 | REAL(wp) :: zbactfer, zolimit, zonitr, zrfact2 |
---|
69 | REAL(wp) :: zammonic, zoxyremc, zoxyremn, zoxyremp |
---|
70 | REAL(wp) :: zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp |
---|
71 | CHARACTER (len=25) :: charout |
---|
72 | REAL(wp), DIMENSION(jpi,jpj ) :: ztempbac |
---|
73 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdepbac, zolimi, zdepprod, zfacsi, zfacsib, zdepeff, zfebact |
---|
74 | !!--------------------------------------------------------------------- |
---|
75 | ! |
---|
76 | IF( ln_timing ) CALL timing_start('p4z_rem') |
---|
77 | ! |
---|
78 | ! Initialisation of arrys |
---|
79 | zdepprod(:,:,:) = 1._wp |
---|
80 | zdepeff (:,:,:) = 0.3_wp |
---|
81 | ztempbac(:,:) = 0._wp |
---|
82 | zfacsib(:,:,:) = xsilab / ( 1.0 - xsilab ) |
---|
83 | zfebact(:,:,:) = 0._wp |
---|
84 | zfacsi(:,:,:) = xsilab |
---|
85 | |
---|
86 | ! Computation of the mean phytoplankton concentration as |
---|
87 | ! a crude estimate of the bacterial biomass |
---|
88 | ! this parameterization has been deduced from a model version |
---|
89 | ! that was modeling explicitely bacteria |
---|
90 | ! ------------------------------------------------------- |
---|
91 | DO_3D_11_11( 1, jpkm1 ) |
---|
92 | zdep = MAX( hmld(ji,jj), heup(ji,jj) ) |
---|
93 | IF( gdept(ji,jj,jk,Kmm) < zdep ) THEN |
---|
94 | zdepbac(ji,jj,jk) = MIN( 0.7 * ( tr(ji,jj,jk,jpzoo,Kbb) + 2.* tr(ji,jj,jk,jpmes,Kbb) ), 4.e-6 ) |
---|
95 | ztempbac(ji,jj) = zdepbac(ji,jj,jk) |
---|
96 | ELSE |
---|
97 | zdepmin = MIN( 1., zdep / gdept(ji,jj,jk,Kmm) ) |
---|
98 | zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj) |
---|
99 | zdepprod(ji,jj,jk) = zdepmin**0.273 |
---|
100 | zdepeff (ji,jj,jk) = zdepeff(ji,jj,jk) * zdepmin**0.3 |
---|
101 | ENDIF |
---|
102 | END_3D |
---|
103 | |
---|
104 | IF( ln_p4z ) THEN |
---|
105 | DO_3D_11_11( 1, jpkm1 ) |
---|
106 | ! DOC ammonification. Depends on depth, phytoplankton biomass |
---|
107 | ! and a limitation term which is supposed to be a parameterization of the bacterial activity. |
---|
108 | zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) |
---|
109 | zremik = MAX( zremik, 2.74e-4 * xstep ) |
---|
110 | ! Ammonification in oxic waters with oxygen consumption |
---|
111 | ! ----------------------------------------------------- |
---|
112 | zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * tr(ji,jj,jk,jpdoc,Kbb) |
---|
113 | zolimi(ji,jj,jk) = MIN( ( tr(ji,jj,jk,jpoxy,Kbb) - rtrn ) / o2ut, zolimit ) |
---|
114 | ! Ammonification in suboxic waters with denitrification |
---|
115 | ! ------------------------------------------------------- |
---|
116 | zammonic = zremik * nitrfac(ji,jj,jk) * tr(ji,jj,jk,jpdoc,Kbb) |
---|
117 | denitr(ji,jj,jk) = zammonic * ( 1. - nitrfac2(ji,jj,jk) ) |
---|
118 | denitr(ji,jj,jk) = MIN( ( tr(ji,jj,jk,jpno3,Kbb) - rtrn ) / rdenit, denitr(ji,jj,jk) ) |
---|
119 | zoxyremc = zammonic - denitr(ji,jj,jk) |
---|
120 | ! |
---|
121 | zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) ) |
---|
122 | denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) ) |
---|
123 | zoxyremc = MAX( 0.e0, zoxyremc ) |
---|
124 | |
---|
125 | ! |
---|
126 | tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc |
---|
127 | tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc |
---|
128 | tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - denitr (ji,jj,jk) * rdenit |
---|
129 | tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) - zolimi (ji,jj,jk) - denitr(ji,jj,jk) - zoxyremc |
---|
130 | tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - zolimi (ji,jj,jk) * o2ut |
---|
131 | tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc |
---|
132 | tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zolimi(ji,jj,jk) + zoxyremc & |
---|
133 | & + ( rdenit + 1.) * denitr(ji,jj,jk) ) |
---|
134 | END_3D |
---|
135 | ELSE |
---|
136 | DO_3D_11_11( 1, jpkm1 ) |
---|
137 | ! DOC ammonification. Depends on depth, phytoplankton biomass |
---|
138 | ! and a limitation term which is supposed to be a parameterization of the bacterial activity. |
---|
139 | ! ----------------------------------------------------------------- |
---|
140 | zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) |
---|
141 | zremik = MAX( zremik, 2.74e-4 * xstep / xremikc ) |
---|
142 | |
---|
143 | zremikc = xremikc * zremik |
---|
144 | zremikn = xremikn / xremikc |
---|
145 | zremikp = xremikp / xremikc |
---|
146 | |
---|
147 | ! Ammonification in oxic waters with oxygen consumption |
---|
148 | ! ----------------------------------------------------- |
---|
149 | zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * tr(ji,jj,jk,jpdoc,Kbb) |
---|
150 | zolimic = MAX( 0.e0, MIN( ( tr(ji,jj,jk,jpoxy,Kbb) - rtrn ) / o2ut, zolimit ) ) |
---|
151 | zolimi(ji,jj,jk) = zolimic |
---|
152 | zolimin = zremikn * zolimic * tr(ji,jj,jk,jpdon,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
---|
153 | zolimip = zremikp * zolimic * tr(ji,jj,jk,jpdop,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
---|
154 | |
---|
155 | ! Ammonification in suboxic waters with denitrification |
---|
156 | ! ------------------------------------------------------- |
---|
157 | zammonic = zremikc * nitrfac(ji,jj,jk) * tr(ji,jj,jk,jpdoc,Kbb) |
---|
158 | denitr(ji,jj,jk) = zammonic * ( 1. - nitrfac2(ji,jj,jk) ) |
---|
159 | denitr(ji,jj,jk) = MAX(0., MIN( ( tr(ji,jj,jk,jpno3,Kbb) - rtrn ) / rdenit, denitr(ji,jj,jk) ) ) |
---|
160 | zoxyremc = MAX(0., zammonic - denitr(ji,jj,jk)) |
---|
161 | zdenitrn = zremikn * denitr(ji,jj,jk) * tr(ji,jj,jk,jpdon,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
---|
162 | zdenitrp = zremikp * denitr(ji,jj,jk) * tr(ji,jj,jk,jpdop,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
---|
163 | zoxyremn = zremikn * zoxyremc * tr(ji,jj,jk,jpdon,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
---|
164 | zoxyremp = zremikp * zoxyremc * tr(ji,jj,jk,jpdop,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
---|
165 | |
---|
166 | tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zolimip + zdenitrp + zoxyremp |
---|
167 | tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zolimin + zdenitrn + zoxyremn |
---|
168 | tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - denitr(ji,jj,jk) * rdenit |
---|
169 | tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) - zolimic - denitr(ji,jj,jk) - zoxyremc |
---|
170 | tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) - zolimin - zdenitrn - zoxyremn |
---|
171 | tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) - zolimip - zdenitrp - zoxyremp |
---|
172 | tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - zolimic * o2ut |
---|
173 | tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zolimic + denitr(ji,jj,jk) + zoxyremc |
---|
174 | tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zolimin + zoxyremn + ( rdenit + 1.) * zdenitrn ) |
---|
175 | END_3D |
---|
176 | ! |
---|
177 | ENDIF |
---|
178 | |
---|
179 | |
---|
180 | DO_3D_11_11( 1, jpkm1 ) |
---|
181 | ! NH4 nitrification to NO3. Ceased for oxygen concentrations |
---|
182 | ! below 2 umol/L. Inhibited at strong light |
---|
183 | ! ---------------------------------------------------------- |
---|
184 | zonitr = nitrif * xstep * tr(ji,jj,jk,jpnh4,Kbb) * ( 1.- nitrfac(ji,jj,jk) ) & |
---|
185 | & / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) |
---|
186 | zdenitnh4 = nitrif * xstep * tr(ji,jj,jk,jpnh4,Kbb) * nitrfac(ji,jj,jk) |
---|
187 | zdenitnh4 = MIN( ( tr(ji,jj,jk,jpno3,Kbb) - rtrn ) / rdenita, zdenitnh4 ) |
---|
188 | ! Update of the tracers trends |
---|
189 | ! ---------------------------- |
---|
190 | tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) - zonitr - zdenitnh4 |
---|
191 | tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) + zonitr - rdenita * zdenitnh4 |
---|
192 | tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2nit * zonitr |
---|
193 | tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4 |
---|
194 | END_3D |
---|
195 | |
---|
196 | IF(sn_cfctl%l_prttrc) THEN ! print mean trends (used for debugging) |
---|
197 | WRITE(charout, FMT="('rem1')") |
---|
198 | CALL prt_ctl_trc_info(charout) |
---|
199 | CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm) |
---|
200 | ENDIF |
---|
201 | |
---|
202 | DO_3D_11_11( 1, jpkm1 ) |
---|
203 | |
---|
204 | ! Bacterial uptake of iron. No iron is available in DOC. So |
---|
205 | ! Bacteries are obliged to take up iron from the water. Some |
---|
206 | ! studies (especially at Papa) have shown this uptake to be significant |
---|
207 | ! ---------------------------------------------------------- |
---|
208 | zbactfer = feratb * rfact2 * 0.6_wp / rday * tgfunc(ji,jj,jk) * xlimbacl(ji,jj,jk) & |
---|
209 | & * tr(ji,jj,jk,jpfer,Kbb) / ( xkferb + tr(ji,jj,jk,jpfer,Kbb) ) & |
---|
210 | & * zdepprod(ji,jj,jk) * zdepeff(ji,jj,jk) * zdepbac(ji,jj,jk) |
---|
211 | tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zbactfer*0.33 |
---|
212 | tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zbactfer*0.25 |
---|
213 | tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + zbactfer*0.08 |
---|
214 | zfebact(ji,jj,jk) = zbactfer * 0.33 |
---|
215 | blim(ji,jj,jk) = xlimbacl(ji,jj,jk) * zdepbac(ji,jj,jk) / 1.e-6 * zdepprod(ji,jj,jk) |
---|
216 | END_3D |
---|
217 | |
---|
218 | IF(sn_cfctl%l_prttrc) THEN ! print mean trends (used for debugging) |
---|
219 | WRITE(charout, FMT="('rem2')") |
---|
220 | CALL prt_ctl_trc_info(charout) |
---|
221 | CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm) |
---|
222 | ENDIF |
---|
223 | |
---|
224 | ! Initialization of the array which contains the labile fraction |
---|
225 | ! of bSi. Set to a constant in the upper ocean |
---|
226 | ! --------------------------------------------------------------- |
---|
227 | |
---|
228 | DO_3D_11_11( 1, jpkm1 ) |
---|
229 | zdep = MAX( hmld(ji,jj), heup_01(ji,jj) ) |
---|
230 | zsatur = MAX( rtrn, ( sio3eq(ji,jj,jk) - tr(ji,jj,jk,jpsil,Kbb) ) / ( sio3eq(ji,jj,jk) + rtrn ) ) |
---|
231 | zsatur2 = ( 1. + ts(ji,jj,jk,jp_tem,Kmm) / 400.)**37 |
---|
232 | znusil = 0.225 * ( 1. + ts(ji,jj,jk,jp_tem,Kmm) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25 |
---|
233 | ! Remineralization rate of BSi depedant on T and saturation |
---|
234 | ! --------------------------------------------------------- |
---|
235 | IF ( gdept(ji,jj,jk,Kmm) > zdep ) THEN |
---|
236 | zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem ) & |
---|
237 | & * znusil * e3t(ji,jj,jk,Kmm) / wsbio4(ji,jj,jk) ) |
---|
238 | zfacsi(ji,jj,jk) = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) ) |
---|
239 | zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem ) & |
---|
240 | & * znusil * e3t(ji,jj,jk,Kmm) / wsbio4(ji,jj,jk) ) |
---|
241 | ENDIF |
---|
242 | zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil |
---|
243 | zosil = zsiremin * tr(ji,jj,jk,jpgsi,Kbb) |
---|
244 | ! |
---|
245 | tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) - zosil |
---|
246 | tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) + zosil |
---|
247 | END_3D |
---|
248 | |
---|
249 | IF(sn_cfctl%l_prttrc) THEN ! print mean trends (used for debugging) |
---|
250 | WRITE(charout, FMT="('rem3')") |
---|
251 | CALL prt_ctl_trc_info(charout) |
---|
252 | CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm) |
---|
253 | ENDIF |
---|
254 | |
---|
255 | IF( knt == nrdttrc ) THEN |
---|
256 | zrfact2 = 1.e+3 * rfact2r ! conversion from mol/l/kt to mol/m3/s |
---|
257 | ! |
---|
258 | IF( iom_use( "REMIN" ) ) THEN ! Remineralisation rate |
---|
259 | zolimi(:,:,jpk) = 0. ; CALL iom_put( "REMIN" , zolimi(:,:,:) * tmask(:,:,:) * zrfact2 ) |
---|
260 | ENDIF |
---|
261 | CALL iom_put( "DENIT" , denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zrfact2 ) ! Denitrification |
---|
262 | IF( iom_use( "BACT" ) ) THEN ! Bacterial biomass |
---|
263 | zdepbac(:,:,jpk) = 0. ; CALL iom_put( "BACT", zdepbac(:,:,:) * 1.E6 * tmask(:,:,:) ) |
---|
264 | ENDIF |
---|
265 | CALL iom_put( "FEBACT" , zfebact(:,:,:) * 1E9 * tmask(:,:,:) * zrfact2 ) |
---|
266 | ENDIF |
---|
267 | ! |
---|
268 | IF( ln_timing ) CALL timing_stop('p4z_rem') |
---|
269 | ! |
---|
270 | END SUBROUTINE p4z_rem |
---|
271 | |
---|
272 | |
---|
273 | SUBROUTINE p4z_rem_init |
---|
274 | !!---------------------------------------------------------------------- |
---|
275 | !! *** ROUTINE p4z_rem_init *** |
---|
276 | !! |
---|
277 | !! ** Purpose : Initialization of remineralization parameters |
---|
278 | !! |
---|
279 | !! ** Method : Read the nampisrem namelist and check the parameters |
---|
280 | !! called at the first timestep |
---|
281 | !! |
---|
282 | !! ** input : Namelist nampisrem |
---|
283 | !! |
---|
284 | !!---------------------------------------------------------------------- |
---|
285 | NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & |
---|
286 | & xremikc, xremikn, xremikp |
---|
287 | INTEGER :: ios ! Local integer output status for namelist read |
---|
288 | !!---------------------------------------------------------------------- |
---|
289 | ! |
---|
290 | IF(lwp) THEN |
---|
291 | WRITE(numout,*) |
---|
292 | WRITE(numout,*) 'p4z_rem_init : Initialization of remineralization parameters' |
---|
293 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
294 | ENDIF |
---|
295 | ! |
---|
296 | READ ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901) |
---|
297 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist' ) |
---|
298 | READ ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 ) |
---|
299 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist' ) |
---|
300 | IF(lwm) WRITE( numonp, nampisrem ) |
---|
301 | |
---|
302 | IF(lwp) THEN ! control print |
---|
303 | WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem' |
---|
304 | IF( ln_p4z ) THEN |
---|
305 | WRITE(numout,*) ' remineralization rate of DOC xremik =', xremik |
---|
306 | ELSE |
---|
307 | WRITE(numout,*) ' remineralization rate of DOC xremikc =', xremikc |
---|
308 | WRITE(numout,*) ' remineralization rate of DON xremikn =', xremikn |
---|
309 | WRITE(numout,*) ' remineralization rate of DOP xremikp =', xremikp |
---|
310 | ENDIF |
---|
311 | WRITE(numout,*) ' remineralization rate of Si xsirem =', xsirem |
---|
312 | WRITE(numout,*) ' fast remineralization rate of Si xsiremlab =', xsiremlab |
---|
313 | WRITE(numout,*) ' fraction of labile biogenic silica xsilab =', xsilab |
---|
314 | WRITE(numout,*) ' NH4 nitrification rate nitrif =', nitrif |
---|
315 | WRITE(numout,*) ' Bacterial Fe/C ratio feratb =', feratb |
---|
316 | WRITE(numout,*) ' Half-saturation constant for bact. Fe/C xkferb =', xkferb |
---|
317 | ENDIF |
---|
318 | ! |
---|
319 | denitr(:,:,:) = 0._wp |
---|
320 | ! |
---|
321 | END SUBROUTINE p4z_rem_init |
---|
322 | |
---|
323 | |
---|
324 | INTEGER FUNCTION p4z_rem_alloc() |
---|
325 | !!---------------------------------------------------------------------- |
---|
326 | !! *** ROUTINE p4z_rem_alloc *** |
---|
327 | !!---------------------------------------------------------------------- |
---|
328 | ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc ) |
---|
329 | ! |
---|
330 | IF( p4z_rem_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p4z_rem_alloc: failed to allocate arrays' ) |
---|
331 | ! |
---|
332 | END FUNCTION p4z_rem_alloc |
---|
333 | |
---|
334 | !!====================================================================== |
---|
335 | END MODULE p4zrem |
---|