New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpctl.F90 in NEMO/branches/2020/dev_r12527_Gurvan_ShallowWater/src/SWE – NEMO

source: NEMO/branches/2020/dev_r12527_Gurvan_ShallowWater/src/SWE/stpctl.F90 @ 13151

Last change on this file since 13151 was 13151, checked in by gm, 4 years ago

result from merge with qco r12983
  • Property svn:keywords set to Id
File size: 8.6 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (G. Madec) Original code
7   !!            6.0  ! 1992-06  (M. Imbard)
8   !!            8.0  ! 1997-06  (A.M. Treguier)
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
11   !!            3.7  ! 2016-09  (G. Madec)  Remove solver
12   !!            4.0  ! 2017-04  (G. Madec)  regroup global communications
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   stp_ctl      : Control the run
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE c1d             ! 1D vertical configuration
21   USE diawri          ! Standard run outputs       (dia_wri_state routine)
22   !
23   USE in_out_manager  ! I/O manager
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE lib_mpp         ! distributed memory computing
26   USE zdf_oce ,  ONLY : ln_zad_Aimp       ! ocean vertical physics variables
27   USE wet_dry,   ONLY : ll_wd, ssh_ref    ! reference depth for negative bathy
28
29   USE netcdf          ! NetCDF library
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC stp_ctl           ! routine called by step.F90
34
35   INTEGER  ::   idrun, idtime, idssh, idu, ids1, ids2, idt1, idt2, idc1, idw1, istatus
36   LOGICAL  ::   lsomeoce
37!!stoops
38#  include "domzgr_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE stp_ctl( kt, Kbb, Kmm, kindic )
47      !!----------------------------------------------------------------------
48      !!                    ***  ROUTINE stp_ctl  ***
49      !!                     
50      !! ** Purpose :   Control the run
51      !!
52      !! ** Method  : - Save the time step in numstp
53      !!              - Print it each 50 time steps
54      !!              - Stop the run IF problem encountered by setting indic=-3
55      !!                Problems checked: |ssh| maximum larger than 10 m
56      !!                                  |U|   maximum larger than 10 m/s
57      !!                                  negative sea surface salinity
58      !!
59      !! ** Actions :   "time.step" file = last ocean time-step
60      !!                "run.stat"  file = run statistics
61      !!                nstop indicator sheared among all local domain (lk_mpp=T)
62      !!----------------------------------------------------------------------
63      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
64      INTEGER, INTENT(in   ) ::   Kbb, Kmm      ! ocean time level index
65      INTEGER, INTENT(inout) ::   kindic   ! error indicator
66      !!
67      INTEGER                ::   ji, jj, jk          ! dummy loop indices
68      INTEGER, DIMENSION(2)  ::   ih                  ! min/max loc indices
69      INTEGER, DIMENSION(3)  ::   iu, is1, is2        ! min/max loc indices
70      REAL(wp)               ::   zzz                 ! local real
71      REAL(wp), DIMENSION(3) ::   zmax
72      LOGICAL                ::   ll_wrtstp, ll_colruns, ll_wrtruns
73      CHARACTER(len=20) :: clname
74      !!----------------------------------------------------------------------
75      !
76      ll_wrtstp  = ( MOD( kt, sn_cfctl%ptimincr ) == 0 ) .OR. ( kt == nitend )
77      ll_colruns = ll_wrtstp .AND. ( sn_cfctl%l_runstat )
78      ll_wrtruns = ll_colruns .AND. lwm
79      IF( kt == nit000 .AND. lwp ) THEN
80         WRITE(numout,*)
81         WRITE(numout,*) 'stp_ctl : time-stepping control'
82         WRITE(numout,*) '~~~~~~~'
83         !                                ! open time.step file
84         IF( lwm ) CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
85         !                                ! open run.stat file(s) at start whatever
86         !                                ! the value of sn_cfctl%ptimincr
87         IF( lwm .AND. ( sn_cfctl%l_runstat ) ) THEN
88            CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
89            clname = 'run.stat.nc'
90            IF( .NOT. Agrif_Root() )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(clname)
91            istatus = NF90_CREATE( TRIM(clname), NF90_CLOBBER, idrun )
92            istatus = NF90_DEF_DIM( idrun, 'time', NF90_UNLIMITED, idtime )
93            istatus = NF90_DEF_VAR( idrun, 'abs_ssh_max', NF90_DOUBLE, (/ idtime /), idssh )
94            istatus = NF90_DEF_VAR( idrun,   'abs_u_max', NF90_DOUBLE, (/ idtime /), idu   )
95            istatus = NF90_ENDDEF(idrun)
96         ENDIF
97      ENDIF
98      IF( kt == nit000 )   lsomeoce = COUNT( ssmask(:,:) == 1._wp ) > 0
99      !
100      IF(lwm .AND. ll_wrtstp) THEN        !==  current time step  ==!   ("time.step" file)
101         WRITE ( numstp, '(1x, i8)' )   kt
102         REWIND( numstp )
103      ENDIF
104      !
105      !                                   !==  test of extrema  ==!
106      IF( ll_wd ) THEN
107         zmax(1) = MAXVAL(  ABS( ssh(:,:,Kmm) + ssh_ref*tmask(:,:,1) )  )        ! ssh max
108      ELSE
109         zmax(1) = MINVAL( e3t(:,:,1,Kmm)  )                                         ! ssh min
110      ENDIF
111      zmax(2) = MAXVAL(  ABS( uu(:,:,:,Kmm) )  )                                  ! velocity max (zonal only)
112      zmax(3) = REAL( nstop , wp )                                            ! stop indicator
113      !
114      IF( ll_colruns ) THEN
115         CALL mpp_max( "stpctl", zmax )          ! max over the global domain
116         nstop = NINT( zmax(3) )                 ! nstop indicator sheared among all local domains
117      ENDIF
118      !                                   !==  run statistics  ==!   ("run.stat" files)
119      IF( ll_wrtruns ) THEN
120         WRITE(numrun,9500) kt, zmax(1), zmax(2)
121         istatus = NF90_PUT_VAR( idrun, idssh, (/ zmax(1)/), (/kt/), (/1/) )
122         istatus = NF90_PUT_VAR( idrun,   idu, (/ zmax(2)/), (/kt/), (/1/) )
123         IF( MOD( kt , 100 ) == 0 ) istatus = NF90_SYNC(idrun)
124         IF( kt == nitend         ) istatus = NF90_CLOSE(idrun)
125      END IF
126      !                                   !==  error handling  ==!
127      IF( ( sn_cfctl%l_glochk .OR. lsomeoce ) .AND. (   &  ! domain contains some ocean points, check for sensible ranges
128         &  zmax(1) <    0._wp .OR.   &                    ! negative sea surface height
129         &  zmax(2) >   10._wp .OR.   &                    ! too large velocity ( > 10 m/s)
130         &  ISNAN( zmax(1) + zmax(2) ) ) ) THEN            ! NaN encounter in the tests
131         IF( lk_mpp .AND. sn_cfctl%l_glochk ) THEN
132            ! have use mpp_max (because sn_cfctl%l_glochk=.T. and distributed)
133            CALL mpp_maxloc( 'stpctl', ABS(ssh(:,:,Kmm))        , ssmask(:,:)  , zzz, ih  )
134            CALL mpp_maxloc( 'stpctl', ABS(uu(:,:,:,Kmm))          , umask (:,:,:), zzz, iu  )
135         ELSE
136            ! find local min and max locations
137            ih(:)  = MAXLOC( ABS( ssh(:,:,Kmm)   )                              ) + (/ nimpp - 1, njmpp - 1    /)
138            iu(:)  = MAXLOC( ABS( uu  (:,:,:,Kmm) )                              ) + (/ nimpp - 1, njmpp - 1, 0 /)
139         ENDIF
140         
141         WRITE(ctmp1,*) ' stp_ctl: (e3t0) ssh < 0 m  or  |U| > 10 m/s  or  NaN encounter in the tests'
142         WRITE(ctmp2,9100) kt,   zmax(1), ih(1) , ih(2)
143         WRITE(ctmp3,9200) kt,   zmax(2), iu(1) , iu(2) , iu(3)
144         WRITE(ctmp4,*) '      ===> output of last computed fields in output.abort.nc file'
145         
146         CALL dia_wri_state( Kmm, 'output.abort' )     ! create an output.abort file
147         
148         IF( .NOT. sn_cfctl%l_glochk ) THEN
149            WRITE(ctmp8,*) 'E R R O R message from sub-domain: ', narea
150            CALL ctl_stop( 'STOP', ctmp1, ' ', ctmp8, ' ', ctmp2, ctmp3, ctmp4 )
151         ELSE
152            CALL ctl_stop( ctmp1, ' ', ctmp2, ctmp3, ctmp4 )
153         ENDIF
154
155         kindic = -3
156         !
157      ENDIF
158      !
1599100  FORMAT (' kt=',i8,'   |ssh| min: ',1pg11.4,', at  i j  : ',2i5)
1609200  FORMAT (' kt=',i8,'   |U|   max: ',1pg11.4,', at  i j k: ',3i5)
1619500  FORMAT(' it :', i8, '    |ssh|_max: ', D23.16, ' |U|_max: ', D23.16)
162      !
163   END SUBROUTINE stp_ctl
164
165   !!======================================================================
166END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.