New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OCE/TRA/traadv_fct.F90 @ 13247

Last change on this file since 13247 was 13247, checked in by francesca, 4 years ago

dev_r12558_HPC-08_epico_Extra_Halo: merge with trunk@13227, see #2366
  • Property svn:keywords set to Id
File size: 32.8 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
40   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
41
42   !                                        ! tridiag solver associated indices:
43   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
44   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
45
46   !! * Substitutions
47#  include "do_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
50   !! $Id$
51   !! Software governed by the CeCILL license (see ./LICENSE)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
56      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE tra_adv_fct  ***
59      !!
60      !! **  Purpose :   Compute the now trend due to total advection of tracers
61      !!               and add it to the general trend of tracer equations
62      !!
63      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
64      !!               (choice through the value of kn_fct)
65      !!               - on the vertical the 4th order is a compact scheme
66      !!               - corrected flux (monotonic correction)
67      !!
68      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
69      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
70      !!             - poleward advective heat and salt transport (ln_diaptr=T)
71      !!----------------------------------------------------------------------
72      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
73      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
74      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
75      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
76      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
77      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
78      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
79      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
80      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
82      !
83      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
84      REAL(wp) ::   ztra                                     ! local scalar
85      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
86      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
87      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
88      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
89      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
90      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
91      !!----------------------------------------------------------------------
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
97      ENDIF
98      !! -- init to 0
99      zwi(:,:,:) = 0._wp
100      zwx(:,:,:) = 0._wp
101      zwy(:,:,:) = 0._wp
102      zwz(:,:,:) = 0._wp
103      ztu(:,:,:) = 0._wp
104      ztv(:,:,:) = 0._wp
105      zltu(:,:,:) = 0._wp
106      zltv(:,:,:) = 0._wp
107      ztw(:,:,:) = 0._wp
108      !
109      l_trd = .FALSE.            ! set local switches
110      l_hst = .FALSE.
111      l_ptr = .FALSE.
112      ll_zAimp = .FALSE.
113      IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
114      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE. 
115      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
116         &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
117      !
118      IF( l_trd .OR. l_hst )  THEN
119         ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
120         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
121      ENDIF
122      !
123      IF( l_ptr ) THEN 
124         ALLOCATE( zptry(jpi,jpj,jpk) )
125         zptry(:,:,:) = 0._wp
126      ENDIF
127      !                          ! surface & bottom value : flux set to zero one for all
128      zwz(:,:, 1 ) = 0._wp           
129      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
130      !
131      zwi(:,:,:) = 0._wp       
132      !
133      ! If adaptive vertical advection, check if it is needed on this PE at this time
134      IF( ln_zad_Aimp ) THEN
135         IF( MAXVAL( ABS( wi(:,:,:) ) ) > 0._wp ) ll_zAimp = .TRUE.
136      END IF
137      ! If active adaptive vertical advection, build tridiagonal matrix
138      IF( ll_zAimp ) THEN
139         ALLOCATE(zwdia(jpi,jpj,jpk), zwinf(jpi,jpj,jpk),zwsup(jpi,jpj,jpk))
140         DO_3D_00_00( 1, jpkm1 )
141            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) ) / e3t(ji,jj,jk,Krhs)
142            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
143            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
144         END_3D
145      END IF
146      !
147      DO jn = 1, kjpt            !==  loop over the tracers  ==!
148         !
149         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
150         !                    !* upstream tracer flux in the i and j direction
151         DO_3D_10_10( 1, jpkm1 )
152            ! upstream scheme
153            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
154            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
155            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
156            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
157            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
158            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
159         END_3D
160         !                    !* upstream tracer flux in the k direction *!
161         DO_3D_11_11( 2, jpkm1 )
162            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
163            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
164            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
165         END_3D
166         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
167            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
168               DO_2D_11_11
169                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
170               END_2D
171            ELSE                             ! no cavities: only at the ocean surface
172               DO_2D_11_11
173                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
174               END_2D
175            ENDIF
176         ENDIF
177         !               
178         DO_3D_00_00( 1, jpkm1 )
179            !                             ! total intermediate advective trends
180            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
181               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
182               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
183            !                             ! update and guess with monotonic sheme
184            pt(ji,jj,jk,jn,Krhs) =                     pt(ji,jj,jk,jn,Krhs) +        ztra   / e3t(ji,jj,jk,Kmm) * tmask(ji,jj,jk)
185            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
186         END_3D
187         
188         IF ( ll_zAimp ) THEN
189            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
190            !
191            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
192            DO_3D_00_00( 2, jpkm1 )
193               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
194               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
195               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
196               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
197            END_3D
198            DO_3D_00_00( 1, jpkm1 )
199               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
200                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
201            END_3D
202            !
203         END IF
204         !               
205         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
206            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
207         END IF
208         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
209         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
210         !
211         !        !==  anti-diffusive flux : high order minus low order  ==!
212         !
213         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
214         !
215         CASE(  2  )                   !- 2nd order centered
216            DO_3D_10_10( 1, jpkm1 )
217               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
218               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
219            END_3D
220            !
221         CASE(  4  )                   !- 4th order centered
222            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
223            zltv(:,:,jpk) = 0._wp
224            DO jk = 1, jpkm1                 ! Laplacian
225               DO_2D_10_10
226                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
227                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
228               END_2D
229               DO_2D_00_00
230                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
231                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
232               END_2D
233            END DO
234            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
235            !
236            DO_3D_10_10( 1, jpkm1 )
237               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
238               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
239               !                                                  ! C4 minus upstream advective fluxes
240               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
241               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
242            END_3D
243            !
244         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
245            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
246            ztv(:,:,jpk) = 0._wp
247            DO_3D_10_10( 1, jpkm1 )
248               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
249               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
250            END_3D
251            CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
252            !
253            DO_3D_00_00( 1, jpkm1 )
254               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
255               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
256               !                                                  ! C4 interpolation of T at u- & v-points (x2)
257               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
258               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
259               !                                                  ! C4 minus upstream advective fluxes
260               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
261               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
262            END_3D
263            !
264         END SELECT
265         !                     
266         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
267         !
268         CASE(  2  )                   !- 2nd order centered
269            DO_3D_00_00( 2, jpkm1 )
270               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
271                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
272            END_3D
273            !
274         CASE(  4  )                   !- 4th order COMPACT
275            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
276            DO_3D_00_00( 2, jpkm1 )
277               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
278            END_3D
279            !
280         END SELECT
281         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
282            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
283         ENDIF
284         !         
285         IF ( ll_zAimp ) THEN
286            DO_3D_00_00( 1, jpkm1 )
287               !                             ! total intermediate advective trends
288               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
289                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
290                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
291               ztw(ji,jj,jk)  = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
292            END_3D
293            !
294            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
295            !
296            DO_3D_00_00( 2, jpkm1 )
297               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
298               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
299               zwz(ji,jj,jk) =  zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
300            END_3D
301         END IF
302         !
303         CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp,  zwz, 'W',  1.0_wp )
304         !
305         !        !==  monotonicity algorithm  ==!
306         !
307         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
308         !
309         !        !==  final trend with corrected fluxes  ==!
310         !
311         DO_3D_00_00( 1, jpkm1 )
312            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
313               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
314               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
315            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
316            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
317         END_3D
318         !
319         IF ( ll_zAimp ) THEN
320            !
321            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
322            DO_3D_00_00( 2, jpkm1 )
323               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
324               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
325               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
326               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
327            END_3D
328            DO_3D_00_00( 1, jpkm1 )
329               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
330                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
331            END_3D
332         END IF         
333         !
334         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
335            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
336            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
337            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
338            !
339            IF( l_trd ) THEN              ! trend diagnostics
340               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
341               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
342               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
343            ENDIF
344            !                             ! heat/salt transport
345            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
346            !
347         ENDIF
348         IF( l_ptr ) THEN              ! "Poleward" transports
349            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
350            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
351         ENDIF
352         !
353      END DO                     ! end of tracer loop
354      !
355      IF ( ll_zAimp ) THEN
356         DEALLOCATE( zwdia, zwinf, zwsup )
357      ENDIF
358      IF( l_trd .OR. l_hst ) THEN
359         DEALLOCATE( ztrdx, ztrdy, ztrdz )
360      ENDIF
361      IF( l_ptr ) THEN
362         DEALLOCATE( zptry )
363      ENDIF
364      !
365   END SUBROUTINE tra_adv_fct
366
367
368   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
369      !!---------------------------------------------------------------------
370      !!                    ***  ROUTINE nonosc  ***
371      !!     
372      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
373      !!       scheme and the before field by a nonoscillatory algorithm
374      !!
375      !! **  Method  :   ... ???
376      !!       warning : pbef and paft must be masked, but the boundaries
377      !!       conditions on the fluxes are not necessary zalezak (1979)
378      !!       drange (1995) multi-dimensional forward-in-time and upstream-
379      !!       in-space based differencing for fluid
380      !!----------------------------------------------------------------------
381      INTEGER                          , INTENT(in   ) ::   Kmm             ! time level index
382      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
383      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
384      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
385      !
386      INTEGER  ::   ji, jj, jk   ! dummy loop indices
387      INTEGER  ::   ikm1         ! local integer
388      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
389      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
390      REAL(dp), DIMENSION(jpi,jpj,jpk) :: zbetup, zbetdo, zbup, zbdo
391      !!----------------------------------------------------------------------
392      !
393      zbig  = 1.e+40_dp
394      zrtrn = 1.e-15_dp
395      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
396
397      ! Search local extrema
398      ! --------------------
399      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
400      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
401         &        paft * tmask - zbig * ( 1._wp - tmask )  )
402      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
403         &        paft * tmask + zbig * ( 1._wp - tmask )  )
404
405      DO jk = 1, jpkm1
406         ikm1 = MAX(jk-1,1)
407         DO_2D_00_00
408
409            ! search maximum in neighbourhood
410            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
411               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
412               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
413               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
414
415            ! search minimum in neighbourhood
416            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
417               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
418               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
419               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
420
421            ! positive part of the flux
422            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
423               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
424               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
425
426            ! negative part of the flux
427            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
428               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
429               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
430
431            ! up & down beta terms
432            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
433            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
434            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
435         END_2D
436      END DO
437      CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
438
439      ! 3. monotonic flux in the i & j direction (paa & pbb)
440      ! ----------------------------------------
441      DO_3D_00_00( 1, jpkm1 )
442         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
443         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
444         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
445         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
446
447         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
448         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
449         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
450         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
451
452! monotonic flux in the k direction, i.e. pcc
453! -------------------------------------------
454         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
455         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
456         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
457         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
458      END_3D
459      CALL lbc_lnk_multi( 'traadv_fct', paa, 'U', -1.0_wp , pbb, 'V', -1.0_wp )   ! lateral boundary condition (changed sign)
460      !
461   END SUBROUTINE nonosc
462
463
464   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
465      !!----------------------------------------------------------------------
466      !!                  ***  ROUTINE interp_4th_cpt_org  ***
467      !!
468      !! **  Purpose :   Compute the interpolation of tracer at w-point
469      !!
470      !! **  Method  :   4th order compact interpolation
471      !!----------------------------------------------------------------------
472      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
473      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
474      !
475      INTEGER :: ji, jj, jk   ! dummy loop integers
476      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
477      !!----------------------------------------------------------------------
478     
479      DO_3D_11_11( 3, jpkm1 )
480         zwd (ji,jj,jk) = 4._wp
481         zwi (ji,jj,jk) = 1._wp
482         zws (ji,jj,jk) = 1._wp
483         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
484         !
485         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
486            zwd (ji,jj,jk) = 1._wp
487            zwi (ji,jj,jk) = 0._wp
488            zws (ji,jj,jk) = 0._wp
489            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
490         ENDIF
491      END_3D
492      !
493      jk = 2                                          ! Switch to second order centered at top
494      DO_2D_11_11
495         zwd (ji,jj,jk) = 1._wp
496         zwi (ji,jj,jk) = 0._wp
497         zws (ji,jj,jk) = 0._wp
498         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
499      END_2D
500      !
501      !                       !==  tridiagonal solve  ==!
502      DO_2D_11_11
503         zwt(ji,jj,2) = zwd(ji,jj,2)
504      END_2D
505      DO_3D_11_11( 3, jpkm1 )
506         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
507      END_3D
508      !
509      DO_2D_11_11
510         pt_out(ji,jj,2) = zwrm(ji,jj,2)
511      END_2D
512      DO_3D_11_11( 3, jpkm1 )
513         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
514      END_3D
515
516      DO_2D_11_11
517         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
518      END_2D
519      DO_3DS_11_11( jpk-2, 2, -1 )
520         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
521      END_3D
522      !   
523   END SUBROUTINE interp_4th_cpt_org
524   
525
526   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
527      !!----------------------------------------------------------------------
528      !!                  ***  ROUTINE interp_4th_cpt  ***
529      !!
530      !! **  Purpose :   Compute the interpolation of tracer at w-point
531      !!
532      !! **  Method  :   4th order compact interpolation
533      !!----------------------------------------------------------------------
534      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
535      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
536      !
537      INTEGER ::   ji, jj, jk   ! dummy loop integers
538      INTEGER ::   ikt, ikb     ! local integers
539      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
540      !!----------------------------------------------------------------------
541      !
542      !                      !==  build the three diagonal matrix & the RHS  ==!
543      !
544      DO_3D_00_00( 3, jpkm1 )
545         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
546         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
547         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
548         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
549            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
550      END_3D
551      !
552!!gm
553!      SELECT CASE( kbc )               !* boundary condition
554!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
555!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
556!      END SELECT
557!!gm 
558      !
559      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
560         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
561      END IF
562      !
563      DO_2D_00_00
564         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
565         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
566         !
567         zwd (ji,jj,ikt) = 1._wp          ! top
568         zwi (ji,jj,ikt) = 0._wp
569         zws (ji,jj,ikt) = 0._wp
570         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
571         !
572         zwd (ji,jj,ikb) = 1._wp          ! bottom
573         zwi (ji,jj,ikb) = 0._wp
574         zws (ji,jj,ikb) = 0._wp
575         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
576      END_2D
577      !
578      !                       !==  tridiagonal solver  ==!
579      !
580      DO_2D_00_00
581         zwt(ji,jj,2) = zwd(ji,jj,2)
582      END_2D
583      DO_3D_00_00( 3, jpkm1 )
584         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
585      END_3D
586      !
587      DO_2D_00_00
588         pt_out(ji,jj,2) = zwrm(ji,jj,2)
589      END_2D
590      DO_3D_00_00( 3, jpkm1 )
591         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
592      END_3D
593
594      DO_2D_00_00
595         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
596      END_2D
597      DO_3DS_00_00( jpk-2, 2, -1 )
598         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
599      END_3D
600      !   
601   END SUBROUTINE interp_4th_cpt
602
603
604   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
605      !!----------------------------------------------------------------------
606      !!                  ***  ROUTINE tridia_solver  ***
607      !!
608      !! **  Purpose :   solve a symmetric 3diagonal system
609      !!
610      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
611      !!     
612      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
613      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
614      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
615      !!             (        ...          )( ... )   ( ...  )
616      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
617      !!     
618      !!        M is decomposed in the product of an upper and lower triangular matrix.
619      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
620      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
621      !!        The solution is pta.
622      !!        The 3d array zwt is used as a work space array.
623      !!----------------------------------------------------------------------
624      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
625      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
626      REAL(wp),DIMENSION(:,:,:), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
627      INTEGER                  , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
628      !                                                           ! =0 pt at t-level
629      INTEGER ::   ji, jj, jk   ! dummy loop integers
630      INTEGER ::   kstart       ! local indices
631      REAL(wp),DIMENSION(jpi,jpj,jpk) ::   zwt   ! 3D work array
632      !!----------------------------------------------------------------------
633      !
634      kstart =  1  + klev
635      !
636      DO_2D_00_00
637         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
638      END_2D
639      DO_3D_00_00( kstart+1, jpkm1 )
640         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
641      END_3D
642      !
643      DO_2D_00_00
644         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
645      END_2D
646      DO_3D_00_00( kstart+1, jpkm1 )
647         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
648      END_3D
649
650      DO_2D_00_00
651         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
652      END_2D
653      DO_3DS_00_00( jpk-2, kstart, -1 )
654         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
655      END_3D
656      !
657   END SUBROUTINE tridia_solver
658
659   !!======================================================================
660END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.