| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Off-line Ocean : passive tracer evolution, dynamics read in files |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line |
|---|
| 7 | !! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 8 | !! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface |
|---|
| 9 | !! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! nemo_gcm : off-line: solve ocean tracer only |
|---|
| 14 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
|---|
| 15 | !! nemo_init : initialization of the NEMO system |
|---|
| 16 | !! nemo_ctl : initialisation of the contol print |
|---|
| 17 | !! nemo_closefile: close remaining open files |
|---|
| 18 | !! nemo_alloc : dynamical allocation |
|---|
| 19 | !! istate_init : simple initialization to zero of ocean fields |
|---|
| 20 | !! stp_ctl : reduced step control (no dynamics in off-line) |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | USE dom_oce ! ocean space domain variables |
|---|
| 23 | USE oce ! dynamics and tracers variables |
|---|
| 24 | USE trc_oce ! Shared ocean/passive tracers variables |
|---|
| 25 | USE c1d ! 1D configuration |
|---|
| 26 | USE domain ! domain initialization from coordinate & bathymetry (dom_init routine) |
|---|
| 27 | USE closea ! treatment of closed seas (for ln_closea) |
|---|
| 28 | USE usrdef_nam ! user defined configuration |
|---|
| 29 | USE eosbn2 ! equation of state (eos bn2 routine) |
|---|
| 30 | #if defined key_qco |
|---|
| 31 | USE domqco ! tools for scale factor (dom_qco_r3c routine) |
|---|
| 32 | #endif |
|---|
| 33 | USE bdy_oce, ONLY : ln_bdy |
|---|
| 34 | USE bdyini ! open boundary cond. setting (bdy_init routine) |
|---|
| 35 | ! ! ocean physics |
|---|
| 36 | USE ldftra ! lateral diffusivity setting (ldf_tra_init routine) |
|---|
| 37 | USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine) |
|---|
| 38 | USE traqsr ! solar radiation penetration (tra_qsr_init routine) |
|---|
| 39 | USE trabbl ! bottom boundary layer (tra_bbl_init routine) |
|---|
| 40 | USE traldf ! lateral physics (tra_ldf_init routine) |
|---|
| 41 | USE sbcmod ! surface boundary condition (sbc_init routine) |
|---|
| 42 | USE phycst ! physical constant (par_cst routine) |
|---|
| 43 | USE dtadyn ! Lecture and Interpolation of the dynamical fields |
|---|
| 44 | USE trcini ! Initilization of the passive tracers |
|---|
| 45 | USE daymod ! calendar (day routine) |
|---|
| 46 | USE trcstp ! passive tracer time-stepping (trc_stp routine) |
|---|
| 47 | USE dtadyn ! Lecture and interpolation of the dynamical fields |
|---|
| 48 | ! ! Passive tracers needs |
|---|
| 49 | USE trc ! passive tracer : variables |
|---|
| 50 | USE trcnam ! passive tracer : namelist |
|---|
| 51 | USE trcrst ! passive tracer restart |
|---|
| 52 | USE diaptr ! Need to initialise this as some variables are used in if statements later |
|---|
| 53 | USE sbc_oce , ONLY : ln_rnf |
|---|
| 54 | USE sbcrnf ! surface boundary condition : runoffs |
|---|
| 55 | ! ! I/O & MPP |
|---|
| 56 | USE iom ! I/O library |
|---|
| 57 | USE in_out_manager ! I/O manager |
|---|
| 58 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 59 | USE lib_mpp ! distributed memory computing |
|---|
| 60 | #if defined key_iomput |
|---|
| 61 | USE xios ! xIOserver |
|---|
| 62 | #endif |
|---|
| 63 | USE prtctl ! Print control (prt_ctl_init routine) |
|---|
| 64 | USE timing ! Timing |
|---|
| 65 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 66 | USE lbcnfd , ONLY : isendto, nsndto ! Setup of north fold exchanges |
|---|
| 67 | USE step, ONLY : Nbb, Nnn, Naa, Nrhs ! time level indices |
|---|
| 68 | USE halo_mng |
|---|
| 69 | |
|---|
| 70 | IMPLICIT NONE |
|---|
| 71 | PRIVATE |
|---|
| 72 | |
|---|
| 73 | PUBLIC nemo_gcm ! called by nemo.F90 |
|---|
| 74 | |
|---|
| 75 | CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 76 | |
|---|
| 77 | !!---------------------------------------------------------------------- |
|---|
| 78 | !! NEMO/OFF 4.0 , NEMO Consortium (2018) |
|---|
| 79 | !! $Id$ |
|---|
| 80 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 81 | !!---------------------------------------------------------------------- |
|---|
| 82 | CONTAINS |
|---|
| 83 | |
|---|
| 84 | SUBROUTINE nemo_gcm |
|---|
| 85 | !!---------------------------------------------------------------------- |
|---|
| 86 | !! *** ROUTINE nemo_gcm *** |
|---|
| 87 | !! |
|---|
| 88 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
|---|
| 89 | !! curvilinear mesh on the sphere. |
|---|
| 90 | !! |
|---|
| 91 | !! ** Method : - model general initialization |
|---|
| 92 | !! - launch the time-stepping (dta_dyn and trc_stp) |
|---|
| 93 | !! - finalize the run by closing files and communications |
|---|
| 94 | !! |
|---|
| 95 | !! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL. |
|---|
| 96 | !! Madec, 2008, internal report, IPSL. |
|---|
| 97 | !!---------------------------------------------------------------------- |
|---|
| 98 | INTEGER :: istp ! time step index |
|---|
| 99 | !!---------------------------------------------------------------------- |
|---|
| 100 | |
|---|
| 101 | CALL nemo_init ! Initializations |
|---|
| 102 | |
|---|
| 103 | ! check that all process are still there... If some process have an error, |
|---|
| 104 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
|---|
| 105 | CALL mpp_max( 'nemogcm', nstop ) |
|---|
| 106 | |
|---|
| 107 | ! !-----------------------! |
|---|
| 108 | ! !== time stepping ==! |
|---|
| 109 | ! !-----------------------! |
|---|
| 110 | istp = nit000 |
|---|
| 111 | ! |
|---|
| 112 | IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization |
|---|
| 113 | ! |
|---|
| 114 | CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 115 | ! |
|---|
| 116 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==! |
|---|
| 117 | ! |
|---|
| 118 | IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 119 | CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp |
|---|
| 120 | #if defined key_sed_off |
|---|
| 121 | CALL dta_dyn_sed( istp, Nnn ) ! Interpolation of the dynamical fields |
|---|
| 122 | #else |
|---|
| 123 | CALL dta_dyn ( istp, Nbb, Nnn, Naa ) ! Interpolation of the dynamical fields |
|---|
| 124 | #endif |
|---|
| 125 | #if ! defined key_sed_off |
|---|
| 126 | IF( .NOT.ln_linssh ) THEN |
|---|
| 127 | CALL dta_dyn_atf( istp, Nbb, Nnn, Naa ) ! time filter of sea surface height and vertical scale factors |
|---|
| 128 | # if defined key_qco |
|---|
| 129 | CALL dom_qco_r3c( ssh(:,:,Kmm), r3t_f, r3u_f, r3v_f ) |
|---|
| 130 | # endif |
|---|
| 131 | ENDIF |
|---|
| 132 | CALL trc_stp ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping |
|---|
| 133 | # if defined key_qco |
|---|
| 134 | !r3t(:,:,Kmm) = r3t_f(:,:) ! update ssh to h0 ratio |
|---|
| 135 | !r3u(:,:,Kmm) = r3u_f(:,:) |
|---|
| 136 | !r3v(:,:,Kmm) = r3v_f(:,:) |
|---|
| 137 | # endif |
|---|
| 138 | #endif |
|---|
| 139 | ! Swap time levels |
|---|
| 140 | Nrhs = Nbb |
|---|
| 141 | Nbb = Nnn |
|---|
| 142 | Nnn = Naa |
|---|
| 143 | Naa = Nrhs |
|---|
| 144 | ! |
|---|
| 145 | #if ! defined key_qco |
|---|
| 146 | #if ! defined key_sed_off |
|---|
| 147 | IF( .NOT.ln_linssh ) CALL dta_dyn_sf_interp( istp, Nnn ) ! calculate now grid parameters |
|---|
| 148 | #endif |
|---|
| 149 | #endif |
|---|
| 150 | CALL stp_ctl ( istp ) ! Time loop: control and print |
|---|
| 151 | istp = istp + 1 |
|---|
| 152 | END DO |
|---|
| 153 | ! |
|---|
| 154 | #if defined key_iomput |
|---|
| 155 | CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF |
|---|
| 156 | #endif |
|---|
| 157 | |
|---|
| 158 | ! !------------------------! |
|---|
| 159 | ! !== finalize the run ==! |
|---|
| 160 | ! !------------------------! |
|---|
| 161 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 162 | |
|---|
| 163 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
|---|
| 164 | WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found' |
|---|
| 165 | WRITE(ctmp2,*) ' Look for "E R R O R" messages in all existing ocean_output* files' |
|---|
| 166 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 ) |
|---|
| 167 | ENDIF |
|---|
| 168 | ! |
|---|
| 169 | IF( ln_timing ) CALL timing_finalize |
|---|
| 170 | ! |
|---|
| 171 | CALL nemo_closefile |
|---|
| 172 | ! |
|---|
| 173 | #if defined key_iomput |
|---|
| 174 | CALL xios_finalize ! end mpp communications with xios |
|---|
| 175 | #else |
|---|
| 176 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
|---|
| 177 | #endif |
|---|
| 178 | ! |
|---|
| 179 | IF(lwm) THEN |
|---|
| 180 | IF( nstop == 0 ) THEN ; STOP 0 |
|---|
| 181 | ELSE ; STOP 123 |
|---|
| 182 | ENDIF |
|---|
| 183 | ENDIF |
|---|
| 184 | ! |
|---|
| 185 | END SUBROUTINE nemo_gcm |
|---|
| 186 | |
|---|
| 187 | |
|---|
| 188 | SUBROUTINE nemo_init |
|---|
| 189 | !!---------------------------------------------------------------------- |
|---|
| 190 | !! *** ROUTINE nemo_init *** |
|---|
| 191 | !! |
|---|
| 192 | !! ** Purpose : initialization of the nemo model in off-line mode |
|---|
| 193 | !!---------------------------------------------------------------------- |
|---|
| 194 | INTEGER :: ios, ilocal_comm ! local integers |
|---|
| 195 | !! |
|---|
| 196 | NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl, & |
|---|
| 197 | & nn_isplt, nn_jsplt, nn_ictls, nn_ictle, nn_jctls, nn_jctle |
|---|
| 198 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
|---|
| 199 | !!---------------------------------------------------------------------- |
|---|
| 200 | ! |
|---|
| 201 | cxios_context = 'nemo' |
|---|
| 202 | nn_hls = 1 |
|---|
| 203 | ! |
|---|
| 204 | ! !-------------------------------------------------! |
|---|
| 205 | ! ! set communicator & select the local rank ! |
|---|
| 206 | ! ! must be done as soon as possible to get narea ! |
|---|
| 207 | ! !-------------------------------------------------! |
|---|
| 208 | ! |
|---|
| 209 | #if defined key_iomput |
|---|
| 210 | CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios |
|---|
| 211 | CALL mpp_start( ilocal_comm ) |
|---|
| 212 | #else |
|---|
| 213 | CALL mpp_start( ) |
|---|
| 214 | #endif |
|---|
| 215 | ! |
|---|
| 216 | narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 ) |
|---|
| 217 | lwm = (narea == 1) ! control of output namelists |
|---|
| 218 | ! |
|---|
| 219 | ! !---------------------------------------------------------------! |
|---|
| 220 | ! ! Open output files, reference and configuration namelist files ! |
|---|
| 221 | ! !---------------------------------------------------------------! |
|---|
| 222 | ! |
|---|
| 223 | ! open ocean.output as soon as possible to get all output prints (including errors messages) |
|---|
| 224 | IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 225 | ! open reference and configuration namelist files |
|---|
| 226 | CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm ) |
|---|
| 227 | CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm ) |
|---|
| 228 | IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 229 | ! open /dev/null file to be able to supress output write easily |
|---|
| 230 | IF( Agrif_Root() ) THEN |
|---|
| 231 | CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 232 | #ifdef key_agrif |
|---|
| 233 | ELSE |
|---|
| 234 | numnul = Agrif_Parent(numnul) |
|---|
| 235 | #endif |
|---|
| 236 | ENDIF |
|---|
| 237 | ! |
|---|
| 238 | ! !--------------------! |
|---|
| 239 | ! ! Open listing units ! -> need sn_cfctl from namctl to define lwp |
|---|
| 240 | ! !--------------------! |
|---|
| 241 | ! |
|---|
| 242 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
|---|
| 243 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' ) |
|---|
| 244 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
|---|
| 245 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' ) |
|---|
| 246 | ! |
|---|
| 247 | ! finalize the definition of namctl variables |
|---|
| 248 | IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) & |
|---|
| 249 | & CALL nemo_set_cfctl( sn_cfctl, .FALSE. ) |
|---|
| 250 | ! |
|---|
| 251 | lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print |
|---|
| 252 | ! |
|---|
| 253 | IF(lwp) THEN ! open listing units |
|---|
| 254 | ! |
|---|
| 255 | IF( .NOT. lwm ) & ! alreay opened for narea == 1 |
|---|
| 256 | & CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea ) |
|---|
| 257 | ! |
|---|
| 258 | WRITE(numout,*) |
|---|
| 259 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC' |
|---|
| 260 | WRITE(numout,*) ' NEMO team' |
|---|
| 261 | WRITE(numout,*) ' Off-line TOP Model' |
|---|
| 262 | WRITE(numout,*) ' NEMO version 4.0 (2019) ' |
|---|
| 263 | WRITE(numout,*) |
|---|
| 264 | WRITE(numout,*) " ._ ._ ._ ._ ._ " |
|---|
| 265 | WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ " |
|---|
| 266 | WRITE(numout,*) |
|---|
| 267 | WRITE(numout,*) " o _, _, " |
|---|
| 268 | WRITE(numout,*) " o .' ( .-' / " |
|---|
| 269 | WRITE(numout,*) " o _/..._'. .' / " |
|---|
| 270 | WRITE(numout,*) " ( o .-'` ` '-./ _.' " |
|---|
| 271 | WRITE(numout,*) " ) ( o) ;= <_ ( " |
|---|
| 272 | WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) " |
|---|
| 273 | WRITE(numout,*) " ) ) \) |`\ \) '. \ ( ( " |
|---|
| 274 | WRITE(numout,*) " ( ( \_/ '-._\ ) ) " |
|---|
| 275 | WRITE(numout,*) " ) ) ` ( ( " |
|---|
| 276 | WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ " |
|---|
| 277 | WRITE(numout,*) |
|---|
| 278 | ! |
|---|
| 279 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 280 | ! |
|---|
| 281 | ENDIF |
|---|
| 282 | ! |
|---|
| 283 | IF(lwm) WRITE( numond, namctl ) |
|---|
| 284 | ! |
|---|
| 285 | ! !------------------------------------! |
|---|
| 286 | ! ! Set global domain size parameters ! |
|---|
| 287 | ! !------------------------------------! |
|---|
| 288 | ! |
|---|
| 289 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
|---|
| 290 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' ) |
|---|
| 291 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
|---|
| 292 | 904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' ) |
|---|
| 293 | ! |
|---|
| 294 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
|---|
| 295 | CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio ) |
|---|
| 296 | ELSE ! user-defined namelist |
|---|
| 297 | CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio ) |
|---|
| 298 | ENDIF |
|---|
| 299 | ! |
|---|
| 300 | IF(lwm) WRITE( numond, namcfg ) |
|---|
| 301 | l_offline = .true. ! passive tracers are run offline |
|---|
| 302 | ! |
|---|
| 303 | ! !-----------------------------------------! |
|---|
| 304 | ! ! mpp parameters and domain decomposition ! |
|---|
| 305 | ! !-----------------------------------------! |
|---|
| 306 | ! |
|---|
| 307 | CALL mpp_init |
|---|
| 308 | |
|---|
| 309 | CALL halo_mng_init() |
|---|
| 310 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
|---|
| 311 | CALL nemo_alloc() |
|---|
| 312 | |
|---|
| 313 | ! Initialise time level indices |
|---|
| 314 | Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa |
|---|
| 315 | |
|---|
| 316 | ! !-------------------------------! |
|---|
| 317 | ! ! NEMO general initialization ! |
|---|
| 318 | ! !-------------------------------! |
|---|
| 319 | |
|---|
| 320 | CALL nemo_ctl ! Control prints |
|---|
| 321 | ! |
|---|
| 322 | ! ! General initialization |
|---|
| 323 | IF( ln_timing ) CALL timing_init |
|---|
| 324 | IF( ln_timing ) CALL timing_start( 'nemo_init') |
|---|
| 325 | ! |
|---|
| 326 | CALL phy_cst ! Physical constants |
|---|
| 327 | CALL eos_init ! Equation of state |
|---|
| 328 | IF( lk_c1d ) CALL c1d_init ! 1D column configuration |
|---|
| 329 | CALL dom_init( Nbb, Nnn, Naa, "OPA") ! Domain |
|---|
| 330 | IF( sn_cfctl%l_prtctl ) & |
|---|
| 331 | & CALL prt_ctl_init ! Print control |
|---|
| 332 | |
|---|
| 333 | CALL istate_init( Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 334 | |
|---|
| 335 | CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module |
|---|
| 336 | CALL bdy_init ! Open boundaries initialisation |
|---|
| 337 | |
|---|
| 338 | ! ! Tracer physics |
|---|
| 339 | CALL ldf_tra_init ! Lateral ocean tracer physics |
|---|
| 340 | CALL ldf_eiv_init ! Eddy induced velocity param |
|---|
| 341 | CALL tra_ldf_init ! lateral mixing |
|---|
| 342 | IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
|---|
| 343 | IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation |
|---|
| 344 | IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 345 | |
|---|
| 346 | ! ! Passive tracers |
|---|
| 347 | CALL trc_nam_run ! Needed to get restart parameters for passive tracers |
|---|
| 348 | CALL trc_rst_cal( nit000, 'READ' ) ! calendar |
|---|
| 349 | #if defined key_sed_off |
|---|
| 350 | CALL dta_dyn_sed_init( Nnn ) ! Initialization for the dynamics |
|---|
| 351 | #else |
|---|
| 352 | CALL dta_dyn_init( Nbb, Nnn, Naa ) ! Initialization for the dynamics |
|---|
| 353 | #endif |
|---|
| 354 | |
|---|
| 355 | CALL trc_init( Nbb, Nnn, Naa ) ! Passive tracers initialization |
|---|
| 356 | CALL dia_ptr_init ! Poleward TRansports initialization |
|---|
| 357 | |
|---|
| 358 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 359 | ! |
|---|
| 360 | IF( ln_timing ) CALL timing_stop( 'nemo_init') |
|---|
| 361 | ! |
|---|
| 362 | END SUBROUTINE nemo_init |
|---|
| 363 | |
|---|
| 364 | |
|---|
| 365 | SUBROUTINE nemo_ctl |
|---|
| 366 | !!---------------------------------------------------------------------- |
|---|
| 367 | !! *** ROUTINE nemo_ctl *** |
|---|
| 368 | !! |
|---|
| 369 | !! ** Purpose : control print setting |
|---|
| 370 | !! |
|---|
| 371 | !! ** Method : - print namctl and namcfg information and check some consistencies |
|---|
| 372 | !!---------------------------------------------------------------------- |
|---|
| 373 | ! |
|---|
| 374 | IF(lwp) THEN ! control print |
|---|
| 375 | WRITE(numout,*) |
|---|
| 376 | WRITE(numout,*) 'nemo_ctl: Control prints' |
|---|
| 377 | WRITE(numout,*) '~~~~~~~~' |
|---|
| 378 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 379 | WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat |
|---|
| 380 | WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat |
|---|
| 381 | WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout |
|---|
| 382 | WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout |
|---|
| 383 | WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl |
|---|
| 384 | WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc |
|---|
| 385 | WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout |
|---|
| 386 | WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin |
|---|
| 387 | WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax |
|---|
| 388 | WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr |
|---|
| 389 | WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr |
|---|
| 390 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
|---|
| 391 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
|---|
| 392 | ENDIF |
|---|
| 393 | |
|---|
| 394 | IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file |
|---|
| 395 | IF(lwp) THEN ! control print |
|---|
| 396 | WRITE(numout,*) |
|---|
| 397 | WRITE(numout,*) ' Namelist namcfg' |
|---|
| 398 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
|---|
| 399 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
|---|
| 400 | WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea |
|---|
| 401 | WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg |
|---|
| 402 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
|---|
| 403 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
|---|
| 404 | ENDIF |
|---|
| 405 | ! |
|---|
| 406 | IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', & |
|---|
| 407 | & 'Compile with key_nosignedzero enabled' ) |
|---|
| 408 | ! |
|---|
| 409 | END SUBROUTINE nemo_ctl |
|---|
| 410 | |
|---|
| 411 | |
|---|
| 412 | SUBROUTINE nemo_closefile |
|---|
| 413 | !!---------------------------------------------------------------------- |
|---|
| 414 | !! *** ROUTINE nemo_closefile *** |
|---|
| 415 | !! |
|---|
| 416 | !! ** Purpose : Close the files |
|---|
| 417 | !!---------------------------------------------------------------------- |
|---|
| 418 | ! |
|---|
| 419 | IF( lk_mpp ) CALL mppsync |
|---|
| 420 | ! |
|---|
| 421 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 422 | ! |
|---|
| 423 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 424 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
|---|
| 425 | ! |
|---|
| 426 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 427 | ! |
|---|
| 428 | END SUBROUTINE nemo_closefile |
|---|
| 429 | |
|---|
| 430 | |
|---|
| 431 | SUBROUTINE nemo_alloc |
|---|
| 432 | !!---------------------------------------------------------------------- |
|---|
| 433 | !! *** ROUTINE nemo_alloc *** |
|---|
| 434 | !! |
|---|
| 435 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
|---|
| 436 | !! |
|---|
| 437 | !! ** Method : |
|---|
| 438 | !!---------------------------------------------------------------------- |
|---|
| 439 | USE diawri , ONLY : dia_wri_alloc |
|---|
| 440 | USE dom_oce, ONLY : dom_oce_alloc |
|---|
| 441 | USE zdf_oce, ONLY : zdf_oce_alloc |
|---|
| 442 | USE trc_oce, ONLY : trc_oce_alloc |
|---|
| 443 | USE bdy_oce, ONLY : bdy_oce_alloc |
|---|
| 444 | ! |
|---|
| 445 | INTEGER :: ierr |
|---|
| 446 | !!---------------------------------------------------------------------- |
|---|
| 447 | ! |
|---|
| 448 | ierr = oce_alloc () ! ocean |
|---|
| 449 | ierr = ierr + dia_wri_alloc() |
|---|
| 450 | ierr = ierr + dom_oce_alloc() ! ocean domain |
|---|
| 451 | ierr = ierr + zdf_oce_alloc() ! ocean vertical physics |
|---|
| 452 | ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays |
|---|
| 453 | ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization) |
|---|
| 454 | ! |
|---|
| 455 | CALL mpp_sum( 'nemogcm', ierr ) |
|---|
| 456 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
|---|
| 457 | ! |
|---|
| 458 | END SUBROUTINE nemo_alloc |
|---|
| 459 | |
|---|
| 460 | SUBROUTINE nemo_set_cfctl(sn_cfctl, setto ) |
|---|
| 461 | !!---------------------------------------------------------------------- |
|---|
| 462 | !! *** ROUTINE nemo_set_cfctl *** |
|---|
| 463 | !! |
|---|
| 464 | !! ** Purpose : Set elements of the output control structure to setto. |
|---|
| 465 | !! |
|---|
| 466 | !! ** Method : Note this routine can be used to switch on/off some |
|---|
| 467 | !! types of output for selected areas. |
|---|
| 468 | !!---------------------------------------------------------------------- |
|---|
| 469 | TYPE(sn_ctl), INTENT(inout) :: sn_cfctl |
|---|
| 470 | LOGICAL , INTENT(in ) :: setto |
|---|
| 471 | !!---------------------------------------------------------------------- |
|---|
| 472 | sn_cfctl%l_runstat = setto |
|---|
| 473 | sn_cfctl%l_trcstat = setto |
|---|
| 474 | sn_cfctl%l_oceout = setto |
|---|
| 475 | sn_cfctl%l_layout = setto |
|---|
| 476 | sn_cfctl%l_prtctl = setto |
|---|
| 477 | sn_cfctl%l_prttrc = setto |
|---|
| 478 | sn_cfctl%l_oasout = setto |
|---|
| 479 | END SUBROUTINE nemo_set_cfctl |
|---|
| 480 | |
|---|
| 481 | SUBROUTINE istate_init( Kmm, Kaa ) |
|---|
| 482 | !!---------------------------------------------------------------------- |
|---|
| 483 | !! *** ROUTINE istate_init *** |
|---|
| 484 | !! |
|---|
| 485 | !! ** Purpose : Initialization to zero of the dynamics and tracers. |
|---|
| 486 | !!---------------------------------------------------------------------- |
|---|
| 487 | INTEGER, INTENT(in) :: Kmm, Kaa ! ocean time level indices |
|---|
| 488 | ! |
|---|
| 489 | ! now fields ! after fields ! |
|---|
| 490 | uu (:,:,:,Kmm) = 0._wp ; uu(:,:,:,Kaa) = 0._wp ! |
|---|
| 491 | vv (:,:,:,Kmm) = 0._wp ; vv(:,:,:,Kaa) = 0._wp ! |
|---|
| 492 | ww (:,:,:) = 0._wp ! ! |
|---|
| 493 | hdiv (:,:,:) = 0._wp ! ! |
|---|
| 494 | ts (:,:,:,:,Kmm) = 0._wp ! ! |
|---|
| 495 | ! |
|---|
| 496 | rhd (:,:,:) = 0.e0 |
|---|
| 497 | rhop (:,:,:) = 0.e0 |
|---|
| 498 | rn2 (:,:,:) = 0.e0 |
|---|
| 499 | ! |
|---|
| 500 | END SUBROUTINE istate_init |
|---|
| 501 | |
|---|
| 502 | |
|---|
| 503 | SUBROUTINE stp_ctl( kt ) |
|---|
| 504 | !!---------------------------------------------------------------------- |
|---|
| 505 | !! *** ROUTINE stp_ctl *** |
|---|
| 506 | !! |
|---|
| 507 | !! ** Purpose : Control the run |
|---|
| 508 | !! |
|---|
| 509 | !! ** Method : - Save the time step in numstp |
|---|
| 510 | !! |
|---|
| 511 | !! ** Actions : 'time.step' file containing the last ocean time-step |
|---|
| 512 | !!---------------------------------------------------------------------- |
|---|
| 513 | INTEGER, INTENT(in ) :: kt ! ocean time-step index |
|---|
| 514 | !!---------------------------------------------------------------------- |
|---|
| 515 | ! |
|---|
| 516 | IF( kt == nit000 .AND. lwm ) THEN |
|---|
| 517 | WRITE(numout,*) |
|---|
| 518 | WRITE(numout,*) 'stp_ctl : time-stepping control' |
|---|
| 519 | WRITE(numout,*) '~~~~~~~' |
|---|
| 520 | ! open time.step file |
|---|
| 521 | CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea ) |
|---|
| 522 | ENDIF |
|---|
| 523 | ! |
|---|
| 524 | IF(lwm) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp |
|---|
| 525 | IF(lwm) REWIND( numstp ) ! -------------------------- |
|---|
| 526 | ! |
|---|
| 527 | END SUBROUTINE stp_ctl |
|---|
| 528 | !!====================================================================== |
|---|
| 529 | END MODULE nemogcm |
|---|
