New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/DYN – NEMO

source: NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/DYN/dynhpg.F90 @ 13630

Last change on this file since 13630 was 13630, checked in by mocavero, 4 years ago

Add neighborhood collectives calls in the NEMO src - ticket #2496
  • Property svn:keywords set to Id
File size: 70.2 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE isf_oce , ONLY : risfload  ! ice shelf  (risfload variable)
34   USE isfload , ONLY : isf_load  ! ice shelf  (isf_load routine )
35   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
36   USE dom_oce         ! ocean space and time domain
37   USE wet_dry         ! wetting and drying
38   USE phycst          ! physical constants
39   USE trd_oce         ! trends: ocean variables
40   USE trddyn          ! trend manager: dynamics
41   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE prtctl          ! Print control
45   USE lbclnk          ! lateral boundary condition
46   USE lib_mpp         ! MPP library
47   USE eosbn2          ! compute density
48   USE timing          ! Timing
49   USE iom
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   dyn_hpg        ! routine called by step module
55   PUBLIC   dyn_hpg_init   ! routine called by opa module
56
57   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
58   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
59   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
60   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
61   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
62   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
63   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
64
65   !                                !! Flag to control the type of hydrostatic pressure gradient
66   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
67   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
68   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
69   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
70   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
71   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
72   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
73   !
74   INTEGER, PUBLIC ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
75
76   !! * Substitutions
77#  include "do_loop_substitute.h90"
78#  include "domzgr_substitute.h90"
79
80   !!----------------------------------------------------------------------
81   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
82   !! $Id$
83   !! Software governed by the CeCILL license (see ./LICENSE)
84   !!----------------------------------------------------------------------
85CONTAINS
86
87   SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
88      !!---------------------------------------------------------------------
89      !!                  ***  ROUTINE dyn_hpg  ***
90      !!
91      !! ** Method  :   Call the hydrostatic pressure gradient routine
92      !!              using the scheme defined in the namelist
93      !!
94      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
95      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
96      !!----------------------------------------------------------------------
97      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
98      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
99      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
100      !
101      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
102      !!----------------------------------------------------------------------
103      !
104      IF( ln_timing )   CALL timing_start('dyn_hpg')
105      !
106      IF( l_trddyn ) THEN                    ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
107         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
108         ztrdu(:,:,:) = puu(:,:,:,Krhs)
109         ztrdv(:,:,:) = pvv(:,:,:,Krhs)
110      ENDIF
111      !
112      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
113      CASE ( np_zco )   ;   CALL hpg_zco    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate
114      CASE ( np_zps )   ;   CALL hpg_zps    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate plus partial steps (interpolation)
115      CASE ( np_sco )   ;   CALL hpg_sco    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (standard jacobian formulation)
116      CASE ( np_djc )   ;   CALL hpg_djc    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Density Jacobian with Cubic polynomial)
117      CASE ( np_prj )   ;   CALL hpg_prj    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Pressure Jacobian scheme)
118      CASE ( np_isf )   ;   CALL hpg_isf    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate similar to sco modify for ice shelf
119      END SELECT
120      !
121      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
122         ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
123         ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
124         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
125         DEALLOCATE( ztrdu , ztrdv )
126      ENDIF
127      !
128      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' hpg  - Ua: ', mask1=umask,   &
129         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
130      !
131      IF( ln_timing )   CALL timing_stop('dyn_hpg')
132      !
133   END SUBROUTINE dyn_hpg
134
135
136   SUBROUTINE dyn_hpg_init( Kmm )
137      !!----------------------------------------------------------------------
138      !!                 ***  ROUTINE dyn_hpg_init  ***
139      !!
140      !! ** Purpose :   initializations for the hydrostatic pressure gradient
141      !!              computation and consistency control
142      !!
143      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
144      !!      with the type of vertical coordinate used (zco, zps, sco)
145      !!----------------------------------------------------------------------
146      INTEGER, INTENT( in ) :: Kmm   ! ocean time level index
147      !
148      INTEGER ::   ioptio = 0      ! temporary integer
149      INTEGER ::   ios             ! Local integer output status for namelist read
150      !!
151      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
152      REAL(wp) ::   znad
153      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
154      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
155      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
156      !!
157      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
158         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
159      !!----------------------------------------------------------------------
160      !
161      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
162901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
163      !
164      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
165902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
166      IF(lwm) WRITE ( numond, namdyn_hpg )
167      !
168      IF(lwp) THEN                   ! Control print
169         WRITE(numout,*)
170         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
171         WRITE(numout,*) '~~~~~~~~~~~~'
172         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
173         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
174         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
175         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
176         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
177         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
178         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
179      ENDIF
180      !
181      IF( ln_hpg_djc )   &
182         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method',   &
183         &                 '   currently disabled (bugs under investigation).'        ,   &
184         &                 '   Please select either  ln_hpg_sco or  ln_hpg_prj instead' )
185         !
186      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )          &
187         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ',   &
188         &                 '   the standard jacobian formulation hpg_sco    or '    ,   &
189         &                 '   the pressure jacobian formulation hpg_prj'             )
190         !
191      IF( ln_hpg_isf ) THEN
192         IF( .NOT. ln_isfcav )   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
193       ELSE
194         IF(       ln_isfcav )   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
195      ENDIF
196      !
197      !                               ! Set nhpg from ln_hpg_... flags & consistency check
198      nhpg   = np_ERROR
199      ioptio = 0
200      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
201      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
202      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
203      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
204      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
205      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
206      !
207      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
208      !
209      IF(lwp) THEN
210         WRITE(numout,*)
211         SELECT CASE( nhpg )
212         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
213         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
214         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
215         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
216         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
217         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
218         END SELECT
219         WRITE(numout,*)
220      ENDIF
221      !                         
222   END SUBROUTINE dyn_hpg_init
223
224
225   SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
226      !!---------------------------------------------------------------------
227      !!                  ***  ROUTINE hpg_zco  ***
228      !!
229      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
230      !!      The now hydrostatic pressure gradient at a given level, jk,
231      !!      is computed by taking the vertical integral of the in-situ
232      !!      density gradient along the model level from the suface to that
233      !!      level:    zhpi = grav .....
234      !!                zhpj = grav .....
235      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
236      !!            puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
237      !!            pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
238      !!
239      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
240      !!----------------------------------------------------------------------
241      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
242      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
243      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
244      !
245      INTEGER  ::   ji, jj, jk       ! dummy loop indices
246      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
247      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
248      !!----------------------------------------------------------------------
249      !
250      IF( kt == nit000 ) THEN
251         IF(lwp) WRITE(numout,*)
252         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
253         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
254      ENDIF
255
256      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
257
258      ! Surface value
259      DO_2D( 0, 0, 0, 0 )
260         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
261         ! hydrostatic pressure gradient
262         zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
263         zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
264         ! add to the general momentum trend
265         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
266         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
267      END_2D
268
269      !
270      ! interior value (2=<jk=<jpkm1)
271      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
272         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
273         ! hydrostatic pressure gradient
274         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
275            &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
276            &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
277
278         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
279            &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
280            &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
281         ! add to the general momentum trend
282         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
283         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
284      END_3D
285      !
286   END SUBROUTINE hpg_zco
287
288
289   SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
290      !!---------------------------------------------------------------------
291      !!                 ***  ROUTINE hpg_zps  ***
292      !!
293      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
294      !!
295      !! ** Action  : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
296      !!----------------------------------------------------------------------
297      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
298      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
299      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
300      !!
301      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
302      INTEGER  ::   iku, ikv                         ! temporary integers
303      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
304      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
305      REAL(wp), DIMENSION(jpi,jpj) :: zgtsu, zgtsv, zgru, zgrv
306      !!----------------------------------------------------------------------
307      !
308      IF( kt == nit000 ) THEN
309         IF(lwp) WRITE(numout,*)
310         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
311         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
312      ENDIF
313
314      ! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
315      CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
316
317      ! Local constant initialization
318      zcoef0 = - grav * 0.5_wp
319
320      !  Surface value (also valid in partial step case)
321      DO_2D( 0, 0, 0, 0 )
322         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
323         ! hydrostatic pressure gradient
324         zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
325         zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
326         ! add to the general momentum trend
327         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
328         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
329      END_2D
330
331      ! interior value (2=<jk=<jpkm1)
332      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
333         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
334         ! hydrostatic pressure gradient
335         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
336            &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
337            &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
338
339         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
340            &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
341            &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
342         ! add to the general momentum trend
343         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
344         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
345      END_3D
346
347      ! partial steps correction at the last level  (use zgru & zgrv computed in zpshde.F90)
348      DO_2D( 0, 0, 0, 0 )
349         iku = mbku(ji,jj)
350         ikv = mbkv(ji,jj)
351         zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj  ,iku,Kmm) )
352         zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji  ,jj+1,ikv,Kmm) )
353         IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
354            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku)         ! subtract old value
355            zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
356               &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
357            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
358         ENDIF
359         IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
360            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv)         ! subtract old value
361            zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
362               &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
363            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
364         ENDIF
365      END_2D
366      !
367   END SUBROUTINE hpg_zps
368
369
370   SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
371      !!---------------------------------------------------------------------
372      !!                  ***  ROUTINE hpg_sco  ***
373      !!
374      !! ** Method  :   s-coordinate case. Jacobian scheme.
375      !!      The now hydrostatic pressure gradient at a given level, jk,
376      !!      is computed by taking the vertical integral of the in-situ
377      !!      density gradient along the model level from the suface to that
378      !!      level. s-coordinates (ln_sco): a corrective term is added
379      !!      to the horizontal pressure gradient :
380      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
381      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
382      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
383      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
384      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
385      !!
386      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
387      !!----------------------------------------------------------------------
388      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
389      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
390      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
391      !!
392      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
393      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
394      LOGICAL  ::   ll_tmp1, ll_tmp2                     ! local logical variables
395      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
396      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
397      !!----------------------------------------------------------------------
398      !
399      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
400      !
401      IF( kt == nit000 ) THEN
402         IF(lwp) WRITE(numout,*)
403         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
404         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
405      ENDIF
406      !
407      zcoef0 = - grav * 0.5_wp
408      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
409      ELSE                    ;   znad = 1._wp         ! Variable volume: density
410      ENDIF
411      !
412      IF( ln_wd_il ) THEN
413        DO_2D( 0, 0, 0, 0 )
414          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)               ,  ssh(ji+1,jj,Kmm) ) >                &
415               &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
416               &    MAX(  ssh(ji,jj,Kmm) +  ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
417               &                                                       > rn_wdmin1 + rn_wdmin2
418          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)              -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (       &
419               &    MAX(   ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
420               &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
421
422          IF(ll_tmp1) THEN
423            zcpx(ji,jj) = 1.0_wp
424          ELSE IF(ll_tmp2) THEN
425            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
426            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
427                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
428          ELSE
429            zcpx(ji,jj) = 0._wp
430          END IF
431   
432          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
433               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
434               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
435               &                                                      > rn_wdmin1 + rn_wdmin2
436          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
437               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
438               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
439
440          IF(ll_tmp1) THEN
441            zcpy(ji,jj) = 1.0_wp
442          ELSE IF(ll_tmp2) THEN
443            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
444            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
445                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
446          ELSE
447            zcpy(ji,jj) = 0._wp
448          END IF
449        END_2D
450#if defined key_mpi3
451        CALL lbc_lnk_nc_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
452#else
453        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
454#endif
455      END IF
456
457      ! Surface value
458      DO_2D( 0, 0, 0, 0 )
459         ! hydrostatic pressure gradient along s-surfaces
460         zhpi(ji,jj,1) =   &
461            &  zcoef0 * (  e3w(ji+1,jj  ,1,Kmm) * ( znad + rhd(ji+1,jj  ,1) )    &
462            &            - e3w(ji  ,jj  ,1,Kmm) * ( znad + rhd(ji  ,jj  ,1) )  ) &
463            &           * r1_e1u(ji,jj)
464         zhpj(ji,jj,1) =   &
465            &  zcoef0 * (  e3w(ji  ,jj+1,1,Kmm) * ( znad + rhd(ji  ,jj+1,1) )    &
466            &            - e3w(ji  ,jj  ,1,Kmm) * ( znad + rhd(ji  ,jj  ,1) )  ) &
467            &           * r1_e2v(ji,jj)
468         ! s-coordinate pressure gradient correction
469         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
470            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
471         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
472            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
473         !
474         IF( ln_wd_il ) THEN
475            zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
476            zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
477            zuap = zuap * zcpx(ji,jj)
478            zvap = zvap * zcpy(ji,jj)
479         ENDIF
480         !
481         ! add to the general momentum trend
482         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
483         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
484      END_2D
485
486      ! interior value (2=<jk=<jpkm1)
487      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
488         ! hydrostatic pressure gradient along s-surfaces
489         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
490            &           * (  e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
491            &              - e3w(ji  ,jj,jk,Kmm) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
492         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
493            &           * (  e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
494            &              - e3w(ji,jj  ,jk,Kmm) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
495         ! s-coordinate pressure gradient correction
496         zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
497            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
498         zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
499            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
500         !
501         IF( ln_wd_il ) THEN
502            zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
503            zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
504            zuap = zuap * zcpx(ji,jj)
505            zvap = zvap * zcpy(ji,jj)
506         ENDIF
507         !
508         ! add to the general momentum trend
509         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
510         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
511      END_3D
512      !
513      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
514      !
515   END SUBROUTINE hpg_sco
516
517
518   SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
519      !!---------------------------------------------------------------------
520      !!                  ***  ROUTINE hpg_isf  ***
521      !!
522      !! ** Method  :   s-coordinate case. Jacobian scheme.
523      !!      The now hydrostatic pressure gradient at a given level, jk,
524      !!      is computed by taking the vertical integral of the in-situ
525      !!      density gradient along the model level from the suface to that
526      !!      level. s-coordinates (ln_sco): a corrective term is added
527      !!      to the horizontal pressure gradient :
528      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
529      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
530      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
531      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
532      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
533      !!      iceload is added
534      !!     
535      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
536      !!----------------------------------------------------------------------
537      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
538      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
539      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
540      !!
541      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
542      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
543      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
544      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
545      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
546      !!----------------------------------------------------------------------
547      !
548      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
549      !
550      znad=1._wp                 ! To use density and not density anomaly
551      !
552      !                          ! iniitialised to 0. zhpi zhpi
553      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
554
555      ! compute rhd at the ice/oce interface (ocean side)
556      ! usefull to reduce residual current in the test case ISOMIP with no melting
557      DO ji = 1, jpi
558        DO jj = 1, jpj
559          ikt = mikt(ji,jj)
560          zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
561          zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
562        END DO
563      END DO
564      CALL eos( zts_top, risfdep, zrhdtop_oce )
565
566!==================================================================================     
567!===== Compute surface value =====================================================
568!==================================================================================
569      DO_2D( 0, 0, 0, 0 )
570         ikt    = mikt(ji,jj)
571         iktp1i = mikt(ji+1,jj)
572         iktp1j = mikt(ji,jj+1)
573         ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
574         ! we assume ISF is in isostatic equilibrium
575         zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w(ji+1,jj,iktp1i,Kmm)                                    &
576            &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
577            &                                  - 0.5_wp * e3w(ji,jj,ikt,Kmm)                                         &
578            &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
579            &                                  + ( risfload(ji+1,jj) - risfload(ji,jj))                            ) 
580         zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w(ji,jj+1,iktp1j,Kmm)                                    &
581            &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
582            &                                  - 0.5_wp * e3w(ji,jj,ikt,Kmm)                                         & 
583            &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
584            &                                  + ( risfload(ji,jj+1) - risfload(ji,jj))                            ) 
585         ! s-coordinate pressure gradient correction (=0 if z coordinate)
586         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
587            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
588         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
589            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
590         ! add to the general momentum trend
591         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
592         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
593      END_2D
594!==================================================================================     
595!===== Compute interior value =====================================================
596!==================================================================================
597      ! interior value (2=<jk=<jpkm1)
598      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
599         ! hydrostatic pressure gradient along s-surfaces
600         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
601            &           * (  e3w(ji+1,jj,jk,Kmm)                   &
602            &                  * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
603            &              - e3w(ji  ,jj,jk,Kmm)                   &
604            &                  * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
605         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
606            &           * (  e3w(ji,jj+1,jk,Kmm)                   &
607            &                  * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
608            &              - e3w(ji,jj  ,jk,Kmm)                   &
609            &                  * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
610         ! s-coordinate pressure gradient correction
611         zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
612            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
613         zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
614            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
615         ! add to the general momentum trend
616         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
617         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
618      END_3D
619      !
620   END SUBROUTINE hpg_isf
621
622
623   SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
624      !!---------------------------------------------------------------------
625      !!                  ***  ROUTINE hpg_djc  ***
626      !!
627      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
628      !!
629      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
630      !!----------------------------------------------------------------------
631      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
632      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
633      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
634      !!
635      INTEGER  ::   ji, jj, jk          ! dummy loop indices
636      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
637      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
638      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
639      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
640      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
641      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   dzx, dzy, dzz, dzu, dzv, dzw
642      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, drhoy, drhoz, drhou, drhov, drhow
643      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   rho_i, rho_j, rho_k
644      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
645      !!----------------------------------------------------------------------
646      !
647      IF( ln_wd_il ) THEN
648         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
649        DO_2D( 0, 0, 0, 0 )
650          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
651               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
652               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
653               &                                                      > rn_wdmin1 + rn_wdmin2
654          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (        &
655               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
656               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
657          IF(ll_tmp1) THEN
658            zcpx(ji,jj) = 1.0_wp
659          ELSE IF(ll_tmp2) THEN
660            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
661            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
662                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
663          ELSE
664            zcpx(ji,jj) = 0._wp
665          END IF
666   
667          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
668               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
669               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
670               &                                                      > rn_wdmin1 + rn_wdmin2
671          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
672               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
673               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
674
675          IF(ll_tmp1) THEN
676            zcpy(ji,jj) = 1.0_wp
677          ELSE IF(ll_tmp2) THEN
678            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
679            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
680                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
681          ELSE
682            zcpy(ji,jj) = 0._wp
683          END IF
684        END_2D
685#if defined key_mpi3
686        CALL lbc_lnk_nc_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
687#else
688        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
689#endif
690      END IF
691
692      IF( kt == nit000 ) THEN
693         IF(lwp) WRITE(numout,*)
694         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
695         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
696      ENDIF
697
698      ! Local constant initialization
699      zcoef0 = - grav * 0.5_wp
700      z1_10  = 1._wp / 10._wp
701      z1_12  = 1._wp / 12._wp
702
703      !----------------------------------------------------------------------------------------
704      !  compute and store in provisional arrays elementary vertical and horizontal differences
705      !----------------------------------------------------------------------------------------
706
707!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
708
709      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
710         drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
711         dzz  (ji,jj,jk) = gde3w(ji  ,jj  ,jk) - gde3w(ji,jj,jk-1)
712         drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
713         dzx  (ji,jj,jk) = gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk  )
714         drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
715         dzy  (ji,jj,jk) = gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk  )
716      END_3D
717
718      !-------------------------------------------------------------------------
719      ! compute harmonic averages using eq. 5.18
720      !-------------------------------------------------------------------------
721      zep = 1.e-15
722
723!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
724!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
725
726      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
727         cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
728
729         cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
730         cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
731
732         cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
733         cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
734
735         IF( cffw > zep) THEN
736            drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
737               &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
738         ELSE
739            drhow(ji,jj,jk) = 0._wp
740         ENDIF
741
742         dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
743            &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
744
745         IF( cffu > zep ) THEN
746            drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
747               &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
748         ELSE
749            drhou(ji,jj,jk ) = 0._wp
750         ENDIF
751
752         IF( cffx > zep ) THEN
753            dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
754               &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
755         ELSE
756            dzu(ji,jj,jk) = 0._wp
757         ENDIF
758
759         IF( cffv > zep ) THEN
760            drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
761               &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
762         ELSE
763            drhov(ji,jj,jk) = 0._wp
764         ENDIF
765
766         IF( cffy > zep ) THEN
767            dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
768               &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
769         ELSE
770            dzv(ji,jj,jk) = 0._wp
771         ENDIF
772
773      END_3D
774
775      !----------------------------------------------------------------------------------
776      ! apply boundary conditions at top and bottom using 5.36-5.37
777      !----------------------------------------------------------------------------------
778      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
779      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
780      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
781
782      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
783      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
784      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
785
786
787      !--------------------------------------------------------------
788      ! Upper half of top-most grid box, compute and store
789      !-------------------------------------------------------------
790
791!!bug gm   :  e3w-gde3w(:,:,:) = 0.5*e3w  ....  and gde3w(:,:,2)-gde3w(:,:,1)=e3w(:,:,2,Kmm) ....   to be verified
792!          true if gde3w(:,:,:) is really defined as the sum of the e3w scale factors as, it seems to me, it should be
793
794      DO_2D( 0, 0, 0, 0 )
795         rho_k(ji,jj,1) = -grav * ( e3w(ji,jj,1,Kmm) - gde3w(ji,jj,1) )               &
796            &                   * (  rhd(ji,jj,1)                                     &
797            &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
798            &                              * ( e3w  (ji,jj,1,Kmm) - gde3w(ji,jj,1) )  &
799            &                              / ( gde3w(ji,jj,2) - gde3w(ji,jj,1) )  )
800      END_2D
801
802!!bug gm    : here also, simplification is possible
803!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
804
805      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
806
807         rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
808            &                     * ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) )                                   &
809            &            - grav * z1_10 * (                                                                   &
810            &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
811            &   * ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
812            &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
813            &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
814            &                             )
815
816         rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
817            &                     * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) )                                   &
818            &            - grav* z1_10 * (                                                                    &
819            &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
820            &   * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
821            &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
822            &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
823            &                            )
824
825         rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
826            &                     * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) )                                   &
827            &            - grav* z1_10 * (                                                                    &
828            &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
829            &   * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
830            &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
831            &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
832            &                            )
833
834      END_3D
835#if defined key_mpi3
836      CALL lbc_lnk_nc_multi( 'dynhpg', rho_k, 'W', 1.0_wp, rho_i, 'U', 1.0_wp, rho_j, 'V', 1.0_wp )
837#else
838      CALL lbc_lnk_multi( 'dynhpg', rho_k, 'W', 1.0_wp, rho_i, 'U', 1.0_wp, rho_j, 'V', 1.0_wp )
839#endif
840
841      ! ---------------
842      !  Surface value
843      ! ---------------
844      DO_2D( 0, 0, 0, 0 )
845         zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
846         zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
847         IF( ln_wd_il ) THEN
848           zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
849           zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
850         ENDIF
851         ! add to the general momentum trend
852         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
853         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
854      END_2D
855
856      ! ----------------
857      !  interior value   (2=<jk=<jpkm1)
858      ! ----------------
859      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
860         ! hydrostatic pressure gradient along s-surfaces
861         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
862            &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
863            &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
864         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
865            &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
866            &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
867         IF( ln_wd_il ) THEN
868           zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
869           zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
870         ENDIF
871         ! add to the general momentum trend
872         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
873         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
874      END_3D
875      !
876      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
877      !
878   END SUBROUTINE hpg_djc
879
880
881   SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
882      !!---------------------------------------------------------------------
883      !!                  ***  ROUTINE hpg_prj  ***
884      !!
885      !! ** Method  :   s-coordinate case.
886      !!      A Pressure-Jacobian horizontal pressure gradient method
887      !!      based on the constrained cubic-spline interpolation for
888      !!      all vertical coordinate systems
889      !!
890      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
891      !!----------------------------------------------------------------------
892      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
893      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
894      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
895      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
896      !!
897      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
898      REAL(wp) ::   zcoef0, znad                    ! local scalars
899      !
900      !! The local variables for the correction term
901      INTEGER  :: jk1, jis, jid, jjs, jjd
902      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
903      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
904      REAL(wp) :: zrhdt1
905      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
906      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
907      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
908      REAL(wp), DIMENSION(jpi,jpj)   ::   zsshu_n, zsshv_n
909      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
910      !!----------------------------------------------------------------------
911      !
912      IF( kt == nit000 ) THEN
913         IF(lwp) WRITE(numout,*)
914         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
915         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
916      ENDIF
917
918      ! Local constant initialization
919      zcoef0 = - grav
920      znad = 1._wp
921      IF( ln_linssh )   znad = 0._wp
922
923      IF( ln_wd_il ) THEN
924         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
925         DO_2D( 0, 0, 0, 0 )
926          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
927               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
928               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
929               &                                                      > rn_wdmin1 + rn_wdmin2
930          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (         &
931               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
932               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
933
934          IF(ll_tmp1) THEN
935            zcpx(ji,jj) = 1.0_wp
936          ELSE IF(ll_tmp2) THEN
937            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
938            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
939                        &    / (ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm)) )
940           
941             zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
942          ELSE
943            zcpx(ji,jj) = 0._wp
944          END IF
945   
946          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
947               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
948               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
949               &                                                      > rn_wdmin1 + rn_wdmin2
950          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (      &
951               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
952               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
953
954          IF(ll_tmp1) THEN
955            zcpy(ji,jj) = 1.0_wp
956          ELSE IF(ll_tmp2) THEN
957            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
958            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
959                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
960             zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
961
962            ELSE
963               zcpy(ji,jj) = 0._wp
964            ENDIF
965         END_2D
966#if defined key_mpi3
967         CALL lbc_lnk_nc_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
968#else
969         CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
970#endif
971      ENDIF
972
973      ! Clean 3-D work arrays
974      zhpi(:,:,:) = 0._wp
975      zrhh(:,:,:) = rhd(:,:,:)
976
977      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
978      DO_2D( 1, 1, 1, 1 )
979       jk = mbkt(ji,jj)
980       IF(     jk <=  1   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
981       ELSEIF( jk ==  2   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
982       ELSEIF( jk < jpkm1 ) THEN
983          DO jkk = jk+1, jpk
984             zrhh(ji,jj,jkk) = interp1(gde3w(ji,jj,jkk  ), gde3w(ji,jj,jkk-1),   &
985                &                      gde3w(ji,jj,jkk-2), zrhh (ji,jj,jkk-1), zrhh(ji,jj,jkk-2))
986          END DO
987       ENDIF
988      END_2D
989
990      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
991      DO_2D( 1, 1, 1, 1 )
992         zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm) * znad
993      END_2D
994
995      DO_3D( 1, 1, 1, 1, 2, jpk )
996         zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
997      END_3D
998
999      fsp(:,:,:) = zrhh (:,:,:)
1000      xsp(:,:,:) = zdept(:,:,:)
1001
1002      ! Construct the vertical density profile with the
1003      ! constrained cubic spline interpolation
1004      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1005      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1006
1007      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1008      DO_2D( 0, 1, 0, 1 )
1009       zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1010          &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
1011
1012       ! assuming linear profile across the top half surface layer
1013       zhpi(ji,jj,1) =  0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
1014      END_2D
1015
1016      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1017      DO_3D( 0, 1, 0, 1, 2, jpkm1 )
1018      zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1019         &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1020         &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1021         &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1022      END_3D
1023
1024      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1025
1026      ! Prepare zsshu_n and zsshv_n
1027      DO_2D( 0, 0, 0, 0 )
1028!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1029!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1030!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1031!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1032!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1033!!gm not this:
1034       zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1035                      & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1036       zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1037                      & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1038      END_2D
1039
1040#if defined key_mpi3
1041      CALL lbc_lnk_nc_multi ('dynhpg', zsshu_n, 'U', 1.0_wp, zsshv_n, 'V', 1.0_wp )
1042#else
1043      CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1.0_wp, zsshv_n, 'V', 1.0_wp )
1044#endif
1045
1046      DO_2D( 0, 0, 0, 0 )
1047       zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) * znad) 
1048       zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) * znad)
1049      END_2D
1050
1051      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
1052      zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1053      zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1054      END_3D
1055
1056      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1057      zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1058      zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1059      END_3D
1060
1061      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1062      zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1063      zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1064      zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1065      zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1066      END_3D
1067
1068
1069      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1070      zpwes = 0._wp; zpwed = 0._wp
1071      zpnss = 0._wp; zpnsd = 0._wp
1072      zuijk = zu(ji,jj,jk)
1073      zvijk = zv(ji,jj,jk)
1074
1075      !!!!!     for u equation
1076      IF( jk <= mbku(ji,jj) ) THEN
1077         IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1078           jis = ji + 1; jid = ji
1079         ELSE
1080           jis = ji;     jid = ji +1
1081         ENDIF
1082
1083         ! integrate the pressure on the shallow side
1084         jk1 = jk
1085         DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1086           IF( jk1 == mbku(ji,jj) ) THEN
1087             zuijk = -zdept(jis,jj,jk1)
1088             EXIT
1089           ENDIF
1090           zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1091           zpwes = zpwes +                                    &
1092                integ_spline(zdept(jis,jj,jk1), zdeps,            &
1093                       asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1094                       csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1095           jk1 = jk1 + 1
1096         END DO
1097
1098         ! integrate the pressure on the deep side
1099         jk1 = jk
1100         DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1101           IF( jk1 == 1 ) THEN
1102             zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1103             zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1104                                               bsp(jid,jj,1),   csp(jid,jj,1), &
1105                                               dsp(jid,jj,1)) * zdeps
1106             zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1107             EXIT
1108           ENDIF
1109           zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1110           zpwed = zpwed +                                        &
1111                  integ_spline(zdeps,              zdept(jid,jj,jk1), &
1112                         asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1113                         csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1114           jk1 = jk1 - 1
1115         END DO
1116
1117         ! update the momentum trends in u direction
1118
1119         zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1120         IF( .NOT.ln_linssh ) THEN
1121           zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1122              &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1123          ELSE
1124           zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1125         ENDIF
1126         IF( ln_wd_il ) THEN
1127            zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1128            zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1129         ENDIF
1130         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1131      ENDIF
1132
1133      !!!!!     for v equation
1134      IF( jk <= mbkv(ji,jj) ) THEN
1135         IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1136           jjs = jj + 1; jjd = jj
1137         ELSE
1138           jjs = jj    ; jjd = jj + 1
1139         ENDIF
1140
1141         ! integrate the pressure on the shallow side
1142         jk1 = jk
1143         DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1144           IF( jk1 == mbkv(ji,jj) ) THEN
1145             zvijk = -zdept(ji,jjs,jk1)
1146             EXIT
1147           ENDIF
1148           zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1149           zpnss = zpnss +                                      &
1150                  integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1151                         asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1152                         csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1153           jk1 = jk1 + 1
1154         END DO
1155
1156         ! integrate the pressure on the deep side
1157         jk1 = jk
1158         DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1159           IF( jk1 == 1 ) THEN
1160             zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1161             zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1162                                               bsp(ji,jjd,1),   csp(ji,jjd,1), &
1163                                               dsp(ji,jjd,1) ) * zdeps
1164             zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1165             EXIT
1166           ENDIF
1167           zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1168           zpnsd = zpnsd +                                        &
1169                  integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1170                         asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1171                         csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1172           jk1 = jk1 - 1
1173         END DO
1174
1175
1176         ! update the momentum trends in v direction
1177
1178         zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1179         IF( .NOT.ln_linssh ) THEN
1180            zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1181                    ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1182         ELSE
1183            zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1184         ENDIF
1185         IF( ln_wd_il ) THEN
1186            zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1187            zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1188         ENDIF
1189
1190         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1191      ENDIF
1192         !
1193      END_3D
1194      !
1195      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1196      !
1197   END SUBROUTINE hpg_prj
1198
1199
1200   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1201      !!----------------------------------------------------------------------
1202      !!                 ***  ROUTINE cspline  ***
1203      !!
1204      !! ** Purpose :   constrained cubic spline interpolation
1205      !!
1206      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1207      !!
1208      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1209      !!----------------------------------------------------------------------
1210      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1211      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1212      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1213      !
1214      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1215      INTEGER  ::   jpi, jpj, jpkm1
1216      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1217      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1218      REAL(wp) ::   zdf(size(fsp,3))
1219      !!----------------------------------------------------------------------
1220      !
1221!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1222      jpi   = size(fsp,1)
1223      jpj   = size(fsp,2)
1224      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1225      !
1226      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1227         DO ji = 1, jpi
1228            DO jj = 1, jpj
1229           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1230           !    DO jk = 2, jpkm1-1
1231           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1232           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1233           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1234           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1235           !
1236           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1237           !
1238           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1239           !           zdf(jk) = 0._wp
1240           !       ELSE
1241           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1242           !       ENDIF
1243           !    END DO
1244
1245           !!Simply geometric average
1246               DO jk = 2, jpkm1-1
1247                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1248                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1249
1250                  IF(zdf1 * zdf2 <= 0._wp) THEN
1251                     zdf(jk) = 0._wp
1252                  ELSE
1253                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1254                  ENDIF
1255               END DO
1256
1257               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1258                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1259               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1260                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1261
1262               DO jk = 1, jpkm1 - 1
1263                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1264                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1265                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1266                 zddf1  = -2._wp * ztmp1 + ztmp2
1267                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1268                 zddf2  =  2._wp * ztmp1 - ztmp2
1269
1270                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1271                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1272                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1273                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1274                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1275                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1276                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1277                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1278                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1279               END DO
1280            END DO
1281         END DO
1282
1283      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1284         DO ji = 1, jpi
1285            DO jj = 1, jpj
1286               DO jk = 1, jpkm1-1
1287                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1288                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1289
1290                  dsp(ji,jj,jk) = 0._wp
1291                  csp(ji,jj,jk) = 0._wp
1292                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1293                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1294               END DO
1295            END DO
1296         END DO
1297         !
1298      ELSE
1299         CALL ctl_stop( 'invalid polynomial type in cspline' )
1300      ENDIF
1301      !
1302   END SUBROUTINE cspline
1303
1304
1305   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1306      !!----------------------------------------------------------------------
1307      !!                 ***  ROUTINE interp1  ***
1308      !!
1309      !! ** Purpose :   1-d linear interpolation
1310      !!
1311      !! ** Method  :   interpolation is straight forward
1312      !!                extrapolation is also permitted (no value limit)
1313      !!----------------------------------------------------------------------
1314      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1315      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1316      REAL(wp)             ::  zdeltx
1317      !!----------------------------------------------------------------------
1318      !
1319      zdeltx = xr - xl
1320      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1321         f = 0.5_wp * (fl + fr)
1322      ELSE
1323         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1324      ENDIF
1325      !
1326   END FUNCTION interp1
1327
1328
1329   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1330      !!----------------------------------------------------------------------
1331      !!                 ***  ROUTINE interp1  ***
1332      !!
1333      !! ** Purpose :   1-d constrained cubic spline interpolation
1334      !!
1335      !! ** Method  :  cubic spline interpolation
1336      !!
1337      !!----------------------------------------------------------------------
1338      REAL(wp), INTENT(in) ::  x, a, b, c, d
1339      REAL(wp)             ::  f ! value from the interpolation
1340      !!----------------------------------------------------------------------
1341      !
1342      f = a + x* ( b + x * ( c + d * x ) )
1343      !
1344   END FUNCTION interp2
1345
1346
1347   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1348      !!----------------------------------------------------------------------
1349      !!                 ***  ROUTINE interp1  ***
1350      !!
1351      !! ** Purpose :   Calculate the first order of derivative of
1352      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1353      !!
1354      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1355      !!
1356      !!----------------------------------------------------------------------
1357      REAL(wp), INTENT(in) ::  x, a, b, c, d
1358      REAL(wp)             ::  f ! value from the interpolation
1359      !!----------------------------------------------------------------------
1360      !
1361      f = b + x * ( 2._wp * c + 3._wp * d * x)
1362      !
1363   END FUNCTION interp3
1364
1365
1366   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1367      !!----------------------------------------------------------------------
1368      !!                 ***  ROUTINE interp1  ***
1369      !!
1370      !! ** Purpose :   1-d constrained cubic spline integration
1371      !!
1372      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1373      !!
1374      !!----------------------------------------------------------------------
1375      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1376      REAL(wp)             ::  za1, za2, za3
1377      REAL(wp)             ::  f                   ! integration result
1378      !!----------------------------------------------------------------------
1379      !
1380      za1 = 0.5_wp * b
1381      za2 = c / 3.0_wp
1382      za3 = 0.25_wp * d
1383      !
1384      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1385         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1386      !
1387   END FUNCTION integ_spline
1388
1389   !!======================================================================
1390END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.