New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/TRA/traadv_mus.F90 @ 13630

Last change on this file since 13630 was 13630, checked in by mocavero, 3 years ago

Add neighborhood collectives calls in the NEMO src - ticket #2496

  • Property svn:keywords set to Id
File size: 14.1 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26
27   !
28   USE iom            ! XIOS library
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
38   
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
40   !                                                           !  and in closed seas (orca 2 and 1 configurations)
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
42   
43   LOGICAL  ::   l_trd   ! flag to compute trends
44   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
45   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
46
47   !! * Substitutions
48#  include "do_loop_substitute.h90"
49#  include "domzgr_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
52   !! $Id$
53   !! Software governed by the CeCILL license (see ./LICENSE)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pU, pV, pW,             &
58      &                    Kbb, Kmm, pt, kjpt, Krhs, ld_msc_ups )
59      !!----------------------------------------------------------------------
60      !!                    ***  ROUTINE tra_adv_mus  ***
61      !!
62      !! ** Purpose :   Compute the now trend due to total advection of tracers
63      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
64      !!              Conservation Laws) and add it to the general tracer trend.
65      !!
66      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
67      !!              ld_msc_ups=T :
68      !!
69      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
70      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
71      !!             - poleward advective heat and salt transport (ln_diaptr=T)
72      !!
73      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
74      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
75      !!----------------------------------------------------------------------
76      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
77      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
78      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
79      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
80      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
81      LOGICAL                                  , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
82      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
83      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
85      !
86      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
87      INTEGER  ::   ierr             ! local integer
88      REAL(wp) ::   zu, z0u, zzwx, zw , zalpha   ! local scalars
89      REAL(wp) ::   zv, z0v, zzwy, z0w           !   -      -
90      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwx, zslpx   ! 3D workspace
91      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwy, zslpy   ! -      -
92      !!----------------------------------------------------------------------
93      !
94      IF( kt == kit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
98         IF(lwp) WRITE(numout,*) '~~~~~~~'
99         IF(lwp) WRITE(numout,*)
100         !
101         ! Upstream / MUSCL scheme indicator
102         !
103         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
104         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
105         !
106         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
107            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
108            upsmsk(:,:) = 0._wp                             ! not upstream by default
109            !
110            DO jk = 1, jpkm1
111               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
112                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
113                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
114            END DO
115         ENDIF 
116         !
117      ENDIF 
118      !     
119      l_trd = .FALSE.
120      l_hst = .FALSE.
121      l_ptr = .FALSE.
122      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
123      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) )  )   l_ptr = .TRUE. 
124      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
125         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
126      !
127      DO jn = 1, kjpt            !==  loop over the tracers  ==!
128         !
129         !                          !* Horizontal advective fluxes
130         !
131         !                                !-- first guess of the slopes
132         zwx(:,:,jpk) = 0._wp                   ! bottom values
133         zwy(:,:,jpk) = 0._wp 
134         DO_3D( 1, 0, 1, 0, 1, jpkm1 )
135            zwx(ji,jj,jk) = umask(ji,jj,jk) * ( pt(ji+1,jj,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
136            zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( pt(ji,jj+1,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
137         END_3D
138         ! lateral boundary conditions   (changed sign)
139#if defined key_mpi3
140         CALL lbc_lnk_nc_multi( 'traadv_mus', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )
141#else
142         CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )
143#endif
144         !                                !-- Slopes of tracer
145         zslpx(:,:,jpk) = 0._wp                 ! bottom values
146         zslpy(:,:,jpk) = 0._wp
147         DO_3D( 0, 1, 0, 1, 1, jpkm1 )
148            zslpx(ji,jj,jk) =                       ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
149               &            * ( 0.25 + SIGN( 0.25_wp, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
150            zslpy(ji,jj,jk) =                       ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
151               &            * ( 0.25 + SIGN( 0.25_wp, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
152         END_3D
153         !
154         DO_3D( 0, 1, 0, 1, 1, jpkm1 )    !-- Slopes limitation
155            zslpx(ji,jj,jk) = SIGN( 1.0_wp, zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
156               &                                                     2.*ABS( zwx  (ji-1,jj,jk) ),   &
157               &                                                     2.*ABS( zwx  (ji  ,jj,jk) ) )
158            zslpy(ji,jj,jk) = SIGN( 1.0_wp, zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
159               &                                                     2.*ABS( zwy  (ji,jj-1,jk) ),   &
160               &                                                     2.*ABS( zwy  (ji,jj  ,jk) ) )
161         END_3D
162         !
163         DO_3D( 0, 0, 0, 0, 1, jpkm1 )    !-- MUSCL horizontal advective fluxes
164            ! MUSCL fluxes
165            z0u = SIGN( 0.5_wp, pU(ji,jj,jk) )
166            zalpha = 0.5 - z0u
167            zu  = z0u - 0.5 * pU(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,Kmm)
168            zzwx = pt(ji+1,jj,jk,jn,Kbb) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
169            zzwy = pt(ji  ,jj,jk,jn,Kbb) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
170            zwx(ji,jj,jk) = pU(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
171            !
172            z0v = SIGN( 0.5_wp, pV(ji,jj,jk) )
173            zalpha = 0.5 - z0v
174            zv  = z0v - 0.5 * pV(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,Kmm)
175            zzwx = pt(ji,jj+1,jk,jn,Kbb) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
176            zzwy = pt(ji,jj  ,jk,jn,Kbb) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
177            zwy(ji,jj,jk) = pV(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
178         END_3D
179#if defined key_mpi3
180         CALL lbc_lnk_nc_multi( 'traadv_mus', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! lateral boundary conditions   (changed sign)
181#else
182         CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! lateral boundary conditions   (changed sign)
183#endif
184         !
185         DO_3D( 0, 0, 0, 0, 1, jpkm1 )    !-- Tracer advective trend
186            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
187            &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
188            &                                   * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
189         END_3D
190         !                                ! trend diagnostics
191         IF( l_trd )  THEN
192            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, zwx, pU, pt(:,:,:,jn,Kbb) )
193            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, zwy, pV, pt(:,:,:,jn,Kbb) )
194         END IF
195         !                                 ! "Poleward" heat and salt transports
196         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
197         !                                 !  heat transport
198         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
199         !
200         !                          !* Vertical advective fluxes
201         !
202         !                                !-- first guess of the slopes
203         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
204         zwx(:,:,jpk) = 0._wp
205         DO jk = 2, jpkm1                       ! interior values
206            zwx(:,:,jk) = tmask(:,:,jk) * ( pt(:,:,jk-1,jn,Kbb) - pt(:,:,jk,jn,Kbb) )
207         END DO
208         !                                !-- Slopes of tracer
209         zslpx(:,:,1) = 0._wp                   ! surface values
210         DO_3D( 1, 1, 1, 1, 2, jpkm1 )
211            zslpx(ji,jj,jk) =                        ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
212               &            * (  0.25 + SIGN( 0.25_wp, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
213         END_3D
214         DO_3D( 1, 1, 1, 1, 2, jpkm1 )    !-- Slopes limitation
215            zslpx(ji,jj,jk) = SIGN( 1.0_wp, zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
216               &                                                     2.*ABS( zwx  (ji,jj,jk+1) ),   &
217               &                                                     2.*ABS( zwx  (ji,jj,jk  ) )  )
218         END_3D
219         DO_3D( 0, 0, 0, 0, 1, jpk-2 )    !-- vertical advective flux
220            z0w = SIGN( 0.5_wp, pW(ji,jj,jk+1) )
221            zalpha = 0.5 + z0w
222            zw  = z0w - 0.5 * pW(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w(ji,jj,jk+1,Kmm)
223            zzwx = pt(ji,jj,jk+1,jn,Kbb) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
224            zzwy = pt(ji,jj,jk  ,jn,Kbb) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
225            zwx(ji,jj,jk+1) = pW(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
226         END_3D
227         IF( ln_linssh ) THEN                   ! top values, linear free surface only
228            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
229               DO_2D( 1, 1, 1, 1 )
230                  zwx(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)
231               END_2D
232            ELSE                                      ! no cavities: only at the ocean surface
233               zwx(:,:,1) = pW(:,:,1) * pt(:,:,1,jn,Kbb)
234            ENDIF
235         ENDIF
236         !
237         DO_3D( 0, 0, 0, 0, 1, jpkm1 )     !-- vertical advective trend
238            pt(ji,jj,jk,jn,Krhs) =  pt(ji,jj,jk,jn,Krhs) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )   &
239               &                                      * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
240         END_3D
241         !                                ! send trends for diagnostic
242         IF( l_trd )  CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, zwx, pW, pt(:,:,:,jn,Kbb) )
243         !
244      END DO                     ! end of tracer loop
245      !
246   END SUBROUTINE tra_adv_mus
247
248   !!======================================================================
249END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.