New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf.F90 in NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/TRA/trazdf.F90 @ 13630

Last change on this file since 13630 was 13630, checked in by mocavero, 4 years ago

Add neighborhood collectives calls in the NEMO src - ticket #2496
  • Property svn:keywords set to Id
File size: 13.2 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            4.0  !  2017-06  (G. Madec)  remove explict time-stepping option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE ldftra         ! lateral diffusion: eddy diffusivity
21   USE ldfslp         ! lateral diffusion: iso-neutral slope
22   USE trd_oce        ! trends: ocean variables
23   USE trdtra         ! trends: tracer trend manager
24   !
25   USE in_out_manager ! I/O manager
26   USE prtctl         ! Print control
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_zdf       ! called by step.F90
35   PUBLIC   tra_zdf_imp   ! called by trczdf.F90
36
37   !! * Substitutions
38#  include "do_loop_substitute.h90"
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_zdf( kt, Kbb, Kmm, Krhs, pts, Kaa )
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE tra_zdf  ***
50      !!
51      !! ** Purpose :   compute the vertical ocean tracer physics.
52      !!---------------------------------------------------------------------
53      INTEGER                                  , INTENT(in)    :: kt                  ! ocean time-step index
54      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs, Kaa ! time level indices
55      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts                 ! active tracers and RHS of tracer equation
56      !
57      INTEGER  ::   jk   ! Dummy loop indices
58      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds   ! 3D workspace
59      !!---------------------------------------------------------------------
60      !
61      IF( ln_timing )   CALL timing_start('tra_zdf')
62      !
63      IF( kt == nit000 )  THEN
64         IF(lwp)WRITE(numout,*)
65         IF(lwp)WRITE(numout,*) 'tra_zdf : implicit vertical mixing on T & S'
66         IF(lwp)WRITE(numout,*) '~~~~~~~ '
67      ENDIF
68      !
69      IF( l_trdtra )   THEN                  !* Save ta and sa trends
70         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
71         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kaa)
72         ztrds(:,:,:) = pts(:,:,:,jp_sal,Kaa)
73      ENDIF
74      !
75      !                                      !* compute lateral mixing trend and add it to the general trend
76      CALL tra_zdf_imp( kt, nit000, 'TRA', rDt, Kbb, Kmm, Krhs, pts, Kaa, jpts ) 
77
78!!gm WHY here !   and I don't like that !
79      ! DRAKKAR SSS control {
80      ! JMM avoid negative salinities near river outlet ! Ugly fix
81      ! JMM : restore negative salinities to small salinities:
82      WHERE( pts(:,:,:,jp_sal,Kaa) < 0._wp )   pts(:,:,:,jp_sal,Kaa) = 0.1_wp
83!!gm
84
85      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
86         DO jk = 1, jpkm1
87            ztrdt(:,:,jk) = (   (  pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa)     &
88               &                 - pts(:,:,jk,jp_tem,Kbb)*e3t(:,:,jk,Kbb)  )  &
89               &              / (  e3t(:,:,jk,Kmm)*rDt  )   )                 &
90               &          - ztrdt(:,:,jk)
91            ztrds(:,:,jk) = (   (  pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa)     &
92               &                 - pts(:,:,jk,jp_sal,Kbb)*e3t(:,:,jk,Kbb)  )  &
93               &             / (   e3t(:,:,jk,Kmm)*rDt  )   )                 &
94               &          - ztrds(:,:,jk)
95         END DO
96!!gm this should be moved in trdtra.F90 and done on all trends
97#if defined key_mpi3
98         CALL lbc_lnk_nc_multi( 'trazdf', ztrdt, 'T', 1.0_wp , ztrds, 'T', 1.0_wp )
99#else
100         CALL lbc_lnk_multi( 'trazdf', ztrdt, 'T', 1.0_wp , ztrds, 'T', 1.0_wp )
101#endif
102!!gm
103         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_zdf, ztrdt )
104         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_zdf, ztrds )
105         DEALLOCATE( ztrdt , ztrds )
106      ENDIF
107      !                                          ! print mean trends (used for debugging)
108      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kaa), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
109         &                                  tab3d_2=pts(:,:,:,jp_sal,Kaa), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
110      !
111      IF( ln_timing )   CALL timing_stop('tra_zdf')
112      !
113   END SUBROUTINE tra_zdf
114
115 
116   SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, Kbb, Kmm, Krhs, pt, Kaa, kjpt ) 
117      !!----------------------------------------------------------------------
118      !!                  ***  ROUTINE tra_zdf_imp  ***
119      !!
120      !! ** Purpose :   Compute the after tracer through a implicit computation
121      !!     of the vertical tracer diffusion (including the vertical component
122      !!     of lateral mixing (only for 2nd order operator, for fourth order
123      !!     it is already computed and add to the general trend in traldf)
124      !!
125      !! ** Method  :  The vertical diffusion of a tracer ,t , is given by:
126      !!          difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) )
127      !!      It is computed using a backward time scheme (t=after field)
128      !!      which provide directly the after tracer field.
129      !!      If ln_zdfddm=T, use avs for salinity or for passive tracers
130      !!      Surface and bottom boundary conditions: no diffusive flux on
131      !!      both tracers (bottom, applied through the masked field avt).
132      !!      If iso-neutral mixing, add to avt the contribution due to lateral mixing.
133      !!
134      !! ** Action  : - pt(:,:,:,:,Kaa)  becomes the after tracer
135      !!---------------------------------------------------------------------
136      INTEGER                                  , INTENT(in   ) ::   kt       ! ocean time-step index
137      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs, Kaa  ! ocean time level indices
138      INTEGER                                  , INTENT(in   ) ::   kit000   ! first time step index
139      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
140      INTEGER                                  , INTENT(in   ) ::   kjpt     ! number of tracers
141      REAL(wp)                                 , INTENT(in   ) ::   p2dt     ! tracer time-step
142      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt       ! tracers and RHS of tracer equation
143      !
144      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
145      REAL(wp) ::  zrhs, zzwi, zzws ! local scalars
146      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zwi, zwt, zwd, zws
147      !!---------------------------------------------------------------------
148      !
149      !                                               ! ============= !
150      DO jn = 1, kjpt                                 !  tracer loop  !
151         !                                            ! ============= !
152         !  Matrix construction
153         ! --------------------
154         ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer
155         !
156         IF(  ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR.   &
157            & ( cdtype == 'TRC' .AND. jn == 1 )  )  THEN
158            !
159            ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers
160            IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN   ;   zwt(:,:,2:jpk) = avt(:,:,2:jpk)
161            ELSE                                            ;   zwt(:,:,2:jpk) = avs(:,:,2:jpk)
162            ENDIF
163            zwt(:,:,1) = 0._wp
164            !
165            IF( l_ldfslp ) THEN            ! isoneutral diffusion: add the contribution
166               IF( ln_traldf_msc  ) THEN     ! MSC iso-neutral operator
167                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
168                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk) 
169                  END_3D
170               ELSE                          ! standard or triad iso-neutral operator
171                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
172                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk)
173                  END_3D
174               ENDIF
175            ENDIF
176            !
177            ! Diagonal, lower (i), upper (s)  (including the bottom boundary condition since avt is masked)
178            IF( ln_zad_Aimp ) THEN         ! Adaptive implicit vertical advection
179               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
180                  zzwi = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk  ,Kmm)
181                  zzws = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
182                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zzwi - zzws   &
183                     &                 + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )
184                  zwi(ji,jj,jk) = zzwi + p2dt *   MIN( wi(ji,jj,jk  ) , 0._wp )
185                  zws(ji,jj,jk) = zzws - p2dt *   MAX( wi(ji,jj,jk+1) , 0._wp )
186               END_3D
187            ELSE
188               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
189                  zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk,Kmm)
190                  zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
191                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zwi(ji,jj,jk) - zws(ji,jj,jk)
192               END_3D
193            ENDIF
194            !
195            !! Matrix inversion from the first level
196            !!----------------------------------------------------------------------
197            !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
198            !
199            !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
200            !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
201            !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
202            !        (        ...               )( ...  ) ( ...  )
203            !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
204            !
205            !   m is decomposed in the product of an upper and lower triangular matrix.
206            !   The 3 diagonal terms are in 3d arrays: zwd, zws, zwi.
207            !   Suffices i,s and d indicate "inferior" (below diagonal), diagonal
208            !   and "superior" (above diagonal) components of the tridiagonal system.
209            !   The solution will be in the 4d array pta.
210            !   The 3d array zwt is used as a work space array.
211            !   En route to the solution pt(:,:,:,:,Kaa) is used a to evaluate the rhs and then
212            !   used as a work space array: its value is modified.
213            !
214            DO_2D( 0, 0, 0, 0 )      !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1   (increasing k) ! done one for all passive tracers (so included in the IF instruction)
215               zwt(ji,jj,1) = zwd(ji,jj,1)
216            END_2D
217            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
218               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1)
219            END_3D
220            !
221         ENDIF 
222         !         
223         DO_2D( 0, 0, 0, 0 )         !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
224            pt(ji,jj,1,jn,Kaa) =        e3t(ji,jj,1,Kbb) * pt(ji,jj,1,jn,Kbb)    &
225               &               + p2dt * e3t(ji,jj,1,Kmm) * pt(ji,jj,1,jn,Krhs)
226         END_2D
227         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
228            zrhs =        e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb)    & 
229               & + p2dt * e3t(ji,jj,jk,Kmm) * pt(ji,jj,jk,jn,Krhs)   ! zrhs=right hand side
230            pt(ji,jj,jk,jn,Kaa) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pt(ji,jj,jk-1,jn,Kaa)
231         END_3D
232         !
233         DO_2D( 0, 0, 0, 0 )         !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk   (result is the after tracer)
234            pt(ji,jj,jpkm1,jn,Kaa) = pt(ji,jj,jpkm1,jn,Kaa) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1)
235         END_2D
236         DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
237            pt(ji,jj,jk,jn,Kaa) = ( pt(ji,jj,jk,jn,Kaa) - zws(ji,jj,jk) * pt(ji,jj,jk+1,jn,Kaa) )   &
238               &             / zwt(ji,jj,jk) * tmask(ji,jj,jk)
239         END_3D
240         !                                            ! ================= !
241      END DO                                          !  end tracer loop  !
242      !                                               ! ================= !
243   END SUBROUTINE tra_zdf_imp
244
245   !!==============================================================================
246END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.