New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/TRA/zpshde.F90 @ 13630

Last change on this file since 13630 was 13630, checked in by mocavero, 4 years ago

Add neighborhood collectives calls in the NEMO src - ticket #2496
  • Property svn:keywords set to Id
File size: 25.3 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE phycst          ! physical constants
20   USE eosbn2          ! ocean equation of state
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   zps_hde     ! routine called by step.F90
30   PUBLIC   zps_hde_isf ! routine called by step.F90
31
32   !! * Substitutions
33#  include "do_loop_substitute.h90"
34#  include "domzgr_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE zps_hde( kt, Kmm, kjpt, pta, pgtu, pgtv,   &
43      &                          prd, pgru, pgrv    )
44      !!----------------------------------------------------------------------
45      !!                     ***  ROUTINE zps_hde  ***
46      !!                   
47      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
48      !!      at u- and v-points with a linear interpolation for z-coordinate
49      !!      with partial steps.
50      !!
51      !! ** Method  :   In z-coord with partial steps, scale factors on last
52      !!      levels are different for each grid point, so that T, S and rd
53      !!      points are not at the same depth as in z-coord. To have horizontal
54      !!      gradients again, we interpolate T and S at the good depth :
55      !!      Linear interpolation of T, S   
56      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
57      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
58      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
59      !!         This formulation computes the two cases:
60      !!                 CASE 1                   CASE 2 
61      !!         k-1  ___ ___________   k-1   ___ ___________
62      !!                    Ti  T~                  T~  Ti+1
63      !!                  _____                        _____
64      !!         k        |   |Ti+1     k           Ti |   |
65      !!                  |   |____                ____|   |
66      !!              ___ |   |   |           ___  |   |   |
67      !!                 
68      !!      case 1->   e3w(i+1,:,:,Kmm) >= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) >= e3w(:,j,:,Kmm) ) then
69      !!          t~ = t(i+1,j  ,k) + (e3w(i+1,j,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j,k,Kmm)
70      !!        ( t~ = t(i  ,j+1,k) + (e3w(i,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i,j+1,k,Kmm)  )
71      !!          or
72      !!      case 2->   e3w(i+1,:,:,Kmm) <= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) <= e3w(:,j,:,Kmm) ) then
73      !!          t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
74      !!        ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
75      !!          Idem for di(s) and dj(s)         
76      !!
77      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
78      !!      depth zh from interpolated T and S for the different formulations
79      !!      of the equation of state (eos).
80      !!      Gradient formulation for rho :
81      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
82      !!
83      !! ** Action  : compute for top interfaces
84      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
85      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
86      !!----------------------------------------------------------------------
87      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
88      INTEGER                              , INTENT(in   )           ::  Kmm         ! ocean time level index
89      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
90      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
91      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
92      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
93      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
94      !
95      INTEGER  ::   ji, jj, jn                  ! Dummy loop indices
96      INTEGER  ::   iku, ikv, ikum1, ikvm1      ! partial step level (ocean bottom level) at u- and v-points
97      REAL(wp) ::   ze3wu, ze3wv, zmaxu, zmaxv  ! local scalars
98      REAL(wp), DIMENSION(jpi,jpj)      ::   zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
99      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::   zti, ztj             !
100      !!----------------------------------------------------------------------
101      !
102      IF( ln_timing )   CALL timing_start( 'zps_hde')
103      !
104      pgtu(:,:,:) = 0._wp   ;   zti (:,:,:) = 0._wp   ;   zhi (:,:) = 0._wp
105      pgtv(:,:,:) = 0._wp   ;   ztj (:,:,:) = 0._wp   ;   zhj (:,:) = 0._wp
106      !
107      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
108         !
109         DO_2D( 1, 0, 1, 0 )
110            iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
111            ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
112!!gm BUG ? when applied to before fields, e3w(:,:,k,Kbb) should be used....
113            ze3wu = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
114            ze3wv = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
115            !
116            ! i- direction
117            IF( ze3wu >= 0._wp ) THEN      ! case 1
118               zmaxu =  ze3wu / e3w(ji+1,jj,iku,Kmm)
119               ! interpolated values of tracers
120               zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
121               ! gradient of  tracers
122               pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
123            ELSE                           ! case 2
124               zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
125               ! interpolated values of tracers
126               zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
127               ! gradient of tracers
128               pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
129            ENDIF
130            !
131            ! j- direction
132            IF( ze3wv >= 0._wp ) THEN      ! case 1
133               zmaxv =  ze3wv / e3w(ji,jj+1,ikv,Kmm)
134               ! interpolated values of tracers
135               ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
136               ! gradient of tracers
137               pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
138            ELSE                           ! case 2
139               zmaxv =  -ze3wv / e3w(ji,jj,ikv,Kmm)
140               ! interpolated values of tracers
141               ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
142               ! gradient of tracers
143               pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
144            ENDIF
145         END_2D
146      END DO
147      !
148#if defined key_mpi3
149      CALL lbc_lnk_nc_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
150#else
151      CALL lbc_lnk_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
152#endif
153      !               
154      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
155         pgru(:,:) = 0._wp
156         pgrv(:,:) = 0._wp                ! depth of the partial step level
157         DO_2D( 1, 0, 1, 0 )
158            iku = mbku(ji,jj)
159            ikv = mbkv(ji,jj)
160            ze3wu  = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
161            ze3wv  = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
162            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)     ! i-direction: case 1
163            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)     ! -     -      case 2
164            ENDIF
165            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)     ! j-direction: case 1
166            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)     ! -     -      case 2
167            ENDIF
168         END_2D
169         !
170         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
171         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
172         !
173         DO_2D( 1, 0, 1, 0 )              ! Gradient of density at the last level
174            iku = mbku(ji,jj)
175            ikv = mbkv(ji,jj)
176            ze3wu  = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
177            ze3wv  = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
178            IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
179            ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
180            ENDIF
181            IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
182            ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
183            ENDIF
184         END_2D
185#if defined key_mpi3
186         CALL lbc_lnk_nc_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
187#else
188         CALL lbc_lnk_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
189#endif
190         !
191      END IF
192      !
193      IF( ln_timing )   CALL timing_stop( 'zps_hde')
194      !
195   END SUBROUTINE zps_hde
196
197
198   SUBROUTINE zps_hde_isf( kt, Kmm, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
199      &                          prd, pgru, pgrv, pgrui, pgrvi )
200      !!----------------------------------------------------------------------
201      !!                     ***  ROUTINE zps_hde_isf  ***
202      !!                   
203      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
204      !!      at u- and v-points with a linear interpolation for z-coordinate
205      !!      with partial steps for top (ice shelf) and bottom.
206      !!
207      !! ** Method  :   In z-coord with partial steps, scale factors on last
208      !!      levels are different for each grid point, so that T, S and rd
209      !!      points are not at the same depth as in z-coord. To have horizontal
210      !!      gradients again, we interpolate T and S at the good depth :
211      !!      For the bottom case:
212      !!      Linear interpolation of T, S   
213      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
214      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
215      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
216      !!         This formulation computes the two cases:
217      !!                 CASE 1                   CASE 2 
218      !!         k-1  ___ ___________   k-1   ___ ___________
219      !!                    Ti  T~                  T~  Ti+1
220      !!                  _____                        _____
221      !!         k        |   |Ti+1     k           Ti |   |
222      !!                  |   |____                ____|   |
223      !!              ___ |   |   |           ___  |   |   |
224      !!                 
225      !!      case 1->   e3w(i+1,j,k,Kmm) >= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) >= e3w(i,j,k,Kmm) ) then
226      !!          t~ = t(i+1,j  ,k) + (e3w(i+1,j  ,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j  ,k,Kmm)
227      !!        ( t~ = t(i  ,j+1,k) + (e3w(i  ,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i  ,j+1,k,Kmm)  )
228      !!          or
229      !!      case 2->   e3w(i+1,j,k,Kmm) <= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) <= e3w(i,j,k,Kmm) ) then
230      !!          t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j  ,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
231      !!        ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i  ,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
232      !!          Idem for di(s) and dj(s)         
233      !!
234      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
235      !!      depth zh from interpolated T and S for the different formulations
236      !!      of the equation of state (eos).
237      !!      Gradient formulation for rho :
238      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
239      !!
240      !!      For the top case (ice shelf): As for the bottom case but upside down
241      !!
242      !! ** Action  : compute for top and bottom interfaces
243      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
244      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
245      !!----------------------------------------------------------------------
246      INTEGER                              , INTENT(in   )           ::  kt           ! ocean time-step index
247      INTEGER                              , INTENT(in   )           ::  Kmm          ! ocean time level index
248      INTEGER                              , INTENT(in   )           ::  kjpt         ! number of tracers
249      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta          ! 4D tracers fields
250      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
251      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
252      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd          ! 3D density anomaly fields
253      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
254      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
255      !
256      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
257      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
258      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv             ! temporary scalars
259      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
260      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
261      !!----------------------------------------------------------------------
262      !
263      IF( ln_timing )   CALL timing_start( 'zps_hde_isf')
264      !
265      pgtu (:,:,:) = 0._wp   ;   pgtv (:,:,:) =0._wp
266      pgtui(:,:,:) = 0._wp   ;   pgtvi(:,:,:) =0._wp
267      zti  (:,:,:) = 0._wp   ;   ztj  (:,:,:) =0._wp
268      zhi  (:,:  ) = 0._wp   ;   zhj  (:,:  ) =0._wp
269      !
270      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
271         !
272         DO_2D( 1, 0, 1, 0 )
273
274            iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
275            ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
276            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
277            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
278            !
279            ! i- direction
280            IF( ze3wu >= 0._wp ) THEN      ! case 1
281               zmaxu =  ze3wu / e3w(ji+1,jj,iku,Kmm)
282               ! interpolated values of tracers
283               zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
284               ! gradient of  tracers
285               pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
286            ELSE                           ! case 2
287               zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
288               ! interpolated values of tracers
289               zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
290               ! gradient of tracers
291               pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
292            ENDIF
293            !
294            ! j- direction
295            IF( ze3wv >= 0._wp ) THEN      ! case 1
296               zmaxv =  ze3wv / e3w(ji,jj+1,ikv,Kmm)
297               ! interpolated values of tracers
298               ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
299               ! gradient of tracers
300               pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
301            ELSE                           ! case 2
302               zmaxv =  -ze3wv / e3w(ji,jj,ikv,Kmm)
303               ! interpolated values of tracers
304               ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
305               ! gradient of tracers
306               pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
307            ENDIF
308
309         END_2D
310      END DO
311      !
312#if defined key_mpi3
313      CALL lbc_lnk_nc_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
314#else
315      CALL lbc_lnk_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
316#endif
317
318      ! horizontal derivative of density anomalies (rd)
319      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
320         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
321         !
322         DO_2D( 1, 0, 1, 0 )
323
324            iku = mbku(ji,jj)
325            ikv = mbkv(ji,jj)
326            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
327            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
328            !
329            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)    ! i-direction: case 1
330            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)    ! -     -      case 2
331            ENDIF
332            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)    ! j-direction: case 1
333            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)    ! -     -      case 2
334            ENDIF
335
336         END_2D
337
338         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
339         ! step and store it in  zri, zrj for each  case
340         CALL eos( zti, zhi, zri )
341         CALL eos( ztj, zhj, zrj )
342
343         DO_2D( 1, 0, 1, 0 )            ! Gradient of density at the last level
344            iku = mbku(ji,jj)
345            ikv = mbkv(ji,jj)
346            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
347            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
348
349            IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
350            ELSE                        ;   pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
351            ENDIF
352            IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
353            ELSE                        ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
354            ENDIF
355
356         END_2D
357
358#if defined key_mpi3
359         CALL lbc_lnk_nc_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
360#else
361         CALL lbc_lnk_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
362#endif
363         !
364      END IF
365      !
366      !     !==  (ISH)  compute grui and gruvi  ==!
367      !
368      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
369         DO_2D( 1, 0, 1, 0 )
370            iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
371            ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
372            !
373            ! (ISF) case partial step top and bottom in adjacent cell in vertical
374            ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
375            ! in this case e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm) is not the distance between Tj~ and Tj
376            ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
377            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
378            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
379
380            ! i- direction
381            IF( ze3wu >= 0._wp ) THEN      ! case 1
382               zmaxu = ze3wu / e3w(ji+1,jj,ikup1,Kmm)
383               ! interpolated values of tracers
384               zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
385               ! gradient of tracers
386               pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
387            ELSE                           ! case 2
388               zmaxu = - ze3wu / e3w(ji,jj,ikup1,Kmm)
389               ! interpolated values of tracers
390               zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
391               ! gradient of  tracers
392               pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
393            ENDIF
394            !
395            ! j- direction
396            IF( ze3wv >= 0._wp ) THEN      ! case 1
397               zmaxv =  ze3wv / e3w(ji,jj+1,ikvp1,Kmm)
398               ! interpolated values of tracers
399               ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
400               ! gradient of tracers
401               pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
402            ELSE                           ! case 2
403               zmaxv =  - ze3wv / e3w(ji,jj,ikvp1,Kmm)
404               ! interpolated values of tracers
405               ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
406               ! gradient of tracers
407               pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
408            ENDIF
409
410         END_2D
411         !
412      END DO
413#if defined key_mpi3
414      CALL lbc_lnk_nc_multi( 'zpshde', pgtui(:,:,:), 'U', -1.0_wp , pgtvi(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
415#else
416      CALL lbc_lnk_multi( 'zpshde', pgtui(:,:,:), 'U', -1.0_wp , pgtvi(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
417#endif
418
419      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
420         !
421         pgrui(:,:)  =0.0_wp; pgrvi(:,:)  =0.0_wp;
422         DO_2D( 1, 0, 1, 0 )
423
424            iku = miku(ji,jj)
425            ikv = mikv(ji,jj)
426            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
427            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
428            !
429            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)    ! i-direction: case 1
430            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)    ! -     -      case 2
431            ENDIF
432
433            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)    ! j-direction: case 1
434            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)    ! -     -      case 2
435            ENDIF
436
437         END_2D
438         !
439         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
440         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
441         !
442         DO_2D( 1, 0, 1, 0 )              ! Gradient of density at the last level
443            iku = miku(ji,jj) 
444            ikv = mikv(ji,jj) 
445            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
446            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
447
448            IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) ) ! i: 1
449            ELSE                      ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) ) ! i: 2
450            ENDIF
451            IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
452            ELSE                      ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
453            ENDIF
454
455         END_2D
456#if defined key_mpi3
457         CALL lbc_lnk_nc_multi( 'zpshde', pgrui, 'U', -1.0_wp , pgrvi, 'V', -1.0_wp )   ! Lateral boundary conditions
458#else
459         CALL lbc_lnk_multi( 'zpshde', pgrui, 'U', -1.0_wp , pgrvi, 'V', -1.0_wp )   ! Lateral boundary conditions
460#endif
461         !
462      END IF 
463      !
464      IF( ln_timing )   CALL timing_stop( 'zps_hde_isf')
465      !
466   END SUBROUTINE zps_hde_isf
467
468   !!======================================================================
469END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.