New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldfdyn.F90 in NEMO/branches/2020/dev_r13327_KERNEL-06_2_techene_e3/src/OCE/LDF – NEMO

source: NEMO/branches/2020/dev_r13327_KERNEL-06_2_techene_e3/src/OCE/LDF/ldfdyn.F90 @ 13513

Last change on this file since 13513 was 13513, checked in by techene, 4 years ago

#2527 and #2385 add a symmetric operator for ocean viscosity
  • Property svn:keywords set to Id
File size: 31.3 KB
Line 
1MODULE ldfdyn
2   !!======================================================================
3   !!                       ***  MODULE  ldfdyn  ***
4   !! Ocean physics:  lateral viscosity coefficient
5   !!=====================================================================
6   !! History :  OPA  ! 1997-07  (G. Madec)  multi dimensional coefficients
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.7  ! 2014-01  (F. Lemarie, G. Madec)  restructuration/simplification of ahm specification,
9   !!                 !                                  add velocity dependent coefficient and optional read in file
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   ldf_dyn_init  : initialization, namelist read, and parameters control
14   !!   ldf_dyn       : update lateral eddy viscosity coefficients at each time step
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers   
17   USE dom_oce         ! ocean space and time domain
18   USE phycst          ! physical constants
19   USE ldfslp          ! lateral diffusion: slopes of mixing orientation
20   USE ldfc1d_c2d      ! lateral diffusion: 1D and 2D cases
21   !
22   USE in_out_manager  ! I/O manager
23   USE iom             ! I/O module for ehanced bottom friction file
24   USE timing          ! Timing
25   USE lib_mpp         ! distribued memory computing library
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   ldf_dyn_init   ! called by nemogcm.F90
32   PUBLIC   ldf_dyn        ! called by step.F90
33
34   !                                    !!* Namelist namdyn_ldf : lateral mixing on momentum *
35   LOGICAL , PUBLIC ::   ln_dynldf_OFF   !: No operator (i.e. no explicit diffusion)
36   INTEGER , PUBLIC ::   nn_dynldf_typ   !: operator type (0: div-rot ; 1: symmetric)
37   LOGICAL , PUBLIC ::   ln_dynldf_lap   !: laplacian operator
38   LOGICAL , PUBLIC ::   ln_dynldf_blp   !: bilaplacian operator
39   LOGICAL , PUBLIC ::   ln_dynldf_lev   !: iso-level direction
40   LOGICAL , PUBLIC ::   ln_dynldf_hor   !: horizontal (geopotential) direction
41!  LOGICAL , PUBLIC ::   ln_dynldf_iso   !: iso-neutral direction                        (see ldfslp)
42   INTEGER , PUBLIC ::   nn_ahm_ijk_t    !: choice of time & space variations of the lateral eddy viscosity coef.
43   !                                        !  time invariant coefficients:  aht = 1/2  Ud*Ld   (lap case)
44   !                                           !                             bht = 1/12 Ud*Ld^3 (blp case)
45   REAL(wp), PUBLIC ::   rn_Uv                 !: lateral viscous velocity  [m/s]
46   REAL(wp), PUBLIC ::   rn_Lv                 !: lateral viscous length    [m]
47   !                                        ! Smagorinsky viscosity  (nn_ahm_ijk_t = 32)
48   REAL(wp), PUBLIC ::   rn_csmc               !: Smagorinsky constant of proportionality
49   REAL(wp), PUBLIC ::   rn_minfac             !: Multiplicative factor of theorectical minimum Smagorinsky viscosity
50   REAL(wp), PUBLIC ::   rn_maxfac             !: Multiplicative factor of theorectical maximum Smagorinsky viscosity
51   !                                        ! iso-neutral laplacian (ln_dynldf_lap=ln_dynldf_iso=T)
52   REAL(wp), PUBLIC ::   rn_ahm_b              !: lateral laplacian background eddy viscosity  [m2/s]
53
54   !                                    !!* Parameter to control the type of lateral viscous operator
55   INTEGER, PARAMETER, PUBLIC ::   np_ERROR   =-10                      !: error in setting the operator
56   INTEGER, PARAMETER, PUBLIC ::   np_no_ldf  = 00                      !: without operator (i.e. no lateral viscous trend)
57   !
58   INTEGER, PARAMETER, PUBLIC ::   np_typ_rot = 0                       !: div-rot   operator
59   INTEGER, PARAMETER, PUBLIC ::   np_typ_sym = 1                       !: symmetric operator
60   !
61   !                          !!      laplacian     !    bilaplacian    !
62   INTEGER, PARAMETER, PUBLIC ::   np_lap    = 10   ,   np_blp    = 20  !: iso-level operator
63   INTEGER, PARAMETER, PUBLIC ::   np_lap_i  = 11                       !: iso-neutral or geopotential operator
64   !
65   INTEGER           , PUBLIC ::   nldf_dyn         !: type of lateral diffusion used defined from ln_dynldf_... (namlist logicals)
66   LOGICAL           , PUBLIC ::   l_ldfdyn_time    !: flag for time variation of the lateral eddy viscosity coef.
67
68   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ahmt, ahmf   !: eddy viscosity coef. at T- and F-points [m2/s or m4/s]
69   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   dtensq       !: horizontal tension squared         (Smagorinsky only)
70   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   dshesq       !: horizontal shearing strain squared (Smagorinsky only)
71   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   esqt, esqf   !: Square of the local gridscale (e1e2/(e1+e2))**2           
72
73   REAL(wp) ::   r1_2    = 0.5_wp            ! =1/2
74   REAL(wp) ::   r1_4    = 0.25_wp           ! =1/4
75   REAL(wp) ::   r1_8    = 0.125_wp          ! =1/8
76   REAL(wp) ::   r1_12   = 1._wp / 12._wp    ! =1/12
77   REAL(wp) ::   r1_288  = 1._wp / 288._wp   ! =1/( 12^2 * 2 )
78
79   !! * Substitutions
80#  include "do_loop_substitute.h90"
81   !!----------------------------------------------------------------------
82   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
83   !! $Id$
84   !! Software governed by the CeCILL license (see ./LICENSE)
85   !!----------------------------------------------------------------------
86CONTAINS
87
88   SUBROUTINE ldf_dyn_init
89      !!----------------------------------------------------------------------
90      !!                  ***  ROUTINE ldf_dyn_init  ***
91      !!                   
92      !! ** Purpose :   set the horizontal ocean dynamics physics
93      !!
94      !! ** Method  :   the eddy viscosity coef. specification depends on:
95      !!              - the operator:
96      !!             ln_dynldf_lap = T     laplacian operator
97      !!             ln_dynldf_blp = T   bilaplacian operator
98      !!              - the parameter nn_ahm_ijk_t:
99      !!    nn_ahm_ijk_t  =  0 => = constant
100      !!                  = 10 => = F(z) :     = constant with a reduction of 1/4 with depth
101      !!                  =-20 => = F(i,j)     = shape read in 'eddy_viscosity.nc' file
102      !!                  = 20    = F(i,j)     = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case)
103      !!                  =-30 => = F(i,j,k)   = shape read in 'eddy_viscosity.nc'  file
104      !!                  = 30    = F(i,j,k)   = 2D (case 20) + decrease with depth (case 10)
105      !!                  = 31    = F(i,j,k,t) = F(local velocity) (  |u|e  /12   laplacian operator
106      !!                                                           or |u|e^3/12 bilaplacian operator )
107      !!                  = 32    = F(i,j,k,t) = F(local deformation rate and gridscale) (D and L) (Smagorinsky) 
108      !!                                                           (   L^2|D|      laplacian operator
109      !!                                                           or  L^4|D|/8  bilaplacian operator )
110      !!----------------------------------------------------------------------
111      INTEGER  ::   ji, jj, jk                     ! dummy loop indices
112      INTEGER  ::   ioptio, ierr, inum, ios, inn   ! local integer
113      REAL(wp) ::   zah0, zah_max, zUfac           ! local scalar
114      CHARACTER(len=5) ::   cl_Units               ! units (m2/s or m4/s)
115      !!
116      NAMELIST/namdyn_ldf/ ln_dynldf_OFF, nn_dynldf_typ, ln_dynldf_lap, ln_dynldf_blp,   &   ! type of operator
117         &                 ln_dynldf_lev, ln_dynldf_hor, ln_dynldf_iso,                  &   ! acting direction of the operator
118         &                 nn_ahm_ijk_t , rn_Uv        , rn_Lv        ,   rn_ahm_b,      &   ! lateral eddy coefficient
119         &                 rn_csmc      , rn_minfac    , rn_maxfac                           ! Smagorinsky settings
120      !!----------------------------------------------------------------------
121      !
122      READ  ( numnam_ref, namdyn_ldf, IOSTAT = ios, ERR = 901)
123901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_ldf in reference namelist' )
124
125      READ  ( numnam_cfg, namdyn_ldf, IOSTAT = ios, ERR = 902 )
126902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_ldf in configuration namelist' )
127      IF(lwm) WRITE ( numond, namdyn_ldf )
128
129      IF(lwp) THEN                      ! Parameter print
130         WRITE(numout,*)
131         WRITE(numout,*) 'ldf_dyn : lateral momentum physics'
132         WRITE(numout,*) '~~~~~~~'
133         WRITE(numout,*) '   Namelist namdyn_ldf : set lateral mixing parameters'
134         !
135         WRITE(numout,*) '      type :'
136         WRITE(numout,*) '         no explicit diffusion                ln_dynldf_OFF = ', ln_dynldf_OFF
137         WRITE(numout,*) '         type of operator (div-rot or sym)    nn_dynldf_typ = ', nn_dynldf_typ
138         WRITE(numout,*) '         laplacian operator                   ln_dynldf_lap = ', ln_dynldf_lap
139         WRITE(numout,*) '         bilaplacian operator                 ln_dynldf_blp = ', ln_dynldf_blp
140         !
141         WRITE(numout,*) '      direction of action :'
142         WRITE(numout,*) '         iso-level                            ln_dynldf_lev = ', ln_dynldf_lev
143         WRITE(numout,*) '         horizontal (geopotential)            ln_dynldf_hor = ', ln_dynldf_hor
144         WRITE(numout,*) '         iso-neutral                          ln_dynldf_iso = ', ln_dynldf_iso
145         !
146         WRITE(numout,*) '      coefficients :'
147         WRITE(numout,*) '         type of time-space variation         nn_ahm_ijk_t  = ', nn_ahm_ijk_t
148         WRITE(numout,*) '         lateral viscous velocity  (if cst)      rn_Uv      = ', rn_Uv, ' m/s'
149         WRITE(numout,*) '         lateral viscous length    (if cst)      rn_Lv      = ', rn_Lv, ' m'
150         WRITE(numout,*) '         background viscosity (iso-lap case)     rn_ahm_b   = ', rn_ahm_b, ' m2/s'
151         !
152         WRITE(numout,*) '      Smagorinsky settings (nn_ahm_ijk_t  = 32) :'
153         WRITE(numout,*) '         Smagorinsky coefficient              rn_csmc       = ', rn_csmc
154         WRITE(numout,*) '         factor multiplier for eddy visc.'
155         WRITE(numout,*) '            lower limit (default 1.0)         rn_minfac     = ', rn_minfac
156         WRITE(numout,*) '            upper limit (default 1.0)         rn_maxfac     = ', rn_maxfac
157      ENDIF
158
159      !
160      !           !==  type of lateral operator used  ==!   (set nldf_dyn)
161      !           !=====================================!
162      !
163      nldf_dyn = np_ERROR
164      ioptio = 0
165      IF( ln_dynldf_OFF ) THEN   ;   nldf_dyn = np_no_ldf   ;   ioptio = ioptio + 1   ;   ENDIF
166      IF( ln_dynldf_lap ) THEN   ;                              ioptio = ioptio + 1   ;   ENDIF
167      IF( ln_dynldf_blp ) THEN   ;                              ioptio = ioptio + 1   ;   ENDIF
168      IF( ioptio /= 1   )   CALL ctl_stop( 'ldf_dyn_init: use ONE of the 3 operator options (NONE/lap/blp)' )
169      !
170      IF(.NOT.ln_dynldf_OFF ) THEN     !==  direction ==>> type of operator  ==!
171         !
172         SELECT CASE( nn_dynldf_typ )  ! div-rot or symmetric
173         CASE( np_typ_rot )   ;   WRITE(numout,*) '   ==>>>   use div-rot   operator '
174         CASE( np_typ_sym )   ;   WRITE(numout,*) '   ==>>>   use symmetric operator '
175         CASE DEFAULT                                     ! error
176            CALL ctl_stop('ldf_dyn_init: wrong value for nn_dynldf_typ (0 or 1)'  )
177         END SELECT
178         !
179         ioptio = 0
180         IF( ln_dynldf_lev )   ioptio = ioptio + 1
181         IF( ln_dynldf_hor )   ioptio = ioptio + 1
182         IF( ln_dynldf_iso )   ioptio = ioptio + 1
183         IF( ioptio /= 1   )   CALL ctl_stop( 'ldf_dyn_init: use ONE of the 3 direction options (level/hor/iso)' )
184         !
185         !                             ! Set nldf_dyn, the type of lateral diffusion, from ln_dynldf_... logicals
186         ierr = 0
187         IF( ln_dynldf_lap ) THEN         ! laplacian operator
188            IF( ln_zco ) THEN                   ! z-coordinate
189               IF ( ln_dynldf_lev )   nldf_dyn = np_lap     ! iso-level = horizontal (no rotation)
190               IF ( ln_dynldf_hor )   nldf_dyn = np_lap     ! iso-level = horizontal (no rotation)
191               IF ( ln_dynldf_iso )   nldf_dyn = np_lap_i   ! iso-neutral            (   rotation)
192            ENDIF
193            IF( ln_zps ) THEN                   ! z-coordinate with partial step
194               IF ( ln_dynldf_lev )   nldf_dyn = np_lap     ! iso-level              (no rotation)
195               IF ( ln_dynldf_hor )   nldf_dyn = np_lap     ! iso-level              (no rotation)
196               IF ( ln_dynldf_iso )   nldf_dyn = np_lap_i   ! iso-neutral            (   rotation)
197            ENDIF
198            IF( ln_sco ) THEN                   ! s-coordinate
199               IF ( ln_dynldf_lev )   nldf_dyn = np_lap     ! iso-level = horizontal (no rotation)
200               IF ( ln_dynldf_hor )   nldf_dyn = np_lap_i   ! horizontal             (   rotation)
201               IF ( ln_dynldf_iso )   nldf_dyn = np_lap_i   ! iso-neutral            (   rotation)
202            ENDIF
203         ENDIF
204         !
205         IF( ln_dynldf_blp ) THEN         ! bilaplacian operator
206            IF( ln_zco ) THEN                   ! z-coordinate
207               IF( ln_dynldf_lev )   nldf_dyn = np_blp   ! iso-level = horizontal (no rotation)
208               IF( ln_dynldf_hor )   nldf_dyn = np_blp   ! iso-level = horizontal (no rotation)
209               IF( ln_dynldf_iso )   ierr = 2            ! iso-neutral            (   rotation)
210            ENDIF
211            IF( ln_zps ) THEN                   ! z-coordinate with partial step
212               IF( ln_dynldf_lev )   nldf_dyn = np_blp   ! iso-level              (no rotation)
213               IF( ln_dynldf_hor )   nldf_dyn = np_blp   ! iso-level              (no rotation)
214               IF( ln_dynldf_iso )   ierr = 2            ! iso-neutral            (   rotation)
215            ENDIF
216            IF( ln_sco ) THEN                   ! s-coordinate
217               IF( ln_dynldf_lev )   nldf_dyn = np_blp   ! iso-level              (no rotation)
218               IF( ln_dynldf_hor )   ierr = 2            ! horizontal             (   rotation)
219               IF( ln_dynldf_iso )   ierr = 2            ! iso-neutral            (   rotation)
220            ENDIF
221         ENDIF
222         !
223         IF( ierr == 2 )   CALL ctl_stop( 'rotated bi-laplacian operator does not exist' )
224         !
225         IF( nldf_dyn == np_lap_i )   l_ldfslp = .TRUE.  ! rotation require the computation of the slopes
226         !
227      ENDIF
228      !
229      IF(lwp) THEN
230         WRITE(numout,*)
231         SELECT CASE( nldf_dyn )
232         CASE( np_no_ldf )   ;   WRITE(numout,*) '   ==>>>   NO lateral viscosity'
233         CASE( np_lap    )   ;   WRITE(numout,*) '   ==>>>   iso-level laplacian operator'
234         CASE( np_lap_i  )   ;   WRITE(numout,*) '   ==>>>   rotated laplacian operator with iso-level background'
235         CASE( np_blp    )   ;   WRITE(numout,*) '   ==>>>   iso-level bi-laplacian operator'
236         END SELECT
237         WRITE(numout,*)
238      ENDIF
239     
240      !
241      !           !==  Space/time variation of eddy coefficients  ==!
242      !           !=================================================!
243      !
244      l_ldfdyn_time = .FALSE.                ! no time variation except in case defined below
245      !
246      IF( ln_dynldf_OFF ) THEN
247         IF(lwp) WRITE(numout,*) '   ==>>>   No viscous operator selected. ahmt and ahmf are not allocated'
248         RETURN
249         !
250      ELSE                                   !==  a lateral diffusion operator is used  ==!
251         !
252         !                                         ! allocate the ahm arrays
253         ALLOCATE( ahmt(jpi,jpj,jpk) , ahmf(jpi,jpj,jpk) , STAT=ierr )
254         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'ldf_dyn_init: failed to allocate arrays')
255         !
256         ahmt(:,:,:) = 0._wp                       ! init to 0 needed
257         ahmf(:,:,:) = 0._wp
258         !
259         !                                         ! value of lap/blp eddy mixing coef.
260         IF(     ln_dynldf_lap ) THEN   ;   zUfac = r1_2 *rn_Uv   ;   inn = 1   ;   cl_Units = ' m2/s'   !   laplacian
261         ELSEIF( ln_dynldf_blp ) THEN   ;   zUfac = r1_12*rn_Uv   ;   inn = 3   ;   cl_Units = ' m4/s'   ! bilaplacian
262         ENDIF
263         zah0    = zUfac *    rn_Lv**inn              ! mixing coefficient
264         zah_max = zUfac * (ra*rad)**inn              ! maximum reachable coefficient (value at the Equator)
265         !
266         SELECT CASE(  nn_ahm_ijk_t  )             !* Specification of space-time variations of ahmt, ahmf
267         !
268         CASE(   0  )      !==  constant  ==!
269            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity. = constant = ', zah0, cl_Units
270            ahmt(:,:,1:jpkm1) = zah0
271            ahmf(:,:,1:jpkm1) = zah0
272            !
273         CASE(  10  )      !==  fixed profile  ==!
274            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F( depth )'
275            IF(lwp) WRITE(numout,*) '           surface viscous coef. = constant = ', zah0, cl_Units
276            ahmt(:,:,1) = zah0                        ! constant surface value
277            ahmf(:,:,1) = zah0
278            CALL ldf_c1d( 'DYN', ahmt(:,:,1), ahmf(:,:,1), ahmt, ahmf )
279            !
280         CASE ( -20 )      !== fixed horizontal shape read in file  ==!
281            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F(i,j) read in eddy_viscosity.nc file'
282            CALL iom_open( 'eddy_viscosity_2D.nc', inum )
283            CALL iom_get ( inum, jpdom_global, 'ahmt_2d', ahmt(:,:,1), cd_type = 'T', psgn = 1._wp )
284            CALL iom_get ( inum, jpdom_global, 'ahmf_2d', ahmf(:,:,1), cd_type = 'F', psgn = 1._wp )
285            CALL iom_close( inum )
286            DO jk = 2, jpkm1
287               ahmt(:,:,jk) = ahmt(:,:,1)
288               ahmf(:,:,jk) = ahmf(:,:,1)
289            END DO
290            !
291         CASE(  20  )      !== fixed horizontal shape  ==!
292            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F( e1, e2 ) or F( e1^3, e2^3 ) (lap. or blp. case)'
293            IF(lwp) WRITE(numout,*) '           using a fixed viscous velocity = ', rn_Uv  ,' m/s   and   Lv = Max(e1,e2)'
294            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, cl_Units, '  for e1=1°)'
295            CALL ldf_c2d( 'DYN', zUfac      , inn        , ahmt, ahmf )         ! surface value proportional to scale factor^inn
296            !
297         CASE( -30  )      !== fixed 3D shape read in file  ==!
298            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F(i,j,k) read in eddy_viscosity_3D.nc file'
299            CALL iom_open( 'eddy_viscosity_3D.nc', inum )
300            CALL iom_get ( inum, jpdom_global, 'ahmt_3d', ahmt, cd_type = 'T', psgn = 1._wp )
301            CALL iom_get ( inum, jpdom_global, 'ahmf_3d', ahmf, cd_type = 'F', psgn = 1._wp )
302            CALL iom_close( inum )
303            !
304         CASE(  30  )       !==  fixed 3D shape  ==!
305            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F( latitude, longitude, depth )'
306            IF(lwp) WRITE(numout,*) '           using a fixed viscous velocity = ', rn_Uv  ,' m/s   and   Ld = Max(e1,e2)'
307            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, cl_Units, '  for e1=1°)'
308            CALL ldf_c2d( 'DYN', zUfac      , inn        , ahmt, ahmf )         ! surface value proportional to scale factor^inn
309            CALL ldf_c1d( 'DYN', ahmt(:,:,1), ahmf(:,:,1), ahmt, ahmf )  ! reduction with depth
310            !
311         CASE(  31  )       !==  time varying 3D field  ==!
312            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F( latitude, longitude, depth , time )'
313            IF(lwp) WRITE(numout,*) '           proportional to the local velocity : 1/2 |u|e (lap) or 1/12 |u|e^3 (blp)'
314            !
315            l_ldfdyn_time = .TRUE.     ! will be calculated by call to ldf_dyn routine in step.F90
316            !
317         CASE(  32  )       !==  time varying 3D field  ==!
318            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F( latitude, longitude, depth , time )'
319            IF(lwp) WRITE(numout,*) '           proportional to the local deformation rate and gridscale (Smagorinsky)'
320            !
321            l_ldfdyn_time = .TRUE.     ! will be calculated by call to ldf_dyn routine in step.F90
322            !
323            !                          ! allocate arrays used in ldf_dyn.
324            ALLOCATE( dtensq(jpi,jpj,jpk) , dshesq(jpi,jpj,jpk) , esqt(jpi,jpj) , esqf(jpi,jpj) , STAT=ierr )
325            IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'ldf_dyn_init: failed to allocate Smagorinsky arrays')
326            !
327            DO_2D( 1, 1, 1, 1 )
328               esqt(ji,jj) = ( 2._wp * e1e2t(ji,jj) / ( e1t(ji,jj) + e2t(ji,jj) ) )**2 
329               esqf(ji,jj) = ( 2._wp * e1e2f(ji,jj) / ( e1f(ji,jj) + e2f(ji,jj) ) )**2 
330            END_2D
331            !
332         CASE DEFAULT
333            CALL ctl_stop('ldf_dyn_init: wrong choice for nn_ahm_ijk_t, the type of space-time variation of ahm')
334         END SELECT
335         !
336         IF( .NOT.l_ldfdyn_time ) THEN             !* No time variation
337            IF(     ln_dynldf_lap ) THEN                 !   laplacian operator (mask only)
338               ahmt(:,:,1:jpkm1) =       ahmt(:,:,1:jpkm1)   * tmask(:,:,1:jpkm1)
339               ahmf(:,:,1:jpkm1) =       ahmf(:,:,1:jpkm1)   * fmask(:,:,1:jpkm1)
340            ELSEIF( ln_dynldf_blp ) THEN                 ! bilaplacian operator (square root + mask)
341               ahmt(:,:,1:jpkm1) = SQRT( ahmt(:,:,1:jpkm1) ) * tmask(:,:,1:jpkm1)
342               ahmf(:,:,1:jpkm1) = SQRT( ahmf(:,:,1:jpkm1) ) * fmask(:,:,1:jpkm1)
343            ENDIF
344         ENDIF
345         !
346      ENDIF
347      !
348   END SUBROUTINE ldf_dyn_init
349
350
351   SUBROUTINE ldf_dyn( kt, Kbb )
352      !!----------------------------------------------------------------------
353      !!                  ***  ROUTINE ldf_dyn  ***
354      !!
355      !! ** Purpose :   update at kt the momentum lateral mixing coeff. (ahmt and ahmf)
356      !!
357      !! ** Method  :   time varying eddy viscosity coefficients:
358      !!
359      !!    nn_ahm_ijk_t = 31    ahmt, ahmf = F(i,j,k,t) = F(local velocity)
360      !!                         ( |u|e /12  or  |u|e^3/12 for laplacian or bilaplacian operator )
361      !!
362      !!    nn_ahm_ijk_t = 32    ahmt, ahmf = F(i,j,k,t) = F(local deformation rate and gridscale) (D and L) (Smagorinsky) 
363      !!                         ( L^2|D|    or  L^4|D|/8  for laplacian or bilaplacian operator )
364      !!
365      !! ** note    :    in BLP cases the sqrt of the eddy coef is returned, since bilaplacian is en re-entrant laplacian
366      !! ** action  :    ahmt, ahmf   updated at each time step
367      !!----------------------------------------------------------------------
368      INTEGER, INTENT(in) ::   kt   ! time step index
369      INTEGER, INTENT(in) ::   Kbb  ! ocean time level indices
370      !
371      INTEGER  ::   ji, jj, jk   ! dummy loop indices
372      REAL(wp) ::   zu2pv2_ij_p1, zu2pv2_ij, zu2pv2_ij_m1, zemax   ! local scalar (option 31)
373      REAL(wp) ::   zcmsmag, zstabf_lo, zstabf_up, zdelta, zdb     ! local scalar (option 32)
374      !!----------------------------------------------------------------------
375      !
376      IF( ln_timing )   CALL timing_start('ldf_dyn')
377      !
378      SELECT CASE(  nn_ahm_ijk_t  )       !== Eddy vicosity coefficients ==!
379      !
380      CASE(  31  )       !==  time varying 3D field  ==!   = F( local velocity )
381         !
382         IF( ln_dynldf_lap   ) THEN        ! laplacian operator : |u| e /12 = |u/144| e
383            DO jk = 1, jpkm1
384               DO_2D( 0, 0, 0, 0 )
385                  zu2pv2_ij    = uu(ji  ,jj  ,jk,Kbb) * uu(ji  ,jj  ,jk,Kbb) + vv(ji  ,jj  ,jk,Kbb) * vv(ji  ,jj  ,jk,Kbb)
386                  zu2pv2_ij_m1 = uu(ji-1,jj  ,jk,Kbb) * uu(ji-1,jj  ,jk,Kbb) + vv(ji  ,jj-1,jk,Kbb) * vv(ji  ,jj-1,jk,Kbb)
387                  zemax = MAX( e1t(ji,jj) , e2t(ji,jj) )
388                  ahmt(ji,jj,jk) = SQRT( (zu2pv2_ij + zu2pv2_ij_m1) * r1_288 ) * zemax * tmask(ji,jj,jk)      ! 288= 12*12 * 2
389               END_2D
390               DO_2D( 1, 0, 1, 0 )
391                  zu2pv2_ij_p1 = uu(ji  ,jj+1,jk, Kbb) * uu(ji  ,jj+1,jk, Kbb) + vv(ji+1,jj  ,jk, Kbb) * vv(ji+1,jj  ,jk, Kbb)
392                  zu2pv2_ij    = uu(ji  ,jj  ,jk, Kbb) * uu(ji  ,jj  ,jk, Kbb) + vv(ji  ,jj  ,jk, Kbb) * vv(ji  ,jj  ,jk, Kbb)
393                  zemax = MAX( e1f(ji,jj) , e2f(ji,jj) )
394                  ahmf(ji,jj,jk) = SQRT( (zu2pv2_ij + zu2pv2_ij_p1) * r1_288 ) * zemax * fmask(ji,jj,jk)      ! 288= 12*12 * 2
395               END_2D
396            END DO
397         ELSEIF( ln_dynldf_blp ) THEN      ! bilaplacian operator : sqrt( |u| e^3 /12 ) = sqrt( |u/144| e ) * e
398            DO jk = 1, jpkm1
399               DO_2D( 0, 0, 0, 0 )
400                  zu2pv2_ij    = uu(ji  ,jj  ,jk,Kbb) * uu(ji  ,jj  ,jk,Kbb) + vv(ji  ,jj  ,jk,Kbb) * vv(ji  ,jj  ,jk,Kbb)
401                  zu2pv2_ij_m1 = uu(ji-1,jj  ,jk,Kbb) * uu(ji-1,jj  ,jk,Kbb) + vv(ji  ,jj-1,jk,Kbb) * vv(ji  ,jj-1,jk,Kbb)
402                  zemax = MAX( e1t(ji,jj) , e2t(ji,jj) )
403                  ahmt(ji,jj,jk) = SQRT(  SQRT( (zu2pv2_ij + zu2pv2_ij_m1) * r1_288 ) * zemax  ) * zemax * tmask(ji,jj,jk)
404               END_2D
405               DO_2D( 1, 0, 1, 0 )
406                  zu2pv2_ij_p1 = uu(ji  ,jj+1,jk, Kbb) * uu(ji  ,jj+1,jk, Kbb) + vv(ji+1,jj  ,jk, Kbb) * vv(ji+1,jj  ,jk, Kbb)
407                  zu2pv2_ij    = uu(ji  ,jj  ,jk, Kbb) * uu(ji  ,jj  ,jk, Kbb) + vv(ji  ,jj  ,jk, Kbb) * vv(ji  ,jj  ,jk, Kbb)
408                  zemax = MAX( e1f(ji,jj) , e2f(ji,jj) )
409                  ahmf(ji,jj,jk) = SQRT(  SQRT( (zu2pv2_ij + zu2pv2_ij_p1) * r1_288 ) * zemax  ) * zemax * fmask(ji,jj,jk)
410               END_2D
411            END DO
412         ENDIF
413         !
414         CALL lbc_lnk_multi( 'ldfdyn', ahmt, 'T', 1.0_wp,  ahmf, 'F', 1.0_wp )
415         !
416         !
417      CASE(  32  )       !==  time varying 3D field  ==!   = F( local deformation rate and gridscale ) (Smagorinsky)
418         !
419         IF( ln_dynldf_lap .OR. ln_dynldf_blp  ) THEN        ! laplacian operator : (C_smag/pi)^2 L^2 |D|
420            !
421            zcmsmag   = (rn_csmc/rpi)**2                                            ! (C_smag/pi)^2
422            zstabf_lo = rn_minfac * rn_minfac / ( 2._wp * 12._wp * 12._wp * zcmsmag ) ! lower limit stability factor scaling
423            zstabf_up = rn_maxfac / ( 4._wp * zcmsmag * 2._wp * rn_Dt )               ! upper limit stability factor scaling
424            IF( ln_dynldf_blp ) zstabf_lo = ( 16._wp / 9._wp ) * zstabf_lo          ! provide |U|L^3/12 lower limit instead
425            !                                                                       ! of |U|L^3/16 in blp case
426            DO jk = 1, jpkm1
427               !
428               DO_2D( 0, 0, 0, 0 )
429                  zdb =    ( uu(ji,jj,jk,Kbb) * r1_e2u(ji,jj) -  uu(ji-1,jj,jk,Kbb) * r1_e2u(ji-1,jj) )  &
430                       &                      * r1_e1t(ji,jj) * e2t(ji,jj)                           &
431                       & - ( vv(ji,jj,jk,Kbb) * r1_e1v(ji,jj) -  vv(ji,jj-1,jk,Kbb) * r1_e1v(ji,jj-1) )  &
432                       &                      * r1_e2t(ji,jj) * e1t(ji,jj)
433                  dtensq(ji,jj,jk) = zdb * zdb * tmask(ji,jj,jk)
434               END_2D
435               !
436               DO_2D( 1, 0, 1, 0 )
437                  zdb =   (  uu(ji,jj+1,jk,Kbb) * r1_e1u(ji,jj+1) -  uu(ji,jj,jk,Kbb) * r1_e1u(ji,jj) )  &
438                       &                        * r1_e2f(ji,jj)   * e1f(ji,jj)                       &
439                       & + ( vv(ji+1,jj,jk,Kbb) * r1_e2v(ji+1,jj) -  vv(ji,jj,jk,Kbb) * r1_e2v(ji,jj) )  &
440                       &                        * r1_e1f(ji,jj)   * e2f(ji,jj)
441                  dshesq(ji,jj,jk) = zdb * zdb * fmask(ji,jj,jk)
442               END_2D
443               !
444            END DO
445            !
446            CALL lbc_lnk_multi( 'ldfdyn', dtensq, 'T', 1.0_wp )  ! lbc_lnk on dshesq not needed
447            !
448            DO jk = 1, jpkm1
449              !
450               DO_2D( 0, 0, 0, 0 )
451                  !
452                  zu2pv2_ij    = uu(ji  ,jj  ,jk,Kbb) * uu(ji  ,jj  ,jk,Kbb) + vv(ji  ,jj  ,jk,Kbb) * vv(ji  ,jj  ,jk,Kbb)
453                  zu2pv2_ij_m1 = uu(ji-1,jj  ,jk,Kbb) * uu(ji-1,jj  ,jk,Kbb) + vv(ji  ,jj-1,jk,Kbb) * vv(ji  ,jj-1,jk,Kbb)
454                  !
455                  zdelta         = zcmsmag * esqt(ji,jj)                                        ! L^2 * (C_smag/pi)^2
456                  ahmt(ji,jj,jk) = zdelta * SQRT(          dtensq(ji  ,jj,jk) +                         &
457                     &                            r1_4 * ( dshesq(ji  ,jj,jk) + dshesq(ji  ,jj-1,jk) +  &
458                     &                                     dshesq(ji-1,jj,jk) + dshesq(ji-1,jj-1,jk) ) )
459                  ahmt(ji,jj,jk) = MAX( ahmt(ji,jj,jk), SQRT( (zu2pv2_ij + zu2pv2_ij_m1) * zdelta * zstabf_lo ) ) ! Impose lower limit == minfac  * |U|L/2
460                  ahmt(ji,jj,jk) = MIN( ahmt(ji,jj,jk),                                    zdelta * zstabf_up )   ! Impose upper limit == maxfac  * L^2/(4*2dt)
461                  !
462               END_2D
463               !
464               DO_2D( 1, 0, 1, 0 )
465                  !
466                  zu2pv2_ij_p1 = uu(ji  ,jj+1,jk, kbb) * uu(ji  ,jj+1,jk, kbb) + vv(ji+1,jj  ,jk, kbb) * vv(ji+1,jj  ,jk, kbb)
467                  zu2pv2_ij    = uu(ji  ,jj  ,jk, kbb) * uu(ji  ,jj  ,jk, kbb) + vv(ji  ,jj  ,jk, kbb) * vv(ji  ,jj  ,jk, kbb)
468                  !
469                  zdelta         = zcmsmag * esqf(ji,jj)                                        ! L^2 * (C_smag/pi)^2
470                  ahmf(ji,jj,jk) = zdelta * SQRT(          dshesq(ji  ,jj,jk) +                         &
471                     &                            r1_4 * ( dtensq(ji  ,jj,jk) + dtensq(ji  ,jj+1,jk) +  &
472                     &                                     dtensq(ji+1,jj,jk) + dtensq(ji+1,jj+1,jk) ) )
473                  ahmf(ji,jj,jk) = MAX( ahmf(ji,jj,jk), SQRT( (zu2pv2_ij + zu2pv2_ij_p1) * zdelta * zstabf_lo ) ) ! Impose lower limit == minfac  * |U|L/2
474                  ahmf(ji,jj,jk) = MIN( ahmf(ji,jj,jk),                                    zdelta * zstabf_up )   ! Impose upper limit == maxfac  * L^2/(4*2dt)
475                  !
476               END_2D
477               !
478            END DO
479            !
480         ENDIF
481         !
482         IF( ln_dynldf_blp ) THEN      ! bilaplacian operator : sqrt( (C_smag/pi)^2 L^4 |D|/8)
483            !                          !                      = sqrt( A_lap_smag L^2/8 )
484            !                          ! stability limits already applied to laplacian values
485            !                          ! effective default limits are 1/12 |U|L^3 < B_hm < 1//(32*2dt) L^4
486            DO jk = 1, jpkm1
487               DO_2D( 0, 0, 0, 0 )
488                  ahmt(ji,jj,jk) = SQRT( r1_8 * esqt(ji,jj) * ahmt(ji,jj,jk) )
489               END_2D
490               DO_2D( 1, 0, 1, 0 )
491                  ahmf(ji,jj,jk) = SQRT( r1_8 * esqf(ji,jj) * ahmf(ji,jj,jk) )
492               END_2D
493            END DO
494            !
495         ENDIF
496         !
497         CALL lbc_lnk_multi( 'ldfdyn', ahmt, 'T', 1.0_wp , ahmf, 'F', 1.0_wp )
498         !
499      END SELECT
500      !
501      CALL iom_put( "ahmt_2d", ahmt(:,:,1) )   ! surface u-eddy diffusivity coeff.
502      CALL iom_put( "ahmf_2d", ahmf(:,:,1) )   ! surface v-eddy diffusivity coeff.
503      CALL iom_put( "ahmt_3d", ahmt(:,:,:) )   ! 3D      u-eddy diffusivity coeff.
504      CALL iom_put( "ahmf_3d", ahmf(:,:,:) )   ! 3D      v-eddy diffusivity coeff.
505      !
506      IF( ln_timing )   CALL timing_stop('ldf_dyn')
507      !
508   END SUBROUTINE ldf_dyn
509
510   !!======================================================================
511END MODULE ldfdyn
Note: See TracBrowser for help on using the repository browser.