| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Off-line Ocean : passive tracer evolution, dynamics read in files |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line |
|---|
| 7 | !! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 8 | !! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface |
|---|
| 9 | !! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! nemo_gcm : off-line: solve ocean tracer only |
|---|
| 14 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
|---|
| 15 | !! nemo_init : initialization of the NEMO system |
|---|
| 16 | !! nemo_ctl : initialisation of the contol print |
|---|
| 17 | !! nemo_closefile: close remaining open files |
|---|
| 18 | !! nemo_alloc : dynamical allocation |
|---|
| 19 | !! istate_init : simple initialization to zero of ocean fields |
|---|
| 20 | !! stp_ctl : reduced step control (no dynamics in off-line) |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | USE dom_oce ! ocean space domain variables |
|---|
| 23 | USE oce ! dynamics and tracers variables |
|---|
| 24 | USE trc_oce ! Shared ocean/passive tracers variables |
|---|
| 25 | USE c1d ! 1D configuration |
|---|
| 26 | USE domain ! domain initialization from coordinate & bathymetry (dom_init routine) |
|---|
| 27 | USE closea ! treatment of closed seas (for ln_closea) |
|---|
| 28 | USE usrdef_nam ! user defined configuration |
|---|
| 29 | USE eosbn2 ! equation of state (eos bn2 routine) |
|---|
| 30 | #if defined key_qco |
|---|
| 31 | USE domqco ! tools for scale factor (dom_qco_r3c routine) |
|---|
| 32 | #endif |
|---|
| 33 | USE bdyini ! open boundary cond. setting (bdy_init routine) |
|---|
| 34 | ! ! ocean physics |
|---|
| 35 | USE ldftra ! lateral diffusivity setting (ldf_tra_init routine) |
|---|
| 36 | USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine) |
|---|
| 37 | USE traqsr ! solar radiation penetration (tra_qsr_init routine) |
|---|
| 38 | USE trabbl ! bottom boundary layer (tra_bbl_init routine) |
|---|
| 39 | USE traldf ! lateral physics (tra_ldf_init routine) |
|---|
| 40 | USE sbcmod ! surface boundary condition (sbc_init routine) |
|---|
| 41 | USE phycst ! physical constant (par_cst routine) |
|---|
| 42 | USE dtadyn ! Lecture and Interpolation of the dynamical fields |
|---|
| 43 | USE trcini ! Initilization of the passive tracers |
|---|
| 44 | USE daymod ! calendar (day routine) |
|---|
| 45 | USE trcstp ! passive tracer time-stepping (trc_stp routine) |
|---|
| 46 | USE dtadyn ! Lecture and interpolation of the dynamical fields |
|---|
| 47 | ! ! Passive tracers needs |
|---|
| 48 | USE trc ! passive tracer : variables |
|---|
| 49 | USE trcnam ! passive tracer : namelist |
|---|
| 50 | USE trcrst ! passive tracer restart |
|---|
| 51 | USE diaptr ! Need to initialise this as some variables are used in if statements later |
|---|
| 52 | USE sbc_oce , ONLY : ln_rnf |
|---|
| 53 | USE sbcrnf ! surface boundary condition : runoffs |
|---|
| 54 | ! ! I/O & MPP |
|---|
| 55 | USE iom ! I/O library |
|---|
| 56 | USE in_out_manager ! I/O manager |
|---|
| 57 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 58 | USE lib_mpp ! distributed memory computing |
|---|
| 59 | #if defined key_iomput |
|---|
| 60 | USE xios ! xIOserver |
|---|
| 61 | #endif |
|---|
| 62 | USE prtctl ! Print control (prt_ctl_init routine) |
|---|
| 63 | USE timing ! Timing |
|---|
| 64 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 65 | USE lbcnfd , ONLY : isendto, nsndto ! Setup of north fold exchanges |
|---|
| 66 | #if defined key_qco |
|---|
| 67 | USE stepMLF , ONLY : Nbb, Nnn, Naa, Nrhs ! time level indices |
|---|
| 68 | #else |
|---|
| 69 | USE step , ONLY : Nbb, Nnn, Naa, Nrhs ! time level indices |
|---|
| 70 | #endif |
|---|
| 71 | USE halo_mng |
|---|
| 72 | |
|---|
| 73 | IMPLICIT NONE |
|---|
| 74 | PRIVATE |
|---|
| 75 | |
|---|
| 76 | PUBLIC nemo_gcm ! called by nemo.F90 |
|---|
| 77 | |
|---|
| 78 | CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 79 | |
|---|
| 80 | !!---------------------------------------------------------------------- |
|---|
| 81 | !! NEMO/OFF 4.0 , NEMO Consortium (2018) |
|---|
| 82 | !! $Id$ |
|---|
| 83 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 84 | !!---------------------------------------------------------------------- |
|---|
| 85 | CONTAINS |
|---|
| 86 | |
|---|
| 87 | SUBROUTINE nemo_gcm |
|---|
| 88 | !!---------------------------------------------------------------------- |
|---|
| 89 | !! *** ROUTINE nemo_gcm *** |
|---|
| 90 | !! |
|---|
| 91 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
|---|
| 92 | !! curvilinear mesh on the sphere. |
|---|
| 93 | !! |
|---|
| 94 | !! ** Method : - model general initialization |
|---|
| 95 | !! - launch the time-stepping (dta_dyn and trc_stp) |
|---|
| 96 | !! - finalize the run by closing files and communications |
|---|
| 97 | !! |
|---|
| 98 | !! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL. |
|---|
| 99 | !! Madec, 2008, internal report, IPSL. |
|---|
| 100 | !!---------------------------------------------------------------------- |
|---|
| 101 | INTEGER :: istp ! time step index |
|---|
| 102 | !!---------------------------------------------------------------------- |
|---|
| 103 | |
|---|
| 104 | CALL nemo_init ! Initializations |
|---|
| 105 | |
|---|
| 106 | ! check that all process are still there... If some process have an error, |
|---|
| 107 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
|---|
| 108 | CALL mpp_max( 'nemogcm', nstop ) |
|---|
| 109 | |
|---|
| 110 | ! !-----------------------! |
|---|
| 111 | ! !== time stepping ==! |
|---|
| 112 | ! !-----------------------! |
|---|
| 113 | istp = nit000 |
|---|
| 114 | ! |
|---|
| 115 | IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization |
|---|
| 116 | ! |
|---|
| 117 | CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 118 | ! |
|---|
| 119 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==! |
|---|
| 120 | ! |
|---|
| 121 | IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 122 | CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp |
|---|
| 123 | #if defined key_sed_off |
|---|
| 124 | CALL dta_dyn_sed( istp, Nnn ) ! Interpolation of the dynamical fields |
|---|
| 125 | #else |
|---|
| 126 | CALL dta_dyn ( istp, Nbb, Nnn, Naa ) ! Interpolation of the dynamical fields |
|---|
| 127 | #endif |
|---|
| 128 | #if ! defined key_sed_off |
|---|
| 129 | IF( .NOT.ln_linssh ) THEN |
|---|
| 130 | CALL dta_dyn_atf( istp, Nbb, Nnn, Naa ) ! time filter of sea surface height and vertical scale factors |
|---|
| 131 | # if defined key_qco |
|---|
| 132 | CALL dom_qco_r3c( ssh(:,:,Nnn), r3t_f, r3u_f, r3v_f ) |
|---|
| 133 | # endif |
|---|
| 134 | ENDIF |
|---|
| 135 | CALL trc_stp ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping |
|---|
| 136 | # if defined key_qco |
|---|
| 137 | !r3t(:,:,Nnn) = r3t_f(:,:) ! update ssh to h0 ratio |
|---|
| 138 | !r3u(:,:,Nnn) = r3u_f(:,:) |
|---|
| 139 | !r3v(:,:,Nnn) = r3v_f(:,:) |
|---|
| 140 | # endif |
|---|
| 141 | #endif |
|---|
| 142 | ! Swap time levels |
|---|
| 143 | Nrhs = Nbb |
|---|
| 144 | Nbb = Nnn |
|---|
| 145 | Nnn = Naa |
|---|
| 146 | Naa = Nrhs |
|---|
| 147 | ! |
|---|
| 148 | #if ! defined key_qco |
|---|
| 149 | # if ! defined key_sed_off |
|---|
| 150 | IF( .NOT.ln_linssh ) CALL dta_dyn_sf_interp( istp, Nnn ) ! calculate now grid parameters |
|---|
| 151 | # endif |
|---|
| 152 | #endif |
|---|
| 153 | CALL stp_ctl ( istp ) ! Time loop: control and print |
|---|
| 154 | istp = istp + 1 |
|---|
| 155 | END DO |
|---|
| 156 | ! |
|---|
| 157 | #if defined key_iomput |
|---|
| 158 | CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF |
|---|
| 159 | #endif |
|---|
| 160 | |
|---|
| 161 | ! !------------------------! |
|---|
| 162 | ! !== finalize the run ==! |
|---|
| 163 | ! !------------------------! |
|---|
| 164 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 165 | |
|---|
| 166 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
|---|
| 167 | WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found' |
|---|
| 168 | WRITE(ctmp2,*) ' Look for "E R R O R" messages in all existing ocean_output* files' |
|---|
| 169 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 ) |
|---|
| 170 | ENDIF |
|---|
| 171 | ! |
|---|
| 172 | IF( ln_timing ) CALL timing_finalize |
|---|
| 173 | ! |
|---|
| 174 | CALL nemo_closefile |
|---|
| 175 | ! |
|---|
| 176 | #if defined key_iomput |
|---|
| 177 | CALL xios_finalize ! end mpp communications with xios |
|---|
| 178 | #else |
|---|
| 179 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
|---|
| 180 | #endif |
|---|
| 181 | ! |
|---|
| 182 | IF(lwm) THEN |
|---|
| 183 | IF( nstop == 0 ) THEN ; STOP 0 |
|---|
| 184 | ELSE ; STOP 123 |
|---|
| 185 | ENDIF |
|---|
| 186 | ENDIF |
|---|
| 187 | ! |
|---|
| 188 | END SUBROUTINE nemo_gcm |
|---|
| 189 | |
|---|
| 190 | |
|---|
| 191 | SUBROUTINE nemo_init |
|---|
| 192 | !!---------------------------------------------------------------------- |
|---|
| 193 | !! *** ROUTINE nemo_init *** |
|---|
| 194 | !! |
|---|
| 195 | !! ** Purpose : initialization of the nemo model in off-line mode |
|---|
| 196 | !!---------------------------------------------------------------------- |
|---|
| 197 | INTEGER :: ios, ilocal_comm ! local integers |
|---|
| 198 | !! |
|---|
| 199 | NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl, & |
|---|
| 200 | & nn_isplt, nn_jsplt, nn_ictls, nn_ictle, nn_jctls, nn_jctle |
|---|
| 201 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
|---|
| 202 | !!---------------------------------------------------------------------- |
|---|
| 203 | ! |
|---|
| 204 | cxios_context = 'nemo' |
|---|
| 205 | nn_hls = 1 |
|---|
| 206 | ! |
|---|
| 207 | ! !-------------------------------------------------! |
|---|
| 208 | ! ! set communicator & select the local rank ! |
|---|
| 209 | ! ! must be done as soon as possible to get narea ! |
|---|
| 210 | ! !-------------------------------------------------! |
|---|
| 211 | ! |
|---|
| 212 | #if defined key_iomput |
|---|
| 213 | CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios |
|---|
| 214 | CALL mpp_start( ilocal_comm ) |
|---|
| 215 | #else |
|---|
| 216 | CALL mpp_start( ) |
|---|
| 217 | #endif |
|---|
| 218 | ! |
|---|
| 219 | narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 ) |
|---|
| 220 | lwm = (narea == 1) ! control of output namelists |
|---|
| 221 | ! |
|---|
| 222 | ! !---------------------------------------------------------------! |
|---|
| 223 | ! ! Open output files, reference and configuration namelist files ! |
|---|
| 224 | ! !---------------------------------------------------------------! |
|---|
| 225 | ! |
|---|
| 226 | ! open ocean.output as soon as possible to get all output prints (including errors messages) |
|---|
| 227 | IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 228 | ! open reference and configuration namelist files |
|---|
| 229 | CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm ) |
|---|
| 230 | CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm ) |
|---|
| 231 | IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 232 | ! open /dev/null file to be able to supress output write easily |
|---|
| 233 | IF( Agrif_Root() ) THEN |
|---|
| 234 | CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 235 | #ifdef key_agrif |
|---|
| 236 | ELSE |
|---|
| 237 | numnul = Agrif_Parent(numnul) |
|---|
| 238 | #endif |
|---|
| 239 | ENDIF |
|---|
| 240 | ! |
|---|
| 241 | ! !--------------------! |
|---|
| 242 | ! ! Open listing units ! -> need sn_cfctl from namctl to define lwp |
|---|
| 243 | ! !--------------------! |
|---|
| 244 | ! |
|---|
| 245 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
|---|
| 246 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' ) |
|---|
| 247 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
|---|
| 248 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' ) |
|---|
| 249 | ! |
|---|
| 250 | ! finalize the definition of namctl variables |
|---|
| 251 | IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) & |
|---|
| 252 | & CALL nemo_set_cfctl( sn_cfctl, .FALSE. ) |
|---|
| 253 | ! |
|---|
| 254 | lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print |
|---|
| 255 | ! |
|---|
| 256 | IF(lwp) THEN ! open listing units |
|---|
| 257 | ! |
|---|
| 258 | IF( .NOT. lwm ) & ! alreay opened for narea == 1 |
|---|
| 259 | & CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea ) |
|---|
| 260 | ! |
|---|
| 261 | WRITE(numout,*) |
|---|
| 262 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC' |
|---|
| 263 | WRITE(numout,*) ' NEMO team' |
|---|
| 264 | WRITE(numout,*) ' Off-line TOP Model' |
|---|
| 265 | WRITE(numout,*) ' NEMO version 4.0 (2019) ' |
|---|
| 266 | WRITE(numout,*) |
|---|
| 267 | WRITE(numout,*) " ._ ._ ._ ._ ._ " |
|---|
| 268 | WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ " |
|---|
| 269 | WRITE(numout,*) |
|---|
| 270 | WRITE(numout,*) " o _, _, " |
|---|
| 271 | WRITE(numout,*) " o .' ( .-' / " |
|---|
| 272 | WRITE(numout,*) " o _/..._'. .' / " |
|---|
| 273 | WRITE(numout,*) " ( o .-'` ` '-./ _.' " |
|---|
| 274 | WRITE(numout,*) " ) ( o) ;= <_ ( " |
|---|
| 275 | WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) " |
|---|
| 276 | WRITE(numout,*) " ) ) \) |`\ \) '. \ ( ( " |
|---|
| 277 | WRITE(numout,*) " ( ( \_/ '-._\ ) ) " |
|---|
| 278 | WRITE(numout,*) " ) ) ` ( ( " |
|---|
| 279 | WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ " |
|---|
| 280 | WRITE(numout,*) |
|---|
| 281 | ! |
|---|
| 282 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 283 | ! |
|---|
| 284 | ENDIF |
|---|
| 285 | ! |
|---|
| 286 | IF(lwm) WRITE( numond, namctl ) |
|---|
| 287 | ! |
|---|
| 288 | ! !------------------------------------! |
|---|
| 289 | ! ! Set global domain size parameters ! |
|---|
| 290 | ! !------------------------------------! |
|---|
| 291 | ! |
|---|
| 292 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
|---|
| 293 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' ) |
|---|
| 294 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
|---|
| 295 | 904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' ) |
|---|
| 296 | ! |
|---|
| 297 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
|---|
| 298 | CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio ) |
|---|
| 299 | ELSE ! user-defined namelist |
|---|
| 300 | CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio ) |
|---|
| 301 | ENDIF |
|---|
| 302 | ! |
|---|
| 303 | IF(lwm) WRITE( numond, namcfg ) |
|---|
| 304 | l_offline = .true. ! passive tracers are run offline |
|---|
| 305 | ! |
|---|
| 306 | ! !-----------------------------------------! |
|---|
| 307 | ! ! mpp parameters and domain decomposition ! |
|---|
| 308 | ! !-----------------------------------------! |
|---|
| 309 | ! |
|---|
| 310 | CALL mpp_init |
|---|
| 311 | |
|---|
| 312 | CALL halo_mng_init() |
|---|
| 313 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
|---|
| 314 | CALL nemo_alloc() |
|---|
| 315 | |
|---|
| 316 | ! Initialise time level indices |
|---|
| 317 | Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa |
|---|
| 318 | |
|---|
| 319 | ! !-------------------------------! |
|---|
| 320 | ! ! NEMO general initialization ! |
|---|
| 321 | ! !-------------------------------! |
|---|
| 322 | |
|---|
| 323 | CALL nemo_ctl ! Control prints |
|---|
| 324 | ! |
|---|
| 325 | ! ! General initialization |
|---|
| 326 | IF( ln_timing ) CALL timing_init |
|---|
| 327 | IF( ln_timing ) CALL timing_start( 'nemo_init') |
|---|
| 328 | ! |
|---|
| 329 | CALL phy_cst ! Physical constants |
|---|
| 330 | CALL eos_init ! Equation of state |
|---|
| 331 | IF( lk_c1d ) CALL c1d_init ! 1D column configuration |
|---|
| 332 | CALL dom_init( Nbb, Nnn, Naa, "OPA") ! Domain |
|---|
| 333 | IF( sn_cfctl%l_prtctl ) & |
|---|
| 334 | & CALL prt_ctl_init ! Print control |
|---|
| 335 | |
|---|
| 336 | CALL istate_init( Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 337 | |
|---|
| 338 | CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module |
|---|
| 339 | CALL bdy_init ! Open boundaries initialisation |
|---|
| 340 | |
|---|
| 341 | ! ! Tracer physics |
|---|
| 342 | CALL ldf_tra_init ! Lateral ocean tracer physics |
|---|
| 343 | CALL ldf_eiv_init ! Eddy induced velocity param |
|---|
| 344 | CALL tra_ldf_init ! lateral mixing |
|---|
| 345 | IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
|---|
| 346 | IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation |
|---|
| 347 | IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 348 | |
|---|
| 349 | ! ! Passive tracers |
|---|
| 350 | CALL trc_nam_run ! Needed to get restart parameters for passive tracers |
|---|
| 351 | CALL trc_rst_cal( nit000, 'READ' ) ! calendar |
|---|
| 352 | #if defined key_sed_off |
|---|
| 353 | CALL dta_dyn_sed_init( Nnn ) ! Initialization for the dynamics |
|---|
| 354 | #else |
|---|
| 355 | CALL dta_dyn_init( Nbb, Nnn, Naa ) ! Initialization for the dynamics |
|---|
| 356 | #endif |
|---|
| 357 | |
|---|
| 358 | CALL trc_init( Nbb, Nnn, Naa ) ! Passive tracers initialization |
|---|
| 359 | CALL dia_ptr_init ! Poleward TRansports initialization |
|---|
| 360 | |
|---|
| 361 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 362 | ! |
|---|
| 363 | IF( ln_timing ) CALL timing_stop( 'nemo_init') |
|---|
| 364 | ! |
|---|
| 365 | END SUBROUTINE nemo_init |
|---|
| 366 | |
|---|
| 367 | |
|---|
| 368 | SUBROUTINE nemo_ctl |
|---|
| 369 | !!---------------------------------------------------------------------- |
|---|
| 370 | !! *** ROUTINE nemo_ctl *** |
|---|
| 371 | !! |
|---|
| 372 | !! ** Purpose : control print setting |
|---|
| 373 | !! |
|---|
| 374 | !! ** Method : - print namctl and namcfg information and check some consistencies |
|---|
| 375 | !!---------------------------------------------------------------------- |
|---|
| 376 | ! |
|---|
| 377 | IF(lwp) THEN ! control print |
|---|
| 378 | WRITE(numout,*) |
|---|
| 379 | WRITE(numout,*) 'nemo_ctl: Control prints' |
|---|
| 380 | WRITE(numout,*) '~~~~~~~~' |
|---|
| 381 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 382 | WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat |
|---|
| 383 | WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat |
|---|
| 384 | WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout |
|---|
| 385 | WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout |
|---|
| 386 | WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl |
|---|
| 387 | WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc |
|---|
| 388 | WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout |
|---|
| 389 | WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin |
|---|
| 390 | WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax |
|---|
| 391 | WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr |
|---|
| 392 | WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr |
|---|
| 393 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
|---|
| 394 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
|---|
| 395 | ENDIF |
|---|
| 396 | |
|---|
| 397 | IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file |
|---|
| 398 | IF(lwp) THEN ! control print |
|---|
| 399 | WRITE(numout,*) |
|---|
| 400 | WRITE(numout,*) ' Namelist namcfg' |
|---|
| 401 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
|---|
| 402 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
|---|
| 403 | WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea |
|---|
| 404 | WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg |
|---|
| 405 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
|---|
| 406 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
|---|
| 407 | ENDIF |
|---|
| 408 | ! |
|---|
| 409 | IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', & |
|---|
| 410 | & 'Compile with key_nosignedzero enabled' ) |
|---|
| 411 | ! |
|---|
| 412 | END SUBROUTINE nemo_ctl |
|---|
| 413 | |
|---|
| 414 | |
|---|
| 415 | SUBROUTINE nemo_closefile |
|---|
| 416 | !!---------------------------------------------------------------------- |
|---|
| 417 | !! *** ROUTINE nemo_closefile *** |
|---|
| 418 | !! |
|---|
| 419 | !! ** Purpose : Close the files |
|---|
| 420 | !!---------------------------------------------------------------------- |
|---|
| 421 | ! |
|---|
| 422 | IF( lk_mpp ) CALL mppsync |
|---|
| 423 | ! |
|---|
| 424 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 425 | ! |
|---|
| 426 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 427 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
|---|
| 428 | ! |
|---|
| 429 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 430 | ! |
|---|
| 431 | END SUBROUTINE nemo_closefile |
|---|
| 432 | |
|---|
| 433 | |
|---|
| 434 | SUBROUTINE nemo_alloc |
|---|
| 435 | !!---------------------------------------------------------------------- |
|---|
| 436 | !! *** ROUTINE nemo_alloc *** |
|---|
| 437 | !! |
|---|
| 438 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
|---|
| 439 | !! |
|---|
| 440 | !! ** Method : |
|---|
| 441 | !!---------------------------------------------------------------------- |
|---|
| 442 | USE diawri , ONLY : dia_wri_alloc |
|---|
| 443 | USE dom_oce, ONLY : dom_oce_alloc |
|---|
| 444 | USE zdf_oce, ONLY : zdf_oce_alloc |
|---|
| 445 | USE trc_oce, ONLY : trc_oce_alloc |
|---|
| 446 | USE bdy_oce, ONLY : bdy_oce_alloc |
|---|
| 447 | ! |
|---|
| 448 | INTEGER :: ierr |
|---|
| 449 | !!---------------------------------------------------------------------- |
|---|
| 450 | ! |
|---|
| 451 | ierr = oce_alloc () ! ocean |
|---|
| 452 | ierr = ierr + dia_wri_alloc() |
|---|
| 453 | ierr = ierr + dom_oce_alloc() ! ocean domain |
|---|
| 454 | ierr = ierr + zdf_oce_alloc() ! ocean vertical physics |
|---|
| 455 | ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays |
|---|
| 456 | ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization) |
|---|
| 457 | ! |
|---|
| 458 | CALL mpp_sum( 'nemogcm', ierr ) |
|---|
| 459 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
|---|
| 460 | ! |
|---|
| 461 | END SUBROUTINE nemo_alloc |
|---|
| 462 | |
|---|
| 463 | SUBROUTINE nemo_set_cfctl(sn_cfctl, setto ) |
|---|
| 464 | !!---------------------------------------------------------------------- |
|---|
| 465 | !! *** ROUTINE nemo_set_cfctl *** |
|---|
| 466 | !! |
|---|
| 467 | !! ** Purpose : Set elements of the output control structure to setto. |
|---|
| 468 | !! |
|---|
| 469 | !! ** Method : Note this routine can be used to switch on/off some |
|---|
| 470 | !! types of output for selected areas. |
|---|
| 471 | !!---------------------------------------------------------------------- |
|---|
| 472 | TYPE(sn_ctl), INTENT(inout) :: sn_cfctl |
|---|
| 473 | LOGICAL , INTENT(in ) :: setto |
|---|
| 474 | !!---------------------------------------------------------------------- |
|---|
| 475 | sn_cfctl%l_runstat = setto |
|---|
| 476 | sn_cfctl%l_trcstat = setto |
|---|
| 477 | sn_cfctl%l_oceout = setto |
|---|
| 478 | sn_cfctl%l_layout = setto |
|---|
| 479 | sn_cfctl%l_prtctl = setto |
|---|
| 480 | sn_cfctl%l_prttrc = setto |
|---|
| 481 | sn_cfctl%l_oasout = setto |
|---|
| 482 | END SUBROUTINE nemo_set_cfctl |
|---|
| 483 | |
|---|
| 484 | SUBROUTINE istate_init( Kmm, Kaa ) |
|---|
| 485 | !!---------------------------------------------------------------------- |
|---|
| 486 | !! *** ROUTINE istate_init *** |
|---|
| 487 | !! |
|---|
| 488 | !! ** Purpose : Initialization to zero of the dynamics and tracers. |
|---|
| 489 | !!---------------------------------------------------------------------- |
|---|
| 490 | INTEGER, INTENT(in) :: Kmm, Kaa ! ocean time level indices |
|---|
| 491 | ! |
|---|
| 492 | ! now fields ! after fields ! |
|---|
| 493 | uu (:,:,:,Kmm) = 0._wp ; uu(:,:,:,Kaa) = 0._wp ! |
|---|
| 494 | vv (:,:,:,Kmm) = 0._wp ; vv(:,:,:,Kaa) = 0._wp ! |
|---|
| 495 | ww (:,:,:) = 0._wp ! ! |
|---|
| 496 | hdiv (:,:,:) = 0._wp ! ! |
|---|
| 497 | ts (:,:,:,:,Kmm) = 0._wp ! ! |
|---|
| 498 | ! |
|---|
| 499 | rhd (:,:,:) = 0.e0 |
|---|
| 500 | rhop (:,:,:) = 0.e0 |
|---|
| 501 | rn2 (:,:,:) = 0.e0 |
|---|
| 502 | ! |
|---|
| 503 | END SUBROUTINE istate_init |
|---|
| 504 | |
|---|
| 505 | |
|---|
| 506 | SUBROUTINE stp_ctl( kt ) |
|---|
| 507 | !!---------------------------------------------------------------------- |
|---|
| 508 | !! *** ROUTINE stp_ctl *** |
|---|
| 509 | !! |
|---|
| 510 | !! ** Purpose : Control the run |
|---|
| 511 | !! |
|---|
| 512 | !! ** Method : - Save the time step in numstp |
|---|
| 513 | !! |
|---|
| 514 | !! ** Actions : 'time.step' file containing the last ocean time-step |
|---|
| 515 | !!---------------------------------------------------------------------- |
|---|
| 516 | INTEGER, INTENT(in ) :: kt ! ocean time-step index |
|---|
| 517 | !!---------------------------------------------------------------------- |
|---|
| 518 | ! |
|---|
| 519 | IF( kt == nit000 .AND. lwm ) THEN |
|---|
| 520 | WRITE(numout,*) |
|---|
| 521 | WRITE(numout,*) 'stp_ctl : time-stepping control' |
|---|
| 522 | WRITE(numout,*) '~~~~~~~' |
|---|
| 523 | ! open time.step file |
|---|
| 524 | CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea ) |
|---|
| 525 | ENDIF |
|---|
| 526 | ! |
|---|
| 527 | IF(lwm) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp |
|---|
| 528 | IF(lwm) REWIND( numstp ) ! -------------------------- |
|---|
| 529 | ! |
|---|
| 530 | END SUBROUTINE stp_ctl |
|---|
| 531 | !!====================================================================== |
|---|
| 532 | END MODULE nemogcm |
|---|
