New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/branches/2020/dev_r13327_KERNEL-06_2_techene_e3/src/SWE – NEMO

source: NEMO/branches/2020/dev_r13327_KERNEL-06_2_techene_e3/src/SWE/restart.F90 @ 13604

Last change on this file since 13604 was 13604, checked in by techene, 4 years ago

#2385 cleaning, relevant features moved to OCE, bug corrected in dynvor
File size: 13.4 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_si3
23   USE phycst          ! physical constants
24!!st   USE eosbn2          ! equation of state            (eos bn2 routine)
25!!st   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diu_bulk
30   USE lib_mpp         ! distribued memory computing library
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   rst_opn         ! routine called by step module
36   PUBLIC   rst_write       ! routine called by step module
37   PUBLIC   rst_read        ! routine called by istate module
38   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
39
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id: restart.F90 13427 2020-08-21 16:26:57Z techene $
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE rst_opn( kt )
48      !!---------------------------------------------------------------------
49      !!                   ***  ROUTINE rst_opn  ***
50      !!                     
51      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
52      !!              + open the restart when we are one time step before nitrst
53      !!                   - restart header is defined when kt = nitrst-1
54      !!                   - restart data  are written when kt = nitrst
55      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
56      !!----------------------------------------------------------------------
57      INTEGER, INTENT(in) ::   kt     ! ocean time-step
58      !!
59      CHARACTER(LEN=20)   ::   clkt      ! ocean time-step deine as a character
60      CHARACTER(LEN=50)   ::   clname    ! ocean output restart file name
61      CHARACTER(lc)       ::   clpath    ! full path to ocean output restart file
62      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
63      CHARACTER(LEN=256)  ::   clinfo    ! info character
64      !!----------------------------------------------------------------------
65      !
66      IF( kt == nit000 ) THEN   ! default definitions
67         lrst_oce = .FALSE.   
68         IF( ln_rst_list ) THEN
69            nrst_lst = 1
70            nitrst = nn_stocklist( nrst_lst )
71         ELSE
72            nitrst = nitend
73         ENDIF
74      ENDIF
75     
76      IF( .NOT. ln_rst_list .AND. nn_stock == -1 )   RETURN   ! we will never do any restart
77
78      ! frequency-based restart dumping (nn_stock)
79      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nn_stock ) == 0 ) THEN   
80         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
81         nitrst = kt + nn_stock - 1                  ! define the next value of nitrst for restart writing
82         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
83      ENDIF
84      ! to get better performances with NetCDF format:
85      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
86      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
87      IF( kt == nitrst - 1 .OR. nn_stock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
88         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
89            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
90            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
91            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
92            ENDIF
93            ! create the file
94            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
95            clpath = TRIM(cn_ocerst_outdir)
96            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
97            IF(lwp) THEN
98               WRITE(numout,*)
99               IF(.NOT.lwxios) THEN
100                  WRITE(numout,*) '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
101                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
102                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
103                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
104                  ENDIF
105               ENDIF
106            ENDIF
107            !
108            IF(.NOT.lwxios) THEN
109               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
110            ELSE
111#if defined key_iomput
112               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
113               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
114                  clpname = clname
115               ELSE
116                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
117               ENDIF
118               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname), .false. )
119               CALL xios_update_calendar(nitrst)
120               CALL iom_swap(      cxios_context          )
121#else
122               clinfo = 'Can not use XIOS in rst_opn'
123               CALL ctl_stop(TRIM(clinfo))
124#endif
125            ENDIF
126            lrst_oce = .TRUE.
127         ENDIF
128      ENDIF
129      !
130   END SUBROUTINE rst_opn
131
132
133   SUBROUTINE rst_write( kt, Kbb, Kmm )
134      !!---------------------------------------------------------------------
135      !!                   ***  ROUTINE rstwrite  ***
136      !!                     
137      !! ** Purpose :   Write restart fields in NetCDF format
138      !!
139      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
140      !!              file, save fields which are necessary for restart
141      !!----------------------------------------------------------------------
142      INTEGER, INTENT(in) ::   kt         ! ocean time-step
143      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
144      !!----------------------------------------------------------------------
145      IF(lwxios) CALL iom_swap(      cwxios_context          )
146      CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rn_Dt       , ldxios = lwxios)   ! dynamics time step
147      CALL iom_delay_rst( 'WRITE', 'OCE', numrow )   ! save only ocean delayed global communication variables
148     
149      CALL iom_rstput( kt, nitrst, numrow, 'ub'  , uu(:,:,:,Kbb), ldxios = lwxios )     ! before fields
150      CALL iom_rstput( kt, nitrst, numrow, 'vb'  , vv(:,:,:,Kbb), ldxios = lwxios )
151      CALL iom_rstput( kt, nitrst, numrow, 'sshb',ssh(:,:  ,Kbb), ldxios = lwxios )
152      !
153      CALL iom_rstput( kt, nitrst, numrow, 'un'  , uu(:,:,:,Kmm), ldxios = lwxios )     ! now fields
154      CALL iom_rstput( kt, nitrst, numrow, 'vn'  , vv(:,:,:,Kmm), ldxios = lwxios )
155      CALL iom_rstput( kt, nitrst, numrow, 'sshn',ssh(:,:  ,Kmm), ldxios = lwxios )
156     
157      IF(lwxios) CALL iom_swap(      cxios_context          )
158      IF( kt == nitrst ) THEN
159         IF(.NOT.lwxios) THEN
160            CALL iom_close( numrow )     ! close the restart file (only at last time step)
161         ELSE
162            CALL iom_context_finalize(      cwxios_context          )
163         ENDIF
164         lrst_oce = .FALSE.
165         IF( ln_rst_list ) THEN
166            nrst_lst = MIN(nrst_lst + 1, SIZE(nn_stocklist,1))
167            nitrst = nn_stocklist( nrst_lst )
168         ENDIF
169      ENDIF
170      !
171   END SUBROUTINE rst_write
172
173
174   SUBROUTINE rst_read_open
175      !!----------------------------------------------------------------------
176      !!                   ***  ROUTINE rst_read_open  ***
177      !!
178      !! ** Purpose :   Open read files for NetCDF restart
179      !!
180      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
181      !!                the file has already been opened
182      !!----------------------------------------------------------------------
183      LOGICAL        ::   llok
184      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
185      !!----------------------------------------------------------------------
186      !
187      IF( numror <= 0 ) THEN
188         IF(lwp) THEN                                             ! Contol prints
189            WRITE(numout,*)
190            WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
191            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
192            WRITE(numout,*) '~~~~~~~~'
193         ENDIF
194         lxios_sini = .FALSE.
195         clpath = TRIM(cn_ocerst_indir)
196         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
197         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
198! are we using XIOS to read the data? Part above will have to modified once XIOS
199! can handle checking if variable is in the restart file (there will be no need to open
200! restart)
201         IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
202         IF( lrxios) THEN
203             crxios_context = 'nemo_rst'
204             IF( .NOT.lxios_set ) THEN
205                 IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
206                 CALL iom_init( crxios_context )
207                 lxios_set = .TRUE.
208             ENDIF
209         ENDIF
210         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
211             CALL iom_init( crxios_context )
212             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
213             lxios_set = .TRUE.
214         ENDIF
215      ENDIF
216
217   END SUBROUTINE rst_read_open
218
219
220   SUBROUTINE rst_read( Kbb, Kmm )
221      !!----------------------------------------------------------------------
222      !!                   ***  ROUTINE rst_read  ***
223      !!
224      !! ** Purpose :   Read files for NetCDF restart
225      !!
226      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
227      !!----------------------------------------------------------------------
228      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
229      REAL(wp) ::   zrdt
230      INTEGER  ::   jk
231      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
232      !!----------------------------------------------------------------------
233
234      CALL rst_read_open           ! open restart for reading (if not already opened)
235
236      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
237      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
238         CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
239         IF( zrdt /= rn_Dt ) THEN
240            IF(lwp) WRITE( numout,*)
241            IF(lwp) WRITE( numout,*) 'rst_read:  rdt not equal to the read one'
242            IF(lwp) WRITE( numout,*)
243            IF(lwp) WRITE( numout,*) '      ==>>>   forced euler first time-step'
244            l_1st_euler =  .TRUE.
245         ENDIF
246      ENDIF
247
248      CALL iom_delay_rst( 'READ', 'OCE', numror )   ! read only ocean delayed global communication variables
249     
250      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
251         ! before fields
252         CALL iom_get( numror, jpdom_auto, 'ub'     , uu(:,:,:       ,Kbb), ldxios = lrxios, cd_type = 'U', psgn = -1._wp )
253         CALL iom_get( numror, jpdom_auto, 'vb'     , vv(:,:,:       ,Kbb), ldxios = lrxios, cd_type = 'V', psgn = -1._wp )
254#if ! defined key_qco
255         CALL iom_get( numror, jpdom_auto, 'sshb'   ,ssh(:,:         ,Kbb), ldxios = lrxios )
256#endif
257      ELSE
258         l_1st_euler =  .TRUE.      ! before field not found, forced euler 1st time-step
259      ENDIF
260      !
261      ! now fields
262      CALL iom_get( numror, jpdom_auto, 'un'     , uu(:,:,:       ,Kmm), ldxios = lrxios, cd_type = 'U', psgn = -1._wp )
263      CALL iom_get( numror, jpdom_auto, 'vn'     , vv(:,:,:       ,Kmm), ldxios = lrxios, cd_type = 'V', psgn = -1._wp )
264#if ! defined key_qco
265      CALL iom_get( numror, jpdom_auto, 'sshn'   ,ssh(:,:         ,Kmm), ldxios = lrxios )
266#endif
267      !
268      IF( l_1st_euler ) THEN                                  ! Euler restart
269         uu   (:,:,:  ,Kbb) = uu   (:,:,:  ,Kmm)              ! all before fields set to now values
270         vv   (:,:,:  ,Kbb) = vv   (:,:,:  ,Kmm)
271         ssh  (:,:    ,Kbb) = ssh  (:,:    ,Kmm)
272      ENDIF
273      !
274      ww (:,:,:) = 0._wp !!st  gm is right 3D only !!
275      !
276   END SUBROUTINE rst_read
277
278   !!=====================================================================
279END MODULE restart
Note: See TracBrowser for help on using the repository browser.