New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in NEMO/branches/2020/dev_r13333_KERNEL-08_techene_gm_HPG_SPG/src/OCE/DYN – NEMO

source: NEMO/branches/2020/dev_r13333_KERNEL-08_techene_gm_HPG_SPG/src/OCE/DYN/dynhpg.F90 @ 13364

Last change on this file since 13364 was 13364, checked in by techene, 4 years ago

hydrostatic pressure gradient is computed with density anomaly when possible
  • Property svn:keywords set to Id
File size: 69.8 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE isf_oce , ONLY : risfload  ! ice shelf  (risfload variable)
34   USE isfload , ONLY : isf_load  ! ice shelf  (isf_load routine )
35   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
36   USE dom_oce         ! ocean space and time domain
37   USE wet_dry         ! wetting and drying
38   USE phycst          ! physical constants
39   USE trd_oce         ! trends: ocean variables
40   USE trddyn          ! trend manager: dynamics
41   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE prtctl          ! Print control
45   USE lbclnk          ! lateral boundary condition
46   USE lib_mpp         ! MPP library
47   USE eosbn2          ! compute density
48   USE timing          ! Timing
49   USE iom
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   dyn_hpg        ! routine called by step module
55   PUBLIC   dyn_hpg_init   ! routine called by opa module
56
57   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
58   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
59   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
60   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
61   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
62   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
63   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
64
65   !                                !! Flag to control the type of hydrostatic pressure gradient
66   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
67   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
68   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
69   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
70   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
71   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
72   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
73   !
74   INTEGER, PUBLIC ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
75
76   !! * Substitutions
77#  include "do_loop_substitute.h90"
78#  include "domzgr_substitute.h90"
79
80   !!----------------------------------------------------------------------
81   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
82   !! $Id$
83   !! Software governed by the CeCILL license (see ./LICENSE)
84   !!----------------------------------------------------------------------
85CONTAINS
86
87   SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
88      !!---------------------------------------------------------------------
89      !!                  ***  ROUTINE dyn_hpg  ***
90      !!
91      !! ** Method  :   Call the hydrostatic pressure gradient routine
92      !!              using the scheme defined in the namelist
93      !!
94      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
95      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
96      !!----------------------------------------------------------------------
97      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
98      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
99      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
100      !
101      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
102      !!----------------------------------------------------------------------
103      !
104      IF( ln_timing )   CALL timing_start('dyn_hpg')
105      !
106      IF( l_trddyn ) THEN                    ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
107         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
108         ztrdu(:,:,:) = puu(:,:,:,Krhs)
109         ztrdv(:,:,:) = pvv(:,:,:,Krhs)
110      ENDIF
111      !
112      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
113      CASE ( np_zco )   ;   CALL hpg_zco    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate
114      CASE ( np_zps )   ;   CALL hpg_zps    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate plus partial steps (interpolation)
115      CASE ( np_sco )   ;   CALL hpg_sco    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (standard jacobian formulation)
116      CASE ( np_djc )   ;   CALL hpg_djc    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Density Jacobian with Cubic polynomial)
117      CASE ( np_prj )   ;   CALL hpg_prj    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Pressure Jacobian scheme)
118      CASE ( np_isf )   ;   CALL hpg_isf    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate similar to sco modify for ice shelf
119      END SELECT
120      !
121      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
122         ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
123         ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
124         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
125         DEALLOCATE( ztrdu , ztrdv )
126      ENDIF
127      !
128      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' hpg  - Ua: ', mask1=umask,   &
129         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
130      !
131      IF( ln_timing )   CALL timing_stop('dyn_hpg')
132      !
133   END SUBROUTINE dyn_hpg
134
135
136   SUBROUTINE dyn_hpg_init( Kmm )
137      !!----------------------------------------------------------------------
138      !!                 ***  ROUTINE dyn_hpg_init  ***
139      !!
140      !! ** Purpose :   initializations for the hydrostatic pressure gradient
141      !!              computation and consistency control
142      !!
143      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
144      !!      with the type of vertical coordinate used (zco, zps, sco)
145      !!----------------------------------------------------------------------
146      INTEGER, INTENT( in ) :: Kmm   ! ocean time level index
147      !
148      INTEGER ::   ioptio = 0      ! temporary integer
149      INTEGER ::   ios             ! Local integer output status for namelist read
150      !!
151      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
152      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
153      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
154      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
155      !!
156      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
157         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
158      !!----------------------------------------------------------------------
159      !
160      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
161901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
162      !
163      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
164902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
165      IF(lwm) WRITE ( numond, namdyn_hpg )
166      !
167      IF(lwp) THEN                   ! Control print
168         WRITE(numout,*)
169         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
170         WRITE(numout,*) '~~~~~~~~~~~~'
171         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
172         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
173         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
174         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
175         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
176         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
177         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
178      ENDIF
179      !
180      IF( ln_hpg_djc )   &
181         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method',   &
182         &                 '   currently disabled (bugs under investigation).'        ,   &
183         &                 '   Please select either  ln_hpg_sco or  ln_hpg_prj instead' )
184         !
185      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )          &
186         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ',   &
187         &                 '   the standard jacobian formulation hpg_sco    or '    ,   &
188         &                 '   the pressure jacobian formulation hpg_prj'             )
189         !
190      IF( ln_hpg_isf ) THEN
191         IF( .NOT. ln_isfcav )   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
192       ELSE
193         IF(       ln_isfcav )   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
194      ENDIF
195      !
196      !                               ! Set nhpg from ln_hpg_... flags & consistency check
197      nhpg   = np_ERROR
198      ioptio = 0
199      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
200      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
201      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
202      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
203      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
204      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
205      !
206      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
207      !
208      IF(lwp) THEN
209         WRITE(numout,*)
210         SELECT CASE( nhpg )
211         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
212         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
213         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
214         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
215         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
216         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
217         END SELECT
218         WRITE(numout,*)
219      ENDIF
220      !                         
221   END SUBROUTINE dyn_hpg_init
222
223
224   SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
225      !!---------------------------------------------------------------------
226      !!                  ***  ROUTINE hpg_zco  ***
227      !!
228      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
229      !!      The now hydrostatic pressure gradient at a given level, jk,
230      !!      is computed by taking the vertical integral of the in-situ
231      !!      density gradient along the model level from the suface to that
232      !!      level:    zhpi = grav .....
233      !!                zhpj = grav .....
234      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
235      !!            puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
236      !!            pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
237      !!
238      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
239      !!----------------------------------------------------------------------
240      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
241      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
242      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
243      !
244      INTEGER  ::   ji, jj, jk       ! dummy loop indices
245      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
246      REAL(wp), DIMENSION(jpi,jpj) ::  zhpi, zhpj
247      !!----------------------------------------------------------------------
248      !
249      IF( kt == nit000 ) THEN
250         IF(lwp) WRITE(numout,*)
251         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
252         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
253      ENDIF
254      !
255      zcoef0 = - grav * 0.5_wp            ! Local constant initialization
256      !
257      DO_2D( 0, 0, 0, 0 )                 ! Surface value
258         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
259         !                                   ! hydrostatic pressure gradient
260         zhpi(ji,jj) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
261         zhpj(ji,jj) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
262         !                                   ! add to the general momentum trend
263         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj)
264         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj)
265      END_2D
266      !
267      DO_3D( 0, 0, 0, 0, 2, jpkm1 )        ! interior value (2=<jk=<jpkm1)
268         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
269         !                                   ! hydrostatic pressure gradient
270         zhpi(ji,jj) = zhpi(ji,jj) + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )  &
271            &                                  - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
272
273         zhpj(ji,jj) = zhpj(ji,jj) + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )  &
274            &                                  - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
275         !                                   ! add to the general momentum trend
276         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj)
277         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj)
278      END_3D
279      !
280   END SUBROUTINE hpg_zco
281
282
283   SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
284      !!---------------------------------------------------------------------
285      !!                 ***  ROUTINE hpg_zps  ***
286      !!
287      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
288      !!
289      !! ** Action  : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
290      !!----------------------------------------------------------------------
291      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
292      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
293      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
294      !!
295      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
296      INTEGER  ::   iku, ikv                         ! temporary integers
297      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
298      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
299      REAL(wp), DIMENSION(jpi,jpj) :: zgtsu, zgtsv, zgru, zgrv
300      !!----------------------------------------------------------------------
301      !
302      IF( kt == nit000 ) THEN
303         IF(lwp) WRITE(numout,*)
304         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
305         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
306      ENDIF
307
308      ! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
309      CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
310
311      ! Local constant initialization
312      zcoef0 = - grav * 0.5_wp
313
314      !  Surface value (also valid in partial step case)
315      DO_2D( 0, 0, 0, 0 )
316         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
317         ! hydrostatic pressure gradient
318         zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
319         zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
320         ! add to the general momentum trend
321         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
322         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
323      END_2D
324
325      ! interior value (2=<jk=<jpkm1)
326      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
327         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
328         ! hydrostatic pressure gradient
329         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
330            &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
331            &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
332
333         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
334            &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
335            &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
336         ! add to the general momentum trend
337         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
338         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
339      END_3D
340
341      ! partial steps correction at the last level  (use zgru & zgrv computed in zpshde.F90)
342      DO_2D( 0, 0, 0, 0 )
343         iku = mbku(ji,jj)
344         ikv = mbkv(ji,jj)
345         zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj  ,iku,Kmm) )
346         zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji  ,jj+1,ikv,Kmm) )
347         IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
348            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku)         ! subtract old value
349            zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
350               &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
351            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
352         ENDIF
353         IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
354            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv)         ! subtract old value
355            zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
356               &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
357            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
358         ENDIF
359      END_2D
360      !
361   END SUBROUTINE hpg_zps
362
363
364   SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
365      !!---------------------------------------------------------------------
366      !!                  ***  ROUTINE hpg_sco  ***
367      !!
368      !! ** Method  :   s-coordinate case. Jacobian scheme.
369      !!      The now hydrostatic pressure gradient at a given level, jk,
370      !!      is computed by taking the vertical integral of the in-situ
371      !!      density gradient along the model level from the suface to that
372      !!      level. s-coordinates (ln_sco): a corrective term is added
373      !!      to the horizontal pressure gradient :
374      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
375      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
376      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
377      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
378      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
379      !!
380      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
381      !!----------------------------------------------------------------------
382      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
383      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
384      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
385      !!
386      INTEGER  ::   ji, jj, jk, jii, jjj           ! dummy loop indices
387      REAL(wp) ::   zcoef0, zuap, zvap, ztmp       ! local scalars
388      LOGICAL  ::   ll_tmp1, ll_tmp2               ! local logical variables
389      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
390      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
391      !!----------------------------------------------------------------------
392      !
393      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
394      !
395      IF( kt == nit000 ) THEN
396         IF(lwp) WRITE(numout,*)
397         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
398         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
399      ENDIF
400      !
401      zcoef0 = - grav * 0.5_wp
402      !
403      IF( ln_wd_il ) THEN
404        DO_2D( 0, 0, 0, 0 )
405          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)               ,  ssh(ji+1,jj,Kmm) ) >                &
406               &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
407               &    MAX(  ssh(ji,jj,Kmm) +  ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
408               &                                                       > rn_wdmin1 + rn_wdmin2
409          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)              -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (       &
410               &    MAX(   ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
411               &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
412
413          IF(ll_tmp1) THEN
414            zcpx(ji,jj) = 1.0_wp
415          ELSE IF(ll_tmp2) THEN
416            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
417            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
418                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
419          ELSE
420            zcpx(ji,jj) = 0._wp
421          END IF
422   
423          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
424               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
425               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
426               &                                                      > rn_wdmin1 + rn_wdmin2
427          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
428               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
429               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
430
431          IF(ll_tmp1) THEN
432            zcpy(ji,jj) = 1.0_wp
433          ELSE IF(ll_tmp2) THEN
434            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
435            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
436                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
437          ELSE
438            zcpy(ji,jj) = 0._wp
439          END IF
440        END_2D
441        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
442      END IF
443      !
444      DO_2D( 0, 0, 0, 0 )              ! Surface value
445         !                                   ! hydrostatic pressure gradient along s-surfaces
446         zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj)                      &
447            &          * (  e3w(ji+1,jj  ,1,Kmm) * rhd(ji+1,jj  ,1)  &
448            &             - e3w(ji  ,jj  ,1,Kmm) * rhd(ji  ,jj  ,1)  )
449         zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj)                      &
450            &          * (  e3w(ji  ,jj+1,1,Kmm) * rhd(ji  ,jj+1,1)  &
451            &             - e3w(ji  ,jj  ,1,Kmm) * rhd(ji  ,jj  ,1)  )
452         !                                   ! s-coordinate pressure gradient correction
453         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) )   &
454            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
455         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) )   &
456            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
457         !
458         IF( ln_wd_il ) THEN
459            zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
460            zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
461            zuap = zuap * zcpx(ji,jj)
462            zvap = zvap * zcpy(ji,jj)
463         ENDIF
464         !                                   ! add to the general momentum trend
465         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
466         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
467      END_2D
468      !
469      DO_3D( 0, 0, 0, 0, 2, jpkm1 )    ! interior value (2=<jk=<jpkm1)
470         !                                   ! hydrostatic pressure gradient along s-surfaces
471         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)                         &
472            &           * (  e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )  &
473            &              - e3w(ji  ,jj,jk,Kmm) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  )
474         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)                         &
475            &           * (  e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )  &
476            &              - e3w(ji,jj  ,jk,Kmm) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  )
477         !                                   ! s-coordinate pressure gradient correction
478         zuap = -zcoef0 * ( rhd  (ji+1,jj  ,jk) + rhd  (ji,jj,jk) ) &
479            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
480         zvap = -zcoef0 * ( rhd  (ji  ,jj+1,jk) + rhd  (ji,jj,jk) ) &
481            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
482         !
483         IF( ln_wd_il ) THEN
484            zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
485            zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
486            zuap = zuap * zcpx(ji,jj)
487            zvap = zvap * zcpy(ji,jj)
488         ENDIF
489         !
490         ! add to the general momentum trend
491         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
492         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
493      END_3D
494      !
495      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
496      !
497   END SUBROUTINE hpg_sco
498
499
500   SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
501      !!---------------------------------------------------------------------
502      !!                  ***  ROUTINE hpg_isf  ***
503      !!
504      !! ** Method  :   s-coordinate case. Jacobian scheme.
505      !!      The now hydrostatic pressure gradient at a given level, jk,
506      !!      is computed by taking the vertical integral of the in-situ
507      !!      density gradient along the model level from the suface to that
508      !!      level. s-coordinates (ln_sco): a corrective term is added
509      !!      to the horizontal pressure gradient :
510      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
511      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
512      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
513      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
514      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
515      !!      iceload is added
516      !!     
517      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
518      !!----------------------------------------------------------------------
519      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
520      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
521      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
522      !!
523      INTEGER  ::   ji, jj, jk             ! dummy loop indices
524      INTEGER  ::   ikt ,  ikti1,  iktj1   ! local integer
525      REAL(wp) ::   ze3w, ze3wi1, ze3wj1   ! local scalars
526      REAL(wp) ::   zcoef0, zuap, zvap     !   -      -
527      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
528      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
529      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
530      !!----------------------------------------------------------------------
531      !
532      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
533      !
534      !                          ! iniitialised to 0. zhpi zhpi
535      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
536
537      ! compute rhd at the ice/oce interface (ocean side)
538      ! usefull to reduce residual current in the test case ISOMIP with no melting
539      DO ji = 1, jpi
540        DO jj = 1, jpj
541          ikt = mikt(ji,jj)
542          zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
543          zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
544        END DO
545      END DO
546      CALL eos( zts_top, risfdep, zrhdtop_oce )
547
548      !                     !===========================!
549      !                     !=====  surface value  =====!
550      !                     !===========================!
551      DO_2D( 0, 0, 0, 0 )
552         ikt   = mikt(ji  ,jj  )   ;   ze3w   = e3w(ji  ,jj  ,ikt  ,Kmm)
553         ikti1 = mikt(ji+1,jj  )   ;   ze3wi1 = e3w(ji+1,jj  ,ikti1,Kmm)
554         iktj1 = mikt(ji  ,jj+1)   ;   ze3wj1 = e3w(ji  ,jj+1,iktj1,Kmm)
555         !                          ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
556         !                          ! we assume ISF is in isostatic equilibrium
557         zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) * (   risfload(ji+1,jj) - risfload(ji,jj)  &
558            &                                       + 0.5_wp * ( ze3wi1 * ( rhd(ji+1,jj,ikti1) + zrhdtop_oce(ji+1,jj) )     &
559            &                                                  - ze3w   * ( rhd(ji  ,jj,ikt  ) + zrhdtop_oce(ji  ,jj) ) )   )
560         zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) * (   risfload(ji,jj+1) - risfload(ji,jj)  &
561            &                                       + 0.5_wp * ( ze3wj1 * ( rhd(ji,jj+1,iktj1) + zrhdtop_oce(ji,jj+1) )      &
562            &                                                  - ze3w   * ( rhd(ji,jj  ,ikt  ) + zrhdtop_oce(ji,jj  ) ) )   ) 
563         !                          ! s-coordinate pressure gradient correction (=0 if z coordinate)
564         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) )   &
565            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
566         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) )   &
567            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
568         !                          ! add to the general momentum trend
569         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
570         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
571      END_2D
572      !   
573      !                     !=============================!
574      !                     !=====  interior values  =====!
575      !                     !=============================!
576      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
577         ze3w   = e3w(ji  ,jj  ,jk,Kmm)
578         ze3wi1 = e3w(ji+1,jj  ,jk,Kmm)
579         ze3wj1 = e3w(ji  ,jj+1,jk,Kmm)
580         !                          ! hydrostatic pressure gradient along s-surfaces
581         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
582            &           * (  ze3wi1 * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) * wmask(ji+1,jj,jk)   &
583            &              - ze3w   * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) ) * wmask(ji  ,jj,jk)   )
584         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
585            &           * (  ze3wj1 * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) * wmask(ji,jj+1,jk)   &
586            &              - ze3w   * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) ) * wmask(ji,jj  ,jk)   )
587         !                          ! s-coordinate pressure gradient correction
588         zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
589            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
590         zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
591            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
592         !                          ! add to the general momentum trend
593         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
594         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
595      END_3D
596      !
597   END SUBROUTINE hpg_isf
598
599
600   SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
601      !!---------------------------------------------------------------------
602      !!                  ***  ROUTINE hpg_djc  ***
603      !!
604      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
605      !!
606      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
607      !!----------------------------------------------------------------------
608      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
609      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
610      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
611      !!
612      INTEGER  ::   ji, jj, jk          ! dummy loop indices
613      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
614      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
615      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
616      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
617      REAL(wp), DIMENSION(jpi,jpj)     ::   zpgu, zpgv   ! 2D workspace
618      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
619      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   dzx, dzy, dzz, dzu, dzv, dzw
620      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, drhoy, drhoz, drhou, drhov, drhow
621      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   rho_i, rho_j, rho_k
622      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
623      !!----------------------------------------------------------------------
624      !
625      IF( ln_wd_il ) THEN
626         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
627        DO_2D( 0, 0, 0, 0 )
628          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
629               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
630               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
631               &                                                      > rn_wdmin1 + rn_wdmin2
632          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (        &
633               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
634               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
635          IF(ll_tmp1) THEN
636            zcpx(ji,jj) = 1.0_wp
637          ELSE IF(ll_tmp2) THEN
638            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
639            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
640                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
641          ELSE
642            zcpx(ji,jj) = 0._wp
643          END IF
644   
645          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
646               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
647               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
648               &                                                      > rn_wdmin1 + rn_wdmin2
649          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
650               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
651               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
652
653          IF(ll_tmp1) THEN
654            zcpy(ji,jj) = 1.0_wp
655          ELSE IF(ll_tmp2) THEN
656            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
657            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
658                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
659          ELSE
660            zcpy(ji,jj) = 0._wp
661          END IF
662        END_2D
663        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
664      END IF
665
666      IF( kt == nit000 ) THEN
667         IF(lwp) WRITE(numout,*)
668         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
669         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
670      ENDIF
671
672      ! Local constant initialization
673      zcoef0 = - grav * 0.5_wp
674      z1_10  = 1._wp / 10._wp
675      z1_12  = 1._wp / 12._wp
676
677      !----------------------------------------------------------------------------------------
678      !  compute and store in provisional arrays elementary vertical and horizontal differences
679      !----------------------------------------------------------------------------------------
680
681!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
682
683      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
684         drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
685         dzz  (ji,jj,jk) = gde3w(ji  ,jj  ,jk) - gde3w(ji,jj,jk-1)
686         drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
687         dzx  (ji,jj,jk) = gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk  )
688         drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
689         dzy  (ji,jj,jk) = gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk  )
690      END_3D
691
692      !-------------------------------------------------------------------------
693      ! compute harmonic averages using eq. 5.18
694      !-------------------------------------------------------------------------
695      zep = 1.e-15
696
697!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
698!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
699
700      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
701         cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
702
703         cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
704         cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
705
706         cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
707         cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
708
709         IF( cffw > zep) THEN
710            drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
711               &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
712         ELSE
713            drhow(ji,jj,jk) = 0._wp
714         ENDIF
715
716         dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
717            &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
718
719         IF( cffu > zep ) THEN
720            drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
721               &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
722         ELSE
723            drhou(ji,jj,jk ) = 0._wp
724         ENDIF
725
726         IF( cffx > zep ) THEN
727            dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
728               &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
729         ELSE
730            dzu(ji,jj,jk) = 0._wp
731         ENDIF
732
733         IF( cffv > zep ) THEN
734            drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
735               &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
736         ELSE
737            drhov(ji,jj,jk) = 0._wp
738         ENDIF
739
740         IF( cffy > zep ) THEN
741            dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
742               &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
743         ELSE
744            dzv(ji,jj,jk) = 0._wp
745         ENDIF
746
747      END_3D
748
749      !----------------------------------------------------------------------------------
750      ! apply boundary conditions at top and bottom using 5.36-5.37
751      !----------------------------------------------------------------------------------
752      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
753      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
754      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
755
756      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
757      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
758      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
759
760
761      !--------------------------------------------------------------
762      ! Upper half of top-most grid box, compute and store
763      !-------------------------------------------------------------
764
765!!bug gm   :  e3w-gde3w(:,:,:) = 0.5*e3w  ....  and gde3w(:,:,2)-gde3w(:,:,1)=e3w(:,:,2,Kmm) ....   to be verified
766!          true if gde3w(:,:,:) is really defined as the sum of the e3w scale factors as, it seems to me, it should be
767
768      DO_2D( 0, 0, 0, 0 )
769         rho_k(ji,jj,1) = -grav * ( e3w(ji,jj,1,Kmm) - gde3w(ji,jj,1) )               &
770            &                   * (  rhd(ji,jj,1)                                     &
771            &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
772            &                              * ( e3w  (ji,jj,1,Kmm) - gde3w(ji,jj,1) )  &
773            &                              / ( gde3w(ji,jj,2) - gde3w(ji,jj,1) )  )
774      END_2D
775
776!!bug gm    : here also, simplification is possible
777!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
778
779      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
780
781         rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
782            &                     * ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) )                                   &
783            &            - grav * z1_10 * (                                                                   &
784            &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
785            &   * ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
786            &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
787            &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
788            &                             )
789
790         rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
791            &                     * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) )                                   &
792            &            - grav* z1_10 * (                                                                    &
793            &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
794            &   * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
795            &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
796            &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
797            &                            )
798
799         rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
800            &                     * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) )                                   &
801            &            - grav* z1_10 * (                                                                    &
802            &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
803            &   * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
804            &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
805            &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
806            &                            )
807
808      END_3D
809      CALL lbc_lnk_multi( 'dynhpg', rho_k, 'W', 1.0_wp, rho_i, 'U', 1.0_wp, rho_j, 'V', 1.0_wp )
810      !
811      ! ---------------
812      !  Surface pressure gradient to be removed
813      ! ---------------
814      DO_2D( 0, 0, 0, 0 )
815         zpgu(ji,jj) = - grav * ( ssh(ji+1,jj,Kmm) - ssh(ji,jj,Kmm) ) * r1_e1u(ji,jj)
816         zpgv(ji,jj) = - grav * ( ssh(ji,jj+1,Kmm) - ssh(ji,jj,Kmm) ) * r1_e2v(ji,jj)
817      END_2D
818      !
819      ! ---------------
820      !  Surface value
821      ! ---------------
822      DO_2D( 0, 0, 0, 0 )
823         zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
824         zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
825         IF( ln_wd_il ) THEN
826           zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
827           zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
828         ENDIF
829         ! add to the general momentum trend
830         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) - zpgu(ji,jj)
831         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) - zpgv(ji,jj)
832      END_2D
833
834      ! ----------------
835      !  interior value   (2=<jk=<jpkm1)
836      ! ----------------
837      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
838         ! hydrostatic pressure gradient along s-surfaces
839         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
840            &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
841            &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
842         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
843            &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
844            &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
845         IF( ln_wd_il ) THEN
846           zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
847           zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
848         ENDIF
849         ! add to the general momentum trend
850         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) - zpgu(ji,jj)
851         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) - zpgv(ji,jj)
852      END_3D
853      !
854      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
855      !
856   END SUBROUTINE hpg_djc
857
858
859   SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
860      !!---------------------------------------------------------------------
861      !!                  ***  ROUTINE hpg_prj  ***
862      !!
863      !! ** Method  :   s-coordinate case.
864      !!      A Pressure-Jacobian horizontal pressure gradient method
865      !!      based on the constrained cubic-spline interpolation for
866      !!      all vertical coordinate systems
867      !!
868      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
869      !!----------------------------------------------------------------------
870      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
871      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
872      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
873      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
874      !!
875      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
876      REAL(wp) ::   zcoef0, znad                    ! local scalars
877      !
878      !! The local variables for the correction term
879      INTEGER  :: jk1, jis, jid, jjs, jjd
880      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
881      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
882      REAL(wp) :: zrhdt1
883      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
884      REAL(wp), DIMENSION(jpi,jpj)     ::   zpgu, zpgv   ! 2D workspace
885      REAL(wp), DIMENSION(jpi,jpj)     ::   zsshu_n, zsshv_n
886      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
887      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
888      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
889      !!----------------------------------------------------------------------
890      !
891      IF( kt == nit000 ) THEN
892         IF(lwp) WRITE(numout,*)
893         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
894         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
895      ENDIF
896
897      ! Local constant initialization
898      zcoef0 = - grav
899      znad = 1._wp
900      IF( ln_linssh )   znad = 1._wp
901      !
902      ! ---------------
903      !  Surface pressure gradient to be removed
904      ! ---------------
905      DO_2D( 0, 0, 0, 0 )
906         zpgu(ji,jj) = - grav * ( ssh(ji+1,jj,Kmm) - ssh(ji,jj,Kmm) ) * r1_e1u(ji,jj)
907         zpgv(ji,jj) = - grav * ( ssh(ji,jj+1,Kmm) - ssh(ji,jj,Kmm) ) * r1_e2v(ji,jj)
908      END_2D
909      !
910      IF( ln_wd_il ) THEN
911         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
912         DO_2D( 0, 0, 0, 0 )
913          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
914               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
915               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
916               &                                                      > rn_wdmin1 + rn_wdmin2
917          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (         &
918               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
919               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
920
921          IF(ll_tmp1) THEN
922            zcpx(ji,jj) = 1.0_wp
923          ELSE IF(ll_tmp2) THEN
924            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
925            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
926                        &    / (ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm)) )
927           
928             zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
929          ELSE
930            zcpx(ji,jj) = 0._wp
931          END IF
932   
933          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
934               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
935               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
936               &                                                      > rn_wdmin1 + rn_wdmin2
937          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (      &
938               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
939               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
940
941          IF(ll_tmp1) THEN
942            zcpy(ji,jj) = 1.0_wp
943          ELSE IF(ll_tmp2) THEN
944            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
945            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
946                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
947             zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
948
949            ELSE
950               zcpy(ji,jj) = 0._wp
951            ENDIF
952         END_2D
953         CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
954      ENDIF
955
956      ! Clean 3-D work arrays
957      zhpi(:,:,:) = 0._wp
958      zrhh(:,:,:) = rhd(:,:,:)
959
960      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
961      DO_2D( 1, 1, 1, 1 )
962       jk = mbkt(ji,jj)
963       IF(     jk <=  1   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
964       ELSEIF( jk ==  2   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
965       ELSEIF( jk < jpkm1 ) THEN
966          DO jkk = jk+1, jpk
967             zrhh(ji,jj,jkk) = interp1(gde3w(ji,jj,jkk  ), gde3w(ji,jj,jkk-1),   &
968                &                      gde3w(ji,jj,jkk-2), zrhh (ji,jj,jkk-1), zrhh(ji,jj,jkk-2))
969          END DO
970       ENDIF
971      END_2D
972
973      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
974      DO_2D( 1, 1, 1, 1 )
975         zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm)
976      END_2D
977
978      DO_3D( 1, 1, 1, 1, 2, jpk )
979         zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
980      END_3D
981
982      fsp(:,:,:) = zrhh (:,:,:)
983      xsp(:,:,:) = zdept(:,:,:)
984
985      ! Construct the vertical density profile with the
986      ! constrained cubic spline interpolation
987      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
988      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
989
990      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
991      DO_2D( 0, 1, 0, 1 )
992       zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
993          &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
994
995       ! assuming linear profile across the top half surface layer
996       zhpi(ji,jj,1) =  0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
997      END_2D
998
999      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1000      DO_3D( 0, 1, 0, 1, 2, jpkm1 )
1001      zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1002         &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1003         &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1004         &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1005      END_3D
1006
1007      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1008
1009      ! Prepare zsshu_n and zsshv_n
1010      DO_2D( 0, 0, 0, 0 )
1011!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1012!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1013!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1014!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1015!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1016!!gm not this:
1017       zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1018                      & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1019       zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1020                      & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1021      END_2D
1022
1023      CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1.0_wp, zsshv_n, 'V', 1.0_wp )
1024
1025      DO_2D( 0, 0, 0, 0 )
1026       zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) ) 
1027       zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) )
1028      END_2D
1029
1030      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
1031      zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1032      zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1033      END_3D
1034
1035      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1036      zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1037      zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1038      END_3D
1039
1040      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1041      zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1042      zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1043      zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1044      zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1045      END_3D
1046
1047
1048      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1049      zpwes = 0._wp; zpwed = 0._wp
1050      zpnss = 0._wp; zpnsd = 0._wp
1051      zuijk = zu(ji,jj,jk)
1052      zvijk = zv(ji,jj,jk)
1053
1054      !!!!!     for u equation
1055      IF( jk <= mbku(ji,jj) ) THEN
1056         IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1057           jis = ji + 1; jid = ji
1058         ELSE
1059           jis = ji;     jid = ji +1
1060         ENDIF
1061
1062         ! integrate the pressure on the shallow side
1063         jk1 = jk
1064         DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1065           IF( jk1 == mbku(ji,jj) ) THEN
1066             zuijk = -zdept(jis,jj,jk1)
1067             EXIT
1068           ENDIF
1069           zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1070           zpwes = zpwes +                                    &
1071                integ_spline(zdept(jis,jj,jk1), zdeps,            &
1072                       asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1073                       csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1074           jk1 = jk1 + 1
1075         END DO
1076
1077         ! integrate the pressure on the deep side
1078         jk1 = jk
1079         DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1080           IF( jk1 == 1 ) THEN
1081             zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1082             zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1083                                               bsp(jid,jj,1),   csp(jid,jj,1), &
1084                                               dsp(jid,jj,1)) * zdeps
1085             zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1086             EXIT
1087           ENDIF
1088           zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1089           zpwed = zpwed +                                        &
1090                  integ_spline(zdeps,              zdept(jid,jj,jk1), &
1091                         asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1092                         csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1093           jk1 = jk1 - 1
1094         END DO
1095
1096         ! update the momentum trends in u direction
1097
1098         zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1099         IF( .NOT.ln_linssh ) THEN
1100           zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1101              &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1102          ELSE
1103           zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1104         ENDIF
1105         IF( ln_wd_il ) THEN
1106            zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1107            zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1108         ENDIF
1109         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2 - zpgu(ji,jj)) * umask(ji,jj,jk) 
1110      ENDIF
1111
1112      !!!!!     for v equation
1113      IF( jk <= mbkv(ji,jj) ) THEN
1114         IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1115           jjs = jj + 1; jjd = jj
1116         ELSE
1117           jjs = jj    ; jjd = jj + 1
1118         ENDIF
1119
1120         ! integrate the pressure on the shallow side
1121         jk1 = jk
1122         DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1123           IF( jk1 == mbkv(ji,jj) ) THEN
1124             zvijk = -zdept(ji,jjs,jk1)
1125             EXIT
1126           ENDIF
1127           zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1128           zpnss = zpnss +                                      &
1129                  integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1130                         asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1131                         csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1132           jk1 = jk1 + 1
1133         END DO
1134
1135         ! integrate the pressure on the deep side
1136         jk1 = jk
1137         DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1138           IF( jk1 == 1 ) THEN
1139             zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1140             zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1141                                               bsp(ji,jjd,1),   csp(ji,jjd,1), &
1142                                               dsp(ji,jjd,1) ) * zdeps
1143             zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1144             EXIT
1145           ENDIF
1146           zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1147           zpnsd = zpnsd +                                        &
1148                  integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1149                         asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1150                         csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1151           jk1 = jk1 - 1
1152         END DO
1153
1154
1155         ! update the momentum trends in v direction
1156
1157         zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1158         IF( .NOT.ln_linssh ) THEN
1159            zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1160                    ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1161         ELSE
1162            zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1163         ENDIF
1164         IF( ln_wd_il ) THEN
1165            zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1166            zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1167         ENDIF
1168
1169         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2 - zpgv(ji,jj)) * vmask(ji,jj,jk)
1170      ENDIF
1171         !
1172      END_3D
1173      !
1174      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1175      !
1176   END SUBROUTINE hpg_prj
1177
1178
1179   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1180      !!----------------------------------------------------------------------
1181      !!                 ***  ROUTINE cspline  ***
1182      !!
1183      !! ** Purpose :   constrained cubic spline interpolation
1184      !!
1185      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1186      !!
1187      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1188      !!----------------------------------------------------------------------
1189      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1190      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1191      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1192      !
1193      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1194      INTEGER  ::   jpi, jpj, jpkm1
1195      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1196      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1197      REAL(wp) ::   zdf(size(fsp,3))
1198      !!----------------------------------------------------------------------
1199      !
1200!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1201      jpi   = size(fsp,1)
1202      jpj   = size(fsp,2)
1203      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1204      !
1205      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1206         DO ji = 1, jpi
1207            DO jj = 1, jpj
1208           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1209           !    DO jk = 2, jpkm1-1
1210           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1211           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1212           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1213           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1214           !
1215           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1216           !
1217           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1218           !           zdf(jk) = 0._wp
1219           !       ELSE
1220           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1221           !       ENDIF
1222           !    END DO
1223
1224           !!Simply geometric average
1225               DO jk = 2, jpkm1-1
1226                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1227                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1228
1229                  IF(zdf1 * zdf2 <= 0._wp) THEN
1230                     zdf(jk) = 0._wp
1231                  ELSE
1232                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1233                  ENDIF
1234               END DO
1235
1236               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1237                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1238               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1239                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1240
1241               DO jk = 1, jpkm1 - 1
1242                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1243                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1244                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1245                 zddf1  = -2._wp * ztmp1 + ztmp2
1246                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1247                 zddf2  =  2._wp * ztmp1 - ztmp2
1248
1249                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1250                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1251                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1252                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1253                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1254                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1255                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1256                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1257                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1258               END DO
1259            END DO
1260         END DO
1261
1262      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1263         DO ji = 1, jpi
1264            DO jj = 1, jpj
1265               DO jk = 1, jpkm1-1
1266                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1267                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1268
1269                  dsp(ji,jj,jk) = 0._wp
1270                  csp(ji,jj,jk) = 0._wp
1271                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1272                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1273               END DO
1274            END DO
1275         END DO
1276         !
1277      ELSE
1278         CALL ctl_stop( 'invalid polynomial type in cspline' )
1279      ENDIF
1280      !
1281   END SUBROUTINE cspline
1282
1283
1284   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1285      !!----------------------------------------------------------------------
1286      !!                 ***  ROUTINE interp1  ***
1287      !!
1288      !! ** Purpose :   1-d linear interpolation
1289      !!
1290      !! ** Method  :   interpolation is straight forward
1291      !!                extrapolation is also permitted (no value limit)
1292      !!----------------------------------------------------------------------
1293      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1294      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1295      REAL(wp)             ::  zdeltx
1296      !!----------------------------------------------------------------------
1297      !
1298      zdeltx = xr - xl
1299      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1300         f = 0.5_wp * (fl + fr)
1301      ELSE
1302         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1303      ENDIF
1304      !
1305   END FUNCTION interp1
1306
1307
1308   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1309      !!----------------------------------------------------------------------
1310      !!                 ***  ROUTINE interp1  ***
1311      !!
1312      !! ** Purpose :   1-d constrained cubic spline interpolation
1313      !!
1314      !! ** Method  :  cubic spline interpolation
1315      !!
1316      !!----------------------------------------------------------------------
1317      REAL(wp), INTENT(in) ::  x, a, b, c, d
1318      REAL(wp)             ::  f ! value from the interpolation
1319      !!----------------------------------------------------------------------
1320      !
1321      f = a + x* ( b + x * ( c + d * x ) )
1322      !
1323   END FUNCTION interp2
1324
1325
1326   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1327      !!----------------------------------------------------------------------
1328      !!                 ***  ROUTINE interp1  ***
1329      !!
1330      !! ** Purpose :   Calculate the first order of derivative of
1331      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1332      !!
1333      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1334      !!
1335      !!----------------------------------------------------------------------
1336      REAL(wp), INTENT(in) ::  x, a, b, c, d
1337      REAL(wp)             ::  f ! value from the interpolation
1338      !!----------------------------------------------------------------------
1339      !
1340      f = b + x * ( 2._wp * c + 3._wp * d * x)
1341      !
1342   END FUNCTION interp3
1343
1344
1345   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1346      !!----------------------------------------------------------------------
1347      !!                 ***  ROUTINE interp1  ***
1348      !!
1349      !! ** Purpose :   1-d constrained cubic spline integration
1350      !!
1351      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1352      !!
1353      !!----------------------------------------------------------------------
1354      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1355      REAL(wp)             ::  za1, za2, za3
1356      REAL(wp)             ::  f                   ! integration result
1357      !!----------------------------------------------------------------------
1358      !
1359      za1 = 0.5_wp * b
1360      za2 = c / 3.0_wp
1361      za3 = 0.25_wp * d
1362      !
1363      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1364         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1365      !
1366   END FUNCTION integ_spline
1367
1368   !!======================================================================
1369END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.