New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/2020/dev_r13333_KERNEL-08_techene_gm_HPG_SPG/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13333_KERNEL-08_techene_gm_HPG_SPG/src/OCE/TRA/traadv_fct.F90 @ 14037

Last change on this file since 14037 was 14037, checked in by ayoung, 3 years ago

Updated to trunk at 14020. Sette tests passed with change of results for configurations with non-linear ssh. Ticket #2506.
  • Property svn:keywords set to Id
File size: 36.7 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36   PUBLIC   tridia_solver      ! called by traadv_fct_lf.F90
37   PUBLIC   nonosc             ! called by traadv_fct_lf.F90 - key_agrif
38
39   LOGICAL  ::   l_trd   ! flag to compute trends
40   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
41   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
42   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
43
44   !                                        ! tridiag solver associated indices:
45   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
46   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
47
48   !! * Substitutions
49#  include "do_loop_substitute.h90"
50#  include "domzgr_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
53   !! $Id$
54   !! Software governed by the CeCILL license (see ./LICENSE)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
59      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE tra_adv_fct  ***
62      !!
63      !! **  Purpose :   Compute the now trend due to total advection of tracers
64      !!               and add it to the general trend of tracer equations
65      !!
66      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
67      !!               (choice through the value of kn_fct)
68      !!               - on the vertical the 4th order is a compact scheme
69      !!               - corrected flux (monotonic correction)
70      !!
71      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
72      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
73      !!             - poleward advective heat and salt transport (ln_diaptr=T)
74      !!----------------------------------------------------------------------
75      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
76      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
77      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
78      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
79      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
80      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
81      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
82      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
83      ! TEMP: [tiling] This can be A2D(nn_hls) if using XIOS (subdomain support)
84      ! NOTE: [tiling-comms-merge] These were changed to INTENT(inout) but they are not modified, so it is reverted
85      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
86      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
87      !
88      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices
89      REAL(wp) ::   ztra                                     ! local scalar
90      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
91      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
92      REAL(wp), DIMENSION(A2D(nn_hls),jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
93      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
94      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
95      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
96      !!----------------------------------------------------------------------
97      !
98      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
99         IF( kt == kit000 )  THEN
100            IF(lwp) WRITE(numout,*)
101            IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
102            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
103         ENDIF
104         ! NOTE: [tiling-comms-merge] Bug fix- move array zeroing out of this IF block
105         !
106         l_trd = .FALSE.            ! set local switches
107         l_hst = .FALSE.
108         l_ptr = .FALSE.
109         ll_zAimp = .FALSE.
110         IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
111         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE.
112         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
113            &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
114         !
115      ENDIF
116
117      !! -- init to 0
118      zwi(:,:,:) = 0._wp
119      zwx(:,:,:) = 0._wp
120      zwy(:,:,:) = 0._wp
121      zwz(:,:,:) = 0._wp
122      ztu(:,:,:) = 0._wp
123      ztv(:,:,:) = 0._wp
124      zltu(:,:,:) = 0._wp
125      zltv(:,:,:) = 0._wp
126      ztw(:,:,:) = 0._wp
127      !
128      IF( l_trd .OR. l_hst )  THEN
129         ALLOCATE( ztrdx(A2D(nn_hls),jpk), ztrdy(A2D(nn_hls),jpk), ztrdz(A2D(nn_hls),jpk) )
130         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
131      ENDIF
132      !
133      IF( l_ptr ) THEN
134         ALLOCATE( zptry(A2D(nn_hls),jpk) )
135         zptry(:,:,:) = 0._wp
136      ENDIF
137      !
138      ! If adaptive vertical advection, check if it is needed on this PE at this time
139      IF( ln_zad_Aimp ) THEN
140         IF( MAXVAL( ABS( wi(A2D(nn_hls),:) ) ) > 0._wp ) ll_zAimp = .TRUE.
141      END IF
142      ! If active adaptive vertical advection, build tridiagonal matrix
143      IF( ll_zAimp ) THEN
144         ALLOCATE(zwdia(A2D(nn_hls),jpk), zwinf(A2D(nn_hls),jpk), zwsup(A2D(nn_hls),jpk))
145         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
146            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
147            &                               / e3t(ji,jj,jk,Krhs)
148            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
149            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
150         END_3D
151      END IF
152      !
153      DO jn = 1, kjpt            !==  loop over the tracers  ==!
154         !
155         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
156         !                    !* upstream tracer flux in the i and j direction
157         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
158            ! upstream scheme
159            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
160            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
161            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
162            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
163            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
164            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
165         END_3D
166         !                               !* upstream tracer flux in the k direction *!
167         DO_3D( 1, 1, 1, 1, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
168            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
169            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
170            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
171         END_3D
172         IF( ln_linssh ) THEN               ! top ocean value (only in linear free surface as zwz has been w-masked)
173            IF( ln_isfcav ) THEN                        ! top of the ice-shelf cavities and at the ocean surface
174               DO_2D( 1, 1, 1, 1 )
175                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
176               END_2D
177            ELSE                                        ! no cavities: only at the ocean surface
178               DO_2D( 1, 1, 1, 1 )
179                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
180               END_2D
181            ENDIF
182         ENDIF
183         !               
184         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )   !* trend and after field with monotonic scheme
185            !                               ! total intermediate advective trends
186            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
187               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
188               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
189            !                               ! update and guess with monotonic sheme
190            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
191               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
192            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
193               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
194         END_3D
195         
196         IF ( ll_zAimp ) THEN
197            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
198            !
199            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
200            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
201               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
202               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
203               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
204               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
205            END_3D
206            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
207               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
208                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
209            END_3D
210            !
211         END IF
212         !
213         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
214            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
215         END IF
216         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
217         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
218         !
219         !        !==  anti-diffusive flux : high order minus low order  ==!
220         !
221         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
222         !
223         CASE(  2  )                   !- 2nd order centered
224            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
225               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
226               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
227            END_3D
228            !
229         CASE(  4  )                   !- 4th order centered
230            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
231            zltv(:,:,jpk) = 0._wp
232            DO jk = 1, jpkm1                 ! Laplacian
233               DO_2D( 1, 0, 1, 0 )                 ! 1st derivative (gradient)
234                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
235                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
236               END_2D
237               DO_2D( 0, 0, 0, 0 )                 ! 2nd derivative * 1/ 6
238                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
239                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
240               END_2D
241            END DO
242            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
243            !
244            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
245               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
246               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
247               !                                                        ! C4 minus upstream advective fluxes
248               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
249               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
250            END_3D
251            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp, zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
252            !
253         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
254            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
255            ztv(:,:,jpk) = 0._wp
256            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )    ! 1st derivative (gradient)
257               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
258               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
259            END_3D
260            IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
261            !
262            IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
263            !
264            DO_3D( 0, 0, 0, 0, 1, jpkm1 )    ! Horizontal advective fluxes
265               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
266               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
267               !                                                  ! C4 interpolation of T at u- & v-points (x2)
268               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
269               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
270               !                                                  ! C4 minus upstream advective fluxes
271               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
272               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
273            END_3D
274            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
275            !
276         END SELECT
277         !                     
278         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
279         !
280         CASE(  2  )                   !- 2nd order centered
281            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
282               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
283                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
284            END_3D
285            !
286         CASE(  4  )                   !- 4th order COMPACT
287            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
288            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
289               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
290            END_3D
291            !
292         END SELECT
293         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
294            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
295         ENDIF
296         !
297         IF (nn_hls.EQ.1) THEN
298            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
299         ELSE
300            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
301         END IF
302         !
303         IF (nn_hls.EQ.1) THEN
304            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
305         ELSE
306            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
307         END IF
308         !
309         IF ( ll_zAimp ) THEN
310            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    !* trend and after field with monotonic scheme
311               !                                                ! total intermediate advective trends
312               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
313                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
314                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
315               ztw(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
316            END_3D
317            !
318            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
319            !
320            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
321               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
322               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
323               zwz(ji,jj,jk) = zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
324            END_3D
325         END IF
326         !
327         !        !==  monotonicity algorithm  ==!
328         !
329         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
330         !
331         !        !==  final trend with corrected fluxes  ==!
332         !
333         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
334            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
335               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
336               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
337            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
338            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
339         END_3D
340         !
341         IF ( ll_zAimp ) THEN
342            !
343            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
344            DO_3D( 0, 0, 0, 0, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
345               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
346               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
347               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
348               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
349            END_3D
350            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
351               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
352                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
353            END_3D
354         END IF
355         ! NOTE: [tiling-comms-merge] I tested this
356         ! NOT TESTED - NEED l_trd OR l_hst TRUE
357         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
358            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
359            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
360            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
361            !
362            IF( l_trd ) THEN              ! trend diagnostics
363               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
364               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
365               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
366            ENDIF
367            !                             ! heat/salt transport
368            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
369            !
370         ENDIF
371         ! NOTE: [tiling-comms-merge] I tested this
372         ! NOT TESTED - NEED l_ptr TRUE
373         IF( l_ptr ) THEN              ! "Poleward" transports
374            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
375            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
376         ENDIF
377         !
378      END DO                     ! end of tracer loop
379      !
380      IF ( ll_zAimp ) THEN
381         DEALLOCATE( zwdia, zwinf, zwsup )
382      ENDIF
383      IF( l_trd .OR. l_hst ) THEN
384         DEALLOCATE( ztrdx, ztrdy, ztrdz )
385      ENDIF
386      IF( l_ptr ) THEN
387         DEALLOCATE( zptry )
388      ENDIF
389      !
390   END SUBROUTINE tra_adv_fct
391
392
393   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
394      !!---------------------------------------------------------------------
395      !!                    ***  ROUTINE nonosc  ***
396      !!     
397      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
398      !!       scheme and the before field by a nonoscillatory algorithm
399      !!
400      !! **  Method  :   ... ???
401      !!       warning : pbef and paft must be masked, but the boundaries
402      !!       conditions on the fluxes are not necessary zalezak (1979)
403      !!       drange (1995) multi-dimensional forward-in-time and upstream-
404      !!       in-space based differencing for fluid
405      !!----------------------------------------------------------------------
406      INTEGER                         , INTENT(in   ) ::   Kmm             ! time level index
407      REAL(wp)                        , INTENT(in   ) ::   p2dt            ! tracer time-step
408      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pbef            ! before field
409      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(in   ) ::   paft            ! after field
410      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
411      !
412      INTEGER  ::   ji, jj, jk   ! dummy loop indices
413      INTEGER  ::   ikm1         ! local integer
414      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
415      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
416      REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zbetup, zbetdo, zbup, zbdo
417      !!----------------------------------------------------------------------
418      !
419      zbig  = 1.e+40_dp
420      zrtrn = 1.e-15_dp
421      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
422
423      ! Search local extrema
424      ! --------------------
425      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
426      DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpk )
427         zbup(ji,jj,jk) = MAX( pbef(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
428            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) )  )
429         zbdo(ji,jj,jk) = MIN( pbef(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
430            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) )  )
431      END_3D
432
433      DO jk = 1, jpkm1
434         ikm1 = MAX(jk-1,1)
435         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
436
437            ! search maximum in neighbourhood
438            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
439               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
440               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
441               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
442
443            ! search minimum in neighbourhood
444            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
445               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
446               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
447               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
448
449            ! positive part of the flux
450            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
451               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
452               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
453
454            ! negative part of the flux
455            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
456               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
457               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
458
459            ! up & down beta terms
460            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
461            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
462            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
463         END_2D
464      END DO
465      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
466
467      ! 3. monotonic flux in the i & j direction (paa & pbb)
468      ! ----------------------------------------
469      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
470         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
471         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
472         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
473         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
474
475         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
476         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
477         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
478         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
479
480      ! monotonic flux in the k direction, i.e. pcc
481      ! -------------------------------------------
482         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
483         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
484         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
485         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
486      END_3D
487      !
488   END SUBROUTINE nonosc
489
490
491   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
492      !!----------------------------------------------------------------------
493      !!                  ***  ROUTINE interp_4th_cpt_org  ***
494      !!
495      !! **  Purpose :   Compute the interpolation of tracer at w-point
496      !!
497      !! **  Method  :   4th order compact interpolation
498      !!----------------------------------------------------------------------
499      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
500      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
501      !
502      INTEGER :: ji, jj, jk   ! dummy loop integers
503      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
504      !!----------------------------------------------------------------------
505     
506      DO_3D( 1, 1, 1, 1, 3, jpkm1 )       !==  build the three diagonal matrix  ==!
507         zwd (ji,jj,jk) = 4._wp
508         zwi (ji,jj,jk) = 1._wp
509         zws (ji,jj,jk) = 1._wp
510         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
511         !
512         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
513            zwd (ji,jj,jk) = 1._wp
514            zwi (ji,jj,jk) = 0._wp
515            zws (ji,jj,jk) = 0._wp
516            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
517         ENDIF
518      END_3D
519      !
520      jk = 2                                    ! Switch to second order centered at top
521      DO_2D( 1, 1, 1, 1 )
522         zwd (ji,jj,jk) = 1._wp
523         zwi (ji,jj,jk) = 0._wp
524         zws (ji,jj,jk) = 0._wp
525         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
526      END_2D
527      !
528      !                       !==  tridiagonal solve  ==!
529      DO_2D( 1, 1, 1, 1 )           ! first recurrence
530         zwt(ji,jj,2) = zwd(ji,jj,2)
531      END_2D
532      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
533         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
534      END_3D
535      !
536      DO_2D( 1, 1, 1, 1 )           ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
537         pt_out(ji,jj,2) = zwrm(ji,jj,2)
538      END_2D
539      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
540         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
541      END_3D
542
543      DO_2D( 1, 1, 1, 1 )           ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
544         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
545      END_2D
546      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
547         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
548      END_3D
549      !   
550   END SUBROUTINE interp_4th_cpt_org
551   
552
553   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
554      !!----------------------------------------------------------------------
555      !!                  ***  ROUTINE interp_4th_cpt  ***
556      !!
557      !! **  Purpose :   Compute the interpolation of tracer at w-point
558      !!
559      !! **  Method  :   4th order compact interpolation
560      !!----------------------------------------------------------------------
561      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
562      REAL(wp),DIMENSION(A2D(nn_hls)    ,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
563      !
564      INTEGER ::   ji, jj, jk   ! dummy loop integers
565      INTEGER ::   ikt, ikb     ! local integers
566      REAL(wp),DIMENSION(A2D(nn_hls),jpk) :: zwd, zwi, zws, zwrm, zwt
567      !!----------------------------------------------------------------------
568      !
569      !                      !==  build the three diagonal matrix & the RHS  ==!
570      !
571      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )    ! interior (from jk=3 to jpk-1)
572         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
573         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
574         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
575         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
576            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
577      END_3D
578      !
579!!gm
580!      SELECT CASE( kbc )               !* boundary condition
581!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
582!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
583!      END SELECT
584!!gm 
585      !
586      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
587         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
588      END IF
589      !
590      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! 2nd order centered at top & bottom
591         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
592         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
593         !
594         zwd (ji,jj,ikt) = 1._wp          ! top
595         zwi (ji,jj,ikt) = 0._wp
596         zws (ji,jj,ikt) = 0._wp
597         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
598         !
599         zwd (ji,jj,ikb) = 1._wp          ! bottom
600         zwi (ji,jj,ikb) = 0._wp
601         zws (ji,jj,ikb) = 0._wp
602         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
603      END_2D
604      !
605      !                       !==  tridiagonal solver  ==!
606      !
607      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
608         zwt(ji,jj,2) = zwd(ji,jj,2)
609      END_2D
610      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
611         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
612      END_3D
613      !
614      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
615         pt_out(ji,jj,2) = zwrm(ji,jj,2)
616      END_2D
617      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
618         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
619      END_3D
620
621      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
622         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
623      END_2D
624      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, 2, -1 )
625         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
626      END_3D
627      !   
628   END SUBROUTINE interp_4th_cpt
629
630
631   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
632      !!----------------------------------------------------------------------
633      !!                  ***  ROUTINE tridia_solver  ***
634      !!
635      !! **  Purpose :   solve a symmetric 3diagonal system
636      !!
637      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
638      !!     
639      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
640      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
641      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
642      !!             (        ...          )( ... )   ( ...  )
643      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
644      !!     
645      !!        M is decomposed in the product of an upper and lower triangular matrix.
646      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
647      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
648      !!        The solution is pta.
649      !!        The 3d array zwt is used as a work space array.
650      !!----------------------------------------------------------------------
651      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
652      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
653      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
654      INTEGER                    , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
655      !                                                             ! =0 pt at t-level
656      INTEGER ::   ji, jj, jk   ! dummy loop integers
657      INTEGER ::   kstart       ! local indices
658      REAL(wp),DIMENSION(A2D(nn_hls),jpk) ::   zwt   ! 3D work array
659      !!----------------------------------------------------------------------
660      !
661      kstart =  1  + klev
662      !
663      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                         !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
664         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
665      END_2D
666      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
667         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
668      END_3D
669      !
670      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                        !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
671         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
672      END_2D
673      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
674         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
675      END_3D
676
677      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                       !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
678         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
679      END_2D
680      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, kstart, -1 )
681         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
682      END_3D
683      !
684   END SUBROUTINE tridia_solver
685
686   !!======================================================================
687END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.