New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in NEMO/branches/2020/dev_r13333_KERNEL-08_techene_gm_HPG_SPG/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13333_KERNEL-08_techene_gm_HPG_SPG/src/OCE/TRA/trasbc.F90 @ 14037

Last change on this file since 14037 was 14037, checked in by ayoung, 3 years ago

Updated to trunk at 14020. Sette tests passed with change of results for configurations with non-linear ssh. Ticket #2506.
  • Property svn:keywords set to Id
File size: 12.3 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!            4.1  !  2019-09  (P. Mathiot) isf moved in traisf
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_sbc       : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE dom_oce        ! ocean space domain variables
21   USE phycst         ! physical constant
22   USE eosbn2         ! Equation Of State
23   USE sbcmod         ! ln_rnf 
24   USE sbcrnf         ! River runoff 
25   USE traqsr         ! solar radiation penetration
26   USE trd_oce        ! trends: ocean variables
27   USE trdtra         ! trends manager: tracers
28#if defined key_asminc   
29   USE asminc         ! Assimilation increment
30#endif
31   !
32   USE in_out_manager ! I/O manager
33   USE prtctl         ! Print control
34   USE iom            ! xIOS server
35   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
36   USE timing         ! Timing
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   tra_sbc   ! routine called by step.F90
42
43   !! * Substitutions
44#  include "do_loop_substitute.h90"
45#  include "domzgr_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL license (see ./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_sbc ( kt, Kmm, pts, Krhs )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE tra_sbc  ***
56      !!                   
57      !! ** Purpose :   Compute the tracer surface boundary condition trend of
58      !!      (flux through the interface, concentration/dilution effect)
59      !!      and add it to the general trend of tracer equations.
60      !!
61      !! ** Method :   The (air+ice)-sea flux has two components:
62      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
63      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
64      !!               The input forcing fields (emp, rnf, sfx) contain Fext+Fwe,
65      !!             they are simply added to the tracer trend (ts(Krhs)).
66      !!               In linear free surface case (ln_linssh=T), the volume of the
67      !!             ocean does not change with the water exchanges at the (air+ice)-sea
68      !!             interface. Therefore another term has to be added, to mimic the
69      !!             concentration/dilution effect associated with water exchanges.
70      !!
71      !! ** Action  : - Update ts(Krhs) with the surface boundary condition trend
72      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
73      !!----------------------------------------------------------------------
74      INTEGER,                                   INTENT(in   ) :: kt         ! ocean time-step index
75      INTEGER,                                   INTENT(in   ) :: Kmm, Krhs  ! time level indices
76      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts        ! active tracers and RHS of tracer equation
77      !
78      INTEGER  ::   ji, jj, jk, jn               ! dummy loop indices
79      INTEGER  ::   ikt, ikb, isi, iei, isj, iej ! local integers
80      REAL(wp) ::   zfact, z1_e3t, zdep, ztim    ! local scalar
81      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  ztrdt, ztrds
82      !!----------------------------------------------------------------------
83      !
84      IF( ln_timing )   CALL timing_start('tra_sbc')
85      !
86      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
87         IF( kt == nit000 ) THEN
88            IF(lwp) WRITE(numout,*)
89            IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
90            IF(lwp) WRITE(numout,*) '~~~~~~~ '
91         ENDIF
92      ENDIF
93      !
94      IF( l_trdtra ) THEN                    !* Save ta and sa trends
95         ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
96         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
97         ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
98      ENDIF
99      !
100      ! NOTE: [tiling-comms-merge] Many DO loop bounds changed to avoid changing results when using tiling. Some bounds were also adjusted to account for those changed in tra_atf
101      IF( ntsi == Nis0 ) THEN ; isi = nn_hls ; ELSE ; isi = 0 ; ENDIF    ! Avoid double-counting when using tiling
102      IF( ntsj == Njs0 ) THEN ; isj = nn_hls ; ELSE ; isj = 0 ; ENDIF
103      IF( ntei == Nie0 ) THEN ; iei = nn_hls ; ELSE ; iei = 0 ; ENDIF
104      IF( ntej == Nje0 ) THEN ; iej = nn_hls ; ELSE ; iej = 0 ; ENDIF
105
106!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
107      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
108         DO_2D( isj, iej, isi, iei )
109            qns(ji,jj) = qns(ji,jj) + qsr(ji,jj)      ! total heat flux in qns
110            qsr(ji,jj) = 0._wp                        ! qsr set to zero
111         END_2D
112      ENDIF
113
114      !----------------------------------------
115      !        EMP, SFX and QNS effects
116      !----------------------------------------
117      !                             !==  Set before sbc tracer content fields  ==!
118      IF( kt == nit000 ) THEN             !* 1st time-step
119         IF( ln_rstart .AND.    &               ! Restart: read in restart file
120              & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN
121            zfact = 0.5_wp
122            IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
123               IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
124               sbc_tsc(:,:,:) = 0._wp
125               CALL iom_get( numror, jpdom_auto, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
126               CALL iom_get( numror, jpdom_auto, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
127            ENDIF
128         ELSE                                   ! No restart or restart not found: Euler forward time stepping
129            zfact = 1._wp
130            DO_2D( isj, iej, isi, iei )
131               sbc_tsc(ji,jj,:) = 0._wp
132               sbc_tsc_b(ji,jj,:) = 0._wp
133            END_2D
134         ENDIF
135      ELSE                                !* other time-steps: swap of forcing fields
136         zfact = 0.5_wp
137         DO_2D( isj, iej, isi, iei )
138            sbc_tsc_b(ji,jj,:) = sbc_tsc(ji,jj,:)
139         END_2D
140      ENDIF
141      !                             !==  Now sbc tracer content fields  ==!
142      DO_2D( isj, iej, isi, iei )
143         sbc_tsc(ji,jj,jp_tem) = r1_rho0_rcp * qns(ji,jj)   ! non solar heat flux
144         sbc_tsc(ji,jj,jp_sal) = r1_rho0     * sfx(ji,jj)   ! salt flux due to freezing/melting
145      END_2D
146      IF( ln_linssh ) THEN                !* linear free surface 
147         DO_2D( isj, iej, isi, iei )                    !==>> add concentration/dilution effect due to constant volume cell
148            sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rho0 * emp(ji,jj) * pts(ji,jj,1,jp_tem,Kmm)
149            sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rho0 * emp(ji,jj) * pts(ji,jj,1,jp_sal,Kmm)
150         END_2D                                 !==>> output c./d. term
151         IF( ntile == 0 .OR. ntile == nijtile )  THEN             ! Do only on the last tile
152            IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * pts(:,:,1,jp_tem,Kmm) )
153            IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * pts(:,:,1,jp_sal,Kmm) )
154         ENDIF
155      ENDIF
156      !
157      DO jn = 1, jpts               !==  update tracer trend  ==!
158         ! NOTE: [tiling-comms-merge] This looped over nn_hls, which changes the results when using tiling
159         DO_2D( 0, 0, 0, 0 )
160            pts(ji,jj,1,jn,Krhs) = pts(ji,jj,1,jn,Krhs) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) )    &
161               &                                                / e3t(ji,jj,1,Kmm)
162         END_2D
163      END DO
164      !                 
165      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
166         IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
167            CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
168            CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
169         ENDIF
170      ENDIF
171      !
172      !----------------------------------------
173      !        River Runoff effects
174      !----------------------------------------
175      !
176      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
177         zfact = 0.5_wp
178         DO_2D( 0, 0, 0, 0 )
179            IF( rnf(ji,jj) /= 0._wp ) THEN
180               zdep = zfact / h_rnf(ji,jj)
181               DO jk = 1, nk_rnf(ji,jj)
182                                     pts(ji,jj,jk,jp_tem,Krhs) = pts(ji,jj,jk,jp_tem,Krhs)                                  &
183                                        &                      +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
184                  IF( ln_rnf_sal )   pts(ji,jj,jk,jp_sal,Krhs) = pts(ji,jj,jk,jp_sal,Krhs)                                  &
185                                        &                      +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep 
186               END DO
187            ENDIF
188         END_2D
189      ENDIF
190
191      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
192         IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*pts(:,:,1,jp_tem,Kmm) )   ! runoff term on sst
193         IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*pts(:,:,1,jp_sal,Kmm) )   ! runoff term on sss
194      ENDIF
195
196#if defined key_asminc
197      !
198      !----------------------------------------
199      !        Assmilation effects
200      !----------------------------------------
201      !
202      IF( ln_sshinc ) THEN         ! input of heat and salt due to assimilation
203          !
204         IF( ln_linssh ) THEN
205            DO_2D( 0, 0, 0, 0 )
206               ztim = ssh_iau(ji,jj) / e3t(ji,jj,1,Kmm)
207               pts(ji,jj,1,jp_tem,Krhs) = pts(ji,jj,1,jp_tem,Krhs) + pts(ji,jj,1,jp_tem,Kmm) * ztim
208               pts(ji,jj,1,jp_sal,Krhs) = pts(ji,jj,1,jp_sal,Krhs) + pts(ji,jj,1,jp_sal,Kmm) * ztim
209            END_2D
210         ELSE
211            DO_2D( 0, 0, 0, 0 )
212               ztim = ssh_iau(ji,jj) / ( ht(ji,jj) + 1. - ssmask(ji, jj) )
213               pts(ji,jj,:,jp_tem,Krhs) = pts(ji,jj,:,jp_tem,Krhs) + pts(ji,jj,:,jp_tem,Kmm) * ztim
214               pts(ji,jj,:,jp_sal,Krhs) = pts(ji,jj,:,jp_sal,Krhs) + pts(ji,jj,:,jp_sal,Kmm) * ztim
215            END_2D
216         ENDIF
217         !
218      ENDIF
219      !
220#endif
221      !
222      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
223         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs) - ztrdt(:,:,:)
224         ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs) - ztrds(:,:,:)
225         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_nsr, ztrdt )
226         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_nsr, ztrds )
227         DEALLOCATE( ztrdt , ztrds )
228      ENDIF
229      !
230      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
231         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
232      !
233      IF( ln_timing )   CALL timing_stop('tra_sbc')
234      !
235   END SUBROUTINE tra_sbc
236
237   !!======================================================================
238END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.