New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in NEMO/branches/2020/dev_r13333_KERNEL-08_techene_gm_HPG_SPG/tests/ISOMIP+/MY_SRC – NEMO

source: NEMO/branches/2020/dev_r13333_KERNEL-08_techene_gm_HPG_SPG/tests/ISOMIP+/MY_SRC/dtatsd.F90 @ 14037

Last change on this file since 14037 was 14037, checked in by ayoung, 3 years ago

Updated to trunk at 14020. Sette tests passed with change of results for configurations with non-linear ssh. Ticket #2506.
File size: 14.2 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + remove CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE phycst          ! physical constants
19   USE dom_oce         ! ocean space and time domain
20   USE domain, ONLY : dom_tile
21   USE fldread         ! read input fields
22   !
23   USE in_out_manager  ! I/O manager
24   USE lib_mpp         ! MPP library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dta_tsd_init   ! called by opa.F90
30   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
31
32   !                                  !!* namtsd  namelist : Temperature & Salinity Data *
33   LOGICAL , PUBLIC ::   ln_tsd_init   !: T & S data flag
34   LOGICAL , PUBLIC ::   ln_tsd_dmp    !: internal damping toward input data flag
35
36   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsdini ! structure of input SST (file informations, fields read)
37   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsddmp ! structure of input SST (file informations, fields read)
38
39   !! * Substitutions
40#  include "do_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id: dtatsd.F90 10213 2018-10-23 14:40:09Z aumont $
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE dta_tsd_init( ld_tradmp )
49      !!----------------------------------------------------------------------
50      !!                   ***  ROUTINE dta_tsd_init  ***
51      !!                   
52      !! ** Purpose :   initialisation of T & S input data
53      !!
54      !! ** Method  : - Read namtsd namelist
55      !!              - allocates T & S data structure
56      !!----------------------------------------------------------------------
57      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
58      !
59      INTEGER ::   ios, ierr0, ierr1, ierr2, ierr3   ! local integers
60      !!
61      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
62      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
63      TYPE(FLD_N)                   ::   sn_tem, sn_sal
64      TYPE(FLD_N)                   ::   sn_dmpt, sn_dmps
65      !!
66      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_dmp, cn_dir, sn_tem, sn_sal, sn_dmpt, sn_dmps
67      !!----------------------------------------------------------------------
68      !
69      !  Initialisation
70      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
71      !
72      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
73901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtsd in reference namelist' )
74      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
75902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtsd in configuration namelist' )
76      IF(lwm) WRITE ( numond, namtsd )
77
78      IF( PRESENT( ld_tradmp ) )   ln_tsd_dmp = .TRUE.     ! forces the initialization when tradmp is used
79     
80      IF(lwp) THEN                  ! control print
81         WRITE(numout,*)
82         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
83         WRITE(numout,*) '~~~~~~~~~~~~ '
84         WRITE(numout,*) '   Namelist namtsd'
85         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init = ', ln_tsd_init
86         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_dmp  = ', ln_tsd_dmp
87         WRITE(numout,*)
88         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_dmp ) THEN
89            WRITE(numout,*)
90            WRITE(numout,*) '   ===>>   T & S data not used'
91         ENDIF
92      ENDIF
93      !
94      IF( ln_rstart .AND. ln_tsd_init ) THEN
95         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
96            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
97         ln_tsd_init = .FALSE.
98      ENDIF
99      !
100      !                             ! allocate the arrays (if necessary)
101      IF( ln_tsd_init ) THEN
102         !
103         ALLOCATE( sf_tsdini(jpts), STAT=ierr0 )
104         IF( ierr0 > 0 ) THEN
105            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
106         ENDIF
107         !
108                                ALLOCATE( sf_tsdini(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
109         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsdini(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
110                                ALLOCATE( sf_tsdini(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
111         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsdini(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
112         !
113         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
114            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
115         ENDIF
116         !
117         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
118         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
119         CALL fld_fill( sf_tsdini, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd', no_print )
120         !
121      END IF
122
123      IF( ln_tsd_dmp ) THEN
124         !
125         ALLOCATE( sf_tsddmp(jpts), STAT=ierr0 )
126         IF( ierr0 > 0 ) THEN
127            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsddmp structure' )   ;   RETURN
128         ENDIF
129         !
130         ! dmp file
131                                 ALLOCATE( sf_tsddmp(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
132         IF( sn_dmpt%ln_tint )   ALLOCATE( sf_tsddmp(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
133                                 ALLOCATE( sf_tsddmp(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
134         IF( sn_dmps%ln_tint )   ALLOCATE( sf_tsddmp(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
135         !
136         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
137            CALL ctl_stop( 'dta_tsd : unable to allocate T & S dmp data arrays' )   ;   RETURN
138         ENDIF
139         !
140         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
141         slf_i(jp_tem) = sn_dmpt   ;   slf_i(jp_sal) = sn_dmps
142         CALL fld_fill( sf_tsddmp, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity dmp data', 'namtsd', no_print )
143         !
144      ENDIF
145      !
146   END SUBROUTINE dta_tsd_init
147
148
149   SUBROUTINE dta_tsd( kt, cddta, ptsd )
150      !!----------------------------------------------------------------------
151      !!                   ***  ROUTINE dta_tsd  ***
152      !!                   
153      !! ** Purpose :   provides T and S data at kt
154      !!
155      !! ** Method  : - call fldread routine
156      !!              - ORCA_R2: add some hand made alteration to read data 
157      !!              - 'key_orca_lev10' interpolates on 10 times more levels
158      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
159      !!              - ln_tsd_dmp=F: deallocates the T-S data structure
160      !!                as T-S data are no are used
161      !!
162      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
163      !!----------------------------------------------------------------------
164      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
165      CHARACTER(LEN=3)                     , INTENT(in   ) ::   cddta  ! dmp or ini
166      REAL(wp), DIMENSION(A2D(nn_hls),jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
167      !
168      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
169      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
170      INTEGER ::   itile
171      REAL(wp)::   zl, zi                             ! local scalars
172      REAL(wp), DIMENSION(jpk) ::  ztp, zsp   ! 1D workspace
173      !!----------------------------------------------------------------------
174      !
175      IF( ntile == 0 .OR. ntile == 1 )  THEN                                         ! Do only for the full domain
176         itile = ntile
177         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )            ! Use full domain
178
179         SELECT CASE(cddta)
180         CASE('ini')
181            CALL fld_read( kt, 1, sf_tsdini ) !==   read T & S data at kt time step   ==!
182         CASE('dmp')
183            CALL fld_read( kt, 1, sf_tsddmp ) !==   read T & S data at kt time step   ==!
184         CASE DEFAULT
185            CALL ctl_stop('STOP', 'dta_tsd: cddta case unknown')
186         END SELECT
187
188         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = itile )            ! Revert to tile domain
189      ENDIF
190      !
191      SELECT CASE(cddta)
192      CASE('ini')
193         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpk )
194            ptsd(ji,jj,jk,jp_tem) = sf_tsdini(jp_tem)%fnow(ji,jj,jk)    ! NO mask
195            ptsd(ji,jj,jk,jp_sal) = sf_tsdini(jp_sal)%fnow(ji,jj,jk)
196         END_3D
197      CASE('dmp')
198         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpk )
199            ptsd(ji,jj,jk,jp_tem) = sf_tsddmp(jp_tem)%fnow(ji,jj,jk)    ! NO mask
200            ptsd(ji,jj,jk,jp_sal) = sf_tsddmp(jp_sal)%fnow(ji,jj,jk)
201         END_3D
202      CASE DEFAULT
203         CALL ctl_stop('STOP', 'dta_tsd: cddta case unknown')
204      END SELECT
205      !
206      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
207         !
208         IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
209            IF( kt == nit000 .AND. lwp )THEN
210               WRITE(numout,*)
211               WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
212            ENDIF
213         ENDIF
214         !
215         DO_2D( 1, 1, 1, 1 )                  ! vertical interpolation of T & S
216            DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
217               zl = gdept_0(ji,jj,jk)
218               IF(     zl < gdept_1d(1  ) ) THEN          ! above the first level of data
219                  ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
220                  zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
221               ELSEIF( zl > gdept_1d(jpk) ) THEN          ! below the last level of data
222                  ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
223                  zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
224               ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
225                  DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
226                     IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN
227                        zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk))
228                        ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
229                        zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
230                     ENDIF
231                  END DO
232               ENDIF
233            END DO
234            DO jk = 1, jpkm1
235               ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
236               ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
237            END DO
238            ptsd(ji,jj,jpk,jp_tem) = 0._wp
239            ptsd(ji,jj,jpk,jp_sal) = 0._wp
240         END_2D
241         !
242      ELSE                                !==   z- or zps- coordinate   ==!
243         !                             
244         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpk )
245            ptsd(ji,jj,jk,jp_tem) = ptsd(ji,jj,jk,jp_tem) * tmask(ji,jj,jk)    ! Mask
246            ptsd(ji,jj,jk,jp_sal) = ptsd(ji,jj,jk,jp_sal) * tmask(ji,jj,jk)
247         END_3D
248         !
249         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
250            DO_2D( 1, 1, 1, 1 )
251               ik = mbkt(ji,jj) 
252               IF( ik > 1 ) THEN
253                  zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
254                  ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
255                  ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
256               ENDIF
257               ik = mikt(ji,jj)
258               IF( ik > 1 ) THEN
259                  zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) ) 
260                  ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik+1,jp_tem)
261                  ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik+1,jp_sal)
262               END IF
263            END_2D
264         ENDIF
265         !
266      ENDIF
267      !
268      SELECT CASE(cddta)
269      CASE('ini') 
270         !                        !==   deallocate T & S structure   ==!
271         !                                              (data used only for initialisation)
272         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
273                                        DEALLOCATE( sf_tsdini(jp_tem)%fnow )     ! T arrays in the structure
274         IF( sf_tsdini(jp_tem)%ln_tint )   DEALLOCATE( sf_tsdini(jp_tem)%fdta )
275                                        DEALLOCATE( sf_tsdini(jp_sal)%fnow )     ! S arrays in the structure
276         IF( sf_tsdini(jp_sal)%ln_tint )   DEALLOCATE( sf_tsdini(jp_sal)%fdta )
277                                        DEALLOCATE( sf_tsdini              )     ! the structure itself
278         !
279      END SELECT
280      !
281   END SUBROUTINE dta_tsd
282
283   !!======================================================================
284END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.