New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/2020/dev_r13508_HPC-09_communications_cleanup/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13508_HPC-09_communications_cleanup/src/OCE/TRA/traadv_fct.F90 @ 13660

Last change on this file since 13660 was 13660, checked in by francesca, 4 years ago

communications cleanup of the TRA modules - ticket #2367
  • Property svn:keywords set to Id
File size: 35.0 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
40   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
41
42   !                                        ! tridiag solver associated indices:
43   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
44   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
45
46   !! * Substitutions
47#  include "do_loop_substitute.h90"
48#  include "domzgr_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
57      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
58      !!----------------------------------------------------------------------
59      !!                  ***  ROUTINE tra_adv_fct  ***
60      !!
61      !! **  Purpose :   Compute the now trend due to total advection of tracers
62      !!               and add it to the general trend of tracer equations
63      !!
64      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
65      !!               (choice through the value of kn_fct)
66      !!               - on the vertical the 4th order is a compact scheme
67      !!               - corrected flux (monotonic correction)
68      !!
69      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
70      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
71      !!             - poleward advective heat and salt transport (ln_diaptr=T)
72      !!----------------------------------------------------------------------
73      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
74      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
75      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
76      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
77      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
78      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
79      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
80      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
81      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(inout) ::   pU, pV, pW      ! 3 ocean volume flux components
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
83      !
84      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
85      REAL(wp) ::   ztra                                     ! local scalar
86      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
87      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
88      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
89      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
90      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
91      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
92      !!----------------------------------------------------------------------
93      !
94      IF( kt == kit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
98      ENDIF
99      !! -- init to 0
100      zwi(:,:,:) = 0._wp
101      zwx(:,:,:) = 0._wp
102      zwy(:,:,:) = 0._wp
103      zwz(:,:,:) = 0._wp
104      ztu(:,:,:) = 0._wp
105      ztv(:,:,:) = 0._wp
106      zltu(:,:,:) = 0._wp
107      zltv(:,:,:) = 0._wp
108      ztw(:,:,:) = 0._wp
109      !
110      l_trd = .FALSE.            ! set local switches
111      l_hst = .FALSE.
112      l_ptr = .FALSE.
113      ll_zAimp = .FALSE.
114      IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
115      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE. 
116      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
117         &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
118      !
119      IF( l_trd .OR. l_hst )  THEN
120         ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
121         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
122      ENDIF
123      !
124      IF( l_ptr ) THEN 
125         ALLOCATE( zptry(jpi,jpj,jpk) )
126         zptry(:,:,:) = 0._wp
127      ENDIF
128      !
129      ! If adaptive vertical advection, check if it is needed on this PE at this time
130      IF( ln_zad_Aimp ) THEN
131         IF( MAXVAL( ABS( wi(:,:,:) ) ) > 0._wp ) ll_zAimp = .TRUE.
132      END IF
133      ! If active adaptive vertical advection, build tridiagonal matrix
134      IF( ll_zAimp ) THEN
135         ALLOCATE(zwdia(jpi,jpj,jpk), zwinf(jpi,jpj,jpk),zwsup(jpi,jpj,jpk))
136         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
137            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
138            &                               / e3t(ji,jj,jk,Krhs)
139            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
140            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
141         END_3D
142      END IF
143      !
144      DO jn = 1, kjpt            !==  loop over the tracers  ==!
145         !
146         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
147         !                    !* upstream tracer flux in the i and j direction
148         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
149            ! upstream scheme
150            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
151            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
152            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
153            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
154            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
155            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
156         END_3D
157         !                               !* upstream tracer flux in the k direction *!
158         DO_3D( 1, 1, 1, 1, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
159            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
160            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
161            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
162         END_3D
163         IF( ln_linssh ) THEN               ! top ocean value (only in linear free surface as zwz has been w-masked)
164            IF( ln_isfcav ) THEN                        ! top of the ice-shelf cavities and at the ocean surface
165               DO_2D( 1, 1, 1, 1 )
166                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
167               END_2D
168            ELSE                                        ! no cavities: only at the ocean surface
169               DO_2D( 1, 1, 1, 1 )
170                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
171               END_2D
172            ENDIF
173         ENDIF
174         !               
175         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )   !* trend and after field with monotonic scheme
176            !                               ! total intermediate advective trends
177            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
178               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
179               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
180            !                               ! update and guess with monotonic sheme
181            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
182               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
183            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
184               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
185         END_3D
186         
187         IF ( ll_zAimp ) THEN
188            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
189            !
190            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
191            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
192               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
193               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
194               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
195               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
196            END_3D
197            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
198               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
199                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
200            END_3D
201            !
202         END IF
203         !               
204         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
205            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
206         END IF
207         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
208         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
209         !
210         !        !==  anti-diffusive flux : high order minus low order  ==!
211         !
212         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
213         !
214         CASE(  2  )                   !- 2nd order centered
215            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
216               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
217               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
218            END_3D
219            !
220         CASE(  4  )                   !- 4th order centered
221            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
222            zltv(:,:,jpk) = 0._wp
223            DO jk = 1, jpkm1                 ! Laplacian
224               DO_2D( 1, 0, 1, 0 )                 ! 1st derivative (gradient)
225                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
226                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
227               END_2D
228               DO_2D( 0, 0, 0, 0 )                 ! 2nd derivative * 1/ 6
229                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
230                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
231               END_2D
232            END DO
233            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
234            !
235            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
236               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
237               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
238               !                                                        ! C4 minus upstream advective fluxes
239               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
240               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
241            END_3D
242            !
243         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
244            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
245            ztv(:,:,jpk) = 0._wp
246            DO_3D( 1, 0, 1, 0, 1, jpkm1 )    ! 1st derivative (gradient)
247               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
248               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
249            END_3D
250            !
251            DO_3D( 0, 0, 0, 0, 1, jpkm1 )    ! Horizontal advective fluxes
252               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
253               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
254               !                                                  ! C4 interpolation of T at u- & v-points (x2)
255               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
256               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
257               !                                                  ! C4 minus upstream advective fluxes
258               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
259               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
260            END_3D
261            CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
262            !
263         END SELECT
264         !                     
265         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
266         !
267         CASE(  2  )                   !- 2nd order centered
268            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
269               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
270                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
271            END_3D
272            !
273         CASE(  4  )                   !- 4th order COMPACT
274            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
275            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
276               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
277            END_3D
278            !
279         END SELECT
280         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
281            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
282         ENDIF
283         !         
284         IF (nn_hls.EQ.1) THEN
285            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
286         ELSE
287            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
288         END IF
289         !
290         IF ( ll_zAimp ) THEN
291            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    !* trend and after field with monotonic scheme
292               !                                                ! total intermediate advective trends
293               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
294                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
295                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
296               ztw(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
297            END_3D
298            !
299            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
300            !
301            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
302               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
303               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
304               zwz(ji,jj,jk) = zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
305            END_3D
306         END IF
307         !
308         !        !==  monotonicity algorithm  ==!
309         !
310         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
311         !
312         !        !==  final trend with corrected fluxes  ==!
313         !
314         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
315            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
316               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
317               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
318            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
319            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
320         END_3D
321         !
322         IF ( ll_zAimp ) THEN
323            !
324            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
325            DO_3D( 0, 0, 0, 0, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
326               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
327               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
328               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
329               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
330            END_3D
331            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
332               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
333                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
334            END_3D
335         END IF         
336         ! NOT TESTED - NEED l_trd OR l_hst TRUE
337         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
338            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
339            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
340            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
341            !
342            IF( l_trd ) THEN              ! trend diagnostics
343               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
344               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
345               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
346            ENDIF
347            !                             ! heat/salt transport
348            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
349            !
350         ENDIF
351         ! NOT TESTED - NEED l_ptr TRUE
352         IF( l_ptr ) THEN              ! "Poleward" transports
353            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
354            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
355         ENDIF
356         !
357      END DO                     ! end of tracer loop
358      !
359      IF ( ll_zAimp ) THEN
360         DEALLOCATE( zwdia, zwinf, zwsup )
361      ENDIF
362      IF( l_trd .OR. l_hst ) THEN
363         DEALLOCATE( ztrdx, ztrdy, ztrdz )
364      ENDIF
365      IF( l_ptr ) THEN
366         DEALLOCATE( zptry )
367      ENDIF
368      !
369   END SUBROUTINE tra_adv_fct
370
371
372   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
373      !!---------------------------------------------------------------------
374      !!                    ***  ROUTINE nonosc  ***
375      !!     
376      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
377      !!       scheme and the before field by a nonoscillatory algorithm
378      !!
379      !! **  Method  :   ... ???
380      !!       warning : pbef and paft must be masked, but the boundaries
381      !!       conditions on the fluxes are not necessary zalezak (1979)
382      !!       drange (1995) multi-dimensional forward-in-time and upstream-
383      !!       in-space based differencing for fluid
384      !!----------------------------------------------------------------------
385      INTEGER                          , INTENT(in   ) ::   Kmm             ! time level index
386      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
387      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
388      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
389      !
390      INTEGER  ::   ji, jj, jk   ! dummy loop indices
391      INTEGER  ::   ikm1         ! local integer
392      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
393      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
394      REAL(dp), DIMENSION(jpi,jpj,jpk) :: zbetup, zbetdo, zbup, zbdo
395      !!----------------------------------------------------------------------
396      !
397      zbig  = 1.e+40_dp
398      zrtrn = 1.e-15_dp
399      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
400
401      ! Search local extrema
402      ! --------------------
403      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
404      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
405         &        paft * tmask - zbig * ( 1._wp - tmask )  )
406      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
407         &        paft * tmask + zbig * ( 1._wp - tmask )  )
408
409      DO jk = 1, jpkm1
410         ikm1 = MAX(jk-1,1)
411         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
412
413            ! search maximum in neighbourhood
414            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
415               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
416               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
417               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
418
419            ! search minimum in neighbourhood
420            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
421               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
422               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
423               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
424
425            ! positive part of the flux
426            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
427               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
428               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
429
430            ! negative part of the flux
431            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
432               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
433               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
434
435            ! up & down beta terms
436            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
437            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
438            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
439         END_2D
440      END DO
441      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
442
443      ! 3. monotonic flux in the i & j direction (paa & pbb)
444      ! ----------------------------------------
445      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
446         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
447         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
448         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
449         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
450
451         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
452         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
453         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
454         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
455
456      ! monotonic flux in the k direction, i.e. pcc
457      ! -------------------------------------------
458         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
459         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
460         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
461         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
462      END_3D
463      !
464   END SUBROUTINE nonosc
465
466
467   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
468      !!----------------------------------------------------------------------
469      !!                  ***  ROUTINE interp_4th_cpt_org  ***
470      !!
471      !! **  Purpose :   Compute the interpolation of tracer at w-point
472      !!
473      !! **  Method  :   4th order compact interpolation
474      !!----------------------------------------------------------------------
475      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
476      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
477      !
478      INTEGER :: ji, jj, jk   ! dummy loop integers
479      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
480      !!----------------------------------------------------------------------
481     
482      DO_3D( 1, 1, 1, 1, 3, jpkm1 )       !==  build the three diagonal matrix  ==!
483         zwd (ji,jj,jk) = 4._wp
484         zwi (ji,jj,jk) = 1._wp
485         zws (ji,jj,jk) = 1._wp
486         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
487         !
488         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
489            zwd (ji,jj,jk) = 1._wp
490            zwi (ji,jj,jk) = 0._wp
491            zws (ji,jj,jk) = 0._wp
492            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
493         ENDIF
494      END_3D
495      !
496      jk = 2                                    ! Switch to second order centered at top
497      DO_2D( 1, 1, 1, 1 )
498         zwd (ji,jj,jk) = 1._wp
499         zwi (ji,jj,jk) = 0._wp
500         zws (ji,jj,jk) = 0._wp
501         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
502      END_2D
503      !
504      !                       !==  tridiagonal solve  ==!
505      DO_2D( 1, 1, 1, 1 )           ! first recurrence
506         zwt(ji,jj,2) = zwd(ji,jj,2)
507      END_2D
508      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
509         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
510      END_3D
511      !
512      DO_2D( 1, 1, 1, 1 )           ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
513         pt_out(ji,jj,2) = zwrm(ji,jj,2)
514      END_2D
515      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
516         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
517      END_3D
518
519      DO_2D( 1, 1, 1, 1 )           ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
520         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
521      END_2D
522      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
523         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
524      END_3D
525      !   
526   END SUBROUTINE interp_4th_cpt_org
527   
528
529   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
530      !!----------------------------------------------------------------------
531      !!                  ***  ROUTINE interp_4th_cpt  ***
532      !!
533      !! **  Purpose :   Compute the interpolation of tracer at w-point
534      !!
535      !! **  Method  :   4th order compact interpolation
536      !!----------------------------------------------------------------------
537      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
538      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
539      !
540      INTEGER ::   ji, jj, jk   ! dummy loop integers
541      INTEGER ::   ikt, ikb     ! local integers
542      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
543      !!----------------------------------------------------------------------
544      !
545      !                      !==  build the three diagonal matrix & the RHS  ==!
546      !
547      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )    ! interior (from jk=3 to jpk-1)
548         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
549         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
550         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
551         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
552            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
553      END_3D
554      !
555!!gm
556!      SELECT CASE( kbc )               !* boundary condition
557!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
558!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
559!      END SELECT
560!!gm 
561      !
562      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
563         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
564      END IF
565      !
566      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! 2nd order centered at top & bottom
567         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
568         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
569         !
570         zwd (ji,jj,ikt) = 1._wp          ! top
571         zwi (ji,jj,ikt) = 0._wp
572         zws (ji,jj,ikt) = 0._wp
573         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
574         !
575         zwd (ji,jj,ikb) = 1._wp          ! bottom
576         zwi (ji,jj,ikb) = 0._wp
577         zws (ji,jj,ikb) = 0._wp
578         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
579      END_2D
580      !
581      !                       !==  tridiagonal solver  ==!
582      !
583      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
584         zwt(ji,jj,2) = zwd(ji,jj,2)
585      END_2D
586      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
587         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
588      END_3D
589      !
590      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
591         pt_out(ji,jj,2) = zwrm(ji,jj,2)
592      END_2D
593      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
594         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
595      END_3D
596
597      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
598         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
599      END_2D
600      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, 2, -1 )
601         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
602      END_3D
603      !   
604   END SUBROUTINE interp_4th_cpt
605
606
607   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
608      !!----------------------------------------------------------------------
609      !!                  ***  ROUTINE tridia_solver  ***
610      !!
611      !! **  Purpose :   solve a symmetric 3diagonal system
612      !!
613      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
614      !!     
615      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
616      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
617      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
618      !!             (        ...          )( ... )   ( ...  )
619      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
620      !!     
621      !!        M is decomposed in the product of an upper and lower triangular matrix.
622      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
623      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
624      !!        The solution is pta.
625      !!        The 3d array zwt is used as a work space array.
626      !!----------------------------------------------------------------------
627      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
628      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
629      REAL(wp),DIMENSION(:,:,:), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
630      INTEGER                  , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
631      !                                                           ! =0 pt at t-level
632      INTEGER ::   ji, jj, jk   ! dummy loop integers
633      INTEGER ::   kstart       ! local indices
634      REAL(wp),DIMENSION(jpi,jpj,jpk) ::   zwt   ! 3D work array
635      !!----------------------------------------------------------------------
636      !
637      kstart =  1  + klev
638      !
639      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                         !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
640         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
641      END_2D
642      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
643         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
644      END_3D
645      !
646      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                        !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
647         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
648      END_2D
649      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
650         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
651      END_3D
652
653      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                       !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
654         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
655      END_2D
656      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, kstart, -1 )
657         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
658      END_3D
659      !
660   END SUBROUTINE tridia_solver
661
662   !!======================================================================
663END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.