New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_ubs.F90 in NEMO/branches/2020/dev_r13508_HPC-09_communications_cleanup/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13508_HPC-09_communications_cleanup/src/OCE/TRA/traadv_ubs.F90 @ 13660

Last change on this file since 13660 was 13660, checked in by francesca, 4 years ago

communications cleanup of the TRA modules - ticket #2367
  • Property svn:keywords set to Id
File size: 18.9 KB
Line 
1MODULE traadv_ubs
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_ubs  ***
4   !! Ocean active tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  1.0  !  2006-08  (L. Debreu, R. Benshila)  Original code
7   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv_ubs : update the tracer trend with the horizontal
12   !!                 advection trends using a third order biaised scheme 
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and active tracers
15   USE dom_oce        ! ocean space and time domain
16   USE trc_oce        ! share passive tracers/Ocean variables
17   USE trd_oce        ! trends: ocean variables
18   USE traadv_fct      ! acces to routine interp_4th_cpt
19   USE trdtra         ! trends manager: tracers
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   !
23   USE iom            ! I/O library
24   USE in_out_manager ! I/O manager
25   USE lib_mpp        ! massively parallel library
26   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
27   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_adv_ubs   ! routine called by traadv module
33
34   LOGICAL :: l_trd   ! flag to compute trends
35   LOGICAL :: l_ptr   ! flag to compute poleward transport
36   LOGICAL :: l_hst   ! flag to compute heat transport
37
38
39   !! * Substitutions
40#  include "do_loop_substitute.h90"
41#  include "domzgr_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE tra_adv_ubs( kt, kit000, cdtype, p2dt, pU, pV, pW,          &
50      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_ubs_v )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_adv_ubs  ***
53      !!                 
54      !! ** Purpose :   Compute the now trend due to the advection of tracers
55      !!      and add it to the general trend of passive tracer equations.
56      !!
57      !! ** Method  :   The 3rd order Upstream Biased Scheme (UBS) is based on an
58      !!      upstream-biased parabolic interpolation (Shchepetkin and McWilliams 2005)
59      !!      It is only used in the horizontal direction.
60      !!      For example the i-component of the advective fluxes are given by :
61      !!                !  e2u e3u un ( mi(Tn) - zltu(i  ) )   if un(i) >= 0
62      !!          ztu = !  or
63      !!                !  e2u e3u un ( mi(Tn) - zltu(i+1) )   if un(i) < 0
64      !!      where zltu is the second derivative of the before temperature field:
65      !!          zltu = 1/e3t di[ e2u e3u / e1u di[Tb] ]
66      !!        This results in a dissipatively dominant (i.e. hyper-diffusive)
67      !!      truncation error. The overall performance of the advection scheme
68      !!      is similar to that reported in (Farrow and Stevens, 1995).
69      !!        For stability reasons, the first term of the fluxes which corresponds
70      !!      to a second order centered scheme is evaluated using the now velocity
71      !!      (centered in time) while the second term which is the diffusive part
72      !!      of the scheme, is evaluated using the before velocity (forward in time).
73      !!      Note that UBS is not positive. Do not use it on passive tracers.
74      !!                On the vertical, the advection is evaluated using a FCT scheme,
75      !!      as the UBS have been found to be too diffusive.
76      !!                kn_ubs_v argument controles whether the FCT is based on
77      !!      a 2nd order centrered scheme (kn_ubs_v=2) or on a 4th order compact
78      !!      scheme (kn_ubs_v=4).
79      !!
80      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
81      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
82      !!             - poleward advective heat and salt transport (ln_diaptr=T)
83      !!
84      !! Reference : Shchepetkin, A. F., J. C. McWilliams, 2005, Ocean Modelling, 9, 347-404.
85      !!             Farrow, D.E., Stevens, D.P., 1995, J. Phys. Ocean. 25, 1731�1741.
86      !!----------------------------------------------------------------------
87      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
88      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
89      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
90      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
91      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
92      INTEGER                                  , INTENT(in   ) ::   kn_ubs_v        ! number of tracers
93      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
94      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume transport components
95      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
96      !
97      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
98      REAL(wp) ::   ztra, zbtr, zcoef                       ! local scalars
99      REAL(wp) ::   zfp_ui, zfm_ui, zcenut, ztak, zfp_wk, zfm_wk   !   -      -
100      REAL(wp) ::   zfp_vj, zfm_vj, zcenvt, zeeu, zeev, z_hdivn    !   -      -
101      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztu, ztv, zltu, zltv, zti, ztw   ! 3D workspace
102      !!----------------------------------------------------------------------
103      !
104      IF( kt == kit000 )  THEN
105         IF(lwp) WRITE(numout,*)
106         IF(lwp) WRITE(numout,*) 'tra_adv_ubs :  horizontal UBS advection scheme on ', cdtype
107         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
108      ENDIF
109      !
110      l_trd = .FALSE.
111      l_hst = .FALSE.
112      l_ptr = .FALSE.
113      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
114      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) )  )   l_ptr = .TRUE. 
115      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
116         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
117      !
118      ztw (:,:, 1 ) = 0._wp      ! surface & bottom value : set to zero for all tracers
119      zltu(:,:,jpk) = 0._wp   ;   zltv(:,:,jpk) = 0._wp
120      ztw (:,:,jpk) = 0._wp   ;   zti (:,:,jpk) = 0._wp
121      !                                                          ! ===========
122      DO jn = 1, kjpt                                            ! tracer loop
123         !                                                       ! ===========
124         !                                             
125         DO jk = 1, jpkm1                !==  horizontal laplacian of before tracer ==!
126            DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 )                   ! First derivative (masked gradient)
127               zeeu = e2_e1u(ji,jj) * e3u(ji,jj,jk,Kmm) * umask(ji,jj,jk)
128               zeev = e1_e2v(ji,jj) * e3v(ji,jj,jk,Kmm) * vmask(ji,jj,jk)
129               ztu(ji,jj,jk) = zeeu * ( pt(ji+1,jj  ,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
130               ztv(ji,jj,jk) = zeev * ( pt(ji  ,jj+1,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
131            END_2D
132            DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                   ! Second derivative (divergence)
133               zcoef = 1._wp / ( 6._wp * e3t(ji,jj,jk,Kmm) )
134               zltu(ji,jj,jk) = (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)  ) * zcoef
135               zltv(ji,jj,jk) = (  ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  ) * zcoef
136            END_2D
137            !                                   
138         END DO         
139         IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_ubs', zltu, 'T', 1.0_wp, zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
140         !   
141         DO_3D( 1, 0, 1, 0, 1, jpkm1 )   !==  Horizontal advective fluxes  ==!     (UBS)
142            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )        ! upstream transport (x2)
143            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
144            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
145            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
146            !                                                  ! 2nd order centered advective fluxes (x2)
147            zcenut = pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm) )
148            zcenvt = pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm) )
149            !                                                  ! UBS advective fluxes
150            ztu(ji,jj,jk) = 0.5 * ( zcenut - zfp_ui * zltu(ji,jj,jk) - zfm_ui * zltu(ji+1,jj,jk) )
151            ztv(ji,jj,jk) = 0.5 * ( zcenvt - zfp_vj * zltv(ji,jj,jk) - zfm_vj * zltv(ji,jj+1,jk) )
152         END_3D
153         !
154         zltu(:,:,:) = pt(:,:,:,jn,Krhs)      ! store the initial trends before its update
155         !
156         DO jk = 1, jpkm1        !==  add the horizontal advective trend  ==!
157            DO_2D( 0, 0, 0, 0 )
158               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs)                        &
159                  &             - (  ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk)    &
160                  &                + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk)  ) &
161                  &                * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
162            END_2D
163            !                                             
164         END DO
165         !
166         zltu(:,:,:) = pt(:,:,:,jn,Krhs) - zltu(:,:,:)    ! Horizontal advective trend used in vertical 2nd order FCT case
167         !                                                ! and/or in trend diagnostic (l_trd=T)
168         !               
169         IF( l_trd ) THEN                  ! trend diagnostics
170             CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztu, pU, pt(:,:,:,jn,Kmm) )
171             CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztv, pV, pt(:,:,:,jn,Kmm) )
172         END IF
173         !     
174         !                                ! "Poleward" heat and salt transports (contribution of upstream fluxes)
175         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', ztv(:,:,:) )
176         !                                !  heati/salt transport
177         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', ztu(:,:,:), ztv(:,:,:) )
178         !
179         !
180         !                       !== vertical advective trend  ==!
181         !
182         SELECT CASE( kn_ubs_v )       ! select the vertical advection scheme
183         !
184         CASE(  2  )                   ! 2nd order FCT
185            !         
186            IF( l_trd )   zltv(:,:,:) = pt(:,:,:,jn,Krhs)          ! store pt(:,:,:,:,Krhs) if trend diag.
187            !
188            !                               !*  upstream advection with initial mass fluxes & intermediate update  ==!
189            DO_3D( 1, 1, 1, 1, 2, jpkm1 )
190               zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
191               zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
192               ztw(ji,jj,jk) = 0.5_wp * (  zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb)  ) * wmask(ji,jj,jk)
193            END_3D
194            IF( ln_linssh ) THEN                ! top ocean value (only in linear free surface as ztw has been w-masked)
195               IF( ln_isfcav ) THEN                   ! top of the ice-shelf cavities and at the ocean surface
196                  DO_2D( 1, 1, 1, 1 )
197                     ztw(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
198                  END_2D
199               ELSE                                   ! no cavities: only at the ocean surface
200                  ztw(:,:,1) = pW(:,:,1) * pt(:,:,1,jn,Kbb)
201               ENDIF
202            ENDIF
203            !
204            DO_3D( 0, 0, 0, 0, 1, jpkm1 )   !* trend and after field with monotonic scheme
205               ztak = - ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) )    &
206                  &     * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
207               pt(ji,jj,jk,jn,Krhs) =   pt(ji,jj,jk,jn,Krhs) +  ztak 
208               zti(ji,jj,jk)    = ( pt(ji,jj,jk,jn,Kbb) + p2dt * ( ztak + zltu(ji,jj,jk) ) ) * tmask(ji,jj,jk)
209            END_3D
210            !
211            !                          !*  anti-diffusive flux : high order minus low order
212            DO_3D( 1, 1, 1, 1, 2, jpkm1 )
213               ztw(ji,jj,jk) = (   0.5_wp * pW(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
214                  &              - ztw(ji,jj,jk)   ) * wmask(ji,jj,jk)
215            END_3D
216            !                                            ! top ocean value: high order == upstream  ==>>  zwz=0
217            IF( ln_linssh )   ztw(:,:, 1 ) = 0._wp       ! only ocean surface as interior zwz values have been w-masked
218            !
219            CALL nonosc_z( Kmm, pt(:,:,:,jn,Kbb), ztw, zti, p2dt )      !  monotonicity algorithm
220            !
221         CASE(  4  )                               ! 4th order COMPACT
222            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )         ! 4th order compact interpolation of T at w-point
223            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
224               ztw(ji,jj,jk) = pW(ji,jj,jk) * ztw(ji,jj,jk) * wmask(ji,jj,jk)
225            END_3D
226            IF( ln_linssh )   ztw(:,:, 1 ) = pW(:,:,1) * pt(:,:,1,jn,Kmm)     !!gm ISF & 4th COMPACT doesn't work
227            !
228         END SELECT
229         !
230         DO_3D( 0, 0, 0, 0, 1, jpkm1 )   !  final trend with corrected fluxes
231            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) )    &
232               &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
233         END_3D
234         !
235         IF( l_trd )  THEN               ! vertical advective trend diagnostics
236            DO_3D( 0, 0, 0, 0, 1, jpkm1 )                 ! (compute -w.dk[ptn]= -dk[w.ptn] + ptn.dk[w])
237               zltv(ji,jj,jk) = pt(ji,jj,jk,jn,Krhs) - zltv(ji,jj,jk)                          &
238                  &           + pt(ji,jj,jk,jn,Kmm) * (  pW(ji,jj,jk) - pW(ji,jj,jk+1)  )   &
239                  &                              * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
240            END_3D
241            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, zltv )
242         ENDIF
243         !
244      END DO
245      !
246   END SUBROUTINE tra_adv_ubs
247
248
249   SUBROUTINE nonosc_z( Kmm, pbef, pcc, paft, p2dt )
250      !!---------------------------------------------------------------------
251      !!                    ***  ROUTINE nonosc_z  ***
252      !!     
253      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
254      !!       scheme and the before field by a nonoscillatory algorithm
255      !!
256      !! **  Method  :   ... ???
257      !!       warning : pbef and paft must be masked, but the boundaries
258      !!       conditions on the fluxes are not necessary zalezak (1979)
259      !!       drange (1995) multi-dimensional forward-in-time and upstream-
260      !!       in-space based differencing for fluid
261      !!----------------------------------------------------------------------
262      INTEGER , INTENT(in   )                          ::   Kmm    ! time level index
263      REAL(wp), INTENT(in   )                          ::   p2dt   ! tracer time-step
264      REAL(wp),                DIMENSION (jpi,jpj,jpk) ::   pbef   ! before field
265      REAL(wp), INTENT(inout), DIMENSION (jpi,jpj,jpk) ::   paft   ! after field
266      REAL(wp), INTENT(inout), DIMENSION (jpi,jpj,jpk) ::   pcc    ! monotonic flux in the k direction
267      !
268      INTEGER  ::   ji, jj, jk   ! dummy loop indices
269      INTEGER  ::   ikm1         ! local integer
270      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn   ! local scalars
271      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zbetup, zbetdo     ! 3D workspace
272      !!----------------------------------------------------------------------
273      !
274      zbig  = 1.e+38_wp
275      zrtrn = 1.e-15_wp
276      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
277      !
278      ! Search local extrema
279      ! --------------------
280      !                    ! large negative value (-zbig) inside land
281      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
282      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
283      !
284      DO jk = 1, jpkm1     ! search maximum in neighbourhood
285         ikm1 = MAX(jk-1,1)
286         DO_2D( 0, 0, 0, 0 )
287            zbetup(ji,jj,jk) = MAX(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
288               &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
289               &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
290         END_2D
291      END DO
292      !                    ! large positive value (+zbig) inside land
293      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
294      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
295      !
296      DO jk = 1, jpkm1     ! search minimum in neighbourhood
297         ikm1 = MAX(jk-1,1)
298         DO_2D( 0, 0, 0, 0 )
299            zbetdo(ji,jj,jk) = MIN(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
300               &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
301               &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
302         END_2D
303      END DO
304      !                    ! restore masked values to zero
305      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
306      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
307      !
308      ! Positive and negative part of fluxes and beta terms
309      ! ---------------------------------------------------
310      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
311         ! positive & negative part of the flux
312         zpos = MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
313         zneg = MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
314         ! up & down beta terms
315         zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
316         zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
317         zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
318      END_3D
319      !
320      ! monotonic flux in the k direction, i.e. pcc
321      ! -------------------------------------------
322      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
323         za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
324         zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
325         zc = 0.5 * ( 1.e0 + SIGN( 1.0_wp, pcc(ji,jj,jk) ) )
326         pcc(ji,jj,jk) = pcc(ji,jj,jk) * ( zc * za + ( 1.e0 - zc) * zb )
327      END_3D
328      !
329   END SUBROUTINE nonosc_z
330
331   !!======================================================================
332END MODULE traadv_ubs
Note: See TracBrowser for help on using the repository browser.