| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !! 3.6 ! 2014-11 (P. Mathiot, C. Harris) add ice shelves melting |
|---|
| 16 | !! 4.0 ! 2016-06 (L. Brodeau) new general bulk formulation |
|---|
| 17 | !! 4.0 ! 2019-03 (F. Lemarié & G. Samson) add ABL compatibility (ln_abl=TRUE) |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | !! sbc_init : read namsbc namelist |
|---|
| 22 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 23 | !! sbc_final : Finalize CICE ice model (if used) |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE oce ! ocean dynamics and tracers |
|---|
| 26 | USE dom_oce ! ocean space and time domain |
|---|
| 27 | USE closea ! closed seas |
|---|
| 28 | USE phycst ! physical constants |
|---|
| 29 | USE sbc_phy, ONLY : pp_cldf |
|---|
| 30 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 31 | USE trc_oce ! shared ocean-passive tracers variables |
|---|
| 32 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 33 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 34 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 35 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 36 | USE sbcblk ! surface boundary condition: bulk formulation |
|---|
| 37 | USE sbcabl ! atmospheric boundary layer |
|---|
| 38 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 39 | #if defined key_si3 |
|---|
| 40 | USE icestp ! surface boundary condition: SI3 sea-ice model |
|---|
| 41 | #endif |
|---|
| 42 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 43 | USE sbccpl ! surface boundary condition: coupled formulation |
|---|
| 44 | USE cpl_oasis3 ! OASIS routines for coupling |
|---|
| 45 | USE sbcclo ! surface boundary condition: closed sea correction |
|---|
| 46 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 47 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 48 | USE sbcapr ! surface boundary condition: atmo pressure |
|---|
| 49 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 50 | USE icbstp ! Icebergs |
|---|
| 51 | USE icb_oce , ONLY : ln_passive_mode ! iceberg interaction mode |
|---|
| 52 | USE traqsr ! active tracers: light penetration |
|---|
| 53 | USE sbcwave ! Wave module |
|---|
| 54 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 55 | USE usrdef_sbc ! user defined: surface boundary condition |
|---|
| 56 | USE closea ! closed sea |
|---|
| 57 | ! |
|---|
| 58 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 59 | USE iom ! IOM library |
|---|
| 60 | USE in_out_manager ! I/O manager |
|---|
| 61 | USE lib_mpp ! MPP library |
|---|
| 62 | USE timing ! Timing |
|---|
| 63 | USE wet_dry |
|---|
| 64 | USE diu_bulk, ONLY: ln_diurnal_only ! diurnal SST diagnostic |
|---|
| 65 | |
|---|
| 66 | IMPLICIT NONE |
|---|
| 67 | PRIVATE |
|---|
| 68 | |
|---|
| 69 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 70 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 71 | |
|---|
| 72 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 73 | |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 76 | !! $Id$ |
|---|
| 77 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 78 | !!---------------------------------------------------------------------- |
|---|
| 79 | CONTAINS |
|---|
| 80 | |
|---|
| 81 | SUBROUTINE sbc_init( Kbb, Kmm, Kaa ) |
|---|
| 82 | !!--------------------------------------------------------------------- |
|---|
| 83 | !! *** ROUTINE sbc_init *** |
|---|
| 84 | !! |
|---|
| 85 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 86 | !! |
|---|
| 87 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 88 | !! Call init routines for all other SBC modules that have one |
|---|
| 89 | !! |
|---|
| 90 | !! ** Action : - read namsbc parameters |
|---|
| 91 | !! - nsbc: type of sbc |
|---|
| 92 | !!---------------------------------------------------------------------- |
|---|
| 93 | INTEGER, INTENT(in) :: Kbb, Kmm, Kaa ! ocean time level indices |
|---|
| 94 | INTEGER :: ios, icpt ! local integer |
|---|
| 95 | LOGICAL :: ll_purecpl, ll_opa, ll_not_nemo ! local logical |
|---|
| 96 | !! |
|---|
| 97 | NAMELIST/namsbc/ nn_fsbc , & |
|---|
| 98 | & ln_usr , ln_flx , ln_blk , ln_abl, & |
|---|
| 99 | & ln_cpl , ln_mixcpl, nn_components, & |
|---|
| 100 | & nn_ice , ln_ice_embd, & |
|---|
| 101 | & ln_traqsr, ln_dm2dc , & |
|---|
| 102 | & ln_rnf , nn_fwb , ln_ssr , ln_apr_dyn, & |
|---|
| 103 | & ln_wave , ln_cdgw , ln_sdw , ln_tauwoc , ln_stcor , & |
|---|
| 104 | & ln_tauw , nn_lsm, nn_sdrift |
|---|
| 105 | !!---------------------------------------------------------------------- |
|---|
| 106 | ! |
|---|
| 107 | IF(lwp) THEN |
|---|
| 108 | WRITE(numout,*) |
|---|
| 109 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 110 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 111 | ENDIF |
|---|
| 112 | ! |
|---|
| 113 | ! !** read Surface Module namelist |
|---|
| 114 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 115 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist' ) |
|---|
| 116 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 117 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist' ) |
|---|
| 118 | IF(lwm) WRITE( numond, namsbc ) |
|---|
| 119 | ! |
|---|
| 120 | #if defined key_mpp_mpi |
|---|
| 121 | ncom_fsbc = nn_fsbc ! make nn_fsbc available for lib_mpp |
|---|
| 122 | #endif |
|---|
| 123 | #if ! defined key_si3 |
|---|
| 124 | IF( nn_ice == 2 ) nn_ice = 0 ! without key key_si3 you cannot use si3... |
|---|
| 125 | #endif |
|---|
| 126 | ! |
|---|
| 127 | ! |
|---|
| 128 | IF(lwp) THEN !* Control print |
|---|
| 129 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 130 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 131 | WRITE(numout,*) ' Type of air-sea fluxes : ' |
|---|
| 132 | WRITE(numout,*) ' user defined formulation ln_usr = ', ln_usr |
|---|
| 133 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 134 | WRITE(numout,*) ' bulk formulation ln_blk = ', ln_blk |
|---|
| 135 | WRITE(numout,*) ' ABL formulation ln_abl = ', ln_abl |
|---|
| 136 | WRITE(numout,*) ' Type of coupling (Ocean/Ice/Atmosphere) : ' |
|---|
| 137 | WRITE(numout,*) ' ocean-atmosphere coupled formulation ln_cpl = ', ln_cpl |
|---|
| 138 | WRITE(numout,*) ' mixed forced-coupled formulation ln_mixcpl = ', ln_mixcpl |
|---|
| 139 | !!gm lk_oasis is controlled by key_oasis3 ===>>> It shoud be removed from the namelist |
|---|
| 140 | WRITE(numout,*) ' OASIS coupling (with atm or sas) lk_oasis = ', lk_oasis |
|---|
| 141 | WRITE(numout,*) ' components of your executable nn_components = ', nn_components |
|---|
| 142 | WRITE(numout,*) ' Sea-ice : ' |
|---|
| 143 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 144 | WRITE(numout,*) ' ice embedded into ocean ln_ice_embd = ', ln_ice_embd |
|---|
| 145 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 146 | WRITE(numout,*) ' Light penetration in temperature Eq. ln_traqsr = ', ln_traqsr |
|---|
| 147 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 148 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 149 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 150 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 151 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 152 | WRITE(numout,*) ' nb of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 153 | WRITE(numout,*) ' surface wave ln_wave = ', ln_wave |
|---|
| 154 | WRITE(numout,*) ' Stokes drift corr. to vert. velocity ln_sdw = ', ln_sdw |
|---|
| 155 | WRITE(numout,*) ' vertical parametrization nn_sdrift = ', nn_sdrift |
|---|
| 156 | WRITE(numout,*) ' wave modified ocean stress ln_tauwoc = ', ln_tauwoc |
|---|
| 157 | WRITE(numout,*) ' wave modified ocean stress component ln_tauw = ', ln_tauw |
|---|
| 158 | WRITE(numout,*) ' Stokes coriolis term ln_stcor = ', ln_stcor |
|---|
| 159 | WRITE(numout,*) ' neutral drag coefficient (CORE,NCAR) ln_cdgw = ', ln_cdgw |
|---|
| 160 | ENDIF |
|---|
| 161 | ! |
|---|
| 162 | IF( .NOT.ln_wave ) THEN |
|---|
| 163 | ln_sdw = .false. ; ln_cdgw = .false. ; ln_tauwoc = .false. ; ln_tauw = .false. ; ln_stcor = .false. |
|---|
| 164 | ENDIF |
|---|
| 165 | IF( ln_sdw ) THEN |
|---|
| 166 | IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) & |
|---|
| 167 | CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' ) |
|---|
| 168 | ENDIF |
|---|
| 169 | ll_st_bv2014 = ( nn_sdrift==jp_breivik_2014 ) |
|---|
| 170 | ll_st_li2017 = ( nn_sdrift==jp_li_2017 ) |
|---|
| 171 | ll_st_bv_li = ( ll_st_bv2014 .OR. ll_st_li2017 ) |
|---|
| 172 | ll_st_peakfr = ( nn_sdrift==jp_peakfr ) |
|---|
| 173 | IF( ln_tauwoc .AND. ln_tauw ) & |
|---|
| 174 | CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', & |
|---|
| 175 | '(ln_tauwoc=.true. and ln_tauw=.true.)' ) |
|---|
| 176 | IF( ln_tauwoc ) & |
|---|
| 177 | CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' ) |
|---|
| 178 | IF( ln_tauw ) & |
|---|
| 179 | CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', & |
|---|
| 180 | 'This will override any other specification of the ocean stress' ) |
|---|
| 181 | ! |
|---|
| 182 | IF( .NOT.ln_usr ) THEN ! the model calendar needs some specificities (except in user defined case) |
|---|
| 183 | IF( MOD( rday , rn_Dt ) /= 0. ) CALL ctl_stop( 'the time step must devide the number of second of in a day' ) |
|---|
| 184 | IF( MOD( rday , 2. ) /= 0. ) CALL ctl_stop( 'the number of second of in a day must be an even number' ) |
|---|
| 185 | IF( MOD( rn_Dt , 2. ) /= 0. ) CALL ctl_stop( 'the time step (in second) must be an even number' ) |
|---|
| 186 | ENDIF |
|---|
| 187 | ! !** check option consistency |
|---|
| 188 | ! |
|---|
| 189 | IF(lwp) WRITE(numout,*) !* Single / Multi - executable (NEMO / OPA+SAS) |
|---|
| 190 | SELECT CASE( nn_components ) |
|---|
| 191 | CASE( jp_iam_nemo ) |
|---|
| 192 | IF(lwp) WRITE(numout,*) ' ==>>> NEMO configured as a single executable (i.e. including both OPA and Surface module)' |
|---|
| 193 | CASE( jp_iam_opa ) |
|---|
| 194 | IF(lwp) WRITE(numout,*) ' ==>>> Multi executable configuration. Here, OPA component' |
|---|
| 195 | IF( .NOT.lk_oasis ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 196 | IF( ln_cpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' ) |
|---|
| 197 | IF( ln_mixcpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 198 | CASE( jp_iam_sas ) |
|---|
| 199 | IF(lwp) WRITE(numout,*) ' ==>>> Multi executable configuration. Here, SAS component' |
|---|
| 200 | IF( .NOT.lk_oasis ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 201 | IF( ln_mixcpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 202 | CASE DEFAULT |
|---|
| 203 | CALL ctl_stop( 'sbc_init : unsupported value for nn_components' ) |
|---|
| 204 | END SELECT |
|---|
| 205 | ! !* coupled options |
|---|
| 206 | IF( ln_cpl ) THEN |
|---|
| 207 | IF( .NOT. lk_oasis ) CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)', & |
|---|
| 208 | & ' required to defined key_oasis3' ) |
|---|
| 209 | ENDIF |
|---|
| 210 | IF( ln_mixcpl ) THEN |
|---|
| 211 | IF( .NOT. lk_oasis ) CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ', & |
|---|
| 212 | & ' required to defined key_oasis3' ) |
|---|
| 213 | IF( .NOT.ln_cpl ) CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' ) |
|---|
| 214 | IF( nn_components /= jp_iam_nemo ) & |
|---|
| 215 | & CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ', & |
|---|
| 216 | & ' not yet working with sas-opa coupling via oasis' ) |
|---|
| 217 | ENDIF |
|---|
| 218 | ! !* sea-ice |
|---|
| 219 | SELECT CASE( nn_ice ) |
|---|
| 220 | CASE( 0 ) !- no ice in the domain |
|---|
| 221 | CASE( 1 ) !- Ice-cover climatology ("Ice-if" model) |
|---|
| 222 | CASE( 2 ) !- SI3 ice model |
|---|
| 223 | IF( .NOT.( ln_blk .OR. ln_cpl .OR. ln_abl .OR. ln_usr ) ) & |
|---|
| 224 | & CALL ctl_stop( 'sbc_init : SI3 sea-ice model requires ln_blk or ln_cpl or ln_abl or ln_usr = T' ) |
|---|
| 225 | CASE( 3 ) !- CICE ice model |
|---|
| 226 | IF( .NOT.( ln_blk .OR. ln_cpl .OR. ln_abl .OR. ln_usr ) ) & |
|---|
| 227 | & CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl or ln_abl or ln_usr = T' ) |
|---|
| 228 | IF( lk_agrif ) & |
|---|
| 229 | & CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 230 | CASE DEFAULT !- not supported |
|---|
| 231 | END SELECT |
|---|
| 232 | IF( ln_diurnal .AND. .NOT. ln_blk ) CALL ctl_stop( "sbc_init: diurnal flux processing only implemented for bulk forcing" ) |
|---|
| 233 | ! |
|---|
| 234 | ! !** allocate and set required variables |
|---|
| 235 | ! |
|---|
| 236 | ! !* allocate sbc arrays |
|---|
| 237 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 238 | #if ! defined key_si3 && ! defined key_cice |
|---|
| 239 | IF( sbc_ice_alloc() /= 0 ) CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' ) |
|---|
| 240 | #endif |
|---|
| 241 | ! |
|---|
| 242 | ! |
|---|
| 243 | IF( sbc_ssr_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_ssr arrays' ) |
|---|
| 244 | IF( .NOT.ln_ssr ) THEN !* Initialize qrp and erp if no restoring |
|---|
| 245 | qrp(:,:) = 0._wp |
|---|
| 246 | erp(:,:) = 0._wp |
|---|
| 247 | ENDIF |
|---|
| 248 | ! |
|---|
| 249 | IF( nn_ice == 0 ) THEN !* No sea-ice in the domain : ice fraction is always zero |
|---|
| 250 | IF( nn_components /= jp_iam_opa ) fr_i(:,:) = 0._wp ! except for OPA in SAS-OPA coupled case |
|---|
| 251 | ENDIF |
|---|
| 252 | ! |
|---|
| 253 | sfx (:,:) = 0._wp !* salt flux due to freezing/melting |
|---|
| 254 | fmmflx(:,:) = 0._wp !* freezing minus melting flux |
|---|
| 255 | cloud_fra(:,:) = pp_cldf !* cloud fraction over sea ice (used in si3) |
|---|
| 256 | |
|---|
| 257 | taum(:,:) = 0._wp !* wind stress module (needed in GLS in case of reduced restart) |
|---|
| 258 | |
|---|
| 259 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 260 | nday_qsr = -1 ! allow initialization at the 1st call !LB: now warm-layer of COARE* calls "sbc_dcy_param" of sbcdcy.F90! |
|---|
| 261 | IF( ln_dm2dc ) THEN !* daily mean to diurnal cycle |
|---|
| 262 | !LB:nday_qsr = -1 ! allow initialization at the 1st call |
|---|
| 263 | IF( .NOT.( ln_flx .OR. ln_blk .OR. ln_abl ) .AND. nn_components /= jp_iam_opa ) & |
|---|
| 264 | & CALL ctl_stop( 'qsr diurnal cycle from daily values requires flux, bulk or abl formulation' ) |
|---|
| 265 | ENDIF |
|---|
| 266 | ! !* Choice of the Surface Boudary Condition |
|---|
| 267 | ! (set nsbc) |
|---|
| 268 | ! |
|---|
| 269 | ll_purecpl = ln_cpl .AND. .NOT.ln_mixcpl |
|---|
| 270 | ll_opa = nn_components == jp_iam_opa |
|---|
| 271 | ll_not_nemo = nn_components /= jp_iam_nemo |
|---|
| 272 | icpt = 0 |
|---|
| 273 | ! |
|---|
| 274 | IF( ln_usr ) THEN ; nsbc = jp_usr ; icpt = icpt + 1 ; ENDIF ! user defined formulation |
|---|
| 275 | IF( ln_flx ) THEN ; nsbc = jp_flx ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 276 | IF( ln_blk ) THEN ; nsbc = jp_blk ; icpt = icpt + 1 ; ENDIF ! bulk formulation |
|---|
| 277 | IF( ln_abl ) THEN ; nsbc = jp_abl ; icpt = icpt + 1 ; ENDIF ! ABL formulation |
|---|
| 278 | IF( ll_purecpl ) THEN ; nsbc = jp_purecpl ; icpt = icpt + 1 ; ENDIF ! Pure Coupled formulation |
|---|
| 279 | IF( ll_opa ) THEN ; nsbc = jp_none ; icpt = icpt + 1 ; ENDIF ! opa coupling via SAS module |
|---|
| 280 | ! |
|---|
| 281 | IF( icpt /= 1 ) CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' ) |
|---|
| 282 | ! |
|---|
| 283 | IF(lwp) THEN !- print the choice of surface flux formulation |
|---|
| 284 | WRITE(numout,*) |
|---|
| 285 | SELECT CASE( nsbc ) |
|---|
| 286 | CASE( jp_usr ) ; WRITE(numout,*) ' ==>>> user defined forcing formulation' |
|---|
| 287 | CASE( jp_flx ) ; WRITE(numout,*) ' ==>>> flux formulation' |
|---|
| 288 | CASE( jp_blk ) ; WRITE(numout,*) ' ==>>> bulk formulation' |
|---|
| 289 | CASE( jp_abl ) ; WRITE(numout,*) ' ==>>> ABL formulation' |
|---|
| 290 | CASE( jp_purecpl ) ; WRITE(numout,*) ' ==>>> pure coupled formulation' |
|---|
| 291 | !!gm abusive use of jp_none ?? ===>>> need to be check and changed by adding a jp_sas parameter |
|---|
| 292 | CASE( jp_none ) ; WRITE(numout,*) ' ==>>> OPA coupled to SAS via oasis' |
|---|
| 293 | IF( ln_mixcpl ) WRITE(numout,*) ' + forced-coupled mixed formulation' |
|---|
| 294 | END SELECT |
|---|
| 295 | IF( ll_not_nemo ) WRITE(numout,*) ' + OASIS coupled SAS' |
|---|
| 296 | ENDIF |
|---|
| 297 | ! |
|---|
| 298 | ! !* OASIS initialization |
|---|
| 299 | ! |
|---|
| 300 | IF( lk_oasis ) CALL sbc_cpl_init( nn_ice ) ! Must be done before: (1) first time step |
|---|
| 301 | ! ! (2) the use of nn_fsbc |
|---|
| 302 | ! nn_fsbc initialization if OPA-SAS coupling via OASIS |
|---|
| 303 | ! SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly |
|---|
| 304 | IF( nn_components /= jp_iam_nemo ) THEN |
|---|
| 305 | IF( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rn_Dt) |
|---|
| 306 | IF( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rn_Dt) |
|---|
| 307 | ! |
|---|
| 308 | IF(lwp)THEN |
|---|
| 309 | WRITE(numout,*) |
|---|
| 310 | WRITE(numout,*)" OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc |
|---|
| 311 | WRITE(numout,*) |
|---|
| 312 | ENDIF |
|---|
| 313 | ENDIF |
|---|
| 314 | ! |
|---|
| 315 | ! !* check consistency between model timeline and nn_fsbc |
|---|
| 316 | IF( ln_rst_list .OR. nn_stock /= -1 ) THEN ! we will do restart files |
|---|
| 317 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 ) THEN |
|---|
| 318 | WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 319 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 320 | ENDIF |
|---|
| 321 | IF( .NOT. ln_rst_list .AND. MOD( nn_stock, nn_fsbc) /= 0 ) THEN ! we don't use nn_stock if ln_rst_list |
|---|
| 322 | WRITE(ctmp1,*) 'sbc_init : nn_stock (', nn_stock, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 323 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 324 | ENDIF |
|---|
| 325 | ENDIF |
|---|
| 326 | ! |
|---|
| 327 | IF( MOD( rday, REAL(nn_fsbc, wp) * rn_Dt ) /= 0 ) & |
|---|
| 328 | & CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 329 | ! |
|---|
| 330 | IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rn_Dt) ) < 8 ) & |
|---|
| 331 | & CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 332 | ! |
|---|
| 333 | |
|---|
| 334 | ! !** associated modules : initialization |
|---|
| 335 | ! |
|---|
| 336 | CALL sbc_ssm_init ( Kbb, Kmm ) ! Sea-surface mean fields initialization |
|---|
| 337 | ! |
|---|
| 338 | IF( l_sbc_clo ) CALL sbc_clo_init ! closed sea surface initialisation |
|---|
| 339 | ! |
|---|
| 340 | IF( ln_blk ) CALL sbc_blk_init ! bulk formulae initialization |
|---|
| 341 | |
|---|
| 342 | IF( ln_abl ) CALL sbc_abl_init ! Atmospheric Boundary Layer (ABL) |
|---|
| 343 | |
|---|
| 344 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialization |
|---|
| 345 | ! |
|---|
| 346 | ! |
|---|
| 347 | CALL sbc_rnf_init( Kmm ) ! Runof initialization |
|---|
| 348 | ! |
|---|
| 349 | IF( ln_apr_dyn ) CALL sbc_apr_init ! Atmo Pressure Forcing initialization |
|---|
| 350 | ! |
|---|
| 351 | #if defined key_si3 |
|---|
| 352 | IF( lk_agrif .AND. nn_ice == 0 ) THEN ! allocate ice arrays in case agrif + ice-model + no-ice in child grid |
|---|
| 353 | IF( sbc_ice_alloc() /= 0 ) CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' ) |
|---|
| 354 | ELSEIF( nn_ice == 2 ) THEN |
|---|
| 355 | CALL ice_init( Kbb, Kmm, Kaa ) ! ICE initialization |
|---|
| 356 | ENDIF |
|---|
| 357 | #endif |
|---|
| 358 | IF( nn_ice == 3 ) CALL cice_sbc_init( nsbc, Kbb, Kmm ) ! CICE initialization |
|---|
| 359 | ! |
|---|
| 360 | IF( ln_wave ) CALL sbc_wave_init ! surface wave initialisation |
|---|
| 361 | ! |
|---|
| 362 | IF( lwxios ) THEN |
|---|
| 363 | CALL iom_set_rstw_var_active('utau_b') |
|---|
| 364 | CALL iom_set_rstw_var_active('vtau_b') |
|---|
| 365 | CALL iom_set_rstw_var_active('qns_b') |
|---|
| 366 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 367 | ! CALL iom_set_rstw_var_active('qsr_b') |
|---|
| 368 | CALL iom_set_rstw_var_active('emp_b') |
|---|
| 369 | CALL iom_set_rstw_var_active('sfx_b') |
|---|
| 370 | ENDIF |
|---|
| 371 | |
|---|
| 372 | END SUBROUTINE sbc_init |
|---|
| 373 | |
|---|
| 374 | |
|---|
| 375 | SUBROUTINE sbc( kt, Kbb, Kmm ) |
|---|
| 376 | !!--------------------------------------------------------------------- |
|---|
| 377 | !! *** ROUTINE sbc *** |
|---|
| 378 | !! |
|---|
| 379 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 380 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 381 | !! |
|---|
| 382 | !! ** Method : blah blah to be written ????????? |
|---|
| 383 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 384 | !! |
|---|
| 385 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 386 | !! time step, i.e. |
|---|
| 387 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 388 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 389 | !! - updte the ice fraction : fr_i |
|---|
| 390 | !!---------------------------------------------------------------------- |
|---|
| 391 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 392 | INTEGER, INTENT(in) :: Kbb, Kmm ! ocean time level indices |
|---|
| 393 | ! |
|---|
| 394 | LOGICAL :: ll_sas, ll_opa ! local logical |
|---|
| 395 | ! |
|---|
| 396 | REAL(wp) :: zthscl ! wd tanh scale |
|---|
| 397 | REAL(wp), DIMENSION(jpi,jpj) :: zwdht, zwght ! wd dep over wd limit, wgt |
|---|
| 398 | |
|---|
| 399 | !!--------------------------------------------------------------------- |
|---|
| 400 | ! |
|---|
| 401 | IF( ln_timing ) CALL timing_start('sbc') |
|---|
| 402 | ! |
|---|
| 403 | ! ! ---------------------------------------- ! |
|---|
| 404 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 405 | ! ! ---------------------------------------- ! |
|---|
| 406 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 407 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 408 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 409 | emp_b (:,:) = emp (:,:) |
|---|
| 410 | sfx_b (:,:) = sfx (:,:) |
|---|
| 411 | IF( ln_rnf ) THEN |
|---|
| 412 | rnf_b (:,: ) = rnf (:,: ) |
|---|
| 413 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) |
|---|
| 414 | ENDIF |
|---|
| 415 | ! |
|---|
| 416 | ENDIF |
|---|
| 417 | ! ! ---------------------------------------- ! |
|---|
| 418 | ! ! forcing field computation ! |
|---|
| 419 | ! ! ---------------------------------------- ! |
|---|
| 420 | ! |
|---|
| 421 | ll_sas = nn_components == jp_iam_sas ! component flags |
|---|
| 422 | ll_opa = nn_components == jp_iam_opa |
|---|
| 423 | ! |
|---|
| 424 | IF( .NOT.ll_sas ) CALL sbc_ssm ( kt, Kbb, Kmm ) ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 425 | IF( ln_wave ) CALL sbc_wave( kt, Kmm ) ! surface waves |
|---|
| 426 | |
|---|
| 427 | ! |
|---|
| 428 | ! !== sbc formulation ==! |
|---|
| 429 | ! |
|---|
| 430 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 431 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 432 | CASE( jp_usr ) ; CALL usrdef_sbc_oce( kt, Kbb ) ! user defined formulation |
|---|
| 433 | CASE( jp_flx ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 434 | CASE( jp_blk ) |
|---|
| 435 | IF( ll_sas ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice, Kbb, Kmm ) ! OPA-SAS coupling: SAS receiving fields from OPA |
|---|
| 436 | CALL sbc_blk ( kt ) ! bulk formulation for the ocean |
|---|
| 437 | ! |
|---|
| 438 | CASE( jp_abl ) |
|---|
| 439 | IF( ll_sas ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice, Kbb, Kmm ) ! OPA-SAS coupling: SAS receiving fields from OPA |
|---|
| 440 | CALL sbc_abl ( kt ) ! ABL formulation for the ocean |
|---|
| 441 | ! |
|---|
| 442 | CASE( jp_purecpl ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice, Kbb, Kmm ) ! pure coupled formulation |
|---|
| 443 | CASE( jp_none ) |
|---|
| 444 | IF( ll_opa ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice, Kbb, Kmm ) ! OPA-SAS coupling: OPA receiving fields from SAS |
|---|
| 445 | END SELECT |
|---|
| 446 | ! |
|---|
| 447 | IF( ln_mixcpl ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice, Kbb, Kmm ) ! forced-coupled mixed formulation after forcing |
|---|
| 448 | ! |
|---|
| 449 | IF ( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( ) ! Wind stress provided by waves |
|---|
| 450 | ! |
|---|
| 451 | ! !== Misc. Options ==! |
|---|
| 452 | ! |
|---|
| 453 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 454 | CASE( 1 ) ; CALL sbc_ice_if ( kt, Kbb, Kmm ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 455 | #if defined key_si3 |
|---|
| 456 | CASE( 2 ) ; CALL ice_stp ( kt, Kbb, Kmm, nsbc ) ! SI3 ice model |
|---|
| 457 | #endif |
|---|
| 458 | CASE( 3 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 459 | END SELECT |
|---|
| 460 | |
|---|
| 461 | IF( ln_icebergs ) THEN |
|---|
| 462 | CALL icb_stp( kt ) ! compute icebergs |
|---|
| 463 | ! Icebergs do not melt over the haloes. |
|---|
| 464 | ! So emp values over the haloes are no more consistent with the inner domain values. |
|---|
| 465 | ! A lbc_lnk is therefore needed to ensure reproducibility and restartability. |
|---|
| 466 | ! see ticket #2113 for discussion about this lbc_lnk. |
|---|
| 467 | IF( .NOT. ln_passive_mode ) CALL lbc_lnk( 'sbcmod', emp, 'T', 1.0_wp ) ! ensure restartability with icebergs |
|---|
| 468 | ENDIF |
|---|
| 469 | |
|---|
| 470 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 471 | |
|---|
| 472 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 473 | |
|---|
| 474 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc, Kmm ) ! control the freshwater budget |
|---|
| 475 | |
|---|
| 476 | ! Special treatment of freshwater fluxes over closed seas in the model domain |
|---|
| 477 | ! Should not be run if ln_diurnal_only |
|---|
| 478 | IF( l_sbc_clo ) CALL sbc_clo( kt ) |
|---|
| 479 | |
|---|
| 480 | !!$!RBbug do not understand why see ticket 667 |
|---|
| 481 | !!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why. |
|---|
| 482 | !!$ CALL lbc_lnk( 'sbcmod', emp, 'T', 1.0_wp ) |
|---|
| 483 | IF( ll_wd ) THEN ! If near WAD point limit the flux for now |
|---|
| 484 | zthscl = atanh(rn_wd_sbcfra) ! taper frac default is .999 |
|---|
| 485 | zwdht(:,:) = ssh(:,:,Kmm) + ht_0(:,:) - rn_wdmin1 ! do this calc of water |
|---|
| 486 | ! depth above wd limit once |
|---|
| 487 | WHERE( zwdht(:,:) <= 0.0 ) |
|---|
| 488 | taum(:,:) = 0.0 |
|---|
| 489 | utau(:,:) = 0.0 |
|---|
| 490 | vtau(:,:) = 0.0 |
|---|
| 491 | qns (:,:) = 0.0 |
|---|
| 492 | qsr (:,:) = 0.0 |
|---|
| 493 | emp (:,:) = min(emp(:,:),0.0) !can allow puddles to grow but not shrink |
|---|
| 494 | sfx (:,:) = 0.0 |
|---|
| 495 | END WHERE |
|---|
| 496 | zwght(:,:) = tanh(zthscl*zwdht(:,:)) |
|---|
| 497 | WHERE( zwdht(:,:) > 0.0 .and. zwdht(:,:) < rn_wd_sbcdep ) ! 5 m hard limit here is arbitrary |
|---|
| 498 | qsr (:,:) = qsr(:,:) * zwght(:,:) |
|---|
| 499 | qns (:,:) = qns(:,:) * zwght(:,:) |
|---|
| 500 | taum (:,:) = taum(:,:) * zwght(:,:) |
|---|
| 501 | utau (:,:) = utau(:,:) * zwght(:,:) |
|---|
| 502 | vtau (:,:) = vtau(:,:) * zwght(:,:) |
|---|
| 503 | sfx (:,:) = sfx(:,:) * zwght(:,:) |
|---|
| 504 | emp (:,:) = emp(:,:) * zwght(:,:) |
|---|
| 505 | END WHERE |
|---|
| 506 | ENDIF |
|---|
| 507 | ! |
|---|
| 508 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 509 | ! ! ---------------------------------------- ! |
|---|
| 510 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 511 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 512 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 513 | CALL iom_get( numror, jpdom_auto, 'utau_b', utau_b, ldxios = lrxios, cd_type = 'U', psgn = -1._wp ) ! before i-stress (U-point) |
|---|
| 514 | CALL iom_get( numror, jpdom_auto, 'vtau_b', vtau_b, ldxios = lrxios, cd_type = 'V', psgn = -1._wp ) ! before j-stress (V-point) |
|---|
| 515 | CALL iom_get( numror, jpdom_auto, 'qns_b', qns_b, ldxios = lrxios ) ! before non solar heat flux (T-point) |
|---|
| 516 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 517 | ! CALL iom_get( numror, jpdom_auto, 'qsr_b' , qsr_b, ldxios = lrxios ) ! before solar heat flux (T-point) |
|---|
| 518 | CALL iom_get( numror, jpdom_auto, 'emp_b', emp_b, ldxios = lrxios ) ! before freshwater flux (T-point) |
|---|
| 519 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 520 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 521 | CALL iom_get( numror, jpdom_auto, 'sfx_b', sfx_b, ldxios = lrxios ) ! before salt flux (T-point) |
|---|
| 522 | ELSE |
|---|
| 523 | sfx_b (:,:) = sfx(:,:) |
|---|
| 524 | ENDIF |
|---|
| 525 | ELSE !* no restart: set from nit000 values |
|---|
| 526 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 527 | utau_b(:,:) = utau(:,:) |
|---|
| 528 | vtau_b(:,:) = vtau(:,:) |
|---|
| 529 | qns_b (:,:) = qns (:,:) |
|---|
| 530 | emp_b (:,:) = emp (:,:) |
|---|
| 531 | sfx_b (:,:) = sfx (:,:) |
|---|
| 532 | ENDIF |
|---|
| 533 | ENDIF |
|---|
| 534 | ! ! ---------------------------------------- ! |
|---|
| 535 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 536 | ! ! ---------------------------------------- ! |
|---|
| 537 | IF(lwp) WRITE(numout,*) |
|---|
| 538 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 539 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 540 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 541 | IF( lwxios ) CALL iom_swap( cwxios_context ) |
|---|
| 542 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios ) |
|---|
| 543 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios ) |
|---|
| 544 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns, ldxios = lwxios ) |
|---|
| 545 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 546 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 547 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp, ldxios = lwxios ) |
|---|
| 548 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx, ldxios = lwxios ) |
|---|
| 549 | IF( lwxios ) CALL iom_swap( cxios_context ) |
|---|
| 550 | ENDIF |
|---|
| 551 | ! ! ---------------------------------------- ! |
|---|
| 552 | ! ! Outputs and control print ! |
|---|
| 553 | ! ! ---------------------------------------- ! |
|---|
| 554 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 555 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 556 | CALL iom_put( "empbmr" , emp_b - rnf ) ! before upward water flux ( needed to recalculate the time evolution of ssh in offline ) |
|---|
| 557 | CALL iom_put( "saltflx", sfx ) ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case) |
|---|
| 558 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 559 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 560 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 561 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 562 | IF( nn_ice > 0 .OR. ll_opa ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 563 | CALL iom_put( "taum" , taum ) ! wind stress module |
|---|
| 564 | CALL iom_put( "wspd" , wndm ) ! wind speed module over free ocean or leads in presence of sea-ice |
|---|
| 565 | CALL iom_put( "qrp", qrp ) ! heat flux damping |
|---|
| 566 | CALL iom_put( "erp", erp ) ! freshwater flux damping |
|---|
| 567 | ENDIF |
|---|
| 568 | ! |
|---|
| 569 | IF(sn_cfctl%l_prtctl) THEN ! print mean trends (used for debugging) |
|---|
| 570 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask ) |
|---|
| 571 | CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask ) |
|---|
| 572 | CALL prt_ctl(tab2d_1=(sfx-rnf) , clinfo1=' sfx-rnf - : ', mask1=tmask ) |
|---|
| 573 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask ) |
|---|
| 574 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask ) |
|---|
| 575 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, kdim=jpk ) |
|---|
| 576 | CALL prt_ctl(tab3d_1=ts(:,:,:,jp_tem,Kmm), clinfo1=' sst - : ', mask1=tmask, kdim=1 ) |
|---|
| 577 | CALL prt_ctl(tab3d_1=ts(:,:,:,jp_sal,Kmm), clinfo1=' sss - : ', mask1=tmask, kdim=1 ) |
|---|
| 578 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 579 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask ) |
|---|
| 580 | ENDIF |
|---|
| 581 | |
|---|
| 582 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 583 | ! |
|---|
| 584 | IF( ln_timing ) CALL timing_stop('sbc') |
|---|
| 585 | ! |
|---|
| 586 | END SUBROUTINE sbc |
|---|
| 587 | |
|---|
| 588 | |
|---|
| 589 | SUBROUTINE sbc_final |
|---|
| 590 | !!--------------------------------------------------------------------- |
|---|
| 591 | !! *** ROUTINE sbc_final *** |
|---|
| 592 | !! |
|---|
| 593 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 594 | !!--------------------------------------------------------------------- |
|---|
| 595 | ! |
|---|
| 596 | IF( nn_ice == 3 ) CALL cice_sbc_final |
|---|
| 597 | ! |
|---|
| 598 | END SUBROUTINE sbc_final |
|---|
| 599 | |
|---|
| 600 | !!====================================================================== |
|---|
| 601 | END MODULE sbcmod |
|---|
