New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in NEMO/branches/2020/dev_r13648_ASINTER-04_laurent_bulk_ice/src/OCE/SBC – NEMO

source: NEMO/branches/2020/dev_r13648_ASINTER-04_laurent_bulk_ice/src/OCE/SBC/sbcrnf.F90 @ 14038

Last change on this file since 14038 was 14038, checked in by laurent, 3 years ago

Catch up with trunk at rev r14037
  • Property svn:keywords set to Id
File size: 29.8 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf       : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init  : runoffs initialisation
16   !!   rnf_mouth     : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce        ! ocean space and time domain
19   USE phycst         ! physical constants
20   USE sbc_oce        ! surface boundary condition variables
21   USE eosbn2         ! Equation Of State
22   USE closea, ONLY: l_clo_rnf, clo_rnf ! closed seas
23   !
24   USE in_out_manager ! I/O manager
25   USE fldread        ! read input field at current time step
26   USE iom            ! I/O module
27   USE lib_mpp        ! MPP library
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_rnf       ! called in sbcmod module
33   PUBLIC   sbc_rnf_div   ! called in divhor module
34   PUBLIC   sbc_rnf_alloc ! called in sbcmod module
35   PUBLIC   sbc_rnf_init  ! called in sbcmod module
36
37   !                                                !!* namsbc_rnf namelist *
38   CHARACTER(len=100)         ::   cn_dir            !: Root directory for location of rnf files
39   LOGICAL           , PUBLIC ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
40   LOGICAL                    ::      ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
41   REAL(wp)                   ::      rn_rnf_max        !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
42   REAL(wp)                   ::      rn_dep_max        !: depth over which runoffs is spread       (ln_rnf_depth_ini =T)
43   INTEGER                    ::      nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44   LOGICAL           , PUBLIC ::   ln_rnf_icb        !: iceberg flux is specified in a file
45   LOGICAL                    ::   ln_rnf_tem        !: temperature river runoffs attribute specified in a file
46   LOGICAL           , PUBLIC ::   ln_rnf_sal        !: salinity    river runoffs attribute specified in a file
47   TYPE(FLD_N)       , PUBLIC ::   sn_rnf            !: information about the runoff file to be read
48   TYPE(FLD_N)                ::   sn_cnf            !: information about the runoff mouth file to be read
49   TYPE(FLD_N)                ::   sn_i_rnf        !: information about the iceberg flux file to be read
50   TYPE(FLD_N)                ::   sn_s_rnf          !: information about the salinities of runoff file to be read
51   TYPE(FLD_N)                ::   sn_t_rnf          !: information about the temperatures of runoff file to be read
52   TYPE(FLD_N)                ::   sn_dep_rnf        !: information about the depth which river inflow affects
53   LOGICAL           , PUBLIC ::   ln_rnf_mouth      !: specific treatment in mouths vicinity
54   REAL(wp)                   ::   rn_hrnf           !: runoffs, depth over which enhanced vertical mixing is used
55   REAL(wp)          , PUBLIC ::   rn_avt_rnf        !: runoffs, value of the additional vertical mixing coef. [m2/s]
56   REAL(wp)          , PUBLIC ::   rn_rfact          !: multiplicative factor for runoff
57
58   LOGICAL , PUBLIC ::   l_rnfcpl = .false.   !: runoffs recieved from oasis
59   INTEGER , PUBLIC ::   nkrnf = 0            !: nb of levels over which Kz is increased at river mouths
60
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
63   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
64   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
65   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]
66
67   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
68   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_i_rnf     ! structure: iceberg flux (file information, fields read)
69   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read)
70   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read)
71
72   !! * Substitutions
73#  include "do_loop_substitute.h90"
74#  include "domzgr_substitute.h90"
75   !!----------------------------------------------------------------------
76   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
77   !! $Id$
78   !! Software governed by the CeCILL license (see ./LICENSE)
79   !!----------------------------------------------------------------------
80CONTAINS
81
82   INTEGER FUNCTION sbc_rnf_alloc()
83      !!----------------------------------------------------------------------
84      !!                ***  ROUTINE sbc_rnf_alloc  ***
85      !!----------------------------------------------------------------------
86      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
87         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
88         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
89         !
90      CALL mpp_sum ( 'sbcrnf', sbc_rnf_alloc )
91      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
92   END FUNCTION sbc_rnf_alloc
93
94
95   SUBROUTINE sbc_rnf( kt )
96      !!----------------------------------------------------------------------
97      !!                  ***  ROUTINE sbc_rnf  ***
98      !!
99      !! ** Purpose :   Introduce a climatological run off forcing
100      !!
101      !! ** Method  :   Set each river mouth with a monthly climatology
102      !!                provided from different data.
103      !!                CAUTION : upward water flux, runoff forced to be < 0
104      !!
105      !! ** Action  :   runoff updated runoff field at time-step kt
106      !!----------------------------------------------------------------------
107      INTEGER, INTENT(in) ::   kt          ! ocean time step
108      !
109      INTEGER  ::   ji, jj    ! dummy loop indices
110      INTEGER  ::   z_err = 0 ! dummy integer for error handling
111      !!----------------------------------------------------------------------
112      REAL(wp), DIMENSION(jpi,jpj) ::   ztfrz   ! freezing point used for temperature correction
113      !
114      !
115      !                                            !-------------------!
116      !                                            !   Update runoff   !
117      !                                            !-------------------!
118      !
119      !
120      IF( .NOT. l_rnfcpl )  THEN
121                            CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt ( runoffs + iceberg )
122         IF( ln_rnf_icb )   CALL fld_read ( kt, nn_fsbc, sf_i_rnf )    ! idem for iceberg flux if required
123      ENDIF
124      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
125      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
126      !
127      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
128         !
129         IF( .NOT. l_rnfcpl ) THEN
130             rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
131             IF( ln_rnf_icb ) THEN
132                fwficb(:,:) = rn_rfact * ( sf_i_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
133                CALL iom_put( 'iceberg_cea'  , fwficb(:,:)  )         ! output iceberg flux
134                CALL iom_put( 'hflx_icb_cea' , fwficb(:,:) * rLfus )   ! output Heat Flux into Sea Water due to Iceberg Thermodynamics -->
135             ENDIF
136         ENDIF
137         !
138         !                                                           ! set temperature & salinity content of runoffs
139         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
140            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
141            CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
142            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
143               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rho0
144            END WHERE
145         ELSE                                                        ! use SST as runoffs temperature
146            !CEOD River is fresh water so must at least be 0 unless we consider ice
147            rnf_tsc(:,:,jp_tem) = MAX( sst_m(:,:), 0.0_wp ) * rnf(:,:) * r1_rho0
148         ENDIF
149         !                                                           ! use runoffs salinity data
150         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
151         !                                                           ! else use S=0 for runoffs (done one for all in the init)
152                                         CALL iom_put( 'runoffs'     , rnf(:,:)                         )   ! output runoff mass flux
153         IF( iom_use('hflx_rnf_cea') )   CALL iom_put( 'hflx_rnf_cea', rnf_tsc(:,:,jp_tem) * rho0 * rcp )   ! output runoff sensible heat (W/m2)
154      ENDIF
155      !
156      !                                                ! ---------------------------------------- !
157      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
158         !                                             ! ---------------------------------------- !
159         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
160            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
161            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file', lrxios
162            CALL iom_get( numror, jpdom_auto, 'rnf_b', rnf_b )     ! before runoff
163            CALL iom_get( numror, jpdom_auto, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) )   ! before heat content of runoff
164            CALL iom_get( numror, jpdom_auto, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) )   ! before salinity content of runoff
165         ELSE                                                   !* no restart: set from nit000 values
166            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
167            rnf_b    (:,:  ) = rnf    (:,:  )
168            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
169         ENDIF
170      ENDIF
171      !                                                ! ---------------------------------------- !
172      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
173         !                                             ! ---------------------------------------- !
174         IF(lwp) WRITE(numout,*)
175         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
176            &                    'at it= ', kt,' date= ', ndastp
177         IF(lwp) WRITE(numout,*) '~~~~'
178         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
179         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
180         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
181      ENDIF
182      !
183   END SUBROUTINE sbc_rnf
184
185
186   SUBROUTINE sbc_rnf_div( phdivn, Kmm )
187      !!----------------------------------------------------------------------
188      !!                  ***  ROUTINE sbc_rnf  ***
189      !!
190      !! ** Purpose :   update the horizontal divergence with the runoff inflow
191      !!
192      !! ** Method  :
193      !!                CAUTION : rnf is positive (inflow) decreasing the
194      !!                          divergence and expressed in m/s
195      !!
196      !! ** Action  :   phdivn   decreased by the runoff inflow
197      !!----------------------------------------------------------------------
198      INTEGER                   , INTENT(in   ) ::   Kmm      ! ocean time level index
199      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
200      !!
201      INTEGER  ::   ji, jj, jk   ! dummy loop indices
202      REAL(wp) ::   zfact     ! local scalar
203      !!----------------------------------------------------------------------
204      !
205      zfact = 0.5_wp
206      !
207      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
208         IF( ln_linssh ) THEN    !* constant volume case : just apply the runoff input flow
209            DO_2D( 1, 1, 1, 1 )
210               DO jk = 1, nk_rnf(ji,jj)
211                  phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
212               END DO
213            END_2D
214         ELSE                    !* variable volume case
215            DO_2D( 1, 1, 1, 1 )              ! update the depth over which runoffs are distributed
216               h_rnf(ji,jj) = 0._wp
217               DO jk = 1, nk_rnf(ji,jj)                             ! recalculates h_rnf to be the depth in metres
218                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)   ! to the bottom of the relevant grid box
219               END DO
220               !                          ! apply the runoff input flow
221               DO jk = 1, nk_rnf(ji,jj)
222                  phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
223               END DO
224            END_2D
225         ENDIF
226      ELSE                       !==   runoff put only at the surface   ==!
227         h_rnf (:,:)   = e3t (:,:,1,Kmm)        ! update h_rnf to be depth of top box
228         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rho0 / e3t(:,:,1,Kmm)
229      ENDIF
230      !
231   END SUBROUTINE sbc_rnf_div
232
233
234   SUBROUTINE sbc_rnf_init( Kmm )
235      !!----------------------------------------------------------------------
236      !!                  ***  ROUTINE sbc_rnf_init  ***
237      !!
238      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
239      !!
240      !! ** Method  : - read the runoff namsbc_rnf namelist
241      !!
242      !! ** Action  : - read parameters
243      !!----------------------------------------------------------------------
244      INTEGER, INTENT(in) :: Kmm           ! ocean time level index
245      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
246      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
247      INTEGER           ::   ierror, inum  ! temporary integer
248      INTEGER           ::   ios           ! Local integer output status for namelist read
249      INTEGER           ::   nbrec         ! temporary integer
250      REAL(wp)          ::   zacoef
251      REAL(wp), DIMENSION(jpi,jpj,2) :: zrnfcl
252      !!
253      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, ln_rnf_icb,   &
254         &                 sn_rnf, sn_cnf    , sn_i_rnf, sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
255         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
256         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
257      !!----------------------------------------------------------------------
258      !
259      !                                         !==  allocate runoff arrays
260      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
261      !
262      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
263         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
264         nkrnf         = 0
265         rnf     (:,:) = 0.0_wp
266         rnf_b   (:,:) = 0.0_wp
267         rnfmsk  (:,:) = 0.0_wp
268         rnfmsk_z(:)   = 0.0_wp
269         RETURN
270      ENDIF
271      !
272      !                                   ! ============
273      !                                   !   Namelist
274      !                                   ! ============
275      !
276      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
277901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist' )
278
279      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
280902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist' )
281      IF(lwm) WRITE ( numond, namsbc_rnf )
282      !
283      !                                         ! Control print
284      IF(lwp) THEN
285         WRITE(numout,*)
286         WRITE(numout,*) 'sbc_rnf_init : runoff '
287         WRITE(numout,*) '~~~~~~~~~~~~ '
288         WRITE(numout,*) '   Namelist namsbc_rnf'
289         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
290         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
291         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
292         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
293      ENDIF
294      !                                   ! ==================
295      !                                   !   Type of runoff
296      !                                   ! ==================
297      !
298      IF( .NOT. l_rnfcpl ) THEN
299         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
300         IF(lwp) WRITE(numout,*)
301         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs inflow read in a file'
302         IF( ierror > 0 ) THEN
303            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_rnf structure' )   ;   RETURN
304         ENDIF
305         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
306         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
307         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf', no_print )
308         !
309         IF( ln_rnf_icb ) THEN                      ! Create (if required) sf_i_rnf structure
310            IF(lwp) WRITE(numout,*)
311            IF(lwp) WRITE(numout,*) '          iceberg flux read in a file'
312            ALLOCATE( sf_i_rnf(1), STAT=ierror  )
313            IF( ierror > 0 ) THEN
314               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_i_rnf structure' )   ;   RETURN
315            ENDIF
316            ALLOCATE( sf_i_rnf(1)%fnow(jpi,jpj,1)   )
317            IF( sn_i_rnf%ln_tint ) ALLOCATE( sf_i_rnf(1)%fdta(jpi,jpj,1,2) )
318            CALL fld_fill (sf_i_rnf, (/ sn_i_rnf /), cn_dir, 'sbc_rnf_init', 'read iceberg flux data', 'namsbc_rnf' )
319         ELSE
320            fwficb(:,:) = 0._wp
321         ENDIF
322
323      ENDIF
324      !
325      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
326         IF(lwp) WRITE(numout,*)
327         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs temperatures read in a file'
328         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
329         IF( ierror > 0 ) THEN
330            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
331         ENDIF
332         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
333         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
334         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf', no_print )
335      ENDIF
336      !
337      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
338         IF(lwp) WRITE(numout,*)
339         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs salinities read in a file'
340         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
341         IF( ierror > 0 ) THEN
342            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
343         ENDIF
344         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
345         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
346         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf', no_print )
347      ENDIF
348      !
349      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
350         IF(lwp) WRITE(numout,*)
351         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs depth read in a file'
352         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
353         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
354            IF( sn_dep_rnf%clftyp == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
355         ENDIF
356         CALL iom_open ( rn_dep_file, inum )                             ! open file
357         CALL iom_get  ( inum, jpdom_global, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
358         CALL iom_close( inum )                                          ! close file
359         !
360         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
361         DO_2D( 1, 1, 1, 1 )
362            IF( h_rnf(ji,jj) > 0._wp ) THEN
363               jk = 2
364               DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
365               END DO
366               nk_rnf(ji,jj) = jk
367            ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
368            ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
369            ELSE
370               CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
371               WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
372            ENDIF
373         END_2D
374         DO_2D( 1, 1, 1, 1 )                           ! set the associated depth
375            h_rnf(ji,jj) = 0._wp
376            DO jk = 1, nk_rnf(ji,jj)
377               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
378            END DO
379         END_2D
380         !
381      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
382         !
383         IF(lwp) WRITE(numout,*)
384         IF(lwp) WRITE(numout,*) '   ==>>>   depth of runoff computed once from max value of runoff'
385         IF(lwp) WRITE(numout,*) '        max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
386         IF(lwp) WRITE(numout,*) '        depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
387         IF(lwp) WRITE(numout,*) '        create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
388
389         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
390         nbrec = iom_getszuld( inum )
391         zrnfcl(:,:,1) = 0._wp                                                            ! init the max to 0. in 1
392         DO jm = 1, nbrec
393            CALL iom_get( inum, jpdom_global, TRIM( sn_rnf%clvar ), zrnfcl(:,:,2), jm )   ! read the value in 2
394            zrnfcl(:,:,1) = MAXVAL( zrnfcl(:,:,:), DIM=3 )                                ! store the maximum value in time in 1
395         END DO
396         CALL iom_close( inum )
397         !
398         h_rnf(:,:) = 1.
399         !
400         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
401         !
402         WHERE( zrnfcl(:,:,1) > 0._wp )  h_rnf(:,:) = zacoef * zrnfcl(:,:,1)   ! compute depth for all runoffs
403         !
404         DO_2D( 1, 1, 1, 1 )                ! take in account min depth of ocean rn_hmin
405            IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
406               jk = mbkt(ji,jj)
407               h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
408            ENDIF
409         END_2D
410         !
411         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
412         DO_2D( 1, 1, 1, 1 )
413            IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
414               jk = 2
415               DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
416               END DO
417               nk_rnf(ji,jj) = jk
418            ELSE
419               nk_rnf(ji,jj) = 1
420            ENDIF
421         END_2D
422         !
423         DO_2D( 1, 1, 1, 1 )                          ! set the associated depth
424            h_rnf(ji,jj) = 0._wp
425            DO jk = 1, nk_rnf(ji,jj)
426               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
427            END DO
428         END_2D
429         !
430         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
431            IF(lwp) WRITE(numout,*) '   ==>>>   create runoff depht file'
432            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE. )
433            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
434            CALL iom_close ( inum )
435         ENDIF
436      ELSE                                       ! runoffs applied at the surface
437         nk_rnf(:,:) = 1
438         h_rnf (:,:) = e3t(:,:,1,Kmm)
439      ENDIF
440      !
441      rnf(:,:) =  0._wp                         ! runoff initialisation
442      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
443      !
444      !                                   ! ========================
445      !                                   !   River mouth vicinity
446      !                                   ! ========================
447      !
448      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
449         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
450         !                                      !    - set to zero SSS damping (ln_ssr=T)
451         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
452         !
453         IF( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
454            &                                              'be spread through depth by ln_rnf_depth'               )
455         !
456         nkrnf = 0                                  ! Number of level over which Kz increase
457         IF( rn_hrnf > 0._wp ) THEN
458            nkrnf = 2
459            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
460            END DO
461            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf_init: number of levels over which Kz is increased is computed for zco...' )
462         ENDIF
463         IF(lwp) WRITE(numout,*)
464         IF(lwp) WRITE(numout,*) '   ==>>>   Specific treatment used in vicinity of river mouths :'
465         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
466         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
467         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
468         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
469         !
470         CALL rnf_mouth                             ! set river mouth mask
471         !
472      ELSE                                      ! No treatment at river mouths
473         IF(lwp) WRITE(numout,*)
474         IF(lwp) WRITE(numout,*) '   ==>>>   No specific treatment at river mouths'
475         rnfmsk  (:,:) = 0._wp
476         rnfmsk_z(:)   = 0._wp
477         nkrnf = 0
478      ENDIF
479      !
480   END SUBROUTINE sbc_rnf_init
481
482
483   SUBROUTINE rnf_mouth
484      !!----------------------------------------------------------------------
485      !!                  ***  ROUTINE rnf_mouth  ***
486      !!
487      !! ** Purpose :   define the river mouths mask
488      !!
489      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
490      !!                climatological file. Defined a given vertical structure.
491      !!                CAUTION, the vertical structure is hard coded on the
492      !!                first 5 levels.
493      !!                This fields can be used to:
494      !!                 - set an upstream advection scheme
495      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
496      !!                 - increase vertical on the top nn_krnf vertical levels
497      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
498      !!                 - set to zero SSS restoring flux at river mouth grid points
499      !!
500      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
501      !!                rnfmsk_z vertical structure
502      !!----------------------------------------------------------------------
503      INTEGER            ::   inum        ! temporary integers
504      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
505      !!----------------------------------------------------------------------
506      !
507      IF(lwp) WRITE(numout,*)
508      IF(lwp) WRITE(numout,*) '   rnf_mouth : river mouth mask'
509      IF(lwp) WRITE(numout,*) '   ~~~~~~~~~ '
510      !
511      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
512      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
513         IF( sn_cnf%clftyp == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
514      ENDIF
515      !
516      ! horizontal mask (read in NetCDF file)
517      CALL iom_open ( cl_rnfile, inum )                             ! open file
518      CALL iom_get  ( inum, jpdom_global, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
519      CALL iom_close( inum )                                        ! close file
520      !
521      IF( l_clo_rnf )   CALL clo_rnf( rnfmsk )   ! closed sea inflow set as river mouth
522      !
523      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
524      rnfmsk_z(1)   = 1.0
525      rnfmsk_z(2)   = 1.0                                         ! **********
526      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
527      rnfmsk_z(4)   = 0.25                                        ! **********
528      rnfmsk_z(5)   = 0.125
529      !
530   END SUBROUTINE rnf_mouth
531
532   !!======================================================================
533END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.