New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in NEMO/branches/2020/dev_r13787_SI3-10_EAP/src/OCE/SBC – NEMO

source: NEMO/branches/2020/dev_r13787_SI3-10_EAP/src/OCE/SBC/sbcssm.F90 @ 13991

Last change on this file since 13991 was 13991, checked in by acc, 4 years ago

dev_r13787_SI3-10_EAP. Update development branch with trunk changes upto 13986
  • Property svn:keywords set to Id
File size: 13.5 KB
RevLine 
[888]1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
[2715]6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
[2528]7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
[6140]8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
[888]9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
[6140]12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
[888]14   !!----------------------------------------------------------------------
[6140]15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
[10425]20   USE traqsr, ONLY: ln_traqsr
[4990]21   !
[6140]22   USE in_out_manager ! I/O manager
23   USE prtctl         ! Print control
24   USE iom            ! IOM library
[888]25
26   IMPLICIT NONE
27   PRIVATE
28
[6140]29   PUBLIC   sbc_ssm        ! routine called by step.F90
30   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
[4292]31
[6140]32   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
[4292]33   
[13237]34#  include "domzgr_substitute.h90"
[888]35   !!----------------------------------------------------------------------
[9598]36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
[1156]37   !! $Id$
[10068]38   !! Software governed by the CeCILL license (see ./LICENSE)
[888]39   !!----------------------------------------------------------------------
40CONTAINS
41
[12377]42   SUBROUTINE sbc_ssm( kt, Kbb, Kmm )
[888]43      !!---------------------------------------------------------------------
44      !!                     ***  ROUTINE sbc_oce  ***
45      !!                     
46      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
47      !!                condition computation
48      !!               
49      !! ** Method  :   compute mean surface velocity (2 components at U and
[7646]50      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
[888]51      !!      the periode (kt - nn_fsbc) to kt
[2528]52      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
53      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
[888]54      !!---------------------------------------------------------------------
[2715]55      INTEGER, INTENT(in) ::   kt   ! ocean time step
[12377]56      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
[888]57      !
[4990]58      INTEGER  ::   ji, jj               ! loop index
[2715]59      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
[4990]60      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
[888]61      !!---------------------------------------------------------------------
[6140]62      !
[5120]63      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
[12377]64      zts(:,:,jp_tem) = ts(:,:,1,jp_tem,Kmm)
65      zts(:,:,jp_sal) = ts(:,:,1,jp_sal,Kmm)
[4990]66      !
[3607]67      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
[888]68         !                                                ! ---------------------------------------- !
[12377]69         ssu_m(:,:) = uu(:,:,1,Kbb)
70         ssv_m(:,:) = vv(:,:,1,Kbb)
[7753]71         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
[12377]72         ELSE                   ;   sst_m(:,:) = zts(:,:,jp_tem)
[4990]73         ENDIF
[7753]74         sss_m(:,:) = zts(:,:,jp_sal)
[2528]75         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
[12377]76         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh(:,:,Kmm) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
77         ELSE                    ;   ssh_m(:,:) = ssh(:,:,Kmm)
[2528]78         ENDIF
[888]79         !
[12377]80         e3t_m(:,:) = e3t(:,:,1,Kmm)
[4292]81         !
[7753]82         frq_m(:,:) = fraqsr_1lev(:,:)
[5407]83         !
[888]84      ELSE
[3607]85         !                                                ! ----------------------------------------------- !
[3614]86         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
[3607]87            !                                             ! ----------------------------------------------- !
[888]88            IF(lwp) WRITE(numout,*)
[7646]89            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
90            IF(lwp) WRITE(numout,*) '~~~~~~~   '
[3607]91            zcoef = REAL( nn_fsbc - 1, wp )
[12377]92            ssu_m(:,:) = zcoef * uu(:,:,1,Kbb)
93            ssv_m(:,:) = zcoef * vv(:,:,1,Kbb)
[7753]94            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
95            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
[4990]96            ENDIF
[7753]97            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
[4990]98            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
[12377]99            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( ssh(:,:,Kmm) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
100            ELSE                    ;   ssh_m(:,:) = zcoef *   ssh(:,:,Kmm)
[888]101            ENDIF
[4990]102            !
[12377]103            e3t_m(:,:) = zcoef * e3t(:,:,1,Kmm)
[7753]104            !
105            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
[888]106            !                                             ! ---------------------------------------- !
107         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
108            !                                             ! ---------------------------------------- !
[7753]109            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
110            ssv_m(:,:) = 0._wp
111            sst_m(:,:) = 0._wp
112            sss_m(:,:) = 0._wp
113            ssh_m(:,:) = 0._wp
114            e3t_m(:,:) = 0._wp
115            frq_m(:,:) = 0._wp
[888]116         ENDIF
117         !                                                ! ---------------------------------------- !
118         !                                                !        Cumulate at each time step        !
119         !                                                ! ---------------------------------------- !
[12377]120         ssu_m(:,:) = ssu_m(:,:) + uu(:,:,1,Kbb)
121         ssv_m(:,:) = ssv_m(:,:) + vv(:,:,1,Kbb)
[9019]122         IF( l_useCT )  THEN     ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
[7753]123         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
[4990]124         ENDIF
[7753]125         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
[2528]126         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
[12377]127         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + ssh(:,:,Kmm) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
128         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + ssh(:,:,Kmm)
[2528]129         ENDIF
[4990]130         !
[12377]131         e3t_m(:,:) = e3t_m(:,:) + e3t(:,:,1,Kmm)
[7753]132         !
133         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
[888]134
135         !                                                ! ---------------------------------------- !
136         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
137            !                                             ! ---------------------------------------- !
138            zcoef = 1. / REAL( nn_fsbc, wp )
[7753]139            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celsius]
140            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
141            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
142            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
143            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
144            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
145            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
[888]146            !
147         ENDIF
148         !                                                ! ---------------------------------------- !
149         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
150            !                                             ! ---------------------------------------- !
151            IF(lwp) WRITE(numout,*)
152            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
153               &                    'at it= ', kt,' date= ', ndastp
154            IF(lwp) WRITE(numout,*) '~~~~~~~'
155            zf_sbc = REAL( nn_fsbc, wp )
[13991]156            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
157            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
158            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
159            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
160            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
161            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
162            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m  )
163            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m  )
[888]164            !
165         ENDIF
166         !
167      ENDIF
168      !
[5407]169      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
170         CALL iom_put( 'ssu_m', ssu_m )
171         CALL iom_put( 'ssv_m', ssv_m )
172         CALL iom_put( 'sst_m', sst_m )
173         CALL iom_put( 'sss_m', sss_m )
174         CALL iom_put( 'ssh_m', ssh_m )
[6140]175         CALL iom_put( 'e3t_m', e3t_m )
[5407]176         CALL iom_put( 'frq_m', frq_m )
177      ENDIF
178      !
[888]179   END SUBROUTINE sbc_ssm
180
[6140]181
[12377]182   SUBROUTINE sbc_ssm_init( Kbb, Kmm )
[3607]183      !!----------------------------------------------------------------------
184      !!                  ***  ROUTINE sbc_ssm_init  ***
185      !!
186      !! ** Purpose :   Initialisation of the sbc data
187      !!
188      !! ** Action  : - read parameters
189      !!----------------------------------------------------------------------
[12377]190      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
[6140]191      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
[3607]192      !!----------------------------------------------------------------------
[6140]193      !
[3607]194      IF( nn_fsbc == 1 ) THEN
195         !
196         IF(lwp) WRITE(numout,*)
[7646]197         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
198         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
[3607]199         !
200      ELSE
201         !               
202         IF(lwp) WRITE(numout,*)
[7646]203         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
204         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
[3607]205         !
206         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
207            l_ssm_mean = .TRUE.
[13991]208            CALL iom_get( numror            , 'nn_fsbc', zf_sbc )     ! sbc frequency of previous run
209            CALL iom_get( numror, jpdom_auto, 'ssu_m'  , ssu_m, cd_type = 'U', psgn = -1._wp )    ! sea surface mean velocity    (U-point)
210            CALL iom_get( numror, jpdom_auto, 'ssv_m'  , ssv_m, cd_type = 'V', psgn = -1._wp )    !   "         "    velocity    (V-point)
211            CALL iom_get( numror, jpdom_auto, 'sst_m'  , sst_m )    !   "         "    temperature (T-point)
212            CALL iom_get( numror, jpdom_auto, 'sss_m'  , sss_m )    !   "         "    salinity    (T-point)
213            CALL iom_get( numror, jpdom_auto, 'ssh_m'  , ssh_m )    !   "         "    height      (T-point)
214            CALL iom_get( numror, jpdom_auto, 'e3t_m'  , e3t_m )    ! 1st level thickness          (T-point)
[5407]215            ! fraction of solar net radiation absorbed in 1st T level
216            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
[13991]217               CALL iom_get( numror, jpdom_auto, 'frq_m'  , frq_m  )
[5407]218            ELSE
[7753]219               frq_m(:,:) = 1._wp   ! default definition
[5407]220            ENDIF
[3607]221            !
222            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
[7646]223               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
[3607]224               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
[7753]225               ssu_m(:,:) = zcoef * ssu_m(:,:) 
226               ssv_m(:,:) = zcoef * ssv_m(:,:)
227               sst_m(:,:) = zcoef * sst_m(:,:)
228               sss_m(:,:) = zcoef * sss_m(:,:)
229               ssh_m(:,:) = zcoef * ssh_m(:,:)
230               e3t_m(:,:) = zcoef * e3t_m(:,:)
231               frq_m(:,:) = zcoef * frq_m(:,:)
[3607]232            ELSE
[7646]233               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
[3607]234            ENDIF
235         ENDIF
236      ENDIF
237      !
[9019]238      IF( .NOT.l_ssm_mean ) THEN   ! default initialisation. needed by iceistate
[5407]239         !
[7646]240         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
[12377]241         ssu_m(:,:) = uu(:,:,1,Kbb)
242         ssv_m(:,:) = vv(:,:,1,Kbb)
243         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( ts(:,:,1,jp_tem,Kmm), ts(:,:,1,jp_sal,Kmm) )
244         ELSE                   ;   sst_m(:,:) = ts(:,:,1,jp_tem,Kmm)
[5407]245         ENDIF
[12377]246         sss_m(:,:) = ts  (:,:,1,jp_sal,Kmm)
247         ssh_m(:,:) = ssh(:,:,Kmm)
248         e3t_m(:,:) = e3t (:,:,1,Kmm)
[7753]249         frq_m(:,:) = 1._wp
[5407]250         !
251      ENDIF
252      !
[10425]253      IF( .NOT. ln_traqsr )   fraqsr_1lev(:,:) = 1._wp   ! default definition: qsr 100% in the fisrt level
254      !
[3607]255   END SUBROUTINE sbc_ssm_init
256
[888]257   !!======================================================================
258END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.