New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icesbc.F90 in NEMO/branches/2020/dev_r13898_Tiling_Cleanup_MPI3/src/ICE – NEMO

source: NEMO/branches/2020/dev_r13898_Tiling_Cleanup_MPI3/src/ICE/icesbc.F90 @ 14345

Last change on this file since 14345 was 13906, checked in by mocavero, 4 years ago

Merge with dev_r13296_HPC-07_mocavero_mpi3
  • Property svn:keywords set to Id
File size: 17.9 KB
Line 
1MODULE icesbc
2   !!======================================================================
3   !!                       ***  MODULE  icesbc  ***
4   !! Sea-Ice :   air-ice sbc fields
5   !!=====================================================================
6   !! History :  4.0  !  2017-08  (C. Rousset)       Original code
7   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3' :                                     SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ice            ! sea-ice: variables
16   USE sbc_oce        ! Surface boundary condition: ocean fields
17   USE sbc_ice        ! Surface boundary condition: ice   fields
18   USE usrdef_sbc     ! Surface boundary condition: user defined
19   USE sbcblk         ! Surface boundary condition: bulk
20   USE sbccpl         ! Surface boundary condition: coupled interface
21   USE icealb         ! sea-ice: albedo
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O manager library
25   USE lib_mpp        ! MPP library
26   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
27   USE lbclnk         ! lateral boundary conditions (or mpp links)
28   USE timing         ! Timing
29   USE fldread        !!GS: needed by agrif
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC ice_sbc_tau   ! called by icestp.F90
35   PUBLIC ice_sbc_flx   ! called by icestp.F90
36   PUBLIC ice_sbc_init  ! called by icestp.F90
37
38   !! * Substitutions
39#  include "do_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE ice_sbc_tau( kt, ksbc, utau_ice, vtau_ice )
48      !!-------------------------------------------------------------------
49      !!                  ***  ROUTINE ice_sbc_tau  ***
50      !!
51      !! ** Purpose : provide surface boundary condition for sea ice (momentum)
52      !!
53      !! ** Action  : It provides the following fields:
54      !!              utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
55      !!-------------------------------------------------------------------
56      INTEGER                     , INTENT(in   ) ::   kt                   ! ocean time step
57      INTEGER                     , INTENT(in   ) ::   ksbc                 ! type of sbc flux
58      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   utau_ice, vtau_ice   ! air-ice stress   [N/m2]
59      !!
60      INTEGER  ::   ji, jj                 ! dummy loop index
61      REAL(wp), DIMENSION(jpi,jpj) ::   zutau_ice, zvtau_ice 
62      !!-------------------------------------------------------------------
63      !
64      IF( ln_timing )   CALL timing_start('ice_sbc')
65      !
66      IF( kt == nit000 .AND. lwp ) THEN
67         WRITE(numout,*)
68         WRITE(numout,*)'ice_sbc_tau: Surface boundary condition for sea ice (momentum)'
69         WRITE(numout,*)'~~~~~~~~~~~~~~~'
70      ENDIF
71      !
72      SELECT CASE( ksbc )
73         CASE( jp_usr     )   ;    CALL usrdef_sbc_ice_tau( kt )                 ! user defined formulation
74         CASE( jp_blk     )   ;    CALL blk_ice_1( sf(jp_wndi)%fnow(:,:,1), sf(jp_wndj)%fnow(:,:,1),   &
75            &                                      sf(jp_tair)%fnow(:,:,1), sf(jp_humi)%fnow(:,:,1),   &
76            &                                      sf(jp_slp )%fnow(:,:,1), u_ice, v_ice, tm_su    ,   &   ! inputs
77            &                                      putaui = utau_ice, pvtaui = vtau_ice            )       ! outputs                             
78 !        CASE( jp_abl     )    utau_ice & vtau_ice are computed in ablmod
79         CASE( jp_purecpl )   ;    CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled      formulation
80      END SELECT
81      !
82      IF( ln_mixcpl) THEN                                                        ! Case of a mixed Bulk/Coupled formulation
83                                   CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
84         DO_2D( 0, 0, 0, 0 )
85            utau_ice(ji,jj) = utau_ice(ji,jj) * xcplmask(ji,jj,0) + zutau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
86            vtau_ice(ji,jj) = vtau_ice(ji,jj) * xcplmask(ji,jj,0) + zvtau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
87         END_2D
88#if defined key_mpi3
89         CALL lbc_lnk_nc_multi( 'icesbc', utau_ice, 'U', -1.0_wp, vtau_ice, 'V', -1.0_wp )
90#else
91         CALL lbc_lnk_multi( 'icesbc', utau_ice, 'U', -1.0_wp, vtau_ice, 'V', -1.0_wp )
92#endif
93      ENDIF
94      !
95      IF( ln_timing )   CALL timing_stop('ice_sbc')
96      !
97   END SUBROUTINE ice_sbc_tau
98
99   
100   SUBROUTINE ice_sbc_flx( kt, ksbc )
101      !!-------------------------------------------------------------------
102      !!                  ***  ROUTINE ice_sbc_flx  ***
103      !!
104      !! ** Purpose : provide surface boundary condition for sea ice (flux)
105      !!
106      !! ** Action  : It provides the following fields used in sea ice model:
107      !!                emp_oce , emp_ice                        = E-P over ocean and sea ice                    [Kg/m2/s]
108      !!                sprecip                                  = solid precipitation                           [Kg/m2/s]
109      !!                evap_ice                                 = sublimation                                   [Kg/m2/s]
110      !!                qsr_tot , qns_tot                        = solar & non solar heat flux (total)           [W/m2]
111      !!                qsr_ice , qns_ice                        = solar & non solar heat flux over ice          [W/m2]
112      !!                dqns_ice                                 = non solar  heat sensistivity                  [W/m2]
113      !!                qemp_oce, qemp_ice, qprec_ice, qevap_ice = sensible heat (associated with evap & precip) [W/m2]
114      !!            + some fields that are not used outside this module:
115      !!                qla_ice                                  = latent heat flux over ice                     [W/m2]
116      !!                dqla_ice                                 = latent heat sensistivity                      [W/m2]
117      !!                tprecip                                  = total  precipitation                          [Kg/m2/s]
118      !!                alb_ice                                  = albedo above sea ice
119      !!-------------------------------------------------------------------
120      INTEGER, INTENT(in) ::   kt     ! ocean time step
121      INTEGER, INTENT(in) ::   ksbc   ! flux formulation (user defined, bulk or Pure Coupled)
122      !
123      INTEGER  ::   ji, jj, jl      ! dummy loop index
124      REAL(wp) ::   zmiss_val       ! missing value retrieved from xios
125      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zalb, zmsk00      ! 2D workspace
126      !!--------------------------------------------------------------------
127      !
128      IF( ln_timing )   CALL timing_start('ice_sbc_flx')
129
130      IF( kt == nit000 .AND. lwp ) THEN
131         WRITE(numout,*)
132         WRITE(numout,*)'ice_sbc_flx: Surface boundary condition for sea ice (flux)'
133         WRITE(numout,*)'~~~~~~~~~~~~~~~'
134      ENDIF
135
136      ! get missing value from xml
137      CALL iom_miss_val( "icetemp", zmiss_val )
138
139      ! --- ice albedo --- !
140      CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_eff, h_ip, cloud_fra, alb_ice )
141
142      !
143      SELECT CASE( ksbc )   !== fluxes over sea ice ==!
144      !
145      CASE( jp_usr )              !--- user defined formulation
146                                  CALL usrdef_sbc_ice_flx( kt, h_s, h_i )
147      CASE( jp_blk, jp_abl )  !--- bulk formulation & ABL formulation
148                                  CALL blk_ice_2    ( t_su, h_s, h_i, alb_ice, sf(jp_tair)%fnow(:,:,1), sf(jp_humi)%fnow(:,:,1),    &
149            &                                           sf(jp_slp)%fnow(:,:,1), sf(jp_qlw)%fnow(:,:,1), sf(jp_prec)%fnow(:,:,1), sf(jp_snow)%fnow(:,:,1) )    !
150         IF( ln_mixcpl        )   CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
151         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
152         !                        !    compute conduction flux and surface temperature (as in Jules surface module)
153         IF( ln_cndflx .AND. .NOT.ln_cndemulate ) &
154            &                     CALL blk_ice_qcn    ( ln_virtual_itd, t_su, t_bo, h_s, h_i )
155      CASE ( jp_purecpl )         !--- coupled formulation
156                                  CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
157         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
158      END SELECT
159
160      !--- output ice albedo and surface albedo ---!
161      IF( iom_use('icealb') .OR. iom_use('albedo') ) THEN
162
163         ALLOCATE( zalb(jpi,jpj), zmsk00(jpi,jpj) )
164
165         WHERE( at_i_b < 1.e-03 )
166            zmsk00(:,:) = 0._wp
167            zalb  (:,:) = rn_alb_oce
168         ELSEWHERE
169            zmsk00(:,:) = 1._wp           
170            zalb  (:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b
171         END WHERE
172         ! ice albedo
173         CALL iom_put( 'icealb' , zalb * zmsk00 + zmiss_val * ( 1._wp - zmsk00 ) )
174         ! ice+ocean albedo
175         zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b )
176         CALL iom_put( 'albedo' , zalb )
177
178         DEALLOCATE( zalb, zmsk00 )
179
180      ENDIF
181      !
182      IF( ln_timing )   CALL timing_stop('ice_sbc_flx')
183      !
184   END SUBROUTINE ice_sbc_flx
185
186
187   SUBROUTINE ice_flx_dist( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_flxdist )
188      !!-------------------------------------------------------------------
189      !!                  ***  ROUTINE ice_flx_dist  ***
190      !!
191      !! ** Purpose :   update the ice surface boundary condition by averaging
192      !!              and/or redistributing fluxes on ice categories
193      !!
194      !! ** Method  :   average then redistribute
195      !!
196      !! ** Action  :   depends on k_flxdist
197      !!                = -1  Do nothing (needs N(cat) fluxes)
198      !!                =  0  Average N(cat) fluxes then apply the average over the N(cat) ice
199      !!                =  1  Average N(cat) fluxes then redistribute over the N(cat) ice
200      !!                                                 using T-ice and albedo sensitivity
201      !!                =  2  Redistribute a single flux over categories
202      !!-------------------------------------------------------------------
203      INTEGER                   , INTENT(in   ) ::   k_flxdist  ! redistributor
204      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
205      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
206      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
207      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
208      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
209      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
210      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
211      !
212      INTEGER  ::   jl      ! dummy loop index
213      !
214      REAL(wp), DIMENSION(jpi,jpj) ::   z1_at_i   ! inverse of concentration
215      !
216      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qsr_m   ! Mean solar heat flux over all categories
217      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qns_m   ! Mean non solar heat flux over all categories
218      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_evap_m  ! Mean sublimation over all categories
219      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_dqn_m   ! Mean d(qns)/dT over all categories
220      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_devap_m ! Mean d(evap)/dT over all categories
221      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zalb_m    ! Mean albedo over all categories
222      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztem_m    ! Mean temperature over all categories
223      !!----------------------------------------------------------------------
224      !
225      WHERE ( at_i (:,:) > 0._wp )   ; z1_at_i(:,:) = 1._wp / at_i (:,:)
226      ELSEWHERE                      ; z1_at_i(:,:) = 0._wp
227      END WHERE
228     
229      SELECT CASE( k_flxdist )       !==  averaged on all ice categories  ==!
230      !
231      CASE( 0 , 1 )
232         !
233         ALLOCATE( z_qns_m(jpi,jpj), z_qsr_m(jpi,jpj), z_dqn_m(jpi,jpj), z_evap_m(jpi,jpj), z_devap_m(jpi,jpj) ) 
234         !
235         z_qns_m  (:,:) = SUM( a_i(:,:,:) * pqns_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
236         z_qsr_m  (:,:) = SUM( a_i(:,:,:) * pqsr_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
237         z_dqn_m  (:,:) = SUM( a_i(:,:,:) * pdqn_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
238         z_evap_m (:,:) = SUM( a_i(:,:,:) * pevap_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
239         z_devap_m(:,:) = SUM( a_i(:,:,:) * pdevap_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
240         DO jl = 1, jpl
241            pqns_ice  (:,:,jl) = z_qns_m (:,:)
242            pqsr_ice  (:,:,jl) = z_qsr_m (:,:)
243            pdqn_ice  (:,:,jl) = z_dqn_m  (:,:)
244            pevap_ice (:,:,jl) = z_evap_m(:,:)
245            pdevap_ice(:,:,jl) = z_devap_m(:,:)
246         END DO
247         !
248         DEALLOCATE( z_qns_m, z_qsr_m, z_dqn_m, z_evap_m, z_devap_m ) 
249         !
250      END SELECT
251      !
252      SELECT CASE( k_flxdist )       !==  redistribution on all ice categories  ==!
253      !
254      CASE( 1 , 2 )
255         !
256         ALLOCATE( zalb_m(jpi,jpj), ztem_m(jpi,jpj) ) 
257         !
258         zalb_m(:,:) = SUM( a_i(:,:,:) * palb_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
259         ztem_m(:,:) = SUM( a_i(:,:,:) * ptn_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
260         DO jl = 1, jpl
261            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
262            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
263            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
264         END DO
265         !
266         DEALLOCATE( zalb_m, ztem_m ) 
267         !
268      END SELECT
269      !
270   END SUBROUTINE ice_flx_dist
271
272
273   SUBROUTINE ice_sbc_init
274      !!-------------------------------------------------------------------
275      !!                  ***  ROUTINE ice_sbc_init  ***
276      !!
277      !! ** Purpose :   Physical constants and parameters linked to the ice dynamics
278      !!     
279      !! ** Method  :   Read the namsbc namelist and check the ice-dynamic
280      !!              parameter values called at the first timestep (nit000)
281      !!
282      !! ** input   :   Namelist namsbc
283      !!-------------------------------------------------------------------
284      INTEGER ::   ios, ioptio   ! Local integer
285      !!
286      NAMELIST/namsbc/ rn_cio, nn_snwfra, rn_snwblow, nn_flxdist, ln_cndflx, ln_cndemulate, nn_qtrice
287      !!-------------------------------------------------------------------
288      !
289      READ  ( numnam_ice_ref, namsbc, IOSTAT = ios, ERR = 901)
290901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
291      READ  ( numnam_ice_cfg, namsbc, IOSTAT = ios, ERR = 902 )
292902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
293      IF(lwm) WRITE( numoni, namsbc )
294      !
295      IF(lwp) THEN                     ! control print
296         WRITE(numout,*)
297         WRITE(numout,*) 'ice_sbc_init: ice parameters for ice dynamics '
298         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
299         WRITE(numout,*) '   Namelist namsbc:'
300         WRITE(numout,*) '      drag coefficient for oceanic stress                       rn_cio        = ', rn_cio
301         WRITE(numout,*) '      fraction of ice covered by snow (options 0,1,2)           nn_snwfra     = ', nn_snwfra
302         WRITE(numout,*) '      coefficient for ice-lead partition of snowfall            rn_snwblow    = ', rn_snwblow
303         WRITE(numout,*) '      Multicategory heat flux formulation                       nn_flxdist    = ', nn_flxdist
304         WRITE(numout,*) '      Use conduction flux as surface condition                  ln_cndflx     = ', ln_cndflx
305         WRITE(numout,*) '         emulate conduction flux                                ln_cndemulate = ', ln_cndemulate
306         WRITE(numout,*) '      solar flux transmitted thru the surface scattering layer  nn_qtrice     = ', nn_qtrice
307         WRITE(numout,*) '         = 0  Grenfell and Maykut 1977'
308         WRITE(numout,*) '         = 1  Lebrun 2019'
309      ENDIF
310      !
311      IF(lwp) WRITE(numout,*)
312      SELECT CASE( nn_flxdist )         ! SI3 Multi-category heat flux formulation
313      CASE( -1  )
314         IF(lwp) WRITE(numout,*) '   SI3: use per-category fluxes (nn_flxdist = -1) '
315      CASE(  0  )
316         IF(lwp) WRITE(numout,*) '   SI3: use average per-category fluxes (nn_flxdist = 0) '
317      CASE(  1  )
318         IF(lwp) WRITE(numout,*) '   SI3: use average then redistribute per-category fluxes (nn_flxdist = 1) '
319         IF( ln_cpl )         CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in coupled mode must be /=1' )
320      CASE(  2  )
321         IF(lwp) WRITE(numout,*) '   SI3: Redistribute a single flux over categories (nn_flxdist = 2) '
322         IF( .NOT. ln_cpl )   CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in forced mode must be /=2' )
323      CASE DEFAULT
324         CALL ctl_stop( 'ice_thd_init: SI3 option, nn_flxdist, should be between -1 and 2' )
325      END SELECT
326      !
327   END SUBROUTINE ice_sbc_init
328
329#else
330   !!----------------------------------------------------------------------
331   !!   Default option :         Empty module         NO SI3 sea-ice model
332   !!----------------------------------------------------------------------
333#endif
334
335   !!======================================================================
336END MODULE icesbc
Note: See TracBrowser for help on using the repository browser.