New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynatf.F90 in NEMO/branches/2020/dev_r13898_Tiling_Cleanup_MPI3/src/OCE/DYN – NEMO

source: NEMO/branches/2020/dev_r13898_Tiling_Cleanup_MPI3/src/OCE/DYN/dynatf.F90 @ 13906

Last change on this file since 13906 was 13906, checked in by mocavero, 3 years ago

Merge with dev_r13296_HPC-07_mocavero_mpi3
  • Property svn:keywords set to Id
File size: 19.2 KB
Line 
1MODULE dynatf
2   !!=========================================================================
3   !!                       ***  MODULE  dynatf  ***
4   !! Ocean dynamics: time filtering
5   !!=========================================================================
6   !! History :  OPA  !  1987-02  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  1990-10  (C. Levy, G. Madec)
8   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
9   !!            8.0  !  1997-02  (G. Madec & M. Imbard)  opa, release 8.0
10   !!            8.2  !  1997-04  (A. Weaver)  Euler forward step
11   !!             -   !  1997-06  (G. Madec)  lateral boudary cond., lbc routine
12   !!    NEMO    1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!             -   !  2002-10  (C. Talandier, A-M. Treguier) Open boundary cond.
14   !!            2.0  !  2005-11  (V. Garnier) Surface pressure gradient organization
15   !!            2.3  !  2007-07  (D. Storkey) Calls to BDY routines.
16   !!            3.2  !  2009-06  (G. Madec, R.Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-09  (D. Storkey, E.O'Dea) Bug fix for BDY module
18   !!            3.3  !  2011-03  (P. Oddo) Bug fix for time-splitting+(BDY-OBC) and not VVL
19   !!            3.5  !  2013-07  (J. Chanut) Compliant with time splitting changes
20   !!            3.6  !  2014-04  (G. Madec) add the diagnostic of the time filter trends
21   !!            3.7  !  2015-11  (J. Chanut) Free surface simplification
22   !!            4.1  !  2019-08  (A. Coward, D. Storkey) Rename dynnxt.F90 -> dynatf.F90. Now just does time filtering.
23   !!-------------------------------------------------------------------------
24 
25   !!----------------------------------------------------------------------------------------------
26   !!   dyn_atf       : apply Asselin time filtering to "now" velocities and vertical scale factors
27   !!----------------------------------------------------------------------------------------------
28   USE oce            ! ocean dynamics and tracers
29   USE dom_oce        ! ocean space and time domain
30   USE sbc_oce        ! Surface boundary condition: ocean fields
31   USE sbcrnf         ! river runoffs
32   USE phycst         ! physical constants
33   USE dynadv         ! dynamics: vector invariant versus flux form
34   USE dynspg_ts      ! surface pressure gradient: split-explicit scheme
35   USE domvvl         ! variable volume
36   USE bdy_oce , ONLY : ln_bdy
37   USE bdydta         ! ocean open boundary conditions
38   USE bdydyn         ! ocean open boundary conditions
39   USE bdyvol         ! ocean open boundary condition (bdy_vol routines)
40   USE trd_oce        ! trends: ocean variables
41   USE trddyn         ! trend manager: dynamics
42   USE trdken         ! trend manager: kinetic energy
43   USE isf_oce   , ONLY: ln_isf     ! ice shelf
44   USE isfdynatf , ONLY: isf_dynatf ! ice shelf volume filter correction subroutine
45   !
46   USE in_out_manager ! I/O manager
47   USE iom            ! I/O manager library
48   USE lbclnk         ! lateral boundary condition (or mpp link)
49   USE lib_mpp        ! MPP library
50   USE prtctl         ! Print control
51   USE timing         ! Timing
52   USE zdfdrg ,  ONLY : ln_drgice_imp, rCdU_top
53#if defined key_agrif
54   USE agrif_oce_interp
55#endif
56
57   IMPLICIT NONE
58   PRIVATE
59
60   PUBLIC    dyn_atf   ! routine called by step.F90
61
62#if defined key_qco
63   !!----------------------------------------------------------------------
64   !!   'key_qco'      EMPTY ROUTINE     Quasi-Eulerian vertical coordonate
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE dyn_atf ( kt, Kbb, Kmm, Kaa, puu, pvv, pe3t, pe3u, pe3v )
69      INTEGER                             , INTENT(in   ) :: kt               ! ocean time-step index
70      INTEGER                             , INTENT(in   ) :: Kbb, Kmm, Kaa    ! before and after time level indices
71      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv         ! velocities to be time filtered
72      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: pe3t, pe3u, pe3v ! scale factors to be time filtered
73
74      WRITE(*,*) 'dyn_atf: You should not have seen this print! error?', kt
75   END SUBROUTINE dyn_atf
76
77#else
78
79   !! * Substitutions
80#  include "do_loop_substitute.h90"
81   !!----------------------------------------------------------------------
82   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
83   !! $Id$
84   !! Software governed by the CeCILL license (see ./LICENSE)
85   !!----------------------------------------------------------------------
86CONTAINS
87
88   SUBROUTINE dyn_atf ( kt, Kbb, Kmm, Kaa, puu, pvv, pe3t, pe3u, pe3v )
89      !!----------------------------------------------------------------------
90      !!                  ***  ROUTINE dyn_atf  ***
91      !!                   
92      !! ** Purpose :   Finalize after horizontal velocity. Apply the boundary
93      !!             condition on the after velocity and apply the Asselin time
94      !!             filter to the now fields.
95      !!
96      !! ** Method  : * Ensure after velocities transport matches time splitting
97      !!             estimate (ln_dynspg_ts=T)
98      !!
99      !!              * Apply lateral boundary conditions on after velocity
100      !!             at the local domain boundaries through lbc_lnk call,
101      !!             at the one-way open boundaries (ln_bdy=T),
102      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
103      !!
104      !!              * Apply the Asselin time filter to the now fields
105      !!             arrays to start the next time step:
106      !!                (puu(Kmm),pvv(Kmm)) = (puu(Kmm),pvv(Kmm))
107      !!                                    + rn_atfp [ (puu(Kbb),pvv(Kbb)) + (puu(Kaa),pvv(Kaa)) - 2 (puu(Kmm),pvv(Kmm)) ]
108      !!             Note that with flux form advection and non linear free surface,
109      !!             the time filter is applied on thickness weighted velocity.
110      !!             As a result, dyn_atf MUST be called after tra_atf.
111      !!
112      !! ** Action :   puu(Kmm),pvv(Kmm)   filtered now horizontal velocity
113      !!----------------------------------------------------------------------
114      INTEGER                             , INTENT(in   ) :: kt               ! ocean time-step index
115      INTEGER                             , INTENT(in   ) :: Kbb, Kmm, Kaa    ! before and after time level indices
116      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv         ! velocities to be time filtered
117      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: pe3t, pe3u, pe3v ! scale factors to be time filtered
118      !
119      INTEGER  ::   ji, jj, jk   ! dummy loop indices
120      REAL(wp) ::   zue3a, zue3n, zue3b, zcoef    ! local scalars
121      REAL(wp) ::   zve3a, zve3n, zve3b, z1_2dt   !   -      -
122      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zue, zve, zwfld
123      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zutau, zvtau
124      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ze3t_f, ze3u_f, ze3v_f, zua, zva 
125      !!----------------------------------------------------------------------
126      !
127      IF( ln_timing    )   CALL timing_start('dyn_atf')
128      IF( ln_dynspg_ts )   ALLOCATE( zue(jpi,jpj)     , zve(jpi,jpj)     )
129      IF( l_trddyn     )   ALLOCATE( zua(jpi,jpj,jpk) , zva(jpi,jpj,jpk) )
130      !
131      IF( kt == nit000 ) THEN
132         IF(lwp) WRITE(numout,*)
133         IF(lwp) WRITE(numout,*) 'dyn_atf : Asselin time filtering'
134         IF(lwp) WRITE(numout,*) '~~~~~~~'
135      ENDIF
136
137      IF ( ln_dynspg_ts ) THEN
138         ! Ensure below that barotropic velocities match time splitting estimate
139         ! Compute actual transport and replace it with ts estimate at "after" time step
140         zue(:,:) = pe3u(:,:,1,Kaa) * puu(:,:,1,Kaa) * umask(:,:,1)
141         zve(:,:) = pe3v(:,:,1,Kaa) * pvv(:,:,1,Kaa) * vmask(:,:,1)
142         DO jk = 2, jpkm1
143            zue(:,:) = zue(:,:) + pe3u(:,:,jk,Kaa) * puu(:,:,jk,Kaa) * umask(:,:,jk)
144            zve(:,:) = zve(:,:) + pe3v(:,:,jk,Kaa) * pvv(:,:,jk,Kaa) * vmask(:,:,jk)
145         END DO
146         DO jk = 1, jpkm1
147            puu(:,:,jk,Kaa) = ( puu(:,:,jk,Kaa) - zue(:,:) * r1_hu(:,:,Kaa) + uu_b(:,:,Kaa) ) * umask(:,:,jk)
148            pvv(:,:,jk,Kaa) = ( pvv(:,:,jk,Kaa) - zve(:,:) * r1_hv(:,:,Kaa) + vv_b(:,:,Kaa) ) * vmask(:,:,jk)
149         END DO
150         !
151         IF( .NOT.ln_bt_fw ) THEN
152            ! Remove advective velocity from "now velocities"
153            ! prior to asselin filtering     
154            ! In the forward case, this is done below after asselin filtering   
155            ! so that asselin contribution is removed at the same time
156            DO jk = 1, jpkm1
157               puu(:,:,jk,Kmm) = ( puu(:,:,jk,Kmm) - un_adv(:,:)*r1_hu(:,:,Kmm) + uu_b(:,:,Kmm) )*umask(:,:,jk)
158               pvv(:,:,jk,Kmm) = ( pvv(:,:,jk,Kmm) - vn_adv(:,:)*r1_hv(:,:,Kmm) + vv_b(:,:,Kmm) )*vmask(:,:,jk)
159            END DO 
160         ENDIF
161      ENDIF
162
163      ! Update after velocity on domain lateral boundaries
164      ! --------------------------------------------------     
165# if defined key_agrif
166      CALL Agrif_dyn( kt )             !* AGRIF zoom boundaries
167# endif
168      !
169#if defined key_mpi3
170      CALL lbc_lnk_nc_multi( 'dynatf', puu(:,:,:,Kaa), 'U', -1.0_wp, pvv(:,:,:,Kaa), 'V', -1.0_wp )     !* local domain boundaries
171#else
172      CALL lbc_lnk_multi( 'dynatf', puu(:,:,:,Kaa), 'U', -1.0_wp, pvv(:,:,:,Kaa), 'V', -1.0_wp )     !* local domain boundaries
173#endif
174      !
175      !                                !* BDY open boundaries
176      IF( ln_bdy .AND. ln_dynspg_exp )   CALL bdy_dyn( kt, Kbb, puu, pvv, Kaa )
177      IF( ln_bdy .AND. ln_dynspg_ts  )   CALL bdy_dyn( kt, Kbb, puu, pvv, Kaa, dyn3d_only=.true. )
178
179!!$   Do we need a call to bdy_vol here??
180      !
181      IF( l_trddyn ) THEN             ! prepare the atf trend computation + some diagnostics
182         !
183         !                                  ! Kinetic energy and Conversion
184         IF( ln_KE_trd  )   CALL trd_dyn( puu(:,:,:,Kaa), pvv(:,:,:,Kaa), jpdyn_ken, kt, Kmm )
185         !
186         IF( ln_dyn_trd ) THEN              ! 3D output: total momentum trends
187            zua(:,:,:) = ( puu(:,:,:,Kaa) - puu(:,:,:,Kbb) ) * r1_Dt
188            zva(:,:,:) = ( pvv(:,:,:,Kaa) - pvv(:,:,:,Kbb) ) * r1_Dt
189            CALL iom_put( "utrd_tot", zua )        ! total momentum trends, except the asselin time filter
190            CALL iom_put( "vtrd_tot", zva )
191         ENDIF
192         !
193         zua(:,:,:) = puu(:,:,:,Kmm)             ! save the now velocity before the asselin filter
194         zva(:,:,:) = pvv(:,:,:,Kmm)             ! (caution: there will be a shift by 1 timestep in the
195         !                                  !  computation of the asselin filter trends)
196      ENDIF
197
198      ! Time filter and swap of dynamics arrays
199      ! ------------------------------------------
200         
201      IF( .NOT. l_1st_euler ) THEN    !* Leap-Frog : Asselin time filter
202         !                                ! =============!
203         IF( ln_linssh ) THEN             ! Fixed volume !
204            !                             ! =============!
205            DO_3D( 1, 1, 1, 1, 1, jpkm1 )
206               puu(ji,jj,jk,Kmm) = puu(ji,jj,jk,Kmm) + rn_atfp * ( puu(ji,jj,jk,Kbb) - 2._wp * puu(ji,jj,jk,Kmm) + puu(ji,jj,jk,Kaa) )
207               pvv(ji,jj,jk,Kmm) = pvv(ji,jj,jk,Kmm) + rn_atfp * ( pvv(ji,jj,jk,Kbb) - 2._wp * pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk,Kaa) )
208            END_3D
209            !                             ! ================!
210         ELSE                             ! Variable volume !
211            !                             ! ================!
212            ! Time-filtered scale factor at t-points
213            ! ----------------------------------------------------
214            ALLOCATE( ze3t_f(jpi,jpj,jpk), zwfld(jpi,jpj) )
215            DO jk = 1, jpkm1
216               ze3t_f(:,:,jk) = pe3t(:,:,jk,Kmm) + rn_atfp * ( pe3t(:,:,jk,Kbb) - 2._wp * pe3t(:,:,jk,Kmm) + pe3t(:,:,jk,Kaa) )
217            END DO
218            ! Add volume filter correction: compatibility with tracer advection scheme
219            ! => time filter + conservation correction
220            zcoef = rn_atfp * rn_Dt * r1_rho0
221            zwfld(:,:) = emp_b(:,:) - emp(:,:)
222            IF ( ln_rnf ) zwfld(:,:) =  zwfld(:,:) - ( rnf_b(:,:) - rnf(:,:) )
223
224            DO jk = 1, jpkm1
225               ze3t_f(:,:,jk) = ze3t_f(:,:,jk) - zcoef * zwfld(:,:) * tmask(:,:,jk) &
226                              &                        * pe3t(:,:,jk,Kmm) / ( ht(:,:) + 1._wp - ssmask(:,:) ) 
227            END DO
228            !
229            ! ice shelf melting (deal separately as it can be in depth)
230            ! PM: we could probably define a generic subroutine to do the in depth correction
231            !     to manage rnf, isf and possibly in the futur icb, tide water glacier (...)
232            !     ...(kt, coef, ktop, kbot, hz, fwf_b, fwf)
233            IF ( ln_isf ) CALL isf_dynatf( kt, Kmm, ze3t_f, rn_atfp * rn_Dt )
234            !
235            pe3t(:,:,1:jpkm1,Kmm) = ze3t_f(:,:,1:jpkm1)        ! filtered scale factor at T-points
236            !
237            IF( ln_dynadv_vec ) THEN      ! Asselin filter applied on velocity
238               ! Before filtered scale factor at (u/v)-points
239               CALL dom_vvl_interpol( pe3t(:,:,:,Kmm), pe3u(:,:,:,Kmm), 'U' )
240               CALL dom_vvl_interpol( pe3t(:,:,:,Kmm), pe3v(:,:,:,Kmm), 'V' )
241               DO_3D( 1, 1, 1, 1, 1, jpkm1 )
242                  puu(ji,jj,jk,Kmm) = puu(ji,jj,jk,Kmm) + rn_atfp * ( puu(ji,jj,jk,Kbb) - 2._wp * puu(ji,jj,jk,Kmm) + puu(ji,jj,jk,Kaa) )
243                  pvv(ji,jj,jk,Kmm) = pvv(ji,jj,jk,Kmm) + rn_atfp * ( pvv(ji,jj,jk,Kbb) - 2._wp * pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk,Kaa) )
244               END_3D
245               !
246            ELSE                          ! Asselin filter applied on thickness weighted velocity
247               !
248               ALLOCATE( ze3u_f(jpi,jpj,jpk) , ze3v_f(jpi,jpj,jpk) )
249               ! Now filtered scale factor at (u/v)-points stored in ze3u_f, ze3v_f
250               CALL dom_vvl_interpol( pe3t(:,:,:,Kmm), ze3u_f, 'U' )
251               CALL dom_vvl_interpol( pe3t(:,:,:,Kmm), ze3v_f, 'V' )
252               DO_3D( 1, 1, 1, 1, 1, jpkm1 )
253                  zue3a = pe3u(ji,jj,jk,Kaa) * puu(ji,jj,jk,Kaa)
254                  zve3a = pe3v(ji,jj,jk,Kaa) * pvv(ji,jj,jk,Kaa)
255                  zue3n = pe3u(ji,jj,jk,Kmm) * puu(ji,jj,jk,Kmm)
256                  zve3n = pe3v(ji,jj,jk,Kmm) * pvv(ji,jj,jk,Kmm)
257                  zue3b = pe3u(ji,jj,jk,Kbb) * puu(ji,jj,jk,Kbb)
258                  zve3b = pe3v(ji,jj,jk,Kbb) * pvv(ji,jj,jk,Kbb)
259                  !
260                  puu(ji,jj,jk,Kmm) = ( zue3n + rn_atfp * ( zue3b - 2._wp * zue3n  + zue3a ) ) / ze3u_f(ji,jj,jk)
261                  pvv(ji,jj,jk,Kmm) = ( zve3n + rn_atfp * ( zve3b - 2._wp * zve3n  + zve3a ) ) / ze3v_f(ji,jj,jk)
262               END_3D
263               pe3u(:,:,1:jpkm1,Kmm) = ze3u_f(:,:,1:jpkm1) 
264               pe3v(:,:,1:jpkm1,Kmm) = ze3v_f(:,:,1:jpkm1)
265               !
266               DEALLOCATE( ze3u_f , ze3v_f )
267            ENDIF
268            !
269            DEALLOCATE( ze3t_f, zwfld )
270         ENDIF
271         !
272         IF( ln_dynspg_ts .AND. ln_bt_fw ) THEN
273            ! Revert filtered "now" velocities to time split estimate
274            ! Doing it here also means that asselin filter contribution is removed 
275            zue(:,:) = pe3u(:,:,1,Kmm) * puu(:,:,1,Kmm) * umask(:,:,1)
276            zve(:,:) = pe3v(:,:,1,Kmm) * pvv(:,:,1,Kmm) * vmask(:,:,1)   
277            DO jk = 2, jpkm1
278               zue(:,:) = zue(:,:) + pe3u(:,:,jk,Kmm) * puu(:,:,jk,Kmm) * umask(:,:,jk)
279               zve(:,:) = zve(:,:) + pe3v(:,:,jk,Kmm) * pvv(:,:,jk,Kmm) * vmask(:,:,jk)   
280            END DO
281            DO jk = 1, jpkm1
282               puu(:,:,jk,Kmm) = puu(:,:,jk,Kmm) - (zue(:,:) * r1_hu(:,:,Kmm) - uu_b(:,:,Kmm)) * umask(:,:,jk)
283               pvv(:,:,jk,Kmm) = pvv(:,:,jk,Kmm) - (zve(:,:) * r1_hv(:,:,Kmm) - vv_b(:,:,Kmm)) * vmask(:,:,jk)
284            END DO
285         ENDIF
286         !
287      ENDIF ! .NOT. l_1st_euler
288      !
289      ! Set "now" and "before" barotropic velocities for next time step:
290      ! JC: Would be more clever to swap variables than to make a full vertical
291      ! integration
292      !
293      IF(.NOT.ln_linssh ) THEN
294         hu(:,:,Kmm) = pe3u(:,:,1,Kmm ) * umask(:,:,1)
295         hv(:,:,Kmm) = pe3v(:,:,1,Kmm ) * vmask(:,:,1)
296         DO jk = 2, jpkm1
297            hu(:,:,Kmm) = hu(:,:,Kmm) + pe3u(:,:,jk,Kmm ) * umask(:,:,jk)
298            hv(:,:,Kmm) = hv(:,:,Kmm) + pe3v(:,:,jk,Kmm ) * vmask(:,:,jk)
299         END DO
300         r1_hu(:,:,Kmm) = ssumask(:,:) / ( hu(:,:,Kmm) + 1._wp - ssumask(:,:) )
301         r1_hv(:,:,Kmm) = ssvmask(:,:) / ( hv(:,:,Kmm) + 1._wp - ssvmask(:,:) )
302      ENDIF
303      !
304      uu_b(:,:,Kaa) = pe3u(:,:,1,Kaa) * puu(:,:,1,Kaa) * umask(:,:,1)
305      uu_b(:,:,Kmm) = pe3u(:,:,1,Kmm) * puu(:,:,1,Kmm) * umask(:,:,1)
306      vv_b(:,:,Kaa) = pe3v(:,:,1,Kaa) * pvv(:,:,1,Kaa) * vmask(:,:,1)
307      vv_b(:,:,Kmm) = pe3v(:,:,1,Kmm) * pvv(:,:,1,Kmm) * vmask(:,:,1)
308      DO jk = 2, jpkm1
309         uu_b(:,:,Kaa) = uu_b(:,:,Kaa) + pe3u(:,:,jk,Kaa) * puu(:,:,jk,Kaa) * umask(:,:,jk)
310         uu_b(:,:,Kmm) = uu_b(:,:,Kmm) + pe3u(:,:,jk,Kmm) * puu(:,:,jk,Kmm) * umask(:,:,jk)
311         vv_b(:,:,Kaa) = vv_b(:,:,Kaa) + pe3v(:,:,jk,Kaa) * pvv(:,:,jk,Kaa) * vmask(:,:,jk)
312         vv_b(:,:,Kmm) = vv_b(:,:,Kmm) + pe3v(:,:,jk,Kmm) * pvv(:,:,jk,Kmm) * vmask(:,:,jk)
313      END DO
314      uu_b(:,:,Kaa) = uu_b(:,:,Kaa) * r1_hu(:,:,Kaa)
315      vv_b(:,:,Kaa) = vv_b(:,:,Kaa) * r1_hv(:,:,Kaa)
316      uu_b(:,:,Kmm) = uu_b(:,:,Kmm) * r1_hu(:,:,Kmm)
317      vv_b(:,:,Kmm) = vv_b(:,:,Kmm) * r1_hv(:,:,Kmm)
318      !
319      IF( .NOT.ln_dynspg_ts ) THEN        ! output the barotropic currents
320         CALL iom_put(  "ubar", uu_b(:,:,Kmm) )
321         CALL iom_put(  "vbar", vv_b(:,:,Kmm) )
322      ENDIF
323      IF( l_trddyn ) THEN                ! 3D output: asselin filter trends on momentum
324         zua(:,:,:) = ( puu(:,:,:,Kmm) - zua(:,:,:) ) * z1_2dt
325         zva(:,:,:) = ( pvv(:,:,:,Kmm) - zva(:,:,:) ) * z1_2dt
326         CALL trd_dyn( zua, zva, jpdyn_atf, kt, Kmm )
327      ENDIF
328      !
329      IF ( iom_use("utau") ) THEN
330         IF ( ln_drgice_imp.OR.ln_isfcav ) THEN
331            ALLOCATE(zutau(jpi,jpj)) 
332            DO_2D( 0, 0, 0, 0 )
333               jk = miku(ji,jj) 
334               zutau(ji,jj) = utau(ji,jj) + 0.5_wp * rho0 * ( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) * puu(ji,jj,jk,Kaa)
335            END_2D
336            CALL iom_put(  "utau", zutau(:,:) )
337            DEALLOCATE(zutau)
338         ELSE
339            CALL iom_put(  "utau", utau(:,:) )
340         ENDIF
341      ENDIF
342      !
343      IF ( iom_use("vtau") ) THEN
344         IF ( ln_drgice_imp.OR.ln_isfcav ) THEN
345            ALLOCATE(zvtau(jpi,jpj))
346            DO_2D( 0, 0, 0, 0 )
347               jk = mikv(ji,jj)
348               zvtau(ji,jj) = vtau(ji,jj) + 0.5_wp * rho0 * ( rCdU_top(ji,jj+1)+rCdU_top(ji,jj) ) * pvv(ji,jj,jk,Kaa)
349            END_2D
350            CALL iom_put(  "vtau", zvtau(:,:) )
351            DEALLOCATE(zvtau)
352         ELSE
353            CALL iom_put(  "vtau", vtau(:,:) )
354         ENDIF
355      ENDIF
356      !
357      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Kaa), clinfo1=' nxt  - puu(:,:,:,Kaa): ', mask1=umask,   &
358         &                                  tab3d_2=pvv(:,:,:,Kaa), clinfo2=' pvv(:,:,:,Kaa): '       , mask2=vmask )
359      !
360      IF( ln_dynspg_ts )   DEALLOCATE( zue, zve )
361      IF( l_trddyn     )   DEALLOCATE( zua, zva )
362      IF( ln_timing    )   CALL timing_stop('dyn_atf')
363      !
364   END SUBROUTINE dyn_atf
365
366#endif
367
368   !!=========================================================================
369END MODULE dynatf
Note: See TracBrowser for help on using the repository browser.