New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf.F90 in NEMO/branches/2020/dev_r13898_Tiling_Cleanup_MPI3/src/TOP/TRP – NEMO

source: NEMO/branches/2020/dev_r13898_Tiling_Cleanup_MPI3/src/TOP/TRP/trcldf.F90 @ 13945

Last change on this file since 13945 was 13945, checked in by mocavero, 4 years ago

Added MPI3 version of new lbc_lnk in ICE
  • Property svn:keywords set to Id
File size: 10.9 KB
Line 
1MODULE trcldf
2   !!======================================================================
3   !!                       ***  MODULE  trcldf  ***
4   !! Ocean Passive tracers : lateral diffusive trends
5   !!=====================================================================
6   !! History :  1.0  ! 2005-11  (G. Madec)  Original code
7   !!            3.0  ! 2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            3.7  ! 2014-03  (G. Madec)  LDF simplification
9   !!----------------------------------------------------------------------
10#if defined key_top
11   !!----------------------------------------------------------------------
12   !!   'key_top'                                                TOP models
13   !!----------------------------------------------------------------------
14   !!   trc_ldf       : update the tracer trend with the lateral diffusion
15   !!   trc_ldf_ini   : initialization, namelist read, and parameters control
16   !!----------------------------------------------------------------------
17   USE trc            ! ocean passive tracers variables
18   USE oce_trc        ! ocean dynamics and active tracers
19   USE ldftra         ! lateral diffusion: eddy diffusivity & EIV coeff.
20   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
21   USE traldf_lap_blp ! lateral diffusion: lap/bilaplacian iso-level      operator  (tra_ldf_lap/_blp   routine)
22   USE traldf_iso     ! lateral diffusion: laplacian iso-neutral standard operator  (tra_ldf_iso        routine)
23   USE traldf_triad   ! lateral diffusion: laplacian iso-neutral triad    operator  (tra_ldf_     triad routine)
24   USE trd_oce        ! trends: ocean variables
25   USE trdtra         ! trends manager: tracers
26   !
27   USE prtctl         ! Print control
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   trc_ldf   
33   PUBLIC   trc_ldf_ini   
34   !
35   !                                      !!: ** lateral mixing namelist (nam_trcldf) **
36   LOGICAL , PUBLIC ::   ln_trcldf_OFF     !: No operator (no explicit lateral diffusion)
37   LOGICAL , PUBLIC ::   ln_trcldf_tra     !: use active tracer operator
38   REAL(wp), PUBLIC ::      rn_ldf_multi      !: multiplier of T-S eddy diffusivity to obtain the passive tracer one
39   REAL(wp), PUBLIC ::      rn_fact_lap       !: enhanced Equatorial zonal diffusivity coefficent
40   !
41   INTEGER  ::   nldf_trc = 0   ! type of lateral diffusion used defined from ln_traldf_... (namlist logicals)
42   REAL(wp) ::   rldf           ! multiplier between active and passive tracers eddy diffusivity   [-]
43   
44   !! * Substitutions
45#  include "do_loop_substitute.h90"
46#  include "domzgr_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE trc_ldf( kt, Kbb, Kmm, ptr, Krhs )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_ldf  ***
57      !!
58      !! ** Purpose :   compute the lateral ocean tracer physics.
59      !!
60      !!----------------------------------------------------------------------
61      INTEGER,                                    INTENT(in   ) :: kt              ! ocean time-step index
62      INTEGER,                                    INTENT(in   ) :: Kbb, Kmm, Krhs  ! ocean time-level index
63      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr             ! passive tracers and RHS of tracer equation
64      !
65      INTEGER            :: ji, jj, jk, jn
66      REAL(wp)           :: zdep
67      CHARACTER (len=22) :: charout
68      REAL(wp),          DIMENSION(jpi,jpj,jpk) ::   zahu, zahv
69      REAL(wp), POINTER, DIMENSION(:,:,:,:)     ::   ztrtrd
70      !!----------------------------------------------------------------------
71      !
72      IF( ln_trcldf_OFF )   RETURN        ! not lateral diffusion applied on passive tracers
73      !
74      IF( ln_timing )   CALL timing_start('trc_ldf')
75      !
76      IF( l_trdtrc )  THEN
77         ALLOCATE( ztrtrd(jpi,jpj,jpk,jptra) )
78         ztrtrd(:,:,:,:)  = ptr(:,:,:,:,Krhs)
79      ENDIF
80      !                                  !* set the lateral diffusivity coef. for passive tracer     
81      zahu(:,:,:) = rldf * ahtu(:,:,:) 
82      zahv(:,:,:) = rldf * ahtv(:,:,:)
83      !                                  !* Enhanced zonal diffusivity coefficent in the equatorial domain
84      DO_3D( 1, 1, 1, 1, 1, jpk )
85         IF( gdept(ji,jj,jk,Kmm) > 200. .AND. gphit(ji,jj) < 5. .AND. gphit(ji,jj) > -5. ) THEN
86            zdep = MAX( gdept(ji,jj,jk,Kmm) - 1000., 0. ) / 1000.
87            zahu(ji,jj,jk) = zahu(ji,jj,jk) * MAX( 1., rn_fact_lap * EXP( -zdep ) )
88         ENDIF
89      END_3D
90      !
91      SELECT CASE ( nldf_trc )                 !* compute lateral mixing trend and add it to the general trend
92      !
93      CASE ( np_lap   )                                                                                    ! iso-level laplacian
94         CALL tra_ldf_lap  ( kt, Kmm, nittrc000,'TRC', zahu, zahv, gtru, gtrv, gtrui, gtrvi,            &
95           &                     ptr(:,:,:,:,Kbb), ptr(:,:,:,:,Krhs),                   jptra, 1 )
96      CASE ( np_lap_i )                                                                                    ! laplacian : standard iso-neutral operator (Madec)
97         CALL tra_ldf_iso  ( kt, Kmm, nittrc000,'TRC', zahu, zahv, gtru, gtrv, gtrui, gtrvi,            &
98           &                     ptr(:,:,:,:,Kbb), ptr(:,:,:,:,Kbb), ptr(:,:,:,:,Krhs), jptra, 1 )
99      CASE ( np_lap_it )                                                                                   ! laplacian : triad iso-neutral operator (griffies)
100         CALL tra_ldf_triad( kt, Kmm, nittrc000,'TRC', zahu, zahv, gtru, gtrv, gtrui, gtrvi,            &
101           &                     ptr(:,:,:,:,Kbb), ptr(:,:,:,:,Kbb), ptr(:,:,:,:,Krhs), jptra, 1 )
102      CASE ( np_blp , np_blp_i , np_blp_it )                                                               ! bilaplacian: all operator (iso-level, -neutral)
103#if defined key_mpi3
104         IF(nn_hls.EQ.2) CALL lbc_lnk_nc_multi( 'trc_ldf', ptr(:,:,:,:,Kbb), 'T',1.)
105#else
106         IF(nn_hls.EQ.2) CALL lbc_lnk( 'trc_ldf', ptr(:,:,:,:,Kbb), 'T',1.)
107#endif
108         CALL tra_ldf_blp  ( kt, Kmm, nittrc000,'TRC', zahu, zahv, gtru, gtrv, gtrui, gtrvi,            &
109           &                     ptr(:,:,:,:,Kbb) , ptr(:,:,:,:,Krhs),                 jptra, nldf_trc )
110      END SELECT
111      !
112      IF( l_trdtrc )   THEN                    ! send the trends for further diagnostics
113        DO jn = 1, jptra
114           ztrtrd(:,:,:,jn) = ptr(:,:,:,jn,Krhs) - ztrtrd(:,:,:,jn)
115           CALL trd_tra( kt, Kmm, Krhs, 'TRC', jn, jptra_ldf, ztrtrd(:,:,:,jn) )
116        END DO
117        DEALLOCATE( ztrtrd )
118      ENDIF
119      !               
120      IF( sn_cfctl%l_prttrc ) THEN ! print mean trends (used for debugging)
121         WRITE(charout, FMT="('ldf ')")
122         CALL prt_ctl_info( charout, cdcomp = 'top' )
123         CALL prt_ctl( tab4d_1=ptr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm, clinfo3='trd' )
124      ENDIF
125      !
126      IF( ln_timing )   CALL timing_stop('trc_ldf')
127      !
128   END SUBROUTINE trc_ldf
129
130
131   SUBROUTINE trc_ldf_ini
132      !!----------------------------------------------------------------------
133      !!                  ***  ROUTINE ldf_ctl  ***
134      !!
135      !! ** Purpose :   Define the operator for the lateral diffusion
136      !!
137      !! ** Method  : - ln_trcldf_tra=T : use nldf_tra set in ldftra module
138      !!              to defined the passive tracer lateral diffusive operator
139      !!              - ln_trcldf_OFF=T : no explicit diffusion used
140      !!----------------------------------------------------------------------
141      INTEGER ::   ios, ioptio   ! local integers
142      !!
143      NAMELIST/namtrc_ldf/ ln_trcldf_OFF , ln_trcldf_tra,   &   ! operator & direction
144         &                 rn_ldf_multi  , rn_fact_lap          ! coefficient
145      !!----------------------------------------------------------------------
146      !
147      IF(lwp) THEN
148         WRITE(numout,*)
149         WRITE(numout,*) 'trc_ldf_ini : lateral passive tracer diffusive operator'
150         WRITE(numout,*) '~~~~~~~~~~~'
151      ENDIF
152      !
153      READ  ( numnat_ref, namtrc_ldf, IOSTAT = ios, ERR = 903)
154903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_ldf in reference namelist' )
155      !
156      READ  ( numnat_cfg, namtrc_ldf, IOSTAT = ios, ERR = 904 )
157904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_ldf in configuration namelist' )
158      IF(lwm) WRITE ( numont, namtrc_ldf )
159      !
160      IF(lwp) THEN                     ! Namelist print
161         WRITE(numout,*) '   Namelist namtrc_ldf : set lateral mixing parameters (type, direction, coefficients)'
162         WRITE(numout,*) '      no explicit diffusion                 ln_trcldf_OFF   = ', ln_trcldf_OFF
163         WRITE(numout,*) '      use active tracer operator            ln_trcldf_tra   = ', ln_trcldf_tra
164         WRITE(numout,*) '      diffusivity coefficient :'
165         WRITE(numout,*) '         multiplier of TRA coef. for TRC       rn_ldf_multi = ', rn_ldf_multi
166         WRITE(numout,*) '         enhanced zonal Eq. laplacian coef.    rn_fact_lap  = ', rn_fact_lap
167
168      ENDIF
169      !     
170      !                                ! control the namelist parameters
171      nldf_trc = np_ERROR
172      ioptio   = 0
173      IF( ln_trcldf_OFF  ) THEN   ;   nldf_trc = np_no_ldf   ;   ioptio = ioptio + 1   ;   ENDIF
174      IF( ln_trcldf_tra  ) THEN   ;   nldf_trc = nldf_tra    ;   ioptio = ioptio + 1   ;   ENDIF
175      IF( ioptio /=  1   )   CALL ctl_stop( 'trc_ldf_ini: use ONE of the 2 operator options (OFF/tra)' )
176     
177      !                                ! multiplier : passive/active tracers ration
178      IF( ln_traldf_lap ) THEN               ! laplacian operator
179         rldf = rn_ldf_multi                       ! simple multiplier
180      ELSEIF( ln_traldf_blp ) THEN           ! bilaplacian operator:
181         rldf = SQRT( ABS( rn_ldf_multi )  )       ! the coef. used is the SQRT of the bilaplacian coef.
182      ENDIF
183      !
184      IF(lwp) THEN
185         WRITE(numout,*)
186         SELECT CASE( nldf_trc )
187         CASE( np_no_ldf )   ;   WRITE(numout,*) '      ===>>   NO lateral diffusion'
188         CASE( np_lap    )   ;   WRITE(numout,*) '      ===>>   laplacian iso-level operator'
189         CASE( np_lap_i  )   ;   WRITE(numout,*) '      ===>>   Rotated laplacian operator (standard)'
190         CASE( np_lap_it )   ;   WRITE(numout,*) '      ===>>   Rotated laplacian operator (triad)'
191         CASE( np_blp    )   ;   WRITE(numout,*) '      ===>>   bilaplacian iso-level operator'
192         CASE( np_blp_i  )   ;   WRITE(numout,*) '      ===>>   Rotated bilaplacian operator (standard)'
193         CASE( np_blp_it )   ;   WRITE(numout,*) '      ===>>   Rotated bilaplacian operator (triad)'
194         END SELECT
195      ENDIF
196      !
197   END SUBROUTINE trc_ldf_ini
198
199#endif
200   !!======================================================================
201END MODULE trcldf
Note: See TracBrowser for help on using the repository browser.