New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcbdy.F90 in NEMO/branches/2020/dev_r13898_Tiling_Cleanup_MPI3/src/TOP – NEMO

source: NEMO/branches/2020/dev_r13898_Tiling_Cleanup_MPI3/src/TOP/trcbdy.F90 @ 14302

Last change on this file since 14302 was 13906, checked in by mocavero, 4 years ago

Merge with dev_r13296_HPC-07_mocavero_mpi3
  • Property svn:keywords set to Id
File size: 8.6 KB
Line 
1MODULE trcbdy
2   !!======================================================================
3   !!                       ***  MODULE  bdytrc  ***
4   !! Ocean tracers:   Apply boundary conditions for tracers in TOP component
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
8   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
9   !!            3.5  !  2012     (S. Mocavero, I. Epicoco) Optimization of BDY communications
10   !!            3.6  !  2015     (T. Lovato) Adapt BDY for tracers in TOP component
11   !!            4.0  !  2016     (T. Lovato) Generalize OBC structure
12   !!----------------------------------------------------------------------
13#if defined key_top
14   !!----------------------------------------------------------------------
15   !!   trc_bdy       : Apply open boundary conditions & damping to tracers
16   !!----------------------------------------------------------------------
17   USE timing                       ! Timing
18   USE oce_trc                      ! ocean dynamics and tracers variables
19   USE par_trc
20   USE trc                          ! ocean space and time domain variables
21   USE bdylib                       ! for orlanski library routines
22   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
23   USE in_out_manager               ! I/O manager
24   USE bdy_oce                      ! ocean open boundary conditions
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC trc_bdy      ! routine called in trcnxt.F90
30   PUBLIC trc_bdy_dmp  ! routine called in trcstp.F90
31
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE trc_bdy( kt, Kbb, Kmm, Krhs )
40      !!----------------------------------------------------------------------
41      !!                  ***  SUBROUTINE trc_bdy  ***
42      !!
43      !! ** Purpose : - Apply open boundary conditions for TOP tracers
44      !!
45      !!----------------------------------------------------------------------
46      INTEGER, INTENT( in ) :: kt              ! Main time step counter
47      INTEGER, INTENT( in ) :: Kbb, Kmm, Krhs  ! time level indices
48      !!
49      INTEGER                           :: ib_bdy ,ir, jn ,igrd ! Loop indices
50      REAL(wp), POINTER, DIMENSION(:,:) ::  ztrc
51      LOGICAL                           :: llrim0               ! indicate if rim 0 is treated
52      LOGICAL, DIMENSION(4)             :: llsend1, llrecv1     ! indicate how communications are to be carried out
53      !!----------------------------------------------------------------------
54      !
55      IF( ln_timing )   CALL timing_start('trc_bdy')
56      !
57      igrd = 1 
58      llsend1(:) = .false.  ;   llrecv1(:) = .false.
59      DO ir = 1, 0, -1   ! treat rim 1 before rim 0
60         IF( ir == 0 ) THEN   ;   llrim0 = .TRUE.
61         ELSE                 ;   llrim0 = .FALSE.
62         ENDIF
63         DO ib_bdy=1, nb_bdy
64            !
65            DO jn = 1, jptra
66               !
67               IF( ASSOCIATED(trcdta_bdy(jn,ib_bdy)%trc) .AND. trcdta_bdy(jn,ib_bdy)%cn_obc /= 'neumann' ) THEN
68                  IF( .NOT. ASSOCIATED(ztrc) )   ALLOCATE( ztrc(idx_bdy(ib_bdy)%nblen(igrd),jpk) )
69                  ztrc(:,:) = trcdta_bdy(jn,ib_bdy)%trc(:,:) * trcdta_bdy(jn,ib_bdy)%rn_fac
70               ENDIF
71               !
72               SELECT CASE( trcdta_bdy(jn,ib_bdy)%cn_obc )
73               CASE('none'        )   ;   CYCLE
74               CASE('frs'         )   ! treat the whole boundary at once
75                  IF( ir == 0 )           CALL bdy_frs( idx_bdy(ib_bdy),                   tr(:,:,:,jn,Krhs), ztrc )
76               CASE('specified'   )   ! treat the whole rim      at once
77                  IF( ir == 0 )           CALL bdy_spe( idx_bdy(ib_bdy),                   tr(:,:,:,jn,Krhs), ztrc )
78               CASE('neumann'     )   ;   CALL bdy_nmn( idx_bdy(ib_bdy), igrd            , tr(:,:,:,jn,Krhs),       llrim0 )   ! tra masked
79               CASE('orlanski'    )   ;   CALL bdy_orl( idx_bdy(ib_bdy), tr(:,:,:,jn,Kbb), tr(:,:,:,jn,Krhs), ztrc, llrim0,   &
80                  &                                     ll_npo=.FALSE. )
81               CASE('orlanski_npo')   ;   CALL bdy_orl( idx_bdy(ib_bdy), tr(:,:,:,jn,Kbb), tr(:,:,:,jn,Krhs), ztrc, llrim0,   &
82                  &                                     ll_npo=.TRUE.  )
83               CASE DEFAULT           ;   CALL ctl_stop( 'trc_bdy : unrecognised option for open boundaries for passive tracers' )
84               END SELECT
85               !
86            END DO
87            !
88            IF( ASSOCIATED(ztrc) )   DEALLOCATE(ztrc)
89            !
90         END DO
91         !
92         IF( nn_hls > 1 .AND. ir == 1 ) CYCLE   ! at least 2 halos will be corrected -> no need to correct rim 1 before rim 0
93         IF( nn_hls == 1 ) THEN   ;   llsend1(:) = .false.   ;   llrecv1(:) = .false.   ;   ENDIF
94         DO ib_bdy=1, nb_bdy
95            SELECT CASE( cn_tra(ib_bdy) )
96            CASE('neumann')
97               llsend1(:) = llsend1(:) .OR. lsend_bdyint(ib_bdy,1,:,ir)   ! possibly every direction, T points
98               llrecv1(:) = llrecv1(:) .OR. lrecv_bdyint(ib_bdy,1,:,ir)   ! possibly every direction, T points
99            CASE('orlanski','orlanski_npo')
100               llsend1(:) = llsend1(:) .OR. lsend_bdy(ib_bdy,1,:,ir)   ! possibly every direction, T points
101               llrecv1(:) = llrecv1(:) .OR. lrecv_bdy(ib_bdy,1,:,ir)   ! possibly every direction, T points
102            END SELECT
103         END DO
104         IF( ANY(llsend1) .OR. ANY(llrecv1) ) THEN   ! if need to send/recv in at least one direction
105#if defined key_mpi3
106            CALL lbc_lnk_nc_multi( 'trcbdy', tr(:,:,:,:,Krhs), 'T',  1.0_wp, kfillmode=jpfillnothing ,lsend=llsend1, lrecv=llrecv1 )
107#else
108            CALL lbc_lnk( 'trcbdy', tr(:,:,:,:,Krhs), 'T',  1.0_wp, kfillmode=jpfillnothing ,lsend=llsend1, lrecv=llrecv1 )
109#endif
110         ENDIF
111         !
112      END DO   ! ir
113      !
114      IF( ln_timing )   CALL timing_stop('trc_bdy')
115      !
116   END SUBROUTINE trc_bdy
117
118
119   SUBROUTINE trc_bdy_dmp( kt, Kbb, Krhs )
120      !!----------------------------------------------------------------------
121      !!                 ***  SUBROUTINE trc_bdy_dmp  ***
122      !!                   
123      !! ** Purpose : Apply damping for tracers at open boundaries.
124      !!             It currently applies the damping to all tracers!!!
125      !!
126      !!----------------------------------------------------------------------
127      INTEGER,         INTENT(in) ::   kt
128      INTEGER,         INTENT(in) ::   Kbb, Krhs  ! time level indices
129      !!
130      INTEGER  ::   jn             ! Tracer index
131      REAL(wp) ::   zwgt           ! boundary weight
132      REAL(wp) ::   zta, zsa, ztime
133      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
134      INTEGER  ::   ii, ij         ! 2D addresses
135      INTEGER  ::   ib_bdy         ! Loop index
136      !!----------------------------------------------------------------------
137      !
138      IF( ln_timing )   CALL timing_start('trc_bdy_dmp')
139      !
140      DO jn = 1, jptra
141         DO ib_bdy=1, nb_bdy
142            IF( trcdta_bdy(jn, ib_bdy)%dmp ) THEN
143               igrd = 1                       ! Everything is at T-points here
144               DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
145                  ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
146                  ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
147                  zwgt = idx_bdy(ib_bdy)%nbd(ib,igrd)
148                  DO ik = 1, jpkm1
149                     zta = zwgt * ( trcdta_bdy(jn, ib_bdy)%trc(ib,ik) - tr(ii,ij,ik,jn,Kbb) ) * tmask(ii,ij,ik)
150                     tr(ii,ij,ik,jn,Krhs) = tr(ii,ij,ik,jn,Krhs) + zta
151                  END DO
152               END DO
153            ENDIF
154         END DO
155      END DO
156      !
157      IF( ln_timing )   CALL timing_stop('trc_bdy_dmp')
158      !
159   END SUBROUTINE trc_bdy_dmp
160 
161#else
162   !!----------------------------------------------------------------------
163   !!   Dummy module                   NO Unstruct Open Boundary Conditions
164   !!----------------------------------------------------------------------
165CONTAINS
166   SUBROUTINE trc_bdy(kt)      ! Empty routine
167      WRITE(*,*) 'trc_bdy: You should not have seen this print! error?', kt
168   END SUBROUTINE trc_bdy
169
170   SUBROUTINE trc_bdy_dmp(kt)      ! Empty routine
171      WRITE(*,*) 'trc_bdy_dmp: You should not have seen this print! error?', kt
172   END SUBROUTINE trc_bdy_dmp
173
174#endif
175
176   !!======================================================================
177END MODULE trcbdy
Note: See TracBrowser for help on using the repository browser.