New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

dynhpg.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/DYN – NEMO

Context Navigation

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/DYN/dynhpg.F90 @ 14644

Last change on this file since 14644 was 14644, checked in by sparonuz, 3 years ago
Merge trunk -r14642:HEAD
Property svn:keywords set to `Id`
File size: 75.5 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!! 4.2 ! 2020-12 (M. Bell, A. Young) hpg_djc: revised djc scheme
20	!!----------------------------------------------------------------------
21
22	!!----------------------------------------------------------------------
23	!! dyn_hpg : update the momentum trend with the now horizontal
24	!! gradient of the hydrostatic pressure
25	!! dyn_hpg_init : initialisation and control of options
26	!! hpg_zco : z-coordinate scheme
27	!! hpg_zps : z-coordinate plus partial steps (interpolation)
28	!! hpg_sco : s-coordinate (standard jacobian formulation)
29	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
30	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
31	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
32	!!----------------------------------------------------------------------
33	USE oce ! ocean dynamics and tracers
34	USE isf_oce , ONLY : risfload ! ice shelf (risfload variable)
35	USE isfload , ONLY : isf_load ! ice shelf (isf_load routine )
36	USE sbc_oce ! surface variable (only for the flag with ice shelf)
37	USE dom_oce ! ocean space and time domain
38	USE wet_dry ! wetting and drying
39	USE phycst ! physical constants
40	USE trd_oce ! trends: ocean variables
41	USE trddyn ! trend manager: dynamics
42	USE zpshde ! partial step: hor. derivative (zps_hde routine)
43	!
44	USE in_out_manager ! I/O manager
45	USE prtctl ! Print control
46	USE lbclnk ! lateral boundary condition
47	USE lib_mpp ! MPP library
48	USE eosbn2 ! compute density
49	USE timing ! Timing
50	USE iom
51
52	IMPLICIT NONE
53	PRIVATE
54
55	PUBLIC dyn_hpg ! routine called by step module
56	PUBLIC dyn_hpg_init ! routine called by opa module
57
58	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
59	LOGICAL, PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
60	LOGICAL, PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
61	LOGICAL, PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
62	LOGICAL, PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
63	LOGICAL, PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
64	LOGICAL, PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
65
66	! !! Flag to control the type of hydrostatic pressure gradient
67	INTEGER, PARAMETER :: np_ERROR =-10 ! error in specification of lateral diffusion
68	INTEGER, PARAMETER :: np_zco = 0 ! z-coordinate - full steps
69	INTEGER, PARAMETER :: np_zps = 1 ! z-coordinate - partial steps (interpolation)
70	INTEGER, PARAMETER :: np_sco = 2 ! s-coordinate (standard jacobian formulation)
71	INTEGER, PARAMETER :: np_djc = 3 ! s-coordinate (Density Jacobian with Cubic polynomial)
72	INTEGER, PARAMETER :: np_prj = 4 ! s-coordinate (Pressure Jacobian scheme)
73	INTEGER, PARAMETER :: np_isf = 5 ! s-coordinate similar to sco modify for isf
74	!
75	INTEGER, PUBLIC :: nhpg !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
76	!
77	LOGICAL :: ln_hpg_djc_vnh, ln_hpg_djc_vnv ! flag to specify hpg_djc boundary condition type
78	REAL(wp), PUBLIC :: aco_bc_hor, bco_bc_hor, aco_bc_vrt, bco_bc_vrt !: coefficients for hpg_djc hor and vert boundary conditions
79
80	!! * Substitutions
81	# include "do_loop_substitute.h90"
82	# include "domzgr_substitute.h90"
83	# include "single_precision_substitute.h90"
84
85	!!----------------------------------------------------------------------
86	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
87	!! $Id$
88	!! Software governed by the CeCILL license (see ./LICENSE)
89	!!----------------------------------------------------------------------
90	CONTAINS
91
92	SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
93	!!---------------------------------------------------------------------
94	!! * ROUTINE dyn_hpg *
95	!!
96	!! ** Method : Call the hydrostatic pressure gradient routine
97	!! using the scheme defined in the namelist
98	!!
99	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
100	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
101	!!----------------------------------------------------------------------
102	INTEGER , INTENT( in ) :: kt ! ocean time-step index
103	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
104	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
105	!
106	REAL(dp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdu, ztrdv
107	!!----------------------------------------------------------------------
108	!
109	IF( ln_timing ) CALL timing_start('dyn_hpg')
110	!
111	IF( l_trddyn ) THEN ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
112	ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
113	ztrdu(:,:,:) = puu(:,:,:,Krhs)
114	ztrdv(:,:,:) = pvv(:,:,:,Krhs)
115	ENDIF
116	!
117	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
118	CASE ( np_zco ) ; CALL hpg_zco ( kt, Kmm, puu, pvv, Krhs ) ! z-coordinate
119	CASE ( np_zps ) ; CALL hpg_zps ( kt, Kmm, puu, pvv, Krhs ) ! z-coordinate plus partial steps (interpolation)
120	CASE ( np_sco ) ; CALL hpg_sco ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (standard jacobian formulation)
121	CASE ( np_djc ) ; CALL hpg_djc ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (Density Jacobian with Cubic polynomial)
122	CASE ( np_prj ) ; CALL hpg_prj ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (Pressure Jacobian scheme)
123	CASE ( np_isf ) ; CALL hpg_isf ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate similar to sco modify for ice shelf
124	END SELECT
125	!
126	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
127	ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
128	ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
129	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
130	DEALLOCATE( ztrdu , ztrdv )
131	ENDIF
132	!
133	IF(sn_cfctl%l_prtctl) CALL prt_ctl( tab3d_1=CASTWP(puu(:,:,:,Krhs)), clinfo1=' hpg - Ua: ', mask1=umask, &
134	& tab3d_2=CASTWP(pvv(:,:,:,Krhs)), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
135	!
136	IF( ln_timing ) CALL timing_stop('dyn_hpg')
137	!
138	END SUBROUTINE dyn_hpg
139
140
141	SUBROUTINE dyn_hpg_init( Kmm )
142	!!----------------------------------------------------------------------
143	!! * ROUTINE dyn_hpg_init *
144	!!
145	!! ** Purpose : initializations for the hydrostatic pressure gradient
146	!! computation and consistency control
147	!!
148	!! ** Action : Read the namelist namdyn_hpg and check the consistency
149	!! with the type of vertical coordinate used (zco, zps, sco)
150	!!----------------------------------------------------------------------
151	INTEGER, INTENT( in ) :: Kmm ! ocean time level index
152	!
153	INTEGER :: ioptio = 0 ! temporary integer
154	INTEGER :: ios ! Local integer output status for namelist read
155	!!
156	INTEGER :: ji, jj, jk, ikt ! dummy loop indices ISF
157	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zts_top, zrhd ! hypothesys on isf density
158	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zrhdtop_isf ! density at bottom of ISF
159	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: ziceload ! density at bottom of ISF
160	!!
161	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
162	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, &
163	& ln_hpg_djc_vnh, ln_hpg_djc_vnv
164	!!----------------------------------------------------------------------
165	!
166	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
167	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
168	!
169	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
170	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
171	IF(lwm) WRITE ( numond, namdyn_hpg )
172	!
173	IF(lwp) THEN ! Control print
174	WRITE(numout,*)
175	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
176	WRITE(numout,*) '~~~~~~~~~~~~'
177	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
178	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
179	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
180	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
181	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
182	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
183	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
184	ENDIF
185	!
186	IF( .NOT.ln_linssh .AND. (ln_hpg_zco.OR.ln_hpg_zps) ) &
187	& CALL ctl_stop( 'dyn_hpg_init : non-linear free surface incompatible with hpg_zco or hpg_zps' )
188	!
189	IF( (.NOT.ln_hpg_isf .AND. ln_isfcav) .OR. (ln_hpg_isf .AND. .NOT.ln_isfcav) ) &
190	& CALL ctl_stop( 'dyn_hpg_init : ln_hpg_isf=T requires ln_isfcav=T and vice versa' )
191	!
192	#if defined key_qco
193	IF( ln_hpg_isf ) THEN
194	CALL ctl_stop( 'dyn_hpg_init : key_qco and ln_hpg_isf not yet compatible' )
195	ENDIF
196	#endif
197	!
198	! ! Set nhpg from ln_hpg_... flags & consistency check
199	nhpg = np_ERROR
200	ioptio = 0
201	IF( ln_hpg_zco ) THEN ; nhpg = np_zco ; ioptio = ioptio +1 ; ENDIF
202	IF( ln_hpg_zps ) THEN ; nhpg = np_zps ; ioptio = ioptio +1 ; ENDIF
203	IF( ln_hpg_sco ) THEN ; nhpg = np_sco ; ioptio = ioptio +1 ; ENDIF
204	IF( ln_hpg_djc ) THEN ; nhpg = np_djc ; ioptio = ioptio +1 ; ENDIF
205	IF( ln_hpg_prj ) THEN ; nhpg = np_prj ; ioptio = ioptio +1 ; ENDIF
206	IF( ln_hpg_isf ) THEN ; nhpg = np_isf ; ioptio = ioptio +1 ; ENDIF
207	!
208	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
209	!
210	IF(lwp) THEN
211	WRITE(numout,*)
212	SELECT CASE( nhpg )
213	CASE( np_zco ) ; WRITE(numout,*) ' ==>>> z-coord. - full steps '
214	CASE( np_zps ) ; WRITE(numout,*) ' ==>>> z-coord. - partial steps (interpolation)'
215	CASE( np_sco ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation)'
216	CASE( np_djc ) ; WRITE(numout,*) ' ==>>> s-coord. (Density Jacobian: Cubic polynomial)'
217	CASE( np_prj ) ; WRITE(numout,*) ' ==>>> s-coord. (Pressure Jacobian: Cubic polynomial)'
218	CASE( np_isf ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation) for isf'
219	END SELECT
220	WRITE(numout,*)
221	ENDIF
222	!
223	IF ( ln_hpg_djc ) THEN
224	IF (ln_hpg_djc_vnh) THEN ! Von Neumann boundary condition
225	IF(lwp) WRITE(numout,*) ' horizontal bc: von Neumann '
226	aco_bc_hor = 6.0_wp/5.0_wp
227	bco_bc_hor = 7.0_wp/15.0_wp
228	ELSE ! Linear extrapolation
229	IF(lwp) WRITE(numout,*) ' horizontal bc: linear extrapolation'
230	aco_bc_hor = 3.0_wp/2.0_wp
231	bco_bc_hor = 1.0_wp/2.0_wp
232	END IF
233	IF (ln_hpg_djc_vnv) THEN ! Von Neumann boundary condition
234	IF(lwp) WRITE(numout,*) ' vertical bc: von Neumann '
235	aco_bc_vrt = 6.0_wp/5.0_wp
236	bco_bc_vrt = 7.0_wp/15.0_wp
237	ELSE ! Linear extrapolation
238	IF(lwp) WRITE(numout,*) ' vertical bc: linear extrapolation'
239	aco_bc_vrt = 3.0_wp/2.0_wp
240	bco_bc_vrt = 1.0_wp/2.0_wp
241	END IF
242	END IF
243	!
244	END SUBROUTINE dyn_hpg_init
245
246
247	SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
248	!!---------------------------------------------------------------------
249	!! * ROUTINE hpg_zco *
250	!!
251	!! ** Method : z-coordinate case, levels are horizontal surfaces.
252	!! The now hydrostatic pressure gradient at a given level, jk,
253	!! is computed by taking the vertical integral of the in-situ
254	!! density gradient along the model level from the suface to that
255	!! level: zhpi = grav .....
256	!! zhpj = grav .....
257	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
258	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
259	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
260	!!
261	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
262	!!----------------------------------------------------------------------
263	INTEGER , INTENT( in ) :: kt ! ocean time-step index
264	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
265	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
266	!
267	INTEGER :: ji, jj, jk ! dummy loop indices
268	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
269	REAL(wp), DIMENSION(jpi,jpj) :: zhpi, zhpj
270	!!----------------------------------------------------------------------
271	!
272	IF( kt == nit000 ) THEN
273	IF(lwp) WRITE(numout,*)
274	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
275	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
276	ENDIF
277	!
278	zcoef0 = - grav * 0.5_wp ! Local constant initialization
279	!
280	DO_2D( 0, 0, 0, 0 ) ! Surface value
281	zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
282	! ! hydrostatic pressure gradient
283	zhpi(ji,jj) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
284	zhpj(ji,jj) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
285	! ! add to the general momentum trend
286	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj)
287	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj)
288	END_2D
289	!
290	DO_3D( 0, 0, 0, 0, 2, jpkm1 ) ! interior value (2=<jk=<jpkm1)
291	zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
292	! ! hydrostatic pressure gradient
293	zhpi(ji,jj) = zhpi(ji,jj) + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
294	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
295
296	zhpj(ji,jj) = zhpj(ji,jj) + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
297	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
298	! ! add to the general momentum trend
299	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj)
300	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj)
301	END_3D
302	!
303	END SUBROUTINE hpg_zco
304
305
306	SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
307	!!---------------------------------------------------------------------
308	!! * ROUTINE hpg_zps *
309	!!
310	!! ** Method : z-coordinate plus partial steps case. blahblah...
311	!!
312	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
313	!!----------------------------------------------------------------------
314	INTEGER , INTENT( in ) :: kt ! ocean time-step index
315	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
316	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
317	!!
318	INTEGER :: ji, jj, jk ! dummy loop indices
319	INTEGER :: iku, ikv ! temporary integers
320	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
321	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zhpj
322	REAL(wp), DIMENSION(jpi,jpj,jpts) :: zgtsu, zgtsv
323	REAL(wp), DIMENSION(jpi,jpj) :: zgru, zgrv
324	!!----------------------------------------------------------------------
325	!
326	IF( kt == nit000 ) THEN
327	IF(lwp) WRITE(numout,*)
328	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
329	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
330	ENDIF
331
332	! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
333	CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
334
335	! Local constant initialization
336	zcoef0 = - grav * 0.5_wp
337
338	! Surface value (also valid in partial step case)
339	DO_2D( 0, 0, 0, 0 )
340	zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
341	! hydrostatic pressure gradient
342	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
343	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
344	! add to the general momentum trend
345	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
346	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
347	END_2D
348
349	! interior value (2=<jk=<jpkm1)
350	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
351	zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
352	! hydrostatic pressure gradient
353	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
354	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
355	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
356
357	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
358	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
359	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
360	! add to the general momentum trend
361	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
362	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
363	END_3D
364
365	! partial steps correction at the last level (use zgru & zgrv computed in zpshde.F90)
366	DO_2D( 0, 0, 0, 0 )
367	iku = mbku(ji,jj)
368	ikv = mbkv(ji,jj)
369	zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj ,iku,Kmm) )
370	zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji ,jj+1,ikv,Kmm) )
371	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
372	puu (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku) ! subtract old value
373	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
374	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
375	puu (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
376	ENDIF
377	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
378	pvv (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv) ! subtract old value
379	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
380	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
381	pvv (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
382	ENDIF
383	END_2D
384	!
385	END SUBROUTINE hpg_zps
386
387
388	SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
389	!!---------------------------------------------------------------------
390	!! * ROUTINE hpg_sco *
391	!!
392	!! ** Method : s-coordinate case. Jacobian scheme.
393	!! The now hydrostatic pressure gradient at a given level, jk,
394	!! is computed by taking the vertical integral of the in-situ
395	!! density gradient along the model level from the suface to that
396	!! level. s-coordinates (ln_sco): a corrective term is added
397	!! to the horizontal pressure gradient :
398	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
399	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
400	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
401	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
402	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
403	!!
404	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
405	!!----------------------------------------------------------------------
406	INTEGER , INTENT( in ) :: kt ! ocean time-step index
407	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
408	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
409	!!
410	INTEGER :: ji, jj, jk, jii, jjj ! dummy loop indices
411	REAL(wp) :: zcoef0, zuap, zvap, ztmp ! local scalars
412	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
413	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zhpj
414	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
415	!!----------------------------------------------------------------------
416	!
417	IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
418	!
419	IF( kt == nit000 ) THEN
420	IF(lwp) WRITE(numout,*)
421	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
422	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OCE original scheme used'
423	ENDIF
424	!
425	zcoef0 = - grav * 0.5_wp
426	!
427	IF( ln_wd_il ) THEN
428	DO_2D( 0, 0, 0, 0 )
429	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
430	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
431	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
432	& > rn_wdmin1 + rn_wdmin2
433	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
434	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
435	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
436
437	IF(ll_tmp1) THEN
438	zcpx(ji,jj) = 1.0_wp
439	ELSE IF(ll_tmp2) THEN
440	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
441	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
442	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
443	ELSE
444	zcpx(ji,jj) = 0._wp
445	END IF
446
447	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
448	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
449	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
450	& > rn_wdmin1 + rn_wdmin2
451	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
452	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
453	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
454
455	IF(ll_tmp1) THEN
456	zcpy(ji,jj) = 1.0_wp
457	ELSE IF(ll_tmp2) THEN
458	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
459	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
460	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
461	ELSE
462	zcpy(ji,jj) = 0._wp
463	END IF
464	END_2D
465	CALL lbc_lnk( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
466	END IF
467	!
468	DO_2D( 0, 0, 0, 0 ) ! Surface value
469	! ! hydrostatic pressure gradient along s-surfaces
470	zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) &
471	& * ( e3w(ji+1,jj ,1,Kmm) * rhd(ji+1,jj ,1) &
472	& - e3w(ji ,jj ,1,Kmm) * rhd(ji ,jj ,1) )
473	zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) &
474	& * ( e3w(ji ,jj+1,1,Kmm) * rhd(ji ,jj+1,1) &
475	& - e3w(ji ,jj ,1,Kmm) * rhd(ji ,jj ,1) )
476	! ! s-coordinate pressure gradient correction
477	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) ) &
478	& * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
479	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) ) &
480	& * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
481	!
482	IF( ln_wd_il ) THEN
483	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
484	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
485	zuap = zuap * zcpx(ji,jj)
486	zvap = zvap * zcpy(ji,jj)
487	ENDIF
488	! ! add to the general momentum trend
489	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
490	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
491	END_2D
492	!
493	DO_3D( 0, 0, 0, 0, 2, jpkm1 ) ! interior value (2=<jk=<jpkm1)
494	! ! hydrostatic pressure gradient along s-surfaces
495	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj) &
496	& * ( e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
497	& - e3w(ji ,jj,jk,Kmm) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) )
498	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj) &
499	& * ( e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
500	& - e3w(ji,jj ,jk,Kmm) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) )
501	! ! s-coordinate pressure gradient correction
502	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) ) &
503	& * ( gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
504	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) ) &
505	& * ( gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
506	!
507	IF( ln_wd_il ) THEN
508	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
509	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
510	zuap = zuap * zcpx(ji,jj)
511	zvap = zvap * zcpy(ji,jj)
512	ENDIF
513	!
514	! add to the general momentum trend
515	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
516	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
517	END_3D
518	!
519	IF( ln_wd_il ) DEALLOCATE( zcpx , zcpy )
520	!
521	END SUBROUTINE hpg_sco
522
523
524	SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
525	!!---------------------------------------------------------------------
526	!! * ROUTINE hpg_isf *
527	!!
528	!! ** Method : s-coordinate case. Jacobian scheme.
529	!! The now hydrostatic pressure gradient at a given level, jk,
530	!! is computed by taking the vertical integral of the in-situ
531	!! density gradient along the model level from the suface to that
532	!! level. s-coordinates (ln_sco): a corrective term is added
533	!! to the horizontal pressure gradient :
534	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
535	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
536	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
537	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
538	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
539	!! iceload is added
540	!!
541	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
542	!!----------------------------------------------------------------------
543	INTEGER , INTENT( in ) :: kt ! ocean time-step index
544	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
545	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
546	!!
547	INTEGER :: ji, jj, jk ! dummy loop indices
548	INTEGER :: ikt , ikti1, iktj1 ! local integer
549	REAL(wp) :: ze3w, ze3wi1, ze3wj1 ! local scalars
550	REAL(wp) :: zcoef0, zuap, zvap ! - -
551	REAL(wp), DIMENSION(jpi,jpj,jpk ) :: zhpi, zhpj
552	REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts_top
553	REAL(wp), DIMENSION(jpi,jpj) :: zrhdtop_oce
554	!!----------------------------------------------------------------------
555	!
556	zcoef0 = - grav * 0.5_wp ! Local constant initialization
557	!
558	! ! iniitialised to 0. zhpi zhpi
559	zhpi(:,:,:) = 0._wp ; zhpj(:,:,:) = 0._wp
560
561	! compute rhd at the ice/oce interface (ocean side)
562	! usefull to reduce residual current in the test case ISOMIP with no melting
563	DO ji = 1, jpi
564	DO jj = 1, jpj
565	ikt = mikt(ji,jj)
566	zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
567	zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
568	END DO
569	END DO
570	CALL eos( zts_top, risfdep, zrhdtop_oce )
571
572	! !===========================!
573	! !===== surface value =====!
574	! !===========================!
575	DO_2D( 0, 0, 0, 0 )
576	ikt = mikt(ji ,jj ) ; ze3w = e3w(ji ,jj ,ikt ,Kmm)
577	ikti1 = mikt(ji+1,jj ) ; ze3wi1 = e3w(ji+1,jj ,ikti1,Kmm)
578	iktj1 = mikt(ji ,jj+1) ; ze3wj1 = e3w(ji ,jj+1,iktj1,Kmm)
579	! ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
580	! ! we assume ISF is in isostatic equilibrium
581	zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) * ( risfload(ji+1,jj) - risfload(ji,jj) &
582	& + 0.5_wp * ( ze3wi1 * ( rhd(ji+1,jj,ikti1) + zrhdtop_oce(ji+1,jj) ) &
583	& - ze3w * ( rhd(ji ,jj,ikt ) + zrhdtop_oce(ji ,jj) ) ) )
584	zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) * ( risfload(ji,jj+1) - risfload(ji,jj) &
585	& + 0.5_wp * ( ze3wj1 * ( rhd(ji,jj+1,iktj1) + zrhdtop_oce(ji,jj+1) ) &
586	& - ze3w * ( rhd(ji,jj ,ikt ) + zrhdtop_oce(ji,jj ) ) ) )
587	! ! s-coordinate pressure gradient correction (=0 if z coordinate)
588	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) ) &
589	& * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
590	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) ) &
591	& * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
592	! ! add to the general momentum trend
593	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
594	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
595	END_2D
596	!
597	! !=============================!
598	! !===== interior values =====!
599	! !=============================!
600	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
601	ze3w = e3w(ji ,jj ,jk,Kmm)
602	ze3wi1 = e3w(ji+1,jj ,jk,Kmm)
603	ze3wj1 = e3w(ji ,jj+1,jk,Kmm)
604	! ! hydrostatic pressure gradient along s-surfaces
605	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
606	& * ( ze3wi1 * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) * wmask(ji+1,jj,jk) &
607	& - ze3w * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) * wmask(ji ,jj,jk) )
608	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
609	& * ( ze3wj1 * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) * wmask(ji,jj+1,jk) &
610	& - ze3w * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) * wmask(ji,jj ,jk) )
611	! ! s-coordinate pressure gradient correction
612	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) ) &
613	& * ( gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
614	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) ) &
615	& * ( gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
616	! ! add to the general momentum trend
617	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
618	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
619	END_3D
620	!
621	END SUBROUTINE hpg_isf
622
623
624	SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
625	!!---------------------------------------------------------------------
626	!! * ROUTINE hpg_djc *
627	!!
628	!! ** Method : Density Jacobian with Cubic polynomial scheme
629	!!
630	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
631	!!----------------------------------------------------------------------
632	INTEGER , INTENT( in ) :: kt ! ocean time-step index
633	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
634	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
635	!!
636	INTEGER :: ji, jj, jk ! dummy loop indices
637	INTEGER :: iktb, iktt ! jk indices at tracer points for top and bottom points
638	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
639	REAL(wp) :: z_grav_10, z1_12
640	REAL(wp) :: cffu, cffx ! " "
641	REAL(wp) :: cffv, cffy ! " "
642	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
643	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zhpj
644
645	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdzx, zdzy, zdzz ! Primitive grid differences ('delta_xyz')
646	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdz_i, zdz_j, zdz_k ! Harmonic average of primitive grid differences ('d_xyz')
647	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdrhox, zdrhoy, zdrhoz ! Primitive rho differences ('delta_rho')
648	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdrho_i, zdrho_j, zdrho_k ! Harmonic average of primitive rho differences ('d_rho')
649	REAL(wp), DIMENSION(jpi,jpj,jpk) :: z_rho_i, z_rho_j, z_rho_k ! Face intergrals
650	REAL(wp), DIMENSION(jpi,jpj) :: zz_dz_i, zz_dz_j, zz_drho_i, zz_drho_j ! temporary arrays
651	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
652	!!----------------------------------------------------------------------
653	!
654	IF( ln_wd_il ) THEN
655	ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
656	DO_2D( 0, 0, 0, 0 )
657	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
658	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
659	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
660	& > rn_wdmin1 + rn_wdmin2
661	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
662	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
663	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
664	IF(ll_tmp1) THEN
665	zcpx(ji,jj) = 1.0_wp
666	ELSE IF(ll_tmp2) THEN
667	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
668	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
669	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
670	ELSE
671	zcpx(ji,jj) = 0._wp
672	END IF
673
674	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
675	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
676	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
677	& > rn_wdmin1 + rn_wdmin2
678	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
679	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
680	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
681
682	IF(ll_tmp1) THEN
683	zcpy(ji,jj) = 1.0_wp
684	ELSE IF(ll_tmp2) THEN
685	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
686	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
687	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
688	ELSE
689	zcpy(ji,jj) = 0._wp
690	END IF
691	END_2D
692	CALL lbc_lnk( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
693	END IF
694
695	IF( kt == nit000 ) THEN
696	IF(lwp) WRITE(numout,*)
697	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
698	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
699	ENDIF
700
701	! Local constant initialization
702	zcoef0 = - grav * 0.5_wp
703	z_grav_10 = grav / 10._wp
704	z1_12 = 1.0_wp / 12._wp
705
706	!----------------------------------------------------------------------------------------
707	! 1. compute and store elementary vertical differences in provisional arrays
708	!----------------------------------------------------------------------------------------
709
710	!!bug gm Not a true bug, but... zdzz=e3w for zdzx, zdzy verify what it is really
711
712	DO_3D( 1, 1, 1, 1, 2, jpkm1 )
713	zdrhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
714	zdzz (ji,jj,jk) = - gde3w(ji ,jj ,jk) + gde3w(ji,jj,jk-1)
715	END_3D
716
717	!-------------------------------------------------------------------------
718	! 2. compute harmonic averages for vertical differences using eq. 5.18
719	!-------------------------------------------------------------------------
720	zep = 1.e-15
721
722	!! mb zdrho_k, zdz_k, zdrho_i, zdz_i, zdrho_j, zdz_j re-centred about the point (ji,jj,jk)
723	zdrho_k(:,:,:) = 0._wp
724	zdz_k (:,:,:) = 0._wp
725
726	DO_3D( 1, 1, 1, 1, 2, jpk-2 )
727	cffw = 2._wp * zdrhoz(ji ,jj ,jk) * zdrhoz(ji,jj,jk+1)
728	IF( cffw > zep) THEN
729	zdrho_k(ji,jj,jk) = cffw / ( zdrhoz(ji,jj,jk) + zdrhoz(ji,jj,jk+1) )
730	ENDIF
731	zdz_k(ji,jj,jk) = 2._wp * zdzz(ji,jj,jk) * zdzz(ji,jj,jk+1) &
732	& / ( zdzz(ji,jj,jk) + zdzz(ji,jj,jk+1) )
733	END_3D
734
735	!----------------------------------------------------------------------------------
736	! 3. apply boundary conditions at top and bottom using 5.36-5.37
737	!----------------------------------------------------------------------------------
738
739	! mb for sea-ice shelves we will need to re-write this upper boundary condition in the same form as the lower boundary condition
740	zdrho_k(:,:,1) = aco_bc_vrt * ( rhd (:,:,2) - rhd (:,:,1) ) - bco_bc_vrt * zdrho_k(:,:,2)
741	zdz_k (:,:,1) = aco_bc_vrt * (-gde3w(:,:,2) + gde3w(:,:,1) ) - bco_bc_vrt * zdz_k (:,:,2)
742
743	DO_2D( 1, 1, 1, 1 )
744	IF ( mbkt(ji,jj)>1 ) THEN
745	iktb = mbkt(ji,jj)
746	zdrho_k(ji,jj,iktb) = aco_bc_vrt * ( rhd(ji,jj,iktb) - rhd(ji,jj,iktb-1) ) - bco_bc_vrt * zdrho_k(ji,jj,iktb-1)
747	zdz_k (ji,jj,iktb) = aco_bc_vrt * (-gde3w(ji,jj,iktb) + gde3w(ji,jj,iktb-1) ) - bco_bc_vrt * zdz_k (ji,jj,iktb-1)
748	END IF
749	END_2D
750
751	!--------------------------------------------------------------
752	! 4. Compute side face integrals
753	!-------------------------------------------------------------
754
755	!! ssh replaces e3w_n ; gde3w is a depth; the formulae involve heights
756	!! rho_k stores grav * FX / rho_0
757
758	!--------------------------------------------------------------
759	! 4. a) Upper half of top-most grid box, compute and store
760	!-------------------------------------------------------------
761	! *** AY note: ssh(ji,jj,Kmm) + gde3w(ji,jj,1) = e3w(ji,jj,1,Kmm)
762	DO_2D( 0, 1, 0, 1)
763	z_rho_k(ji,jj,1) = grav * ( ssh(ji,jj,Kmm) + gde3w(ji,jj,1) ) &
764	& * ( rhd(ji,jj,1) &
765	& + 0.5_wp * ( rhd (ji,jj,2) - rhd (ji,jj,1) ) &
766	& * ( ssh (ji,jj,Kmm) + gde3w(ji,jj,1) ) &
767	& / ( - gde3w(ji,jj,2) + gde3w(ji,jj,1) ) )
768	END_2D
769
770	!--------------------------------------------------------------
771	! 4. b) Interior faces, compute and store
772	!-------------------------------------------------------------
773
774	DO_3D( 0, 1, 0, 1, 2, jpkm1 )
775	z_rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
776	& * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) ) &
777	& + z_grav_10 * ( &
778	& ( zdrho_k (ji,jj,jk) - zdrho_k (ji,jj,jk-1) ) &
779	& * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) - z1_12 * ( zdz_k (ji,jj,jk) + zdz_k (ji,jj,jk-1) ) ) &
780	& - ( zdz_k (ji,jj,jk) - zdz_k (ji,jj,jk-1) ) &
781	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( zdrho_k(ji,jj,jk) + zdrho_k(ji,jj,jk-1) ) ) &
782	& )
783	END_3D
784
785	!----------------------------------------------------------------------------------------
786	! 5. compute and store elementary horizontal differences in provisional arrays
787	!----------------------------------------------------------------------------------------
788
789	DO_3D( 1, 0, 1, 0, 1, jpkm1 )
790	zdrhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
791	zdzx (ji,jj,jk) = - gde3w(ji+1,jj ,jk) + gde3w(ji,jj,jk )
792	zdrhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
793	zdzy (ji,jj,jk) = - gde3w(ji ,jj+1,jk) + gde3w(ji,jj,jk )
794	END_3D
795
796	CALL lbc_lnk( 'dynhpg', zdrhox, 'U', 1._wp, zdzx, 'U', 1._wp, zdrhoy, 'V', 1._wp, zdzy, 'V', 1._wp )
797
798	!-------------------------------------------------------------------------
799	! 6. compute harmonic averages using eq. 5.18
800	!-------------------------------------------------------------------------
801
802	DO_3D( 0, 1, 0, 1, 1, jpkm1 )
803	cffu = 2._wp * zdrhox(ji-1,jj ,jk) * zdrhox(ji,jj,jk )
804	IF( cffu > zep ) THEN
805	zdrho_i(ji,jj,jk) = cffu / ( zdrhox(ji-1,jj,jk) + zdrhox(ji,jj,jk) )
806	ELSE
807	zdrho_i(ji,jj,jk ) = 0._wp
808	ENDIF
809
810	cffx = 2._wp * zdzx (ji-1,jj ,jk) * zdzx (ji,jj,jk )
811	IF( cffx > zep ) THEN
812	zdz_i(ji,jj,jk) = cffx / ( zdzx(ji-1,jj,jk) + zdzx(ji,jj,jk) )
813	ELSE
814	zdz_i(ji,jj,jk) = 0._wp
815	ENDIF
816
817	cffv = 2._wp * zdrhoy(ji ,jj-1,jk) * zdrhoy(ji,jj,jk )
818	IF( cffv > zep ) THEN
819	zdrho_j(ji,jj,jk) = cffv / ( zdrhoy(ji,jj-1,jk) + zdrhoy(ji,jj,jk) )
820	ELSE
821	zdrho_j(ji,jj,jk) = 0._wp
822	ENDIF
823
824	cffy = 2._wp * zdzy (ji ,jj-1,jk) * zdzy (ji,jj,jk )
825	IF( cffy > zep ) THEN
826	zdz_j(ji,jj,jk) = cffy / ( zdzy(ji,jj-1,jk) + zdzy(ji,jj,jk) )
827	ELSE
828	zdz_j(ji,jj,jk) = 0._wp
829	ENDIF
830	END_3D
831
832	!!! Note that zdzx, zdzy, zdzz, zdrhox, zdrhoy and zdrhoz should NOT be used beyond this point
833
834	!----------------------------------------------------------------------------------
835	! 6B. apply boundary conditions at side boundaries using 5.36-5.37
836	!----------------------------------------------------------------------------------
837
838	DO jk = 1, jpkm1
839	zz_drho_i(:,:) = zdrho_i(:,:,jk)
840	zz_dz_i (:,:) = zdz_i (:,:,jk)
841	zz_drho_j(:,:) = zdrho_j(:,:,jk)
842	zz_dz_j (:,:) = zdz_j (:,:,jk)
843	DO_2D( 0, 1, 0, 1)
844	! Walls coming from left: should check from 2 to jpi-1 (and jpj=2-jpj)
845	IF (ji < jpi) THEN
846	IF ( umask(ji,jj,jk) > 0.5_wp .AND. umask(ji-1,jj,jk) < 0.5_wp .AND. umask(ji+1,jj,jk) > 0.5_wp) THEN
847	zz_drho_i(ji,jj) = aco_bc_hor * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) ) - bco_bc_hor * zdrho_i(ji+1,jj,jk)
848	zz_dz_i (ji,jj) = aco_bc_hor * (-gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_i (ji+1,jj,jk)
849	END IF
850	END IF
851	! Walls coming from right: should check from 3 to jpi (and jpj=2-jpj)
852	IF (ji > 2) THEN
853	IF ( umask(ji,jj,jk) < 0.5_wp .AND. umask(ji-1,jj,jk) > 0.5_wp .AND. umask(ji-2,jj,jk) > 0.5_wp) THEN
854	zz_drho_i(ji,jj) = aco_bc_hor * ( rhd (ji,jj,jk) - rhd (ji-1,jj,jk) ) - bco_bc_hor * zdrho_i(ji-1,jj,jk)
855	zz_dz_i (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji-1,jj,jk) ) - bco_bc_hor * zdz_i (ji-1,jj,jk)
856	END IF
857	END IF
858	! Walls coming from left: should check from 2 to jpj-1 (and jpi=2-jpi)
859	IF (jj < jpj) THEN
860	IF ( vmask(ji,jj,jk) > 0.5_wp .AND. vmask(ji,jj-1,jk) < 0.5_wp .AND. vmask(ji,jj+1,jk) > 0.5_wp) THEN
861	zz_drho_j(ji,jj) = aco_bc_hor * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) ) - bco_bc_hor * zdrho_j(ji,jj+1,jk)
862	zz_dz_j (ji,jj) = aco_bc_hor * (-gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_j (ji,jj+1,jk)
863	END IF
864	END IF
865	! Walls coming from right: should check from 3 to jpj (and jpi=2-jpi)
866	IF (jj > 2) THEN
867	IF ( vmask(ji,jj,jk) < 0.5_wp .AND. vmask(ji,jj-1,jk) > 0.5_wp .AND. vmask(ji,jj-2,jk) > 0.5_wp) THEN
868	zz_drho_j(ji,jj) = aco_bc_hor * ( rhd (ji,jj,jk) - rhd (ji,jj-1,jk) ) - bco_bc_hor * zdrho_j(ji,jj-1,jk)
869	zz_dz_j (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji,jj-1,jk) ) - bco_bc_hor * zdz_j (ji,jj-1,jk)
870	END IF
871	END IF
872	END_2D
873	zdrho_i(:,:,jk) = zz_drho_i(:,:)
874	zdz_i (:,:,jk) = zz_dz_i (:,:)
875	zdrho_j(:,:,jk) = zz_drho_j(:,:)
876	zdz_j (:,:,jk) = zz_dz_j (:,:)
877	END DO
878
879	!--------------------------------------------------------------
880	! 7. Calculate integrals on side faces
881	!-------------------------------------------------------------
882
883	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
884	! two -ve signs cancel in next two lines (within zcoef0 and because gde3w is a depth not a height)
885	z_rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
886	& * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) )
887	IF ( umask(ji-1, jj, jk) > 0.5 .OR. umask(ji+1, jj, jk) > 0.5 ) THEN
888	z_rho_i(ji,jj,jk) = z_rho_i(ji,jj,jk) - z_grav_10 * ( &
889	& ( zdrho_i (ji+1,jj,jk) - zdrho_i (ji,jj,jk) ) &
890	& * ( - gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_i (ji+1,jj,jk) + zdz_i (ji,jj,jk) ) ) &
891	& - ( zdz_i (ji+1,jj,jk) - zdz_i (ji,jj,jk) ) &
892	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( zdrho_i(ji+1,jj,jk) + zdrho_i(ji,jj,jk) ) ) &
893	& )
894	END IF
895
896	z_rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
897	& * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) )
898	IF ( vmask(ji, jj-1, jk) > 0.5 .OR. vmask(ji, jj+1, jk) > 0.5 ) THEN
899	z_rho_j(ji,jj,jk) = z_rho_j(ji,jj,jk) - z_grav_10 * ( &
900	& ( zdrho_j (ji,jj+1,jk) - zdrho_j (ji,jj,jk) ) &
901	& * ( - gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_j (ji,jj+1,jk) + zdz_j (ji,jj,jk) ) ) &
902	& - ( zdz_j (ji,jj+1,jk) - zdz_j (ji,jj,jk) ) &
903	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( zdrho_j(ji,jj+1,jk) + zdrho_j(ji,jj,jk) ) ) &
904	& )
905	END IF
906	END_3D
907
908	!--------------------------------------------------------------
909	! 8. Integrate in the vertical
910	!-------------------------------------------------------------
911	!
912	! ---------------
913	! Surface value
914	! ---------------
915	DO_2D( 0, 0, 0, 0 )
916	zhpi(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji+1,jj ,1) - z_rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
917	zhpj(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji ,jj+1,1) - z_rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
918	IF( ln_wd_il ) THEN
919	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
920	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
921	ENDIF
922	! add to the general momentum trend
923	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
924	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
925	END_2D
926
927	! ----------------
928	! interior value (2=<jk=<jpkm1)
929	! ----------------
930	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
931	! hydrostatic pressure gradient along s-surfaces
932	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
933	& + ( ( z_rho_k(ji,jj,jk) - z_rho_k(ji+1,jj,jk ) ) &
934	& - ( z_rho_i(ji,jj,jk) - z_rho_i(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
935	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
936	& + ( ( z_rho_k(ji,jj,jk) - z_rho_k(ji,jj+1,jk ) ) &
937	& -( z_rho_j(ji,jj,jk) - z_rho_j(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
938	IF( ln_wd_il ) THEN
939	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
940	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
941	ENDIF
942	! add to the general momentum trend
943	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
944	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
945	END_3D
946	!
947	IF( ln_wd_il ) DEALLOCATE( zcpx, zcpy )
948	!
949	END SUBROUTINE hpg_djc
950
951
952	SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
953	!!---------------------------------------------------------------------
954	!! * ROUTINE hpg_prj *
955	!!
956	!! ** Method : s-coordinate case.
957	!! A Pressure-Jacobian horizontal pressure gradient method
958	!! based on the constrained cubic-spline interpolation for
959	!! all vertical coordinate systems
960	!!
961	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
962	!!----------------------------------------------------------------------
963	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
964	INTEGER , INTENT( in ) :: kt ! ocean time-step index
965	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
966	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
967	!!
968	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
969	REAL(wp) :: zcoef0, znad ! local scalars
970	!
971	!! The local variables for the correction term
972	INTEGER :: jk1, jis, jid, jjs, jjd
973	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
974	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
975	REAL(wp) :: zrhdt1
976	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
977	REAL(wp), DIMENSION(jpi,jpj) :: zpgu, zpgv ! 2D workspace
978	REAL(wp), DIMENSION(jpi,jpj) :: zsshu_n, zsshv_n
979	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdept, zrhh
980	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
981	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
982	!!----------------------------------------------------------------------
983	!
984	IF( kt == nit000 ) THEN
985	IF(lwp) WRITE(numout,*)
986	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
987	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
988	ENDIF
989
990	! Local constant initialization
991	zcoef0 = - grav
992	znad = 1._wp
993	IF( ln_linssh ) znad = 1._wp
994	!
995	! ---------------
996	! Surface pressure gradient to be removed
997	! ---------------
998	DO_2D( 0, 0, 0, 0 )
999	zpgu(ji,jj) = - grav * ( ssh(ji+1,jj,Kmm) - ssh(ji,jj,Kmm) ) * r1_e1u(ji,jj)
1000	zpgv(ji,jj) = - grav * ( ssh(ji,jj+1,Kmm) - ssh(ji,jj,Kmm) ) * r1_e2v(ji,jj)
1001	END_2D
1002	!
1003	IF( ln_wd_il ) THEN
1004	ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
1005	DO_2D( 0, 0, 0, 0 )
1006	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
1007	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
1008	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
1009	& > rn_wdmin1 + rn_wdmin2
1010	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
1011	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
1012	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
1013
1014	IF(ll_tmp1) THEN
1015	zcpx(ji,jj) = 1.0_wp
1016	ELSE IF(ll_tmp2) THEN
1017	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
1018	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1019	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
1020
1021	zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
1022	ELSE
1023	zcpx(ji,jj) = 0._wp
1024	END IF
1025
1026	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
1027	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
1028	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
1029	& > rn_wdmin1 + rn_wdmin2
1030	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
1031	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
1032	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
1033
1034	IF(ll_tmp1) THEN
1035	zcpy(ji,jj) = 1.0_wp
1036	ELSE IF(ll_tmp2) THEN
1037	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
1038	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1039	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
1040	zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1041
1042	ELSE
1043	zcpy(ji,jj) = 0._wp
1044	ENDIF
1045	END_2D
1046	CALL lbc_lnk( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
1047	ENDIF
1048
1049	! Clean 3-D work arrays
1050	zhpi(:,:,:) = 0._wp
1051	zrhh(:,:,:) = rhd(:,:,:)
1052
1053	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1054	DO_2D( 1, 1, 1, 1 )
1055	jk = mbkt(ji,jj)
1056	IF( jk <= 1 ) THEN ; zrhh(ji,jj, : ) = 0._wp
1057	ELSEIF( jk == 2 ) THEN ; zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1058	ELSEIF( jk < jpkm1 ) THEN
1059	DO jkk = jk+1, jpk
1060	zrhh(ji,jj,jkk) = interp1(CASTWP(gde3w(ji,jj,jkk )), CASTWP(gde3w(ji,jj,jkk-1)), &
1061	& CASTWP(gde3w(ji,jj,jkk-2)), zrhh (ji,jj,jkk-1), zrhh(ji,jj,jkk-2))
1062	END DO
1063	ENDIF
1064	END_2D
1065
1066	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1067	DO_2D( 1, 1, 1, 1 )
1068	zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm)
1069	END_2D
1070
1071	DO_3D( 1, 1, 1, 1, 2, jpk )
1072	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
1073	END_3D
1074
1075	fsp(:,:,:) = zrhh (:,:,:)
1076	xsp(:,:,:) = zdept(:,:,:)
1077
1078	! Construct the vertical density profile with the
1079	! constrained cubic spline interpolation
1080	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1081	CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1082
1083	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1084	DO_2D( 0, 1, 0, 1 )
1085	zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1), &
1086	& csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
1087
1088	! assuming linear profile across the top half surface layer
1089	zhpi(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
1090	END_2D
1091
1092	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1093	DO_3D( 0, 1, 0, 1, 2, jpkm1 )
1094	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1095	& integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk), &
1096	& asp (ji,jj,jk-1), bsp (ji,jj,jk-1), &
1097	& csp (ji,jj,jk-1), dsp (ji,jj,jk-1) )
1098	END_3D
1099
1100	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1101
1102	! Prepare zsshu_n and zsshv_n
1103	DO_2D( 0, 0, 0, 0 )
1104	!!gm BUG ? if it is ssh at u- & v-point then it should be:
1105	! zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1106	! & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1107	! zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1108	! & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1109	!!gm not this:
1110	zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1111	& r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1112	zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1113	& r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1114	END_2D
1115
1116	CALL lbc_lnk ('dynhpg', zsshu_n, 'U', 1.0_wp, zsshv_n, 'V', 1.0_wp )
1117
1118	DO_2D( 0, 0, 0, 0 )
1119	zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) )
1120	zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) )
1121	END_2D
1122
1123	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
1124	zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1125	zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1126	END_3D
1127
1128	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1129	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1130	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1131	END_3D
1132
1133	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1134	zu(ji,jj,jk) = MIN( zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1135	zu(ji,jj,jk) = MAX( zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1136	zv(ji,jj,jk) = MIN( zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1137	zv(ji,jj,jk) = MAX( zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1138	END_3D
1139
1140
1141	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1142	zpwes = 0._wp; zpwed = 0._wp
1143	zpnss = 0._wp; zpnsd = 0._wp
1144	zuijk = zu(ji,jj,jk)
1145	zvijk = zv(ji,jj,jk)
1146
1147	!!!!! for u equation
1148	IF( jk <= mbku(ji,jj) ) THEN
1149	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1150	jis = ji + 1; jid = ji
1151	ELSE
1152	jis = ji; jid = ji +1
1153	ENDIF
1154
1155	! integrate the pressure on the shallow side
1156	jk1 = jk
1157	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1158	IF( jk1 == mbku(ji,jj) ) THEN
1159	zuijk = -zdept(jis,jj,jk1)
1160	EXIT
1161	ENDIF
1162	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1163	zpwes = zpwes + &
1164	integ_spline(zdept(jis,jj,jk1), zdeps, &
1165	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1166	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1167	jk1 = jk1 + 1
1168	END DO
1169
1170	! integrate the pressure on the deep side
1171	jk1 = jk
1172	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1173	IF( jk1 == 1 ) THEN
1174	zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1175	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1176	bsp(jid,jj,1), csp(jid,jj,1), &
1177	dsp(jid,jj,1)) * zdeps
1178	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1179	EXIT
1180	ENDIF
1181	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1182	zpwed = zpwed + &
1183	integ_spline(zdeps, zdept(jid,jj,jk1), &
1184	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1185	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1186	jk1 = jk1 - 1
1187	END DO
1188
1189	! update the momentum trends in u direction
1190
1191	zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1192	IF( .NOT.ln_linssh ) THEN
1193	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1194	& ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1195	ELSE
1196	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1197	ENDIF
1198	IF( ln_wd_il ) THEN
1199	zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1200	zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1201	ENDIF
1202	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2 - zpgu(ji,jj)) * umask(ji,jj,jk)
1203	ENDIF
1204
1205	!!!!! for v equation
1206	IF( jk <= mbkv(ji,jj) ) THEN
1207	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1208	jjs = jj + 1; jjd = jj
1209	ELSE
1210	jjs = jj ; jjd = jj + 1
1211	ENDIF
1212
1213	! integrate the pressure on the shallow side
1214	jk1 = jk
1215	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1216	IF( jk1 == mbkv(ji,jj) ) THEN
1217	zvijk = -zdept(ji,jjs,jk1)
1218	EXIT
1219	ENDIF
1220	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1221	zpnss = zpnss + &
1222	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1223	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1224	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1225	jk1 = jk1 + 1
1226	END DO
1227
1228	! integrate the pressure on the deep side
1229	jk1 = jk
1230	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1231	IF( jk1 == 1 ) THEN
1232	zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1233	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1234	bsp(ji,jjd,1), csp(ji,jjd,1), &
1235	dsp(ji,jjd,1) ) * zdeps
1236	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1237	EXIT
1238	ENDIF
1239	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1240	zpnsd = zpnsd + &
1241	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1242	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1243	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1244	jk1 = jk1 - 1
1245	END DO
1246
1247
1248	! update the momentum trends in v direction
1249
1250	zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1251	IF( .NOT.ln_linssh ) THEN
1252	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1253	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1254	ELSE
1255	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1256	ENDIF
1257	IF( ln_wd_il ) THEN
1258	zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj)
1259	zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj)
1260	ENDIF
1261
1262	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2 - zpgv(ji,jj)) * vmask(ji,jj,jk)
1263	ENDIF
1264	!
1265	END_3D
1266	!
1267	IF( ln_wd_il ) DEALLOCATE( zcpx, zcpy )
1268	!
1269	END SUBROUTINE hpg_prj
1270
1271
1272	SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1273	!!----------------------------------------------------------------------
1274	!! * ROUTINE cspline *
1275	!!
1276	!! ** Purpose : constrained cubic spline interpolation
1277	!!
1278	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1279	!!
1280	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1281	!!----------------------------------------------------------------------
1282	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: fsp, xsp ! value and coordinate
1283	REAL(wp), DIMENSION(:,:,:), INTENT( out) :: asp, bsp, csp, dsp ! coefficients of the interpoated function
1284	INTEGER , INTENT(in ) :: polynomial_type ! 1: cubic spline ; 2: Linear
1285	!
1286	INTEGER :: ji, jj, jk ! dummy loop indices
1287	INTEGER :: jpi, jpj, jpkm1
1288	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1289	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1290	REAL(wp) :: zdf(size(fsp,3))
1291	!!----------------------------------------------------------------------
1292	!
1293	!!gm WHAT !!!!! THIS IS VERY DANGEROUS !!!!!
1294	jpi = size(fsp,1)
1295	jpj = size(fsp,2)
1296	jpkm1 = MAX( 1, size(fsp,3) - 1 )
1297	!
1298	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1299	DO ji = 1, jpi
1300	DO jj = 1, jpj
1301	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1302	! DO jk = 2, jpkm1-1
1303	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1304	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1305	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1306	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1307	!
1308	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1309	!
1310	! IF(zdf1 * zdf2 <= 0._wp) THEN
1311	! zdf(jk) = 0._wp
1312	! ELSE
1313	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1314	! ENDIF
1315	! END DO
1316
1317	!!Simply geometric average
1318	DO jk = 2, jpkm1-1
1319	zdf1 = (fsp(ji,jj,jk ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk ) - xsp(ji,jj,jk-1))
1320	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk ))
1321
1322	IF(zdf1 * zdf2 <= 0._wp) THEN
1323	zdf(jk) = 0._wp
1324	ELSE
1325	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1326	ENDIF
1327	END DO
1328
1329	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1330	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1331	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1332	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1333
1334	DO jk = 1, jpkm1 - 1
1335	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1336	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1337	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1338	zddf1 = -2._wp * ztmp1 + ztmp2
1339	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1340	zddf2 = 2._wp * ztmp1 - ztmp2
1341
1342	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1343	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1344	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1345	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1346	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1347	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1348	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1349	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1350	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1351	END DO
1352	END DO
1353	END DO
1354
1355	ELSEIF ( polynomial_type == 2 ) THEN ! Linear
1356	DO ji = 1, jpi
1357	DO jj = 1, jpj
1358	DO jk = 1, jpkm1-1
1359	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1360	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1361
1362	dsp(ji,jj,jk) = 0._wp
1363	csp(ji,jj,jk) = 0._wp
1364	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1365	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1366	END DO
1367	END DO
1368	END DO
1369	!
1370	ELSE
1371	CALL ctl_stop( 'invalid polynomial type in cspline' )
1372	ENDIF
1373	!
1374	END SUBROUTINE cspline
1375
1376
1377	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1378	!!----------------------------------------------------------------------
1379	!! * ROUTINE interp1 *
1380	!!
1381	!! ** Purpose : 1-d linear interpolation
1382	!!
1383	!! ** Method : interpolation is straight forward
1384	!! extrapolation is also permitted (no value limit)
1385	!!----------------------------------------------------------------------
1386	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1387	REAL(wp) :: f ! result of the interpolation (extrapolation)
1388	REAL(wp) :: zdeltx
1389	!!----------------------------------------------------------------------
1390	!
1391	zdeltx = xr - xl
1392	IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1393	f = 0.5_wp * (fl + fr)
1394	ELSE
1395	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1396	ENDIF
1397	!
1398	END FUNCTION interp1
1399
1400
1401	FUNCTION interp2( x, a, b, c, d ) RESULT(f)
1402	!!----------------------------------------------------------------------
1403	!! * ROUTINE interp1 *
1404	!!
1405	!! ** Purpose : 1-d constrained cubic spline interpolation
1406	!!
1407	!! ** Method : cubic spline interpolation
1408	!!
1409	!!----------------------------------------------------------------------
1410	REAL(wp), INTENT(in) :: x, a, b, c, d
1411	REAL(wp) :: f ! value from the interpolation
1412	!!----------------------------------------------------------------------
1413	!
1414	f = a + x* ( b + x * ( c + d * x ) )
1415	!
1416	END FUNCTION interp2
1417
1418
1419	FUNCTION interp3( x, a, b, c, d ) RESULT(f)
1420	!!----------------------------------------------------------------------
1421	!! * ROUTINE interp1 *
1422	!!
1423	!! ** Purpose : Calculate the first order of derivative of
1424	!! a cubic spline function y=a+bx+cx^2+d*x^3
1425	!!
1426	!! ** Method : f=dy/dx=b+2cx+3dx^2
1427	!!
1428	!!----------------------------------------------------------------------
1429	REAL(wp), INTENT(in) :: x, a, b, c, d
1430	REAL(wp) :: f ! value from the interpolation
1431	!!----------------------------------------------------------------------
1432	!
1433	f = b + x * ( 2._wp * c + 3._wp * d * x)
1434	!
1435	END FUNCTION interp3
1436
1437
1438	FUNCTION integ_spline( xl, xr, a, b, c, d ) RESULT(f)
1439	!!----------------------------------------------------------------------
1440	!! * ROUTINE interp1 *
1441	!!
1442	!! ** Purpose : 1-d constrained cubic spline integration
1443	!!
1444	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1445	!!
1446	!!----------------------------------------------------------------------
1447	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1448	REAL(wp) :: za1, za2, za3
1449	REAL(wp) :: f ! integration result
1450	!!----------------------------------------------------------------------
1451	!
1452	za1 = 0.5_wp * b
1453	za2 = c / 3.0_wp
1454	za3 = 0.25_wp * d
1455	!
1456	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1457	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1458	!
1459	END FUNCTION integ_spline
1460
1461	!!======================================================================
1462	END MODULE dynhpg

Note: See TracBrowser for help on using the repository browser.

Download in other formats: