1 | MODULE sbcfwb |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE sbcfwb *** |
---|
4 | !! Ocean fluxes : domain averaged freshwater budget |
---|
5 | !!====================================================================== |
---|
6 | !! History : OPA ! 2001-02 (E. Durand) Original code |
---|
7 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
---|
8 | !! 3.0 ! 2006-08 (G. Madec) Surface module |
---|
9 | !! 3.2 ! 2009-07 (C. Talandier) emp mean s spread over erp area |
---|
10 | !! 3.6 ! 2014-11 (P. Mathiot ) add ice shelf melting |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! sbc_fwb : freshwater budget for global ocean configurations (free surface & forced mode) |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | USE oce ! ocean dynamics and tracers |
---|
17 | USE dom_oce ! ocean space and time domain |
---|
18 | USE sbc_oce ! surface ocean boundary condition |
---|
19 | USE isf_oce , ONLY : fwfisf_cav, fwfisf_par ! ice shelf melting contribution |
---|
20 | USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass |
---|
21 | USE phycst ! physical constants |
---|
22 | USE sbcrnf ! ocean runoffs |
---|
23 | USE sbcssr ! Sea-Surface damping terms |
---|
24 | ! |
---|
25 | USE in_out_manager ! I/O manager |
---|
26 | USE iom ! IOM |
---|
27 | USE lib_mpp ! distribued memory computing library |
---|
28 | USE timing ! Timing |
---|
29 | USE lbclnk ! ocean lateral boundary conditions |
---|
30 | USE lib_fortran ! |
---|
31 | |
---|
32 | IMPLICIT NONE |
---|
33 | PRIVATE |
---|
34 | |
---|
35 | PUBLIC sbc_fwb ! routine called by step |
---|
36 | |
---|
37 | REAL(wp) :: rn_fwb0 ! initial freshwater adjustment flux [kg/m2/s] (nn_fwb = 2 only) |
---|
38 | REAL(wp) :: a_fwb ! annual domain averaged freshwater budget from the |
---|
39 | ! previous year |
---|
40 | REAL(wp) :: area ! global mean ocean surface (interior domain) |
---|
41 | |
---|
42 | # include "single_precision_substitute.h90" |
---|
43 | |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
46 | !! $Id$ |
---|
47 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
48 | !!---------------------------------------------------------------------- |
---|
49 | CONTAINS |
---|
50 | |
---|
51 | SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc, Kmm ) |
---|
52 | !!--------------------------------------------------------------------- |
---|
53 | !! *** ROUTINE sbc_fwb *** |
---|
54 | !! |
---|
55 | !! ** Purpose : Control the mean sea surface drift |
---|
56 | !! |
---|
57 | !! ** Method : several ways depending on kn_fwb |
---|
58 | !! =0 no control |
---|
59 | !! =1 global mean of emp set to zero at each nn_fsbc time step |
---|
60 | !! =2 annual global mean corrected from previous year |
---|
61 | !! =3 global mean of emp set to zero at each nn_fsbc time step |
---|
62 | !! & spread out over erp area depending its sign |
---|
63 | !! Note: if sea ice is embedded it is taken into account when computing the budget |
---|
64 | !!---------------------------------------------------------------------- |
---|
65 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
66 | INTEGER, INTENT( in ) :: kn_fsbc ! |
---|
67 | INTEGER, INTENT( in ) :: kn_fwb ! ocean time-step index |
---|
68 | INTEGER, INTENT( in ) :: Kmm ! ocean time level index |
---|
69 | ! |
---|
70 | INTEGER :: ios, inum, ikty ! local integers |
---|
71 | REAL(wp) :: z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp ! local scalars |
---|
72 | REAL(wp) :: zsurf_neg, zsurf_pos, zsurf_tospread, zcoef ! - - |
---|
73 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces |
---|
74 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: ztmsk_tospread, zerp_cor ! - - |
---|
75 | REAL(wp) ,DIMENSION(1) :: z_fwfprv |
---|
76 | COMPLEX(dp),DIMENSION(1) :: y_fwfnow |
---|
77 | ! |
---|
78 | NAMELIST/namsbc_fwb/rn_fwb0 |
---|
79 | !!---------------------------------------------------------------------- |
---|
80 | ! |
---|
81 | IF( kt == nit000 ) THEN |
---|
82 | READ( numnam_ref, namsbc_fwb, IOSTAT = ios, ERR = 901 ) |
---|
83 | 901 IF( ios /= 0 ) CALL ctl_nam( ios, 'namsbc_fwb in reference namelist' ) |
---|
84 | READ( numnam_cfg, namsbc_fwb, IOSTAT = ios, ERR = 902 ) |
---|
85 | 902 IF( ios > 0 ) CALL ctl_nam( ios, 'namsbc_fwb in configuration namelist' ) |
---|
86 | IF(lwm) WRITE( numond, namsbc_fwb ) |
---|
87 | IF(lwp) THEN |
---|
88 | WRITE(numout,*) |
---|
89 | WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction' |
---|
90 | WRITE(numout,*) '~~~~~~~' |
---|
91 | IF( kn_fwb == 1 ) WRITE(numout,*) ' instantaneously set to zero' |
---|
92 | IF( kn_fwb == 3 ) WRITE(numout,*) ' fwf set to zero and spread out over erp area' |
---|
93 | IF( kn_fwb == 2 ) THEN |
---|
94 | WRITE(numout,*) ' adjusted from previous year budget' |
---|
95 | WRITE(numout,*) |
---|
96 | WRITE(numout,*) ' Namelist namsbc_fwb' |
---|
97 | WRITE(numout,*) ' Initial freshwater adjustment flux [kg/m2/s] = ', rn_fwb0 |
---|
98 | END IF |
---|
99 | ENDIF |
---|
100 | ! |
---|
101 | IF( kn_fwb == 3 .AND. nn_sssr /= 2 ) CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' ) |
---|
102 | IF( kn_fwb == 3 .AND. ln_isfcav ) CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' ) |
---|
103 | ! |
---|
104 | area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1)) ! interior global domain surface |
---|
105 | ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes |
---|
106 | ! and in case of no melt, it can generate HSSW. |
---|
107 | ! |
---|
108 | #if ! defined key_si3 && ! defined key_cice |
---|
109 | snwice_mass_b(:,:) = 0.e0 ! no sea-ice model is being used : no snow+ice mass |
---|
110 | snwice_mass (:,:) = 0.e0 |
---|
111 | snwice_fmass (:,:) = 0.e0 |
---|
112 | #endif |
---|
113 | ! |
---|
114 | ENDIF |
---|
115 | |
---|
116 | SELECT CASE ( kn_fwb ) |
---|
117 | ! |
---|
118 | CASE ( 1 ) !== global mean fwf set to zero ==! |
---|
119 | ! |
---|
120 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN |
---|
121 | y_fwfnow(1) = local_sum( CASTWP(e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) )) ) |
---|
122 | CALL mpp_delay_sum( 'sbcfwb', 'fwb', y_fwfnow(:), z_fwfprv(:), kt == nitend - nn_fsbc + 1 ) |
---|
123 | z_fwfprv(1) = z_fwfprv(1) / area |
---|
124 | zcoef = z_fwfprv(1) * rcp |
---|
125 | emp(:,:) = emp(:,:) - z_fwfprv(1) * tmask(:,:,1) |
---|
126 | qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction |
---|
127 | ENDIF |
---|
128 | ! |
---|
129 | CASE ( 2 ) !== fw adjustment based on fw budget at the end of the previous year ==! |
---|
130 | ! |
---|
131 | IF( kt == nit000 ) THEN ! initialisation |
---|
132 | ! ! set the fw adjustment (a_fwb) |
---|
133 | IF ( ln_rstart .AND. iom_varid( numror, 'a_fwb', ldstop = .FALSE. ) > 0 ) THEN ! as read from restart file |
---|
134 | IF(lwp) WRITE(numout,*) 'sbc_fwb : reading FW-budget adjustment from restart file' |
---|
135 | CALL iom_get( numror, 'a_fwb', a_fwb ) |
---|
136 | ELSE ! as specified in namelist |
---|
137 | a_fwb = rn_fwb0 |
---|
138 | END IF |
---|
139 | ! |
---|
140 | IF(lwp)WRITE(numout,*) |
---|
141 | IF(lwp)WRITE(numout,*)'sbc_fwb : initial freshwater-budget adjustment = ', a_fwb, 'kg/m2/s' |
---|
142 | ! |
---|
143 | ENDIF |
---|
144 | ! ! Update a_fwb if new year start |
---|
145 | ikty = 365 * 86400 / rn_Dt !!bug use of 365 days leap year or 360d year !!!!!!! |
---|
146 | IF( MOD( kt, ikty ) == 0 ) THEN |
---|
147 | ! mean sea level taking into account the ice+snow |
---|
148 | ! sum over the global domain |
---|
149 | a_fwb = glob_sum( 'sbcfwb', e1e2t(:,:) * ( ssh(:,:,Kmm) + snwice_mass(:,:) * r1_rho0 ) ) |
---|
150 | a_fwb = a_fwb * 1.e+3 / ( area * rday * 365. ) ! convert in Kg/m3/s = mm/s |
---|
151 | !!gm ! !!bug 365d year |
---|
152 | ENDIF |
---|
153 | ! |
---|
154 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN ! correct the freshwater fluxes |
---|
155 | zcoef = a_fwb * rcp |
---|
156 | emp(:,:) = emp(:,:) + a_fwb * tmask(:,:,1) |
---|
157 | qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction |
---|
158 | ENDIF |
---|
159 | ! Output restart information |
---|
160 | IF( lrst_oce ) THEN |
---|
161 | IF(lwp) WRITE(numout,*) |
---|
162 | IF(lwp) WRITE(numout,*) 'sbc_fwb : writing FW-budget adjustment to ocean restart file at it = ', kt |
---|
163 | IF(lwp) WRITE(numout,*) '~~~~' |
---|
164 | CALL iom_rstput( kt, nitrst, numrow, 'a_fwb', a_fwb ) |
---|
165 | END IF |
---|
166 | ! |
---|
167 | IF( kt == nitend .AND. lwp ) WRITE(numout,*) 'sbc_fwb : final freshwater-budget adjustment = ', a_fwb, 'kg/m2/s' |
---|
168 | ! |
---|
169 | CASE ( 3 ) !== global fwf set to zero and spread out over erp area ==! |
---|
170 | ! |
---|
171 | ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) ) |
---|
172 | ! |
---|
173 | IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN |
---|
174 | ztmsk_pos(:,:) = tmask_i(:,:) ! Select <0 and >0 area of erp |
---|
175 | WHERE( erp < 0._wp ) ztmsk_pos = 0._wp |
---|
176 | ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:) |
---|
177 | ! ! fwf global mean (excluding ocean to ice/snow exchanges) |
---|
178 | z_fwf = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) ) / area |
---|
179 | ! |
---|
180 | IF( z_fwf < 0._wp ) THEN ! spread out over >0 erp area to increase evaporation |
---|
181 | zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) ) |
---|
182 | zsurf_tospread = zsurf_pos |
---|
183 | ztmsk_tospread(:,:) = ztmsk_pos(:,:) |
---|
184 | ELSE ! spread out over <0 erp area to increase precipitation |
---|
185 | zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) ) ! Area filled by <0 and >0 erp |
---|
186 | zsurf_tospread = zsurf_neg |
---|
187 | ztmsk_tospread(:,:) = ztmsk_neg(:,:) |
---|
188 | ENDIF |
---|
189 | ! |
---|
190 | zsum_fwf = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf ) ! fwf global mean over <0 or >0 erp area |
---|
191 | !!gm : zsum_fwf = z_fwf * area ??? it is right? I think so.... |
---|
192 | z_fwf_nsrf = zsum_fwf / ( zsurf_tospread + rsmall ) |
---|
193 | ! ! weight to respect erp field 2D structure |
---|
194 | zsum_erp = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) ) |
---|
195 | z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall ) |
---|
196 | ! ! final correction term to apply |
---|
197 | zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:) |
---|
198 | ! |
---|
199 | !!gm ===>>>> lbc_lnk should be useless as all the computation is done over the whole domain ! |
---|
200 | CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1.0_wp ) |
---|
201 | ! |
---|
202 | emp(:,:) = emp(:,:) + zerp_cor(:,:) |
---|
203 | qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:) ! account for change to the heat budget due to fw correction |
---|
204 | erp(:,:) = erp(:,:) + zerp_cor(:,:) |
---|
205 | ! |
---|
206 | IF( lwp ) THEN ! control print |
---|
207 | IF( z_fwf < 0._wp ) THEN |
---|
208 | WRITE(numout,*)' z_fwf < 0' |
---|
209 | WRITE(numout,*)' SUM(erp+) = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv' |
---|
210 | ELSE |
---|
211 | WRITE(numout,*)' z_fwf >= 0' |
---|
212 | WRITE(numout,*)' SUM(erp-) = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv' |
---|
213 | ENDIF |
---|
214 | WRITE(numout,*)' SUM(empG) = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv' |
---|
215 | WRITE(numout,*)' z_fwf = ', z_fwf ,' Kg/m2/s' |
---|
216 | WRITE(numout,*)' z_fwf_nsrf = ', z_fwf_nsrf ,' Kg/m2/s' |
---|
217 | WRITE(numout,*)' MIN(zerp_cor) = ', MINVAL(zerp_cor) |
---|
218 | WRITE(numout,*)' MAX(zerp_cor) = ', MAXVAL(zerp_cor) |
---|
219 | ENDIF |
---|
220 | ENDIF |
---|
221 | DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor ) |
---|
222 | ! |
---|
223 | CASE DEFAULT !== you should never be there ==! |
---|
224 | CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' ) |
---|
225 | ! |
---|
226 | END SELECT |
---|
227 | ! |
---|
228 | END SUBROUTINE sbc_fwb |
---|
229 | |
---|
230 | !!====================================================================== |
---|
231 | END MODULE sbcfwb |
---|