New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/TRA/traadv_fct.F90 @ 14286

Last change on this file since 14286 was 14219, checked in by mcastril, 3 years ago

Add Mixed Precision support by Oriol Tintó
  • Property svn:keywords set to Id
File size: 36.6 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36   PUBLIC   tridia_solver      ! called by traadv_fct_lf.F90
37   PUBLIC   nonosc             ! called by traadv_fct_lf.F90 - key_agrif
38
39   LOGICAL  ::   l_trd   ! flag to compute trends
40   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
41   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
42   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
43
44   !                                        ! tridiag solver associated indices:
45   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
46   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
47
48   !! * Substitutions
49#  include "do_loop_substitute.h90"
50#  include "domzgr_substitute.h90"
51#  include "single_precision_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
54   !! $Id$
55   !! Software governed by the CeCILL license (see ./LICENSE)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
60      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
61      !!----------------------------------------------------------------------
62      !!                  ***  ROUTINE tra_adv_fct  ***
63      !!
64      !! **  Purpose :   Compute the now trend due to total advection of tracers
65      !!               and add it to the general trend of tracer equations
66      !!
67      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
68      !!               (choice through the value of kn_fct)
69      !!               - on the vertical the 4th order is a compact scheme
70      !!               - corrected flux (monotonic correction)
71      !!
72      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
73      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
74      !!             - poleward advective heat and salt transport (ln_diaptr=T)
75      !!----------------------------------------------------------------------
76      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
77      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
78      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
79      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
80      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
81      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
82      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
83      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
84      ! TEMP: [tiling] This can be A2D(nn_hls) if using XIOS (subdomain support)
85      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
86      REAL(dp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
87      !
88      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices
89      REAL(wp) ::   ztra                                     ! local scalar
90      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
91      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
92      REAL(dp), DIMENSION(jpi,jpj,jpk)        ::   zwx, zwy, zwz
93      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, ztu, ztv, zltu, zltv, ztw
94      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
95      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
96      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
97      !!----------------------------------------------------------------------
98      !
99      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
100         IF( kt == kit000 )  THEN
101            IF(lwp) WRITE(numout,*)
102            IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
103            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
104         ENDIF
105         !
106         l_trd = .FALSE.            ! set local switches
107         l_hst = .FALSE.
108         l_ptr = .FALSE.
109         ll_zAimp = .FALSE.
110         IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
111         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE.
112         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
113            &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
114         !
115      ENDIF
116
117      !! -- init to 0
118      zwi(:,:,:) = 0._wp
119      zwx(:,:,:) = 0._wp
120      zwy(:,:,:) = 0._wp
121      zwz(:,:,:) = 0._wp
122      ztu(:,:,:) = 0._wp
123      ztv(:,:,:) = 0._wp
124      zltu(:,:,:) = 0._wp
125      zltv(:,:,:) = 0._wp
126      ztw(:,:,:) = 0._wp
127      !
128      IF( l_trd .OR. l_hst )  THEN
129         ALLOCATE( ztrdx(A2D(nn_hls),jpk), ztrdy(A2D(nn_hls),jpk), ztrdz(A2D(nn_hls),jpk) )
130         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
131      ENDIF
132      !
133      IF( l_ptr ) THEN
134         ALLOCATE( zptry(A2D(nn_hls),jpk) )
135         zptry(:,:,:) = 0._wp
136      ENDIF
137      !
138      ! If adaptive vertical advection, check if it is needed on this PE at this time
139      IF( ln_zad_Aimp ) THEN
140         IF( MAXVAL( ABS( wi(A2D(nn_hls),:) ) ) > 0._wp ) ll_zAimp = .TRUE.
141      END IF
142      ! If active adaptive vertical advection, build tridiagonal matrix
143      IF( ll_zAimp ) THEN
144         ALLOCATE(zwdia(A2D(nn_hls),jpk), zwinf(A2D(nn_hls),jpk), zwsup(A2D(nn_hls),jpk))
145         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
146            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
147            &                               / e3t(ji,jj,jk,Krhs)
148            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
149            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
150         END_3D
151      END IF
152      !
153      DO jn = 1, kjpt            !==  loop over the tracers  ==!
154         !
155         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
156         !                    !* upstream tracer flux in the i and j direction
157         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
158            ! upstream scheme
159            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
160            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
161            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
162            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
163            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
164            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
165         END_3D
166         !                               !* upstream tracer flux in the k direction *!
167         DO_3D( 1, 1, 1, 1, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
168            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
169            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
170            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
171         END_3D
172         IF( ln_linssh ) THEN               ! top ocean value (only in linear free surface as zwz has been w-masked)
173            IF( ln_isfcav ) THEN                        ! top of the ice-shelf cavities and at the ocean surface
174               DO_2D( 1, 1, 1, 1 )
175                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
176               END_2D
177            ELSE                                        ! no cavities: only at the ocean surface
178               DO_2D( 1, 1, 1, 1 )
179                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
180               END_2D
181            ENDIF
182         ENDIF
183         !
184         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )   !* trend and after field with monotonic scheme
185            !                               ! total intermediate advective trends
186            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
187               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
188               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
189            !                               ! update and guess with monotonic sheme
190            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
191               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
192            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
193               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
194         END_3D
195
196         IF ( ll_zAimp ) THEN
197            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
198            !
199            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
200            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
201               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
202               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
203               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
204               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
205            END_3D
206            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
207               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
208                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
209            END_3D
210            !
211         END IF
212         !
213         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
214            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
215         END IF
216         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
217         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:)
218         !
219         !        !==  anti-diffusive flux : high order minus low order  ==!
220         !
221         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
222         !
223         CASE(  2  )                   !- 2nd order centered
224            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
225               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
226               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
227            END_3D
228            !
229         CASE(  4  )                   !- 4th order centered
230            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
231            zltv(:,:,jpk) = 0._wp
232            DO jk = 1, jpkm1                 ! Laplacian
233               DO_2D( 1, 0, 1, 0 )                 ! 1st derivative (gradient)
234                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
235                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
236               END_2D
237               DO_2D( 0, 0, 0, 0 )                 ! 2nd derivative * 1/ 6
238                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
239                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
240               END_2D
241            END DO
242            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
243            !
244            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
245               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
246               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
247               !                                                        ! C4 minus upstream advective fluxes
248               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
249               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
250            END_3D
251            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp, zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
252            !
253         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
254            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
255            ztv(:,:,jpk) = 0._wp
256            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )    ! 1st derivative (gradient)
257               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
258               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
259            END_3D
260            IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
261            !
262            DO_3D( 0, 0, 0, 0, 1, jpkm1 )    ! Horizontal advective fluxes
263               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
264               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
265               !                                                  ! C4 interpolation of T at u- & v-points (x2)
266               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
267               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
268               !                                                  ! C4 minus upstream advective fluxes
269               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
270               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
271            END_3D
272            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
273            !
274         END SELECT
275         !
276         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
277         !
278         CASE(  2  )                   !- 2nd order centered
279            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
280               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
281                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
282            END_3D
283            !
284         CASE(  4  )                   !- 4th order COMPACT
285            CALL interp_4th_cpt( CASTWP(pt(:,:,:,jn,Kmm)) , ztw )   ! zwt = COMPACT interpolation of T at w-point
286            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
287               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
288            END_3D
289            !
290         END SELECT
291         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
292            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
293         ENDIF
294         !
295         IF (nn_hls.EQ.1) THEN
296#if defined key_single
297            CALL lbc_lnk      ( 'traadv_fct', zwi, 'T', 1.0_wp )
298            CALL lbc_lnk_multi( 'traadv_fct',                   zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
299#else
300            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
301#endif
302         ELSE
303            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
304         END IF
305         !
306         IF (nn_hls.EQ.1) THEN
307#if defined key_single
308            CALL lbc_lnk      ( 'traadv_fct', zwi, 'T', 1.0_wp )
309            CALL lbc_lnk_multi( 'traadv_fct',                   zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
310#else
311            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
312#endif
313         ELSE
314            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
315         END IF
316         !
317         IF ( ll_zAimp ) THEN
318            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    !* trend and after field with monotonic scheme
319               !                                                ! total intermediate advective trends
320               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
321                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
322                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
323               ztw(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
324            END_3D
325            !
326            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
327            !
328            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
329               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
330               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
331               zwz(ji,jj,jk) = zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
332            END_3D
333         END IF
334         !
335         !        !==  monotonicity algorithm  ==!
336         !
337         CALL nonosc( Kmm, CASTWP(pt(:,:,:,jn,Kbb)), zwx, zwy, zwz, zwi, p2dt )
338         !
339         !        !==  final trend with corrected fluxes  ==!
340         !
341         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
342            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
343               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
344               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
345            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
346            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
347         END_3D
348         !
349         IF ( ll_zAimp ) THEN
350            !
351            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
352            DO_3D( 0, 0, 0, 0, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
353               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
354               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
355               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
356               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
357            END_3D
358            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
359               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
360                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
361            END_3D
362         END IF
363         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
364            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
365            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
366            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
367            !
368            IF( l_trd ) THEN              ! trend diagnostics
369               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, CASTWP(pt(:,:,:,jn,Kmm)) )
370               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, CASTWP(pt(:,:,:,jn,Kmm)) )
371               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, CASTWP(pt(:,:,:,jn,Kmm)) )
372            ENDIF
373            !                             ! heat/salt transport
374            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
375            !
376         ENDIF
377         IF( l_ptr ) THEN              ! "Poleward" transports
378            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
379            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
380         ENDIF
381         !
382      END DO                     ! end of tracer loop
383      !
384      IF ( ll_zAimp ) THEN
385         DEALLOCATE( zwdia, zwinf, zwsup )
386      ENDIF
387      IF( l_trd .OR. l_hst ) THEN
388         DEALLOCATE( ztrdx, ztrdy, ztrdz )
389      ENDIF
390      IF( l_ptr ) THEN
391         DEALLOCATE( zptry )
392      ENDIF
393      !
394   END SUBROUTINE tra_adv_fct
395
396
397   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
398      !!---------------------------------------------------------------------
399      !!                    ***  ROUTINE nonosc  ***
400      !!
401      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
402      !!       scheme and the before field by a nonoscillatory algorithm
403      !!
404      !! **  Method  :   ... ???
405      !!       warning : pbef and paft must be masked, but the boundaries
406      !!       conditions on the fluxes are not necessary zalezak (1979)
407      !!       drange (1995) multi-dimensional forward-in-time and upstream-
408      !!       in-space based differencing for fluid
409      !!----------------------------------------------------------------------
410      INTEGER                         , INTENT(in   ) ::   Kmm             ! time level index
411      REAL(wp)                        , INTENT(in   ) ::   p2dt            ! tracer time-step
412      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pbef            ! before field
413      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(in   ) ::   paft            ! after field
414      REAL(dp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
415      !
416      INTEGER  ::   ji, jj, jk   ! dummy loop indices
417      INTEGER  ::   ikm1         ! local integer
418      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
419      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
420      REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zbetup, zbetdo, zbup, zbdo
421      !!----------------------------------------------------------------------
422      !
423      zbig  = 1.e+40_dp
424      zrtrn = 1.e-15_dp
425      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
426
427      ! Search local extrema
428      ! --------------------
429      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
430      DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpk )
431         zbup(ji,jj,jk) = MAX( pbef(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
432            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) )  )
433         zbdo(ji,jj,jk) = MIN( pbef(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
434            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) )  )
435      END_3D
436
437      DO jk = 1, jpkm1
438         ikm1 = MAX(jk-1,1)
439         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
440
441            ! search maximum in neighbourhood
442            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
443               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
444               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
445               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
446
447            ! search minimum in neighbourhood
448            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
449               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
450               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
451               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
452
453            ! positive part of the flux
454            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
455               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
456               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
457
458            ! negative part of the flux
459            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
460               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
461               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
462
463            ! up & down beta terms
464            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
465            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
466            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
467         END_2D
468      END DO
469      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
470
471      ! 3. monotonic flux in the i & j direction (paa & pbb)
472      ! ----------------------------------------
473      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
474         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
475         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
476         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
477         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
478
479         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
480         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
481         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
482         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
483
484      ! monotonic flux in the k direction, i.e. pcc
485      ! -------------------------------------------
486         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
487         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
488         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
489         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
490      END_3D
491      !
492   END SUBROUTINE nonosc
493
494
495   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
496      !!----------------------------------------------------------------------
497      !!                  ***  ROUTINE interp_4th_cpt_org  ***
498      !!
499      !! **  Purpose :   Compute the interpolation of tracer at w-point
500      !!
501      !! **  Method  :   4th order compact interpolation
502      !!----------------------------------------------------------------------
503      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
504      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
505      !
506      INTEGER :: ji, jj, jk   ! dummy loop integers
507      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
508      !!----------------------------------------------------------------------
509
510      DO_3D( 1, 1, 1, 1, 3, jpkm1 )       !==  build the three diagonal matrix  ==!
511         zwd (ji,jj,jk) = 4._wp
512         zwi (ji,jj,jk) = 1._wp
513         zws (ji,jj,jk) = 1._wp
514         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
515         !
516         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
517            zwd (ji,jj,jk) = 1._wp
518            zwi (ji,jj,jk) = 0._wp
519            zws (ji,jj,jk) = 0._wp
520            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
521         ENDIF
522      END_3D
523      !
524      jk = 2                                    ! Switch to second order centered at top
525      DO_2D( 1, 1, 1, 1 )
526         zwd (ji,jj,jk) = 1._wp
527         zwi (ji,jj,jk) = 0._wp
528         zws (ji,jj,jk) = 0._wp
529         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
530      END_2D
531      !
532      !                       !==  tridiagonal solve  ==!
533      DO_2D( 1, 1, 1, 1 )           ! first recurrence
534         zwt(ji,jj,2) = zwd(ji,jj,2)
535      END_2D
536      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
537         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
538      END_3D
539      !
540      DO_2D( 1, 1, 1, 1 )           ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
541         pt_out(ji,jj,2) = zwrm(ji,jj,2)
542      END_2D
543      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
544         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
545      END_3D
546
547      DO_2D( 1, 1, 1, 1 )           ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
548         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
549      END_2D
550      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
551         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
552      END_3D
553      !
554   END SUBROUTINE interp_4th_cpt_org
555
556
557   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
558      !!----------------------------------------------------------------------
559      !!                  ***  ROUTINE interp_4th_cpt  ***
560      !!
561      !! **  Purpose :   Compute the interpolation of tracer at w-point
562      !!
563      !! **  Method  :   4th order compact interpolation
564      !!----------------------------------------------------------------------
565      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
566      REAL(wp),DIMENSION(A2D(nn_hls)    ,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
567      !
568      INTEGER ::   ji, jj, jk   ! dummy loop integers
569      INTEGER ::   ikt, ikb     ! local integers
570      REAL(wp),DIMENSION(A2D(nn_hls),jpk) :: zwd, zwi, zws, zwrm, zwt
571      !!----------------------------------------------------------------------
572      !
573      !                      !==  build the three diagonal matrix & the RHS  ==!
574      !
575      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )    ! interior (from jk=3 to jpk-1)
576         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
577         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
578         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
579         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
580            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
581      END_3D
582      !
583!!gm
584!      SELECT CASE( kbc )               !* boundary condition
585!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
586!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
587!      END SELECT
588!!gm
589      !
590      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
591         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
592      END IF
593      !
594      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! 2nd order centered at top & bottom
595         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
596         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
597         !
598         zwd (ji,jj,ikt) = 1._wp          ! top
599         zwi (ji,jj,ikt) = 0._wp
600         zws (ji,jj,ikt) = 0._wp
601         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
602         !
603         zwd (ji,jj,ikb) = 1._wp          ! bottom
604         zwi (ji,jj,ikb) = 0._wp
605         zws (ji,jj,ikb) = 0._wp
606         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )
607      END_2D
608      !
609      !                       !==  tridiagonal solver  ==!
610      !
611      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
612         zwt(ji,jj,2) = zwd(ji,jj,2)
613      END_2D
614      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
615         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
616      END_3D
617      !
618      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
619         pt_out(ji,jj,2) = zwrm(ji,jj,2)
620      END_2D
621      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
622         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
623      END_3D
624
625      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
626         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
627      END_2D
628      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, 2, -1 )
629         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
630      END_3D
631      !
632   END SUBROUTINE interp_4th_cpt
633
634
635   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
636      !!----------------------------------------------------------------------
637      !!                  ***  ROUTINE tridia_solver  ***
638      !!
639      !! **  Purpose :   solve a symmetric 3diagonal system
640      !!
641      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
642      !!
643      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
644      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
645      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
646      !!             (        ...          )( ... )   ( ...  )
647      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
648      !!
649      !!        M is decomposed in the product of an upper and lower triangular matrix.
650      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
651      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
652      !!        The solution is pta.
653      !!        The 3d array zwt is used as a work space array.
654      !!----------------------------------------------------------------------
655      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
656      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
657      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
658      INTEGER                    , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
659      !                                                             ! =0 pt at t-level
660      INTEGER ::   ji, jj, jk   ! dummy loop integers
661      INTEGER ::   kstart       ! local indices
662      REAL(wp),DIMENSION(A2D(nn_hls),jpk) ::   zwt   ! 3D work array
663      !!----------------------------------------------------------------------
664      !
665      kstart =  1  + klev
666      !
667      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                         !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
668         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
669      END_2D
670      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
671         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
672      END_3D
673      !
674      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                        !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
675         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
676      END_2D
677      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
678         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
679      END_3D
680
681      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                       !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
682         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
683      END_2D
684      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, kstart, -1 )
685         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
686      END_3D
687      !
688   END SUBROUTINE tridia_solver
689
690   !!======================================================================
691END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.