New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traatf.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/TRA/traatf.F90 @ 14644

Last change on this file since 14644 was 14644, checked in by sparonuz, 3 years ago

Merge trunk -r14642:HEAD
  • Property svn:keywords set to Id
File size: 19.7 KB
Line 
1MODULE traatf
2   !!======================================================================
3   !!                       ***  MODULE  traatf  ***
4   !! Ocean active tracers:  Asselin time filtering for temperature and salinity
5   !!======================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
8   !!            8.0  !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
9   !!             -   !  1996-04  (A. Weaver)  Euler forward step
10   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
11   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
12   !!             -   !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
13   !!             -   !  2005-04  (C. Deltel) Add Asselin trend in the ML budget
14   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
15   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
16   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  semi-implicit hpg with asselin filter + modified LF-RA
18   !!             -   !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rename tranxt.F90 -> traatf.F90. Now only does time filtering.
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   tra_atf       : time filtering on tracers
24   !!   tra_atf_fix   : time filtering on tracers : fixed    volume case
25   !!   tra_atf_vvl   : time filtering on tracers : variable volume case
26   !!----------------------------------------------------------------------
27   USE oce             ! ocean dynamics and tracers variables
28   USE dom_oce         ! ocean space and time domain variables
29   USE sbc_oce         ! surface boundary condition: ocean
30   USE sbcrnf          ! river runoffs
31   USE isf_oce         ! ice shelf melting
32   USE zdf_oce         ! ocean vertical mixing
33   USE domvvl          ! variable volume
34   USE trd_oce         ! trends: ocean variables
35   USE trdtra          ! trends manager: tracers
36   USE traqsr          ! penetrative solar radiation (needed for nksr)
37   USE phycst          ! physical constant
38   USE ldftra          ! lateral physics : tracers
39   USE ldfslp          ! lateral physics : slopes
40   USE bdy_oce  , ONLY : ln_bdy
41   USE bdytra          ! open boundary condition (bdy_tra routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
45   USE prtctl          ! Print control
46   USE timing          ! Timing
47#if defined key_agrif
48   USE agrif_oce_interp
49#endif
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   tra_atf       ! routine called by step.F90
55   PUBLIC   tra_atf_fix   ! to be used in trcnxt
56   PUBLIC   tra_atf_vvl   ! to be used in trcnxt
57
58   !! * Substitutions
59#  include "do_loop_substitute.h90"
60#  include "domzgr_substitute.h90"
61#  include "single_precision_substitute.h90"
62   !!----------------------------------------------------------------------
63   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
64   !! $Id$
65   !! Software governed by the CeCILL license (see ./LICENSE)
66   !!----------------------------------------------------------------------
67CONTAINS
68
69   SUBROUTINE tra_atf( kt, Kbb, Kmm, Kaa, pts )
70      !!----------------------------------------------------------------------
71      !!                   ***  ROUTINE traatf  ***
72      !!
73      !! ** Purpose :   Apply the boundary condition on the after temperature
74      !!             and salinity fields and add the Asselin time filter on now fields.
75      !!
76      !! ** Method  :   At this stage of the computation, ta and sa are the
77      !!             after temperature and salinity as the time stepping has
78      !!             been performed in trazdf_imp or trazdf_exp module.
79      !!
80      !!              - Apply lateral boundary conditions on (ta,sa)
81      !!             at the local domain   boundaries through lbc_lnk call,
82      !!             at the one-way open boundaries (ln_bdy=T),
83      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
84      !!
85      !!              - Update lateral boundary conditions on AGRIF children
86      !!             domains (lk_agrif=T)
87      !!
88      !! ** Action  : - ts(Kmm) time filtered
89      !!----------------------------------------------------------------------
90      INTEGER                                  , INTENT(in   ) :: kt             ! ocean time-step index
91      INTEGER                                  , INTENT(in   ) :: Kbb, Kmm, Kaa  ! time level indices
92      REAL(dp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers
93      !!
94      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
95      REAL(wp) ::   zfact            ! local scalars
96      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdt, ztrds
97      !!----------------------------------------------------------------------
98      !
99      IF( ln_timing )   CALL timing_start( 'tra_atf')
100      !
101      IF( kt == nit000 ) THEN
102         IF(lwp) WRITE(numout,*)
103         IF(lwp) WRITE(numout,*) 'tra_atf : apply Asselin time filter to "now" fields'
104         IF(lwp) WRITE(numout,*) '~~~~~~~'
105      ENDIF
106
107      ! Update after tracer on domain lateral boundaries
108      !
109#if defined key_agrif
110      CALL Agrif_tra                     ! AGRIF zoom boundaries
111#endif
112      !                                              ! local domain boundaries  (T-point, unchanged sign)
113      CALL lbc_lnk( 'traatf', pts(:,:,:,jp_tem,Kaa), 'T', 1.0_wp, pts(:,:,:,jp_sal,Kaa), 'T', 1.0_wp )
114      !
115      IF( ln_bdy )   CALL bdy_tra( kt, Kbb, pts, Kaa )  ! BDY open boundaries
116
117      ! trends computation initialisation
118      IF( l_trdtra )   THEN
119         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
120         ztrdt(:,:,:) = 0._wp
121         ztrds(:,:,:) = 0._wp
122         IF( ln_traldf_iso ) THEN              ! diagnose the "pure" Kz diffusive trend
123            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_zdfp, ztrdt )
124            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_zdfp, ztrds )
125         ENDIF
126         ! total trend for the non-time-filtered variables.
127         zfact = 1.0 / rn_Dt
128         ! G Nurser 23 Mar 2017. Recalculate trend as Delta(e3t*T)/e3tn; e3tn cancel from pts(Kmm) terms
129         DO jk = 1, jpkm1
130            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa) / e3t(:,:,jk,Kmm) - pts(:,:,jk,jp_tem,Kmm)) * zfact
131            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa) / e3t(:,:,jk,Kmm) - pts(:,:,jk,jp_sal,Kmm)) * zfact
132         END DO
133         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_tot, ztrdt )
134         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_tot, ztrds )
135         IF( ln_linssh ) THEN       ! linear sea surface height only
136            ! Store now fields before applying the Asselin filter
137            ! in order to calculate Asselin filter trend later.
138            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kmm)
139            ztrds(:,:,:) = pts(:,:,:,jp_sal,Kmm)
140         ENDIF
141      ENDIF
142
143      IF( l_1st_euler ) THEN       ! Euler time-stepping
144         !
145         IF (l_trdtra .AND. .NOT. ln_linssh ) THEN   ! Zero Asselin filter contribution must be explicitly written out since for vvl
146            !                                        ! Asselin filter is output by tra_atf_vvl that is not called on this time step
147            ztrdt(:,:,:) = 0._wp
148            ztrds(:,:,:) = 0._wp
149            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
150            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
151         END IF
152         !
153      ELSE                                            ! Leap-Frog + Asselin filter time stepping
154         !
155         IF( ln_linssh ) THEN   ;   CALL tra_atf_fix( kt, Kbb, Kmm, Kaa, nit000,        'TRA', pts, jpts )  ! linear free surface
156         ELSE                   ;   CALL tra_atf_vvl( kt, Kbb, Kmm, Kaa, nit000, CASTWP(rn_Dt), 'TRA', pts, sbc_tsc, sbc_tsc_b, jpts )  ! non-linear free surface
157         ENDIF
158         !
159         CALL lbc_lnk( 'traatf',  pts(:,:,:,jp_tem,Kmm) , 'T', 1.0_wp, pts(:,:,:,jp_sal,Kmm) , 'T', 1.0_wp )
160
161      ENDIF
162      !
163      IF( l_trdtra .AND. ln_linssh ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt
164         DO jk = 1, jpkm1
165            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kmm) - ztrdt(:,:,jk) ) * r1_Dt
166            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kmm) - ztrds(:,:,jk) ) * r1_Dt
167         END DO
168         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
169         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
170      END IF
171      IF( l_trdtra )   DEALLOCATE( ztrdt , ztrds )
172      !
173      !                        ! control print
174      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=CASTWP(pts(:,:,:,jp_tem,Kmm)), clinfo1=' nxt  - Tn: ', mask1=tmask,   &
175         &                                  tab3d_2=CASTWP(pts(:,:,:,jp_sal,Kmm)), clinfo2=       ' Sn: ', mask2=tmask )
176      !
177      IF( ln_timing )   CALL timing_stop('tra_atf')
178      !
179   END SUBROUTINE tra_atf
180
181
182   SUBROUTINE tra_atf_fix( kt, Kbb, Kmm, Kaa, kit000, cdtype, pt, kjpt )
183      !!----------------------------------------------------------------------
184      !!                   ***  ROUTINE tra_atf_fix  ***
185      !!
186      !! ** Purpose :   fixed volume: apply the Asselin time filter to the "now" field
187      !!
188      !! ** Method  : - Apply a Asselin time filter on now fields.
189      !!
190      !! ** Action  : - pt(Kmm) ready for the next time step
191      !!----------------------------------------------------------------------
192      INTEGER                                  , INTENT(in   ) ::  kt            ! ocean time-step index
193      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
194      INTEGER                                  , INTENT(in   ) ::  kit000        ! first time step index
195      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype        ! =TRA or TRC (tracer indicator)
196      INTEGER                                  , INTENT(in   ) ::  kjpt          ! number of tracers
197      REAL(dp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt            ! tracer fields
198      !
199      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
200      REAL(wp) ::   ztn, ztd         ! local scalars
201      !!----------------------------------------------------------------------
202      !
203      IF( kt == kit000 )  THEN
204         IF(lwp) WRITE(numout,*)
205         IF(lwp) WRITE(numout,*) 'tra_atf_fix : time filtering', cdtype
206         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
207      ENDIF
208      !
209      DO jn = 1, kjpt
210         !
211         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
212            ztn = pt(ji,jj,jk,jn,Kmm)
213            ztd = pt(ji,jj,jk,jn,Kaa) - 2._wp * ztn + pt(ji,jj,jk,jn,Kbb)  ! time laplacian on tracers
214            !
215            pt(ji,jj,jk,jn,Kmm) = ztn + rn_atfp * ztd                      ! pt <-- filtered pt
216         END_3D
217         !
218      END DO
219      !
220   END SUBROUTINE tra_atf_fix
221
222
223   SUBROUTINE tra_atf_vvl( kt, Kbb, Kmm, Kaa, kit000, p2dt, cdtype, pt, psbc_tc, psbc_tc_b, kjpt )
224      !!----------------------------------------------------------------------
225      !!                   ***  ROUTINE tra_atf_vvl  ***
226      !!
227      !! ** Purpose :   Time varying volume: apply the Asselin time filter
228      !!
229      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
230      !!             pt(Kmm)  = ( e3t_Kmm*pt(Kmm) + rn_atfp*[ e3t_Kbb*pt(Kbb) - 2 e3t_Kmm*pt(Kmm) + e3t_Kaa*pt(Kaa) ] )
231      !!                       /( e3t_Kmm         + rn_atfp*[ e3t_Kbb         - 2 e3t_Kmm         + e3t_Kaa    ] )
232      !!
233      !! ** Action  : - pt(Kmm) ready for the next time step
234      !!----------------------------------------------------------------------
235      INTEGER                                  , INTENT(in   ) ::  kt        ! ocean time-step index
236      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
237      INTEGER                                  , INTENT(in   ) ::  kit000    ! first time step index
238      REAL(wp)                                 , INTENT(in   ) ::  p2dt      ! time-step
239      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype    ! =TRA or TRC (tracer indicator)
240      INTEGER                                  , INTENT(in   ) ::  kjpt      ! number of tracers
241      REAL(dp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt        ! tracer fields
242      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc   ! surface tracer content
243      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc_b ! before surface tracer content
244      !
245      LOGICAL  ::   ll_traqsr, ll_rnf, ll_isf   ! local logical
246      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
247      REAL(dp) ::   zfact, zfact1, ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
248      REAL(dp) ::   zfact2, ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d, zscale  !   -      -
249      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrd_atf
250      !!----------------------------------------------------------------------
251      !
252      IF( kt == kit000 )  THEN
253         IF(lwp) WRITE(numout,*)
254         IF(lwp) WRITE(numout,*) 'tra_atf_vvl : time filtering', cdtype
255         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
256      ENDIF
257      !
258      IF( cdtype == 'TRA' )  THEN
259         ll_traqsr  = ln_traqsr        ! active  tracers case  and  solar penetration
260         ll_rnf     = ln_rnf           ! active  tracers case  and  river runoffs
261         ll_isf     = ln_isf           ! active  tracers case  and  ice shelf melting
262      ELSE                          ! passive tracers case
263         ll_traqsr  = .FALSE.          ! NO solar penetration
264         ll_rnf     = .FALSE.          ! NO river runoffs ????          !!gm BUG ?
265         ll_isf     = .FALSE.          ! NO ice shelf melting/freezing  !!gm BUG ??
266      ENDIF
267      !
268      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
269         ALLOCATE( ztrd_atf(jpi,jpj,jpk,kjpt) )
270         ztrd_atf(:,:,:,:) = 0.0_wp
271      ENDIF
272      zfact = 1._wp / p2dt
273      zfact1 = rn_atfp * p2dt
274      zfact2 = zfact1 * r1_rho0
275      DO jn = 1, kjpt
276         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
277            ze3t_b = e3t(ji,jj,jk,Kbb)
278            ze3t_n = e3t(ji,jj,jk,Kmm)
279            ze3t_a = e3t(ji,jj,jk,Kaa)
280            !                                         ! tracer content at Before, now and after
281            ztc_b  = pt(ji,jj,jk,jn,Kbb) * ze3t_b
282            ztc_n  = pt(ji,jj,jk,jn,Kmm) * ze3t_n
283            ztc_a  = pt(ji,jj,jk,jn,Kaa) * ze3t_a
284            !
285            ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
286            ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
287            !
288            ze3t_f = ze3t_n + rn_atfp * ze3t_d
289            ztc_f  = ztc_n  + rn_atfp * ztc_d
290            !
291            ! Add asselin correction on scale factors:
292            zscale = tmask(ji,jj,jk) * e3t(ji,jj,jk,Kmm) / ( ht(ji,jj) + 1._wp - ssmask(ji,jj) )
293            ze3t_f = ze3t_f - zfact2 * zscale * ( emp_b(ji,jj) - emp(ji,jj) )
294            IF ( ll_rnf ) ze3t_f = ze3t_f + zfact2 * zscale * (    rnf_b(ji,jj) -    rnf(ji,jj) )
295            IF ( ll_isf ) THEN
296               IF ( ln_isfcav_mlt ) ze3t_f = ze3t_f - zfact2 * zscale * ( fwfisf_cav_b(ji,jj) - fwfisf_cav(ji,jj) )
297               IF ( ln_isfpar_mlt ) ze3t_f = ze3t_f - zfact2 * zscale * ( fwfisf_par_b(ji,jj) - fwfisf_par(ji,jj) )
298            ENDIF
299            !
300            IF( jk == mikt(ji,jj) ) THEN           ! first level
301               ztc_f  = ztc_f  - zfact1 * ( psbc_tc(ji,jj,jn) - psbc_tc_b(ji,jj,jn) )
302            ENDIF
303            !
304            ! solar penetration (temperature only)
305            IF( ll_traqsr .AND. jn == jp_tem .AND. jk <= nksr )                            &
306               &     ztc_f  = ztc_f  - zfact1 * ( qsr_hc(ji,jj,jk) - qsr_hc_b(ji,jj,jk) )
307               !
308            !
309            IF( ll_rnf .AND. jk <= nk_rnf(ji,jj) )                                          &
310               &     ztc_f  = ztc_f  - zfact1 * ( rnf_tsc(ji,jj,jn) - rnf_tsc_b(ji,jj,jn) ) &
311               &                              * e3t(ji,jj,jk,Kmm) / h_rnf(ji,jj)
312
313            !
314            ! ice shelf
315            IF( ll_isf ) THEN
316               !
317               ! melt in the cavity
318               IF ( ln_isfcav_mlt ) THEN
319                  ! level fully include in the Losch_2008 ice shelf boundary layer
320                  IF ( jk >= misfkt_cav(ji,jj) .AND. jk < misfkb_cav(ji,jj) ) THEN
321                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) ) &
322                        &                     * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj)
323                  END IF
324                  ! level partially include in Losch_2008 ice shelf boundary layer
325                  IF ( jk == misfkb_cav(ji,jj) ) THEN
326                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) )  &
327                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj) * rfrac_tbl_cav(ji,jj)
328                  END IF
329               END IF
330               !
331               ! parametrised melt (cavity closed)
332               IF ( ln_isfpar_mlt ) THEN
333                  ! level fully include in the Losch_2008 ice shelf boundary layer
334                  IF ( jk >= misfkt_par(ji,jj) .AND. jk < misfkb_par(ji,jj) ) THEN
335                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
336                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj)
337                  END IF
338                  ! level partially include in Losch_2008 ice shelf boundary layer
339                  IF ( jk == misfkb_par(ji,jj) ) THEN
340                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
341                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj) * rfrac_tbl_par(ji,jj)
342                  END IF
343               END IF
344               !
345               ! ice sheet coupling correction
346               IF ( ln_isfcpl ) THEN
347                  !
348                  ! at kt = nit000,  risfcpl_vol_n = 0 and risfcpl_vol_b = risfcpl_vol so contribution nul
349                  IF ( ln_rstart .AND. kt == nit000+1 ) THEN
350                     ztc_f  = ztc_f  + zfact1 * risfcpl_tsc(ji,jj,jk,jn) * r1_e1e2t(ji,jj)
351                     ! Shouldn't volume increment be spread according thanks to zscale  ?
352                     ze3t_f = ze3t_f - zfact1 * risfcpl_vol(ji,jj,jk   ) * r1_e1e2t(ji,jj)
353                  END IF
354                  !
355               END IF
356               !
357            END IF
358            !
359            ze3t_f = 1.e0 / ze3t_f
360            pt(ji,jj,jk,jn,Kmm) = ztc_f * ze3t_f    ! time filtered "now" field
361            !
362            IF( ( l_trdtra .and. cdtype == 'TRA' ) .OR. ( l_trdtrc .and. cdtype == 'TRC' ) ) THEN
363               ztrd_atf(ji,jj,jk,jn) = (ztc_f - ztc_n) * zfact/ze3t_n
364            ENDIF
365            !
366         END_3D
367         !
368      END DO
369      !
370      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
371         IF( l_trdtra .AND. cdtype == 'TRA' ) THEN
372            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_tem, jptra_atf, ztrd_atf(:,:,:,jp_tem) )
373            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_sal, jptra_atf, ztrd_atf(:,:,:,jp_sal) )
374         ENDIF
375         IF( l_trdtrc .AND. cdtype == 'TRC' ) THEN
376            DO jn = 1, kjpt
377               CALL trd_tra( kt, Kmm, Kaa, cdtype, jn, jptra_atf, ztrd_atf(:,:,:,jn) )
378            END DO
379         ENDIF
380         DEALLOCATE( ztrd_atf )
381      ENDIF
382      !
383   END SUBROUTINE tra_atf_vvl
384
385   !!======================================================================
386END MODULE traatf
Note: See TracBrowser for help on using the repository browser.