New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/TRA/trazdf.F90 @ 14644

Last change on this file since 14644 was 14644, checked in by sparonuz, 3 years ago

Merge trunk -r14642:HEAD
  • Property svn:keywords set to Id
File size: 13.9 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            4.0  !  2017-06  (G. Madec)  remove explict time-stepping option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE zdfmfc         ! Mass FLux Convection
20   USE sbc_oce        ! surface boundary condition: ocean
21   USE ldftra         ! lateral diffusion: eddy diffusivity
22   USE ldfslp         ! lateral diffusion: iso-neutral slope
23   USE trd_oce        ! trends: ocean variables
24   USE trdtra         ! trends: tracer trend manager
25   USE eosbn2, ONLY: ln_SEOS, rn_b0
26   !
27   USE in_out_manager ! I/O manager
28   USE prtctl         ! Print control
29   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
30   USE lib_mpp        ! MPP library
31   USE timing         ! Timing
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_zdf       ! called by step.F90
37   PUBLIC   tra_zdf_imp   ! called by trczdf.F90
38
39   !! * Substitutions
40#  include "do_loop_substitute.h90"
41#  include "domzgr_substitute.h90"
42#  include "single_precision_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE tra_zdf( kt, Kbb, Kmm, Krhs, pts, Kaa )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_zdf  ***
53      !!
54      !! ** Purpose :   compute the vertical ocean tracer physics.
55      !!---------------------------------------------------------------------
56      INTEGER                                  , INTENT(in)    :: kt                  ! ocean time-step index
57      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs, Kaa ! time level indices
58      REAL(dp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts                 ! active tracers and RHS of tracer equation
59      !
60      INTEGER  ::   ji, jj, jk   ! Dummy loop indices
61      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds   ! 3D workspace
62      !!---------------------------------------------------------------------
63      !
64      IF( ln_timing )   CALL timing_start('tra_zdf')
65      !
66      IF( kt == nit000 )  THEN
67         IF( ntile == 0 .OR. ntile == 1 )  THEN                   ! Do only on the first tile
68            IF(lwp)WRITE(numout,*)
69            IF(lwp)WRITE(numout,*) 'tra_zdf : implicit vertical mixing on T & S'
70            IF(lwp)WRITE(numout,*) '~~~~~~~ '
71         ENDIF
72      ENDIF
73      !
74      IF( l_trdtra )   THEN                  !* Save ta and sa trends
75         ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
76         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kaa)
77         ztrds(:,:,:) = pts(:,:,:,jp_sal,Kaa)
78      ENDIF
79      !
80      !                                      !* compute lateral mixing trend and add it to the general trend
81      CALL tra_zdf_imp( kt, nit000, 'TRA', rDt, Kbb, Kmm, Krhs, pts, Kaa, jpts )
82
83!!gm WHY here !   and I don't like that !
84      ! DRAKKAR SSS control {
85      ! JMM avoid negative salinities near river outlet ! Ugly fix
86      ! JMM : restore negative salinities to small salinities:
87!!jc: discard this correction in case salinity is not used in eos
88      IF ( .NOT.(ln_SEOS.AND.(rn_b0==0._wp)) ) THEN
89         WHERE( pts(A2D(0),:,jp_sal,Kaa) < 0._wp )   pts(A2D(0),:,jp_sal,Kaa) = 0.1_wp
90      ENDIF
91!!gm
92
93      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
94         DO jk = 1, jpk
95            ztrdt(:,:,jk) = (   (  pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa)     &
96               &                 - pts(:,:,jk,jp_tem,Kbb)*e3t(:,:,jk,Kbb)  )  &
97               &              / (  e3t(:,:,jk,Kmm)*rDt  )   )                 &
98               &          - ztrdt(:,:,jk)
99            ztrds(:,:,jk) = (   (  pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa)     &
100               &                 - pts(:,:,jk,jp_sal,Kbb)*e3t(:,:,jk,Kbb)  )  &
101               &             / (   e3t(:,:,jk,Kmm)*rDt  )   )                 &
102               &          - ztrds(:,:,jk)
103         END DO
104!!gm this should be moved in trdtra.F90 and done on all trends
105         CALL lbc_lnk( 'trazdf', ztrdt, 'T', 1.0_wp , ztrds, 'T', 1.0_wp )
106!!gm
107         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_zdf, ztrdt )
108         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_zdf, ztrds )
109         DEALLOCATE( ztrdt , ztrds )
110      ENDIF
111      !                                          ! print mean trends (used for debugging)
112      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=CASTWP(pts(:,:,:,jp_tem,Kaa)), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
113         &                                  tab3d_2=CASTWP(pts(:,:,:,jp_sal,Kaa)), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
114      !
115      IF( ln_timing )   CALL timing_stop('tra_zdf')
116      !
117   END SUBROUTINE tra_zdf
118
119
120   SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, Kbb, Kmm, Krhs, pt, Kaa, kjpt )
121      !!----------------------------------------------------------------------
122      !!                  ***  ROUTINE tra_zdf_imp  ***
123      !!
124      !! ** Purpose :   Compute the after tracer through a implicit computation
125      !!     of the vertical tracer diffusion (including the vertical component
126      !!     of lateral mixing (only for 2nd order operator, for fourth order
127      !!     it is already computed and add to the general trend in traldf)
128      !!
129      !! ** Method  :  The vertical diffusion of a tracer ,t , is given by:
130      !!          difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) )
131      !!      It is computed using a backward time scheme (t=after field)
132      !!      which provide directly the after tracer field.
133      !!      If ln_zdfddm=T, use avs for salinity or for passive tracers
134      !!      Surface and bottom boundary conditions: no diffusive flux on
135      !!      both tracers (bottom, applied through the masked field avt).
136      !!      If iso-neutral mixing, add to avt the contribution due to lateral mixing.
137      !!
138      !! ** Action  : - pt(:,:,:,:,Kaa)  becomes the after tracer
139      !!---------------------------------------------------------------------
140      INTEGER                                  , INTENT(in   ) ::   kt       ! ocean time-step index
141      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs, Kaa  ! ocean time level indices
142      INTEGER                                  , INTENT(in   ) ::   kit000   ! first time step index
143      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
144      INTEGER                                  , INTENT(in   ) ::   kjpt     ! number of tracers
145      REAL(wp)                                 , INTENT(in   ) ::   p2dt     ! tracer time-step
146      REAL(dp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt       ! tracers and RHS of tracer equation
147      !
148      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
149      REAL(dp) ::  zrhs, zzwi, zzws ! local scalars
150      REAL(dp), DIMENSION(A2D(nn_hls),jpk) ::  zwi, zwt, zwd, zws
151      !!---------------------------------------------------------------------
152      !
153      !                                               ! ============= !
154      DO jn = 1, kjpt                                 !  tracer loop  !
155         !                                            ! ============= !
156         !  Matrix construction
157         ! --------------------
158         ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer
159         !
160         IF(  ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR.   &
161            & ( cdtype == 'TRC' .AND. jn == 1 )  )  THEN
162            !
163            ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers
164            IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN
165               DO_3D( 1, 1, 1, 1, 2, jpk )
166                  zwt(ji,jj,jk) = avt(ji,jj,jk)
167               END_3D
168            ELSE
169               DO_3D( 1, 1, 1, 1, 2, jpk )
170                  zwt(ji,jj,jk) = avs(ji,jj,jk)
171               END_3D
172            ENDIF
173            zwt(:,:,1) = 0._wp
174            !
175            IF( l_ldfslp ) THEN            ! isoneutral diffusion: add the contribution
176               IF( ln_traldf_msc  ) THEN     ! MSC iso-neutral operator
177                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
178                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk)
179                  END_3D
180               ELSE                          ! standard or triad iso-neutral operator
181                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
182                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk)
183                  END_3D
184               ENDIF
185            ENDIF
186            !
187            ! Diagonal, lower (i), upper (s)  (including the bottom boundary condition since avt is masked)
188            IF( ln_zad_Aimp ) THEN         ! Adaptive implicit vertical advection
189               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
190                  zzwi = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk  ,Kmm)
191                  zzws = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
192                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zzwi - zzws   &
193                     &                 + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )
194                  zwi(ji,jj,jk) = zzwi + p2dt *   MIN( wi(ji,jj,jk  ) , 0._wp )
195                  zws(ji,jj,jk) = zzws - p2dt *   MAX( wi(ji,jj,jk+1) , 0._wp )
196               END_3D
197            ELSE
198               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
199                  zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk,Kmm)
200                  zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
201                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zwi(ji,jj,jk) - zws(ji,jj,jk)
202               END_3D
203            ENDIF
204            !
205            ! Modification of diagonal to add MF scheme
206            IF ( ln_zdfmfc ) THEN
207               CALL diag_mfc( zwi, zwd, zws, p2dt, Kaa )
208            END IF
209            !
210            !! Matrix inversion from the first level
211            !!----------------------------------------------------------------------
212            !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
213            !
214            !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
215            !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
216            !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
217            !        (        ...               )( ...  ) ( ...  )
218            !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
219            !
220            !   m is decomposed in the product of an upper and lower triangular matrix.
221            !   The 3 diagonal terms are in 3d arrays: zwd, zws, zwi.
222            !   Suffices i,s and d indicate "inferior" (below diagonal), diagonal
223            !   and "superior" (above diagonal) components of the tridiagonal system.
224            !   The solution will be in the 4d array pta.
225            !   The 3d array zwt is used as a work space array.
226            !   En route to the solution pt(:,:,:,:,Kaa) is used a to evaluate the rhs and then
227            !   used as a work space array: its value is modified.
228            !
229            DO_2D( 0, 0, 0, 0 )      !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1   (increasing k) ! done one for all passive tracers (so included in the IF instruction)
230               zwt(ji,jj,1) = zwd(ji,jj,1)
231            END_2D
232            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
233               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1)
234            END_3D
235            !
236         ENDIF
237         !
238         ! Modification of rhs to add MF scheme
239         IF ( ln_zdfmfc ) THEN
240            CALL rhs_mfc( pt(:,:,:,jn,Krhs), jn )
241         END IF
242         !
243         DO_2D( 0, 0, 0, 0 )         !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
244            pt(ji,jj,1,jn,Kaa) =        e3t(ji,jj,1,Kbb) * pt(ji,jj,1,jn,Kbb)    &
245               &               + p2dt * e3t(ji,jj,1,Kmm) * pt(ji,jj,1,jn,Krhs)
246         END_2D
247         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
248            zrhs =        e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb)    &
249               & + p2dt * e3t(ji,jj,jk,Kmm) * pt(ji,jj,jk,jn,Krhs)   ! zrhs=right hand side
250            pt(ji,jj,jk,jn,Kaa) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pt(ji,jj,jk-1,jn,Kaa)
251         END_3D
252         !
253         DO_2D( 0, 0, 0, 0 )         !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk   (result is the after tracer)
254            pt(ji,jj,jpkm1,jn,Kaa) = pt(ji,jj,jpkm1,jn,Kaa) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1)
255         END_2D
256         DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
257            pt(ji,jj,jk,jn,Kaa) = ( pt(ji,jj,jk,jn,Kaa) - zws(ji,jj,jk) * pt(ji,jj,jk+1,jn,Kaa) )   &
258               &             / zwt(ji,jj,jk) * tmask(ji,jj,jk)
259         END_3D
260         !                                            ! ================= !
261      END DO                                          !  end tracer loop  !
262      !                                               ! ================= !
263   END SUBROUTINE tra_zdf_imp
264
265   !!==============================================================================
266END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.