New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

step.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE – NEMO

Context Navigation

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/step.F90 @ 14644

Last change on this file since 14644 was 14644, checked in by sparonuz, 3 years ago
Merge trunk -r14642:HEAD
Property svn:keywords set to `Id`
File size: 24.6 KB

Line
1	MODULE step
2	!!======================================================================
3	!! * MODULE step *
4	!! Time-stepping : manager of the ocean, tracer and ice time stepping
5	!!======================================================================
6	!! History : OPA ! 1991-03 (G. Madec) Original code
7	!! - ! 1991-11 (G. Madec)
8	!! - ! 1992-06 (M. Imbard) add a first output record
9	!! - ! 1996-04 (G. Madec) introduction of dynspg
10	!! - ! 1996-04 (M.A. Foujols) introduction of passive tracer
11	!! 8.0 ! 1997-06 (G. Madec) new architecture of call
12	!! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface
13	!! - ! 1999-02 (G. Madec, N. Grima) hpg implicit
14	!! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions
15	!! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking
16	!! - ! 2004-08 (C. Talandier) New trends organization
17	!! - ! 2005-01 (C. Ethe) Add the KPP closure scheme
18	!! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls
19	!! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation
20	!! - ! 2006-07 (S. Masson) restart using iom
21	!! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate
22	!! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl
23	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25	!! 3.4 ! 2011-04 (G. Madec, C. Ethe) Merge of dtatem and dtasal
26	!! 3.6 ! 2012-07 (J. Simeon, G. Madec. C. Ethe) Online coarsening of outputs
27	!! 3.6 ! 2014-04 (F. Roquet, G. Madec) New equations of state
28	!! 3.6 ! 2014-10 (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves
29	!! 3.7 ! 2014-10 (G. Madec) LDF simplication
30	!! - ! 2014-12 (G. Madec) remove KPP scheme
31	!! - ! 2015-11 (J. Chanut) free surface simplification (remove filtered free surface)
32	!! 4.0 ! 2017-05 (G. Madec) introduction of the vertical physics manager (zdfphy)
33	!! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
34	!!----------------------------------------------------------------------
35
36	#if defined key_qco \|\| defined key_linssh
37	!!----------------------------------------------------------------------
38	!! 'key_qco' EMPTY MODULE Quasi-Eulerian vertical coordinate
39	!! OR
40	!! 'key_linssh EMPTY MODULE Fixed in time vertical coordinate
41	!!----------------------------------------------------------------------
42	#else
43	!!----------------------------------------------------------------------
44	!! stp : OCE system time-stepping
45	!!----------------------------------------------------------------------
46	USE step_oce ! time stepping definition modules
47
48	IMPLICIT NONE
49	PRIVATE
50
51	PUBLIC stp ! called by nemogcm.F90
52
53	! ! time level indices !
54	INTEGER, PUBLIC :: Nbb, Nnn, Naa, Nrhs !: used by nemo_init
55
56	!! * Substitutions
57	# include "do_loop_substitute.h90"
58	# include "single_precision_substitute.h90"
59	!!----------------------------------------------------------------------
60	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
61	!! $Id$
62	!! Software governed by the CeCILL license (see ./LICENSE)
63	!!----------------------------------------------------------------------
64	CONTAINS
65
66	#if defined key_agrif
67	RECURSIVE SUBROUTINE stp( )
68	INTEGER :: kstp ! ocean time-step index
69	#else
70	SUBROUTINE stp( kstp )
71	INTEGER, INTENT(in) :: kstp ! ocean time-step index
72	#endif
73	!!----------------------------------------------------------------------
74	!! * ROUTINE stp *
75	!!
76	!! ** Purpose : - Time stepping of OCE (momentum and active tracer eqs.)
77	!! - Time stepping of SI3 (dynamic and thermodynamic eqs.)
78	!! - Time stepping of TRC (passive tracer eqs.)
79	!!
80	!! ** Method : -1- Update forcings and data
81	!! -2- Update ocean physics
82	!! -3- Compute the t and s trends
83	!! -4- Update t and s
84	!! -5- Compute the momentum trends
85	!! -6- Update the horizontal velocity
86	!! -7- Compute the diagnostics variables (rd,N2, hdiv,w)
87	!! -8- Outputs and diagnostics
88	!!----------------------------------------------------------------------
89	INTEGER :: ji, jj, jk, jtile ! dummy loop indice
90	!! ---------------------------------------------------------------------
91	#if defined key_agrif
92	IF( nstop > 0 ) RETURN ! avoid to go further if an error was detected during previous time step (child grid)
93	kstp = nit000 + Agrif_Nb_Step()
94	Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices
95	IF( lk_agrif_debug ) THEN
96	IF( Agrif_Root() .and. lwp) WRITE(,) '---'
97	IF(lwp) WRITE(,) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
98	ENDIF
99	IF( kstp == nit000 + 1 ) lk_agrif_fstep = .FALSE.
100	# if defined key_xios
101	IF( Agrif_Nbstepint() == 0 ) CALL iom_swap( cxios_context )
102	# endif
103	#endif
104	!
105	IF( ln_timing ) CALL timing_start('stp')
106	!
107	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
108	! model timestep
109	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
110	!
111	IF( l_1st_euler ) THEN ! start or restart with Euler 1st time-step
112	rDt = rn_Dt
113	r1_Dt = 1._wp / rDt
114	ENDIF
115	!
116	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
117	! update I/O and calendar
118	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
119	!
120	IF( kstp == nit000 ) THEN ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
121	CALL iom_init( cxios_context, ld_closedef=.FALSE. ) ! for model grid (including possible AGRIF zoom)
122	IF( lk_diamlr ) CALL dia_mlr_iom_init ! with additional setup for multiple-linear-regression analysis
123	CALL iom_init_closedef
124	IF( ln_crs ) CALL iom_init( TRIM(cxios_context)//"_crs" ) ! for coarse grid
125	ENDIF
126	IF( kstp == nitrst .AND. lwxios ) THEN
127	CALL iom_swap( cw_ocerst_cxt )
128	CALL iom_init_closedef( cw_ocerst_cxt )
129	CALL iom_setkt( kstp - nit000 + 1, cw_ocerst_cxt )
130	#if defined key_top
131	CALL iom_swap( cw_toprst_cxt )
132	CALL iom_init_closedef( cw_toprst_cxt )
133	CALL iom_setkt( kstp - nit000 + 1, cw_toprst_cxt )
134	#endif
135	ENDIF
136	IF( kstp + nn_fsbc - 1 == nitrst .AND. lwxios ) THEN
137	#if defined key_si3
138	CALL iom_swap( cw_icerst_cxt )
139	CALL iom_init_closedef( cw_icerst_cxt )
140	CALL iom_setkt( kstp - nit000 + 1, cw_icerst_cxt )
141	#endif
142	IF( ln_abl ) THEN
143	CALL iom_swap( cw_ablrst_cxt )
144	CALL iom_init_closedef( cw_ablrst_cxt )
145	CALL iom_setkt( kstp - nit000 + 1, cw_ablrst_cxt )
146	ENDIF
147	ENDIF
148	IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init)
149	CALL iom_setkt( kstp - nit000 + 1, cxios_context ) ! tell IOM we are at time step kstp
150	IF( ln_crs ) CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" ) ! tell IOM we are at time step kstp
151
152	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
153	! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice)
154	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
155	IF( ln_tide ) CALL tide_update( kstp ) ! update tide potential
156	IF( ln_apr_dyn ) CALL sbc_apr ( kstp ) ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
157	IF( ln_bdy ) CALL bdy_dta ( kstp, Nnn ) ! update dynamic & tracer data at open boundaries
158	IF( ln_isf ) CALL isf_stp ( kstp, Nnn )
159	CALL sbc ( kstp, Nbb, Nnn ) ! Sea Boundary Condition (including sea-ice)
160
161	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
162	! Update stochastic parameters and random T/S fluctuations
163	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
164	IF( ln_sto_eos ) CALL sto_par( kstp ) ! Stochastic parameters
165	IF( ln_sto_eos ) CALL sto_pts( ts(:,:,:,:,Nnn) ) ! Random T/S fluctuations
166
167	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
168	! Ocean physics update
169	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
170	! THERMODYNAMICS
171	CALL eos_rab( CASTWP(ts(:,:,:,:,Nbb)), rab_b, Nnn ) ! before local thermal/haline expension ratio at T-points
172	CALL eos_rab( CASTWP(ts(:,:,:,:,Nnn)), rab_n, Nnn ) ! now local thermal/haline expension ratio at T-points
173	CALL bn2 ( CASTWP(ts(:,:,:,:,Nbb)), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency
174	CALL bn2 ( CASTWP(ts(:,:,:,:,Nnn)), rab_n, rn2, Nnn ) ! now Brunt-Vaisala frequency
175
176	! VERTICAL PHYSICS
177	CALL zdf_phy( kstp, Nbb, Nnn, Nrhs ) ! vertical physics update (top/bot drag, avt, avs, avm + MLD)
178
179	! LATERAL PHYSICS
180	!
181	IF( l_ldfslp ) THEN ! slope of lateral mixing
182	CALL eos( CASTWP(ts(:,:,:,:,Nbb)), rhd, gdept_0(:,:,:) ) ! before in situ density
183
184	IF( ln_zps .AND. .NOT. ln_isfcav) &
185	& CALL zps_hde ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, & ! Partial steps: before horizontal gradient
186	& rhd, gru , grv ) ! of t, s, rd at the last ocean level
187
188	IF( ln_zps .AND. ln_isfcav) &
189	& CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi, & ! Partial steps for top cell (ISF)
190	& rhd, gru , grv , grui, grvi ) ! of t, s, rd at the first ocean level
191	IF( ln_traldf_triad ) THEN
192	CALL ldf_slp_triad( kstp, Nbb, Nnn ) ! before slope for triad operator
193	ELSE
194	CALL ldf_slp ( kstp, rhd, rn2b, Nbb, Nnn ) ! before slope for standard operator
195	ENDIF
196	ENDIF
197	! ! eddy diffusivity coeff.
198	IF( l_ldftra_time .OR. l_ldfeiv_time ) CALL ldf_tra( kstp, Nbb, Nnn ) ! and/or eiv coeff.
199	IF( l_ldfdyn_time ) CALL ldf_dyn( kstp, Nbb ) ! eddy viscosity coeff.
200
201	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
202	! Ocean dynamics : hdiv, ssh, e3, u, v, w
203	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
204
205	CALL ssh_nxt ( kstp, Nbb, Nnn, ssh, Naa ) ! after ssh (includes call to div_hor)
206	IF( .NOT.ln_linssh ) &
207	& CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa ) ! after vertical scale factors
208	CALL wzv ( kstp, Nbb, Nnn, Naa, ww ) ! now cross-level velocity
209	IF( ln_zad_Aimp ) CALL wAimp ( kstp, Nnn ) ! Adaptive-implicit vertical advection partitioning
210	CALL eos ( ts(:,:,:,:,Nnn), rhd, rhop, gdept(:,:,:,Nnn) ) ! now in situ density for hpg computation
211
212
213	uu(:,:,:,Nrhs) = 0._wp ! set dynamics trends to zero
214	vv(:,:,:,Nrhs) = 0._wp
215
216	IF( lk_asminc .AND. ln_asmiau .AND. ln_dyninc ) &
217	& CALL dyn_asm_inc ( kstp, Nbb, Nnn, uu, vv, Nrhs ) ! apply dynamics assimilation increment
218	IF( ln_bdy ) CALL bdy_dyn3d_dmp ( kstp, Nbb, uu, vv, Nrhs ) ! bdy damping trends
219	#if defined key_agrif
220	IF(.NOT. Agrif_Root()) &
221	& CALL Agrif_Sponge_dyn ! momentum sponge
222	#endif
223	CALL dyn_adv( kstp, Nbb, Nnn , uu, vv, Nrhs ) ! advection (VF or FF) ==> RHS
224	CALL dyn_vor( kstp, Nnn , uu, vv, Nrhs ) ! vorticity ==> RHS
225	CALL dyn_ldf( kstp, Nbb, Nnn , uu, vv, Nrhs ) ! lateral mixing
226	IF( ln_zdfosm ) CALL dyn_osm( kstp, Nnn , uu, vv, Nrhs ) ! OSMOSIS non-local velocity fluxes ==> RHS
227	CALL dyn_hpg( kstp, Nnn , uu, vv, Nrhs ) ! horizontal gradient of Hydrostatic pressure
228	CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa ) ! surface pressure gradient
229
230	! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs) as well
231	IF( ln_dynspg_ts ) THEN ! vertical scale factors and vertical velocity need to be updated
232	CALL div_hor ( kstp, Nbb, Nnn ) ! Horizontal divergence (2nd call in time-split case)
233	IF(.NOT.ln_linssh) CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa, kcall=2 ) ! after vertical scale factors (update depth average component)
234	ENDIF
235	CALL dyn_zdf ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa ) ! vertical diffusion
236	IF( ln_dynspg_ts ) THEN ! vertical scale factors and vertical velocity need to be updated
237	CALL wzv ( kstp, Nbb, Nnn, Naa, ww ) ! Nnn cross-level velocity
238	IF( ln_zad_Aimp ) CALL wAimp ( kstp, Nnn ) ! Adaptive-implicit vertical advection partitioning
239	ENDIF
240
241
242	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
243	! cool skin
244	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
245	IF ( ln_diurnal ) CALL diurnal_layers( kstp )
246
247	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
248	! diagnostics and outputs
249	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
250	IF( ln_floats ) CALL flo_stp ( kstp, Nbb, Nnn ) ! drifting Floats
251	IF( ln_diacfl ) CALL dia_cfl ( kstp, Nnn ) ! Courant number diagnostics
252	CALL dia_hth ( kstp, Nnn ) ! Thermocline depth (20 degres isotherm depth)
253	IF( ln_diadct ) CALL dia_dct ( kstp, Nnn ) ! Transports
254	CALL dia_ar5 ( kstp, Nnn ) ! ar5 diag
255	CALL dia_ptr ( kstp, Nnn ) ! Poleward adv/ldf TRansports diagnostics
256	CALL dia_wri ( kstp, Nnn ) ! ocean model: outputs
257	IF( ln_crs ) CALL crs_fld ( kstp, Nnn ) ! ocean model: online field coarsening & output
258	IF( lk_diadetide ) CALL dia_detide( kstp ) ! Weights computation for daily detiding of model diagnostics
259	IF( lk_diamlr ) CALL dia_mlr ! Update time used in multiple-linear-regression analysis
260
261	#if defined key_top
262	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
263	! Passive Tracer Model
264	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
265	CALL trc_stp ( kstp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping
266	#endif
267
268	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
269	! Active tracers
270	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
271	! Loop over tile domains
272	DO jtile = 1, nijtile
273	IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
274
275	DO_3D( 0, 0, 0, 0, 1, jpk )
276	ts(ji,jj,jk,:,Nrhs) = 0._wp ! set tracer trends to zero
277	END_3D
278
279	IF( lk_asminc .AND. ln_asmiau .AND. &
280	& ln_trainc ) CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs ) ! apply tracer assimilation increment
281	CALL tra_sbc ( kstp, Nnn, ts, Nrhs ) ! surface boundary condition
282	IF( ln_traqsr ) CALL tra_qsr ( kstp, Nnn, ts, Nrhs ) ! penetrative solar radiation qsr
283	IF( ln_isf ) CALL tra_isf ( kstp, Nnn, ts, Nrhs ) ! ice shelf heat flux
284	IF( ln_trabbc ) CALL tra_bbc ( kstp, Nnn, ts, Nrhs ) ! bottom heat flux
285	IF( ln_trabbl ) CALL tra_bbl ( kstp, Nbb, Nnn, ts, Nrhs ) ! advective (and/or diffusive) bottom boundary layer scheme
286	IF( ln_tradmp ) CALL tra_dmp ( kstp, Nbb, Nnn, ts, Nrhs ) ! internal damping trends
287	IF( ln_bdy ) CALL bdy_tra_dmp( kstp, Nbb, ts, Nrhs ) ! bdy damping trends
288	END DO
289
290	#if defined key_agrif
291	IF(.NOT. Agrif_Root() ) THEN
292	IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
293	CALL Agrif_Sponge_tra ! tracers sponge
294	ENDIF
295	#endif
296
297	! TEMP: [tiling] Separate loop over tile domains (due to tra_adv workarounds for tiling)
298	DO jtile = 1, nijtile
299	IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
300
301	CALL tra_adv ( kstp, Nbb, Nnn, ts, Nrhs ) ! hor. + vert. advection ==> RHS
302	IF( ln_zdfmfc ) CALL tra_mfc ( kstp, Nbb, ts, Nrhs ) ! Mass Flux Convection
303	IF( ln_zdfosm ) THEN
304	CALL tra_osm ( kstp, Nnn, ts, Nrhs ) ! OSMOSIS non-local tracer fluxes ==> RHS
305	IF( lrst_oce ) CALL osm_rst ( kstp, Nnn, 'WRITE' ) ! write OSMOSIS outputs + ww (so must do here) to restarts
306	ENDIF
307	CALL tra_ldf ( kstp, Nbb, Nnn, ts, Nrhs ) ! lateral mixing
308
309	CALL tra_zdf ( kstp, Nbb, Nnn, Nrhs, ts, Naa ) ! vertical mixing and after tracer fields
310	IF( ln_zdfnpc ) CALL tra_npc ( kstp, Nnn, Nrhs, ts, Naa ) ! update after fields by non-penetrative convection
311	END DO
312
313	IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 ) ! Revert to tile over full domain
314	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
315	! Set boundary conditions, time filter and swap time levels
316	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
317	!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
318	!! (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
319	!! If so:
320	!! (i) no need to call agrif update at initialization time
321	!! (ii) no need to update "before" fields
322	!!
323	!! Apart from creating new tra_swp/dyn_swp routines, this however:
324	!! (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
325	!! two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
326	!! e.g. a shift of the feedback interface inside child domain.
327	!! (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
328	!! place.
329	!!
330	!!jc2: dynnxt must be the latest call. e3t(:,:,:,Nbb) are indeed updated in that routine
331	CALL tra_atf ( kstp, Nbb, Nnn, Naa, ts ) ! time filtering of "now" tracer arrays
332	CALL dyn_atf ( kstp, Nbb, Nnn, Naa, uu, vv, e3t, e3u, e3v ) ! time filtering of "now" velocities and scale factors
333	CALL ssh_atf ( kstp, Nbb, Nnn, Naa, ssh ) ! time filtering of "now" sea surface height
334	!
335	! Swap time levels
336	Nrhs = Nbb
337	Nbb = Nnn
338	Nnn = Naa
339	Naa = Nrhs
340	!
341	IF(.NOT.ln_linssh) CALL dom_vvl_sf_update( kstp, Nbb, Nnn, Naa ) ! recompute vertical scale factors
342	!
343	IF( ln_diahsb ) CALL dia_hsb ( kstp, Nbb, Nnn ) ! - ML - global conservation diagnostics
344
345	!!gm : This does not only concern the dynamics ==>>> add a new title
346	!!gm2: why ouput restart before AGRIF update?
347	!!
348	!!jc: That would be better, but see comment above
349	!!
350	IF( lrst_oce ) CALL rst_write ( kstp, Nbb, Nnn ) ! write output ocean restart file
351	IF( ln_sto_eos ) CALL sto_rst_write( kstp ) ! write restart file for stochastic parameters
352
353	#if defined key_agrif
354	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
355	! AGRIF recursive integration
356	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
357	Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices
358	CALL Agrif_Integrate_ChildGrids( stp ) ! allows to finish all the Child Grids before updating
359
360	#endif
361	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
362	! Control
363	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
364	CALL stp_ctl ( kstp, Nnn )
365
366	#if defined key_agrif
367	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
368	! AGRIF update
369	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
370	IF( Agrif_NbStepint() == 0 .AND. nstop == 0 ) &
371	& CALL Agrif_update_all( ) ! Update all components
372
373	#endif
374	IF( ln_diaobs .AND. nstop == 0 ) &
375	& CALL dia_obs( kstp, Nnn ) ! obs-minus-model (assimilation) diags (after dynamics update)
376
377	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
378	! File manipulation at the end of the first time step
379	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
380	IF( kstp == nit000 ) THEN ! 1st time step only
381	CALL iom_close( numror ) ! close input ocean restart file
382	IF( lrxios ) CALL iom_context_finalize( cr_ocerst_cxt )
383	IF(lwm) CALL FLUSH ( numond ) ! flush output namelist oce
384	IF(lwm .AND. numoni /= -1 ) CALL FLUSH ( numoni ) ! flush output namelist ice (if exist)
385	ENDIF
386
387	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
388	! Coupled mode
389	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
390	IF( lk_oasis .AND. nstop == 0 ) CALL sbc_cpl_snd( kstp, Nbb, Nnn ) ! coupled mode : field exchanges
391	!
392	#if defined key_xios
393	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
394	! Finalize contextes if end of simulation or error detected
395	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
396	IF( kstp == nitend .OR. nstop > 0 ) THEN
397	CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
398	IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
399	ENDIF
400	#endif
401	!
402	IF( l_1st_euler ) THEN ! recover Leap-frog timestep
403	rDt = 2._wp * rn_Dt
404	r1_Dt = 1._wp / rDt
405	l_1st_euler = .FALSE.
406	ENDIF
407	!
408	IF( ln_timing ) CALL timing_stop('stp')
409	!
410	END SUBROUTINE stp
411	!
412	#endif
413	!!======================================================================
414	END MODULE step

Note: See TracBrowser for help on using the repository browser.

Download in other formats: