1 | MODULE usrdef_zgr |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE usrdef_zgr *** |
---|
4 | !! |
---|
5 | !! === WAD_TEST_CASES case === |
---|
6 | !! |
---|
7 | !! Ocean domain : user defined vertical coordinate system |
---|
8 | !!====================================================================== |
---|
9 | !! History : 4.0 ! 2016-06 (G. Madec) Original code |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! usr_def_zgr : user defined vertical coordinate system (required) |
---|
14 | !! zgr_z : reference 1D z-coordinate |
---|
15 | !!--------------------------------------------------------------------- |
---|
16 | USE oce ! ocean variables |
---|
17 | USE dom_oce , ONLY: ht_0, mi0, mi1, nimpp, njmpp, & |
---|
18 | & mj0, mj1, glamt, gphit ! ocean space and time domain |
---|
19 | USE usrdef_nam ! User defined : namelist variables |
---|
20 | USE wet_dry , ONLY: rn_wdmin1, rn_wdmin2, rn_wdld ! Wetting and drying |
---|
21 | ! |
---|
22 | USE in_out_manager ! I/O manager |
---|
23 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
24 | USE lib_mpp ! distributed memory computing library |
---|
25 | |
---|
26 | IMPLICIT NONE |
---|
27 | PRIVATE |
---|
28 | |
---|
29 | PUBLIC usr_def_zgr ! called by domzgr.F90 |
---|
30 | |
---|
31 | !! * Substitutions |
---|
32 | # include "do_loop_substitute.h90" |
---|
33 | !!---------------------------------------------------------------------- |
---|
34 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
35 | !! $Id$ |
---|
36 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
37 | !!---------------------------------------------------------------------- |
---|
38 | CONTAINS |
---|
39 | |
---|
40 | SUBROUTINE usr_def_zgr( ld_zco , ld_zps , ld_sco , ld_isfcav, & ! type of vertical coordinate |
---|
41 | & pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d , & ! 1D reference vertical coordinate |
---|
42 | & pdept , pdepw , & ! 3D t & w-points depth |
---|
43 | & pe3t , pe3u , pe3v , pe3f , & ! vertical scale factors |
---|
44 | & pe3w , pe3uw , pe3vw , & ! - - - |
---|
45 | & k_top , k_bot ) ! top & bottom ocean level |
---|
46 | !!--------------------------------------------------------------------- |
---|
47 | !! *** ROUTINE usr_def_zgr *** |
---|
48 | !! |
---|
49 | !! ** Purpose : User defined the vertical coordinates |
---|
50 | !! |
---|
51 | !!---------------------------------------------------------------------- |
---|
52 | LOGICAL , INTENT(out) :: ld_zco, ld_zps, ld_sco ! vertical coordinate flags |
---|
53 | LOGICAL , INTENT(out) :: ld_isfcav ! under iceshelf cavity flag |
---|
54 | REAL(wp), DIMENSION(:) , INTENT(out) :: pdept_1d, pdepw_1d ! 1D grid-point depth [m] |
---|
55 | REAL(wp), DIMENSION(:) , INTENT(out) :: pe3t_1d , pe3w_1d ! 1D grid-point depth [m] |
---|
56 | REAL(wp), DIMENSION(:,:,:), INTENT(out) :: pdept, pdepw ! grid-point depth [m] |
---|
57 | REAL(wp), DIMENSION(:,:,:), INTENT(out) :: pe3t , pe3u , pe3v , pe3f ! vertical scale factors [m] |
---|
58 | REAL(wp), DIMENSION(:,:,:), INTENT(out) :: pe3w , pe3uw, pe3vw ! i-scale factors |
---|
59 | INTEGER , DIMENSION(:,:) , INTENT(out) :: k_top, k_bot ! first & last ocean level |
---|
60 | ! |
---|
61 | INTEGER :: ji, jj, jk ! dummy indices |
---|
62 | INTEGER :: ik ! local integers |
---|
63 | REAL(wp) :: zfact, z1_jpkm1 ! local scalar |
---|
64 | REAL(wp) :: ze3min ! local scalar |
---|
65 | REAL(wp) :: zi, zj, zbathy ! local scalar |
---|
66 | REAL(wp) :: ztmpu, ztmpv, ztmpf, ztmpu1, ztmpv1, ztmpf1, zwet |
---|
67 | REAL(wp), DIMENSION(jpi,jpj) :: zht, zhu, zhv, z2d ! 2D workspace |
---|
68 | !!---------------------------------------------------------------------- |
---|
69 | ! |
---|
70 | IF(lwp) WRITE(numout,*) |
---|
71 | IF(lwp) WRITE(numout,*) 'usr_def_zgr : WAD_TEST_CASES configuration (s-coordinate closed box ocean without cavities)' |
---|
72 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' |
---|
73 | ! |
---|
74 | ! |
---|
75 | ! type of vertical coordinate ==>>> here WAD_TEST_CASES : s-coordinate always |
---|
76 | ! --------------------------- |
---|
77 | ld_zco = .FALSE. ! z-partial-step coordinate |
---|
78 | ld_zps = .FALSE. ! z-partial-step coordinate |
---|
79 | ld_sco = .TRUE. ! s-coordinate |
---|
80 | ld_isfcav = .FALSE. ! ISF Ice Shelves Flag |
---|
81 | ! |
---|
82 | ! |
---|
83 | ! Build the vertical coordinate system |
---|
84 | ! ------------------------------------ |
---|
85 | ! |
---|
86 | ! !== UNmasked meter bathymetry ==! |
---|
87 | ! |
---|
88 | ! |
---|
89 | zbathy=10.0 |
---|
90 | IF( cn_cfg == 'wad' ) THEN |
---|
91 | SELECT CASE ( nn_cfg ) |
---|
92 | ! ! ==================== |
---|
93 | CASE ( 1 ) ! WAD 1 configuration |
---|
94 | ! ! ==================== |
---|
95 | ! |
---|
96 | IF(lwp) WRITE(numout,*) |
---|
97 | IF(lwp) WRITE(numout,*) 'usr_def_zgr (WAD) : Closed box with EW linear bottom slope' |
---|
98 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
99 | ! |
---|
100 | zht = 1.5_wp |
---|
101 | DO ji = 1, jpi |
---|
102 | zi = MIN((glamt(ji,1) - 10.0)/40.0, 1.0 ) |
---|
103 | zht(ji,:) = MAX(zbathy*zi, -2.0) |
---|
104 | END DO |
---|
105 | zht(mi0(1):mi1(1),:) = -4._wp |
---|
106 | zht(mi0(jpiglo):mi1(jpiglo),:) = -4._wp |
---|
107 | zht(:,mj0(1):mj1(1)) = -4._wp |
---|
108 | zht(:,mj0(jpjglo):mj1(jpjglo)) = -4._wp |
---|
109 | ! ! ==================== |
---|
110 | CASE ( 2, 3, 8 ) ! WAD 2 or 3 configuration |
---|
111 | ! ! ==================== |
---|
112 | ! |
---|
113 | IF(lwp) WRITE(numout,*) |
---|
114 | IF(lwp) WRITE(numout,*) 'usr_def_zgr (WAD) : Parobolic EW channel' |
---|
115 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
116 | ! |
---|
117 | DO ji = 1, jpi |
---|
118 | zi = MAX(1.0-((glamt(ji,1)-25.0)**2)/484.0, -0.3 ) |
---|
119 | zht(ji,:) = MAX(zbathy*zi, -2.0) |
---|
120 | END DO |
---|
121 | zht(mi0(1):mi1(1),:) = -4._wp |
---|
122 | zht(mi0(jpiglo):mi1(jpiglo),:) = -4._wp |
---|
123 | IF( nn_cfg /= 8 ) THEN |
---|
124 | zht(:,mj0(1):mj1(1)) = -4._wp |
---|
125 | zht(:,mj0(jpjglo):mj1(jpjglo)) = -4._wp |
---|
126 | ENDIF |
---|
127 | ! ! ==================== |
---|
128 | CASE ( 4 ) ! WAD 4 configuration |
---|
129 | ! ! ==================== |
---|
130 | ! |
---|
131 | IF(lwp) WRITE(numout,*) |
---|
132 | IF(lwp) WRITE(numout,*) 'usr_def_zgr (WAD) : Parobolic bowl' |
---|
133 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
134 | ! |
---|
135 | DO ji = 1, jpi |
---|
136 | zi = MAX(1.0-((glamt(ji,1)-25.0)**2)/484.0, -2.0 ) |
---|
137 | DO jj = 1, jpj |
---|
138 | zj = MAX(1.0-((gphit(1,jj)-17.0)**2)/196.0, -2.0 ) |
---|
139 | zht(ji,jj) = MAX(zbathy*zi*zj, -2.0) |
---|
140 | END DO |
---|
141 | END DO |
---|
142 | zht(mi0(1):mi1(1),:) = -4._wp |
---|
143 | zht(mi0(jpiglo):mi1(jpiglo),:) = -4._wp |
---|
144 | zht(:,mj0(1):mj1(1)) = -4._wp |
---|
145 | zht(:,mj0(jpjglo):mj1(jpjglo)) = -4._wp |
---|
146 | ! ! =========================== |
---|
147 | CASE ( 5 ) ! WAD 5 configuration |
---|
148 | ! ! ==================== |
---|
149 | ! |
---|
150 | IF(lwp) WRITE(numout,*) |
---|
151 | IF(lwp) WRITE(numout,*) 'usr_def_zgr (WAD) : Double slope with shelf' |
---|
152 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
153 | ! |
---|
154 | DO ji = 1, jpi |
---|
155 | zi = MIN(glamt(ji,1)/45.0, 1.0 ) |
---|
156 | zht(ji,:) = MAX(zbathy*zi, -2.0) |
---|
157 | IF( glamt(ji,1) >= 46.0 ) THEN |
---|
158 | zht(ji,:) = 10.0 |
---|
159 | ELSE IF( glamt(ji,1) >= 20.0 .AND. glamt(ji,1) < 46.0 ) THEN |
---|
160 | zi = 7.5/25. |
---|
161 | zht(ji,:) = MAX(10. - zi*(47.-glamt(ji,1)),2.5) |
---|
162 | ELSE IF( glamt(ji,1) >= 15.0 .AND. glamt(ji,1) < 20.0 ) THEN |
---|
163 | zht(ji,:) = 2.5 |
---|
164 | ELSE IF( glamt(ji,1) >= 4.0 .AND. glamt(ji,1) < 15.0 ) THEN |
---|
165 | zi = 4.5/11.0 |
---|
166 | zht(ji,:) = MAX(2.5 - zi*(16.0-glamt(ji,1)), -2.0) |
---|
167 | ELSE IF( glamt(ji,1) >= 0.0 .AND. glamt(ji,1) < 4.0 ) THEN |
---|
168 | zht(ji,:) = -2.0 |
---|
169 | ENDIF |
---|
170 | END DO |
---|
171 | ! ! =========================== |
---|
172 | zht(mi0(1):mi1(1),:) = -4._wp |
---|
173 | zht(mi0(jpiglo):mi1(jpiglo),:) = -4._wp |
---|
174 | zht(:,mj0(1):mj1(1)) = -4._wp |
---|
175 | zht(:,mj0(jpjglo):mj1(jpjglo)) = -4._wp |
---|
176 | ! ! =========================== |
---|
177 | CASE ( 6 ) ! WAD 6 configuration |
---|
178 | ! ! ==================== |
---|
179 | ! |
---|
180 | IF(lwp) WRITE(numout,*) |
---|
181 | IF(lwp) WRITE(numout,*) 'usr_def_zgr (WAD) : Parabolic channel with gaussian ridge' |
---|
182 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
183 | ! |
---|
184 | DO ji = 1, jpi |
---|
185 | zi = MAX(1.0-((glamt(ji,1)-25.0)**2)/484.0, -2.0 ) |
---|
186 | zj = 1.075*MAX(EXP(-1.0*((glamt(ji,1)-25.0)**2)/32.0) , 0.0 ) |
---|
187 | zht(ji,:) = MAX(zbathy*(zi-zj), -2.0) |
---|
188 | END DO |
---|
189 | zht(mi0(1):mi1(1),:) = -4._wp |
---|
190 | zht(mi0(jpiglo):mi1(jpiglo),:) = -4._wp |
---|
191 | zht(:,mj0(1):mj1(1)) = -4._wp |
---|
192 | zht(:,mj0(jpjglo):mj1(jpjglo)) = -4._wp |
---|
193 | ! ! =========================== |
---|
194 | CASE ( 7 ) ! WAD 7 configuration |
---|
195 | ! ! ==================== |
---|
196 | ! |
---|
197 | IF(lwp) WRITE(numout,*) |
---|
198 | IF(lwp) WRITE(numout,*) 'usr_def_zgr (WAD) : Double slope with open boundary' |
---|
199 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
200 | ! |
---|
201 | DO ji = 1, jpi |
---|
202 | zi = MIN(glamt(ji,1)/45.0, 1.0 ) |
---|
203 | zht(ji,:) = MAX(zbathy*zi, -2.0) |
---|
204 | IF( glamt(ji,1) >= 46.0 ) THEN |
---|
205 | zht(ji,:) = 10.0 |
---|
206 | ELSE IF( glamt(ji,1) >= 20.0 .AND. glamt(ji,1) < 46.0 ) THEN |
---|
207 | zi = 7.5/25. |
---|
208 | zht(ji,:) = MAX(10. - zi*(47.-glamt(ji,1)),2.5) |
---|
209 | ELSE IF( glamt(ji,1) >= 15.0 .AND. glamt(ji,1) < 20.0 ) THEN |
---|
210 | zht(ji,:) = 2.5 |
---|
211 | ELSE IF( glamt(ji,1) >= 4.0 .AND. glamt(ji,1) < 15.0 ) THEN |
---|
212 | zi = 4.5/11.0 |
---|
213 | zht(ji,:) = MAX(2.5 - zi*(16.0-glamt(ji,1)), -2.0) |
---|
214 | ELSE IF( glamt(ji,1) >= 0.0 .AND. glamt(ji,1) < 4.0 ) THEN |
---|
215 | zht(ji,:) = -2.0 |
---|
216 | ENDIF |
---|
217 | END DO |
---|
218 | ! ! =========================== |
---|
219 | zht(mi0(1):mi1(1),:) = -4._wp |
---|
220 | zht(:,mj0(1):mj1(1)) = -4._wp |
---|
221 | zht(:,mj0(jpjglo):mj1(jpjglo)) = -4._wp |
---|
222 | CASE DEFAULT |
---|
223 | ! ! =========================== |
---|
224 | WRITE(ctmp1,*) 'WAD test with a ', nn_cfg,' option is not coded' |
---|
225 | ! |
---|
226 | CALL ctl_stop( ctmp1 ) |
---|
227 | ! |
---|
228 | END SELECT |
---|
229 | END IF |
---|
230 | |
---|
231 | |
---|
232 | ! at u-point: averaging zht |
---|
233 | DO ji = 1, jpim1 |
---|
234 | zhu(ji,:) = 0.5_wp * ( zht(ji,:) + zht(ji+1,:) ) |
---|
235 | END DO |
---|
236 | CALL lbc_lnk( 'usrdef_zgr', zhu, 'U', 1. ) ! boundary condition: this mask the surrounding grid-points |
---|
237 | ! ! ==>>> set by hand non-zero value on first/last columns & rows |
---|
238 | DO ji = mi0(1), mi1(1) ! first row of global domain only |
---|
239 | zhu(ji,:) = zht(1,:) |
---|
240 | END DO |
---|
241 | DO ji = mi0(jpiglo), mi1(jpiglo) ! last row of global domain only |
---|
242 | zhu(ji,:) = zht(jpi,:) |
---|
243 | END DO |
---|
244 | ! at v-point: averaging zht |
---|
245 | zhv = 0._wp |
---|
246 | DO_2D_00_00 |
---|
247 | zhv(ji,jj) = 0.5_wp * ( zht(ji,jj) + zht(ji,jj+1) ) |
---|
248 | END_2D |
---|
249 | CALL lbc_lnk( 'usrdef_zgr', zhv, 'V', 1. ) ! boundary condition: this mask the surrounding grid-points |
---|
250 | DO jj = mj0(1), mj1(1) ! first row of global domain only |
---|
251 | zhv(:,jj) = zht(:,jj) |
---|
252 | END DO |
---|
253 | DO jj = mj0(jpjglo), mj1(jpjglo) ! last row of global domain only |
---|
254 | zhv(:,jj) = zht(:,jj) |
---|
255 | END DO |
---|
256 | ! |
---|
257 | CALL zgr_z( pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d ) ! Reference z-coordinate system |
---|
258 | ! |
---|
259 | ! |
---|
260 | ! !== top masked level bathymetry ==! (all coordinates) |
---|
261 | ! |
---|
262 | ! no ocean cavities : top ocean level is ONE, except over land |
---|
263 | ! the ocean basin surrounnded by land (1 grid-point) set through lbc_lnk call as jperio=0 |
---|
264 | z2d(:,:) = 1._wp ! surface ocean is the 1st level |
---|
265 | z2d(mi0(1):mi1(1),:) = 0._wp |
---|
266 | z2d(mi0(jpiglo):mi1(jpiglo),:) = 0._wp |
---|
267 | z2d(:,mj0(1):mj1(1)) = 0._wp |
---|
268 | z2d(:,mj0(jpjglo):mj1(jpjglo)) = 0._wp |
---|
269 | |
---|
270 | |
---|
271 | |
---|
272 | |
---|
273 | |
---|
274 | CALL lbc_lnk( 'usrdef_zgr', z2d, 'T', 1. ) ! closed basin since jperio = 0 (see userdef_nam.F90) |
---|
275 | k_top(:,:) = NINT( z2d(:,:) ) |
---|
276 | ! |
---|
277 | ! |
---|
278 | ! |
---|
279 | IF ( ld_sco ) THEN !== s-coordinate ==! (terrain-following coordinate) |
---|
280 | ! |
---|
281 | ht_0 = zht |
---|
282 | k_bot(:,:) = jpkm1 * k_top(:,:) !* bottom ocean = jpk-1 (here use k_top as a land mask) |
---|
283 | DO_2D_11_11 |
---|
284 | IF( zht(ji,jj) <= -(rn_wdld - rn_wdmin2)) THEN |
---|
285 | k_bot(ji,jj) = 0 |
---|
286 | k_top(ji,jj) = 0 |
---|
287 | ENDIF |
---|
288 | END_2D |
---|
289 | ! |
---|
290 | ! !* terrain-following coordinate with e3.(k)=cst) |
---|
291 | ! ! OVERFLOW case : identical with j-index (T=V, U=F) |
---|
292 | DO_2D_00_00 |
---|
293 | z1_jpkm1 = 1._wp / REAL( k_bot(ji,jj) - k_top(ji,jj) + 1 , wp) |
---|
294 | DO jk = 1, jpk |
---|
295 | zwet = MAX( zht(ji,jj), rn_wdmin1 ) |
---|
296 | pdept(ji,jj,jk) = zwet * z1_jpkm1 * ( REAL( jk , wp ) - 0.5_wp ) |
---|
297 | pdepw(ji,jj,jk) = zwet * z1_jpkm1 * ( REAL( jk-1 , wp ) ) |
---|
298 | pe3t (ji,jj,jk) = zwet * z1_jpkm1 |
---|
299 | pe3w (ji,jj,jk) = zwet * z1_jpkm1 |
---|
300 | zwet = MAX( zhu(ji,jj), rn_wdmin1 ) |
---|
301 | pe3u (ji,jj,jk) = zwet * z1_jpkm1 |
---|
302 | pe3uw(ji,jj,jk) = zwet * z1_jpkm1 |
---|
303 | pe3f (ji,jj,jk) = zwet * z1_jpkm1 |
---|
304 | zwet = MAX( zhv(ji,jj), rn_wdmin1 ) |
---|
305 | pe3v (ji,jj,jk) = zwet * z1_jpkm1 |
---|
306 | pe3vw(ji,jj,jk) = zwet * z1_jpkm1 |
---|
307 | END DO |
---|
308 | END_2D |
---|
309 | CALL lbc_lnk( 'usrdef_zgr', pdept, 'T', 1. ) |
---|
310 | CALL lbc_lnk( 'usrdef_zgr', pdepw, 'T', 1. ) |
---|
311 | CALL lbc_lnk( 'usrdef_zgr', pe3t , 'T', 1. ) |
---|
312 | CALL lbc_lnk( 'usrdef_zgr', pe3w , 'T', 1. ) |
---|
313 | CALL lbc_lnk( 'usrdef_zgr', pe3u , 'U', 1. ) |
---|
314 | CALL lbc_lnk( 'usrdef_zgr', pe3uw, 'U', 1. ) |
---|
315 | CALL lbc_lnk( 'usrdef_zgr', pe3f , 'F', 1. ) |
---|
316 | CALL lbc_lnk( 'usrdef_zgr', pe3v , 'V', 1. ) |
---|
317 | CALL lbc_lnk( 'usrdef_zgr', pe3vw, 'V', 1. ) |
---|
318 | WHERE( pe3t (:,:,:) == 0._wp ) pe3t (:,:,:) = 1._wp |
---|
319 | WHERE( pe3u (:,:,:) == 0._wp ) pe3u (:,:,:) = 1._wp |
---|
320 | WHERE( pe3v (:,:,:) == 0._wp ) pe3v (:,:,:) = 1._wp |
---|
321 | WHERE( pe3f (:,:,:) == 0._wp ) pe3f (:,:,:) = 1._wp |
---|
322 | WHERE( pe3w (:,:,:) == 0._wp ) pe3w (:,:,:) = 1._wp |
---|
323 | WHERE( pe3uw(:,:,:) == 0._wp ) pe3uw(:,:,:) = 1._wp |
---|
324 | WHERE( pe3vw(:,:,:) == 0._wp ) pe3vw(:,:,:) = 1._wp |
---|
325 | ENDIF |
---|
326 | ! |
---|
327 | ! |
---|
328 | ! |
---|
329 | END SUBROUTINE usr_def_zgr |
---|
330 | |
---|
331 | |
---|
332 | SUBROUTINE zgr_z( pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d ) ! 1D reference vertical coordinate |
---|
333 | !!---------------------------------------------------------------------- |
---|
334 | !! *** ROUTINE zgr_z *** |
---|
335 | !! |
---|
336 | !! ** Purpose : set the depth of model levels and the resulting |
---|
337 | !! vertical scale factors. |
---|
338 | !! |
---|
339 | !! ** Method : 1D z-coordinate system (use in all type of coordinate) |
---|
340 | !! The depth of model levels is set from dep(k), an analytical function: |
---|
341 | !! w-level: depw_1d = dep(k) |
---|
342 | !! t-level: dept_1d = dep(k+0.5) |
---|
343 | !! The scale factors are the discrete derivative of the depth: |
---|
344 | !! e3w_1d(jk) = dk[ dept_1d ] |
---|
345 | !! e3t_1d(jk) = dk[ depw_1d ] |
---|
346 | !! |
---|
347 | !! === Here constant vertical resolution === |
---|
348 | !! |
---|
349 | !! ** Action : - pdept_1d, pdepw_1d : depth of T- and W-point (m) |
---|
350 | !! - pe3t_1d , pe3w_1d : scale factors at T- and W-levels (m) |
---|
351 | !!---------------------------------------------------------------------- |
---|
352 | REAL(wp), DIMENSION(:), INTENT(out) :: pdept_1d, pdepw_1d ! 1D grid-point depth [m] |
---|
353 | REAL(wp), DIMENSION(:), INTENT(out) :: pe3t_1d , pe3w_1d ! 1D vertical scale factors [m] |
---|
354 | ! |
---|
355 | INTEGER :: jk ! dummy loop indices |
---|
356 | REAL(wp) :: zt, zw ! local scalar |
---|
357 | !!---------------------------------------------------------------------- |
---|
358 | ! |
---|
359 | IF(lwp) THEN ! Parameter print |
---|
360 | WRITE(numout,*) |
---|
361 | WRITE(numout,*) ' zgr_z : Reference vertical z-coordinates: uniform dz = ', rn_dz |
---|
362 | WRITE(numout,*) ' ~~~~~~~' |
---|
363 | ENDIF |
---|
364 | ! |
---|
365 | ! Reference z-coordinate (depth - scale factor at T- and W-points) ! Madec & Imbard 1996 function |
---|
366 | ! ---------------------- |
---|
367 | DO jk = 1, jpk |
---|
368 | zw = REAL( jk , wp ) |
---|
369 | zt = REAL( jk , wp ) + 0.5_wp |
---|
370 | pdepw_1d(jk) = rn_dz * REAL( jk-1 , wp ) |
---|
371 | pdept_1d(jk) = rn_dz * ( REAL( jk-1 , wp ) + 0.5_wp ) |
---|
372 | pe3w_1d (jk) = rn_dz |
---|
373 | pe3t_1d (jk) = rn_dz |
---|
374 | END DO |
---|
375 | ! |
---|
376 | IF(lwp) THEN ! control print |
---|
377 | WRITE(numout,*) |
---|
378 | WRITE(numout,*) ' Reference 1D z-coordinate depth and scale factors:' |
---|
379 | WRITE(numout, "(9x,' level gdept_1d gdepw_1d e3t_1d e3w_1d ')" ) |
---|
380 | WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, pdept_1d(jk), pdepw_1d(jk), pe3t_1d(jk), pe3w_1d(jk), jk = 1, jpk ) |
---|
381 | ENDIF |
---|
382 | ! |
---|
383 | END SUBROUTINE zgr_z |
---|
384 | |
---|
385 | !!====================================================================== |
---|
386 | END MODULE usrdef_zgr |
---|