Context Navigation

icestp.F90 @ 15648

Last change on this file since 15648 was 15648, checked in by sparonuz, 2 years ago
Updated name preprocessor function CASTWP to CASTDP
Property svn:keywords set to `Id`
File size: 26.2 KB

Line
1	MODULE icestp
2	!!======================================================================
3	!! * MODULE icestp *
4	!! sea ice : Master routine for all the sea ice model
5	!!=====================================================================
6	!!
7	!! The sea ice model SI3 (Sea Ice modelling Integrated Initiative),
8	!! aka Sea Ice cube for its nickname
9	!!
10	!! is originally based on LIM3, developed in Louvain-la-Neuve by:
11	!! * Martin Vancoppenolle (UCL-ASTR, Belgium)
12	!! * Sylvain Bouillon (UCL-ASTR, Belgium)
13	!! * Miguel Angel Morales Maqueda (NOC-L, UK)
14	!! thanks to valuable earlier work by
15	!! * Thierry Fichefet
16	!! * Hugues Goosse
17	!! thanks also to the following persons who contributed
18	!! * Gurvan Madec, Claude Talandier, Christian Ethe (LOCEAN, France)
19	!! * Xavier Fettweis (UCL-ASTR), Ralph Timmermann (AWI, Germany)
20	!! * Bill Lipscomb (LANL), Cecilia Bitz (UWa) and Elisabeth Hunke (LANL), USA.
21	!!
22	!! SI3 has been made possible by a handful of persons who met as working group
23	!! (from France, Belgium, UK and Italy)
24	!! * Clement Rousset, Martin Vancoppenolle & Gurvan Madec (LOCEAN, France)
25	!! * Matthieu Chevalier & David Salas (Meteo France, France)
26	!! * Gilles Garric (Mercator Ocean, France)
27	!! * Thierry Fichefet & Francois Massonnet (UCL, Belgium)
28	!! * Ed Blockley & Jeff Ridley (Met Office, UK)
29	!! * Danny Feltham & David Schroeder (CPOM, UK)
30	!! * Yevgeny Aksenov (NOC, UK)
31	!! * Paul Holland (BAS, UK)
32	!! * Dorotea Iovino (CMCC, Italy)
33	!!======================================================================
34	!! History : 4.0 ! 2018 (C. Rousset) Original code SI3
35	!!----------------------------------------------------------------------
36	#if defined key_si3
37	!!----------------------------------------------------------------------
38	!! 'key_si3' SI3 sea-ice model
39	!!----------------------------------------------------------------------
40	!! ice_stp : sea-ice model time-stepping and update ocean SBC over ice-covered area
41	!! ice_init : initialize sea-ice
42	!!----------------------------------------------------------------------
43	USE oce ! ocean dynamics and tracers
44	USE dom_oce ! ocean space and time domain
45	USE c1d ! 1D vertical configuration
46	USE ice ! sea-ice: variables
47	USE ice1D ! sea-ice: thermodynamical 1D variables
48	!
49	USE phycst ! Define parameters for the routines
50	USE eosbn2 ! equation of state
51	USE sbc_oce ! Surface boundary condition: ocean fields
52	USE sbc_ice ! Surface boundary condition: ice fields
53	!
54	USE icesbc ! sea-ice: Surface boundary conditions
55	USE icedyn ! sea-ice: dynamics
56	USE icethd ! sea-ice: thermodynamics
57	USE iceupdate ! sea-ice: sea surface boundary condition update
58	USE icedia ! sea-ice: budget diagnostics
59	USE icewri ! sea-ice: outputs
60	USE icerst ! sea-ice: restarts
61	USE icevar ! sea-ice: operations
62	USE icectl ! sea-ice: control
63	USE iceistate ! sea-ice: initial state
64	USE iceitd ! sea-ice: remapping thickness distribution
65	USE icealb ! sea-ice: albedo
66	!
67	USE bdy_oce , ONLY : ln_bdy ! flag for bdy
68	USE bdyice ! unstructured open boundary data for sea-ice
69	# if defined key_agrif
70	USE agrif_ice
71	USE agrif_ice_interp
72	# endif
73	!
74	USE in_out_manager ! I/O manager
75	USE iom ! I/O manager library
76	USE lib_mpp ! MPP library
77	USE lib_fortran ! fortran utilities (glob_sum + no signed zero)
78	USE timing ! Timing
79	USE prtctl ! Print control
80
81	IMPLICIT NONE
82	PRIVATE
83
84	PUBLIC ice_stp ! called by sbcmod.F90
85	PUBLIC ice_init ! called by sbcmod.F90
86
87	!! * Substitutions
88	# include "do_loop_substitute.h90"
89	# include "single_precision_substitute.h90"
90	!!----------------------------------------------------------------------
91	!! NEMO/ICE 4.0 , NEMO Consortium (2018)
92	!! $Id$
93	!! Software governed by the CeCILL license (see ./LICENSE)
94	!!----------------------------------------------------------------------
95	CONTAINS
96
97	SUBROUTINE ice_stp( kt, Kbb, Kmm, ksbc )
98	!!---------------------------------------------------------------------
99	!! * ROUTINE ice_stp *
100	!!
101	!! ** Purpose : sea-ice model time-stepping and update ocean surface
102	!! boundary condition over ice-covered area
103	!!
104	!! ** Method : ice model time stepping
105	!! - call the ice dynamics routine
106	!! - call the ice advection/diffusion routine
107	!! - call the ice thermodynamics routine
108	!! - call the routine that computes mass and
109	!! heat fluxes at the ice/ocean interface
110	!! - save the outputs
111	!! - save the outputs for restart when necessary
112	!!
113	!! ** Action : - time evolution of the LIM sea-ice model
114	!! - update all sbc variables below sea-ice:
115	!! utau, vtau, taum, wndm, qns , qsr, emp , sfx
116	!!---------------------------------------------------------------------
117	INTEGER, INTENT(in) :: kt ! ocean time step
118	INTEGER, INTENT(in) :: Kbb, Kmm ! ocean time level indices
119	INTEGER, INTENT(in) :: ksbc ! flux formulation (user defined, bulk, or Pure Coupled)
120	!
121	INTEGER :: jl ! dummy loop index
122	!!----------------------------------------------------------------------
123	!
124	IF( ln_timing ) CALL timing_start('icestp')
125	!
126	! !-----------------------!
127	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! --- Ice time step --- !
128	! !-----------------------!
129	!
130	kt_ice = kt ! -- Ice model time step
131	!
132	u_oce(:,:) = ssu_m(:,:) ! -- mean surface ocean current
133	v_oce(:,:) = ssv_m(:,:)
134	!
135	CALL eos_fzp( sss_m(:,:) , t_bo(:,:) ) ! -- freezing temperature [Kelvin] (set to rt0 over land)
136	t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
137	!
138	! !== AGRIF Parent to Child ==!
139	#if defined key_agrif
140	! ! nbstep_ice ranges from 1 to the nb of child ocean steps inside one parent ice step
141	IF( .NOT. Agrif_Root() ) nbstep_ice = MOD( nbstep_ice, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) + 1
142	! ! these calls must remain here for restartability purposes
143	CALL agrif_interp_ice( 'T' )
144	CALL agrif_interp_ice( 'U' )
145	CALL agrif_interp_ice( 'V' )
146	#endif
147	CALL store_fields ! Store now ice values
148	!
149	!------------------------------------------------!
150	! --- Dynamical coupling with the atmosphere --- !
151	!------------------------------------------------!
152	! It provides the following fields used in sea ice model:
153	! utau_ice, vtau_ice = surface ice stress [N/m2]
154	!------------------------------------------------!
155	CALL ice_sbc_tau( kt, ksbc, utau_ice, vtau_ice )
156	!-------------------------------------!
157	! --- ice dynamics and advection --- !
158	!-------------------------------------!
159	CALL diag_set0 ! set diag of mass, heat and salt fluxes to 0
160	CALL ice_rst_opn( kt ) ! Open Ice restart file (if necessary)
161	!
162	IF( ln_icedyn .AND. .NOT.lk_c1d ) &
163	& CALL ice_dyn( kt, Kmm ) ! -- Ice dynamics
164	!
165	CALL diag_trends( 1 ) ! record dyn trends
166	!
167	! !== lateral boundary conditions ==!
168	IF( ln_icethd .AND. ln_bdy ) CALL bdy_ice( kt ) ! -- bdy ice thermo
169	!
170	! !== previous lead fraction and ice volume for flux calculations
171	CALL ice_var_glo2eqv ! h_i and h_s for ice albedo calculation
172	CALL ice_var_agg(1) ! at_i for coupling
173	CALL store_fields ! Store now ice values
174	!
175	!------------------------------------------------------!
176	! --- Thermodynamical coupling with the atmosphere --- !
177	!------------------------------------------------------!
178	! It provides the following fields used in sea ice model:
179	! emp_oce , emp_ice = E-P over ocean and sea ice [Kg/m2/s]
180	! sprecip = solid precipitation [Kg/m2/s]
181	! evap_ice = sublimation [Kg/m2/s]
182	! qsr_tot , qns_tot = solar & non solar heat flux (total) [W/m2]
183	! qsr_ice , qns_ice = solar & non solar heat flux over ice [W/m2]
184	! dqns_ice = non solar heat sensistivity [W/m2]
185	! qemp_oce, qemp_ice, = sensible heat (associated with evap & precip) [W/m2]
186	! qprec_ice, qevap_ice
187	!------------------------------------------------------!
188	CALL ice_sbc_flx( kt, ksbc )
189	!----------------------------!
190	! --- ice thermodynamics --- !
191	!----------------------------!
192	IF( ln_icethd ) CALL ice_thd( kt ) ! -- Ice thermodynamics
193	!
194	CALL diag_trends( 2 ) ! record thermo trends
195	CALL ice_var_glo2eqv ! necessary calls (at least for coupling)
196	CALL ice_var_agg( 2 ) ! necessary calls (at least for coupling)
197	!
198	CALL ice_update_flx( kt ) ! -- Update ocean surface mass, heat and salt fluxes
199	!
200	IF( ln_icediahsb ) CALL ice_dia( kt ) ! -- Diagnostics outputs
201	!
202	IF( ln_icediachk ) CALL ice_drift_wri( kt ) ! -- Diagnostics outputs for conservation
203	!
204	CALL ice_wri( kt ) ! -- Ice outputs
205	!
206	IF( lrst_ice ) CALL ice_rst_write( kt ) ! -- Ice restart file
207	!
208	IF( ln_icectl ) CALL ice_ctl( kt ) ! -- Control checks
209	!
210	ENDIF ! End sea-ice time step only
211
212	!-------------------------!
213	! --- Ocean time step --- !
214	!-------------------------!
215	CALL ice_update_tau( kt, CASTDP(uu(:,:,1,Kbb)), CASTDP(vv(:,:,1,Kbb)) ) ! -- update surface ocean stresses
216	!!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!!
217	!
218	IF( ln_timing ) CALL timing_stop('icestp')
219	!
220	END SUBROUTINE ice_stp
221
222
223	SUBROUTINE ice_init( Kbb, Kmm, Kaa )
224	!!----------------------------------------------------------------------
225	!! * ROUTINE ice_init *
226	!!
227	!! ** purpose : Initialize sea-ice parameters
228	!!----------------------------------------------------------------------
229	INTEGER, INTENT(in) :: Kbb, Kmm, Kaa
230	!
231	INTEGER :: ierr
232	!!----------------------------------------------------------------------
233	IF(lwp) WRITE(numout,*)
234	IF(lwp) WRITE(numout,*) 'Sea Ice Model: SI3 (Sea Ice modelling Integrated Initiative)'
235	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
236	IF(lwp) WRITE(numout,*)
237	IF(lwp) WRITE(numout,*) 'ice_init: Arrays allocation & Initialization of all routines & init state'
238	IF(lwp) WRITE(numout,*) '~~~~~~~~'
239	!
240	! ! Load the reference and configuration namelist files and open namelist output file
241	CALL load_nml( numnam_ice_ref, 'namelist_ice_ref', numout, lwm )
242	CALL load_nml( numnam_ice_cfg, 'namelist_ice_cfg', numout, lwm )
243	IF(lwm) CALL ctl_opn( numoni , 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
244	!
245	CALL par_init ! set some ice run parameters
246	!
247	#if defined key_agrif
248	CALL Agrif_Declare_Var_ice ! " " " " " Sea ice
249	#endif
250	!
251	! ! Allocate the ice arrays (sbc_ice already allocated in sbc_init)
252	ierr = ice_alloc () ! ice variables
253	ierr = ierr + sbc_ice_alloc () ! surface boundary conditions
254	ierr = ierr + ice1D_alloc () ! thermodynamics
255	!
256	CALL mpp_sum( 'icestp', ierr )
257	IF( ierr /= 0 ) CALL ctl_stop('STOP', 'ice_init : unable to allocate ice arrays')
258	!
259	! ! set max concentration in both hemispheres
260	WHERE( gphit(:,:) > 0._wp ) ; rn_amax_2d(:,:) = rn_amax_n ! NH
261	ELSEWHERE ; rn_amax_2d(:,:) = rn_amax_s ! SH
262	END WHERE
263	!
264	CALL diag_set0 ! set diag of mass, heat and salt fluxes to 0: needed for Agrif child grids
265	!
266	CALL ice_itd_init ! ice thickness distribution initialization
267	!
268	CALL ice_thd_init ! set ice thermodynics parameters (clem: important to call it first for melt ponds)
269	!
270	CALL ice_sbc_init ! set ice-ocean and ice-atm. coupling parameters
271	!
272	CALL ice_istate_init ! Initial sea-ice state
273	IF ( ln_rstart .OR. nn_iceini_file == 2 ) THEN
274	CALL ice_rst_read( Kbb, Kmm, Kaa ) ! start from a restart file
275	ELSE
276	CALL ice_istate( nit000, Kbb, Kmm, Kaa ) ! start from rest or read a file
277	ENDIF
278	CALL ice_var_glo2eqv
279	CALL ice_var_agg(1)
280	!
281	CALL ice_dyn_init ! set ice dynamics parameters
282	!
283	CALL ice_update_init ! ice surface boundary condition
284	!
285	CALL ice_alb_init ! ice surface albedo
286	!
287	CALL ice_dia_init ! initialization for diags
288	!
289	CALL ice_drift_init ! initialization for diags of conservation
290	!
291	fr_i (:,:) = at_i(:,:) ! initialisation of sea-ice fraction
292	tn_ice(:,:,:) = t_su(:,:,:) ! initialisation of surface temp for coupled simu
293	!
294	IF( ln_rstart ) THEN
295	CALL iom_close( numrir ) ! close input ice restart file
296	IF(lrxios) CALL iom_context_finalize( cr_icerst_cxt )
297	ENDIF
298	!
299	END SUBROUTINE ice_init
300
301
302	SUBROUTINE par_init
303	!!-------------------------------------------------------------------
304	!! * ROUTINE par_init *
305	!!
306	!! ** Purpose : Definition generic parameters for ice model
307	!!
308	!! ** Method : Read namelist and check the parameter
309	!! values called at the first timestep (nit000)
310	!!
311	!! ** input : Namelist nampar
312	!!-------------------------------------------------------------------
313	INTEGER :: ios ! Local integer
314	!!
315	NAMELIST/nampar/ jpl, nlay_i, nlay_s, ln_virtual_itd, ln_icedyn, ln_icethd, rn_amax_n, rn_amax_s, &
316	& cn_icerst_in, cn_icerst_indir, cn_icerst_out, cn_icerst_outdir
317	!!-------------------------------------------------------------------
318	!
319	READ ( numnam_ice_ref, nampar, IOSTAT = ios, ERR = 901)
320	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampar in reference namelist' )
321	READ ( numnam_ice_cfg, nampar, IOSTAT = ios, ERR = 902 )
322	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'nampar in configuration namelist' )
323	IF(lwm) WRITE( numoni, nampar )
324	!
325	IF(lwp) THEN ! control print
326	WRITE(numout,*)
327	WRITE(numout,*) ' par_init: ice parameters shared among all the routines'
328	WRITE(numout,*) ' ~~~~~~~~'
329	WRITE(numout,*) ' Namelist nampar: '
330	WRITE(numout,*) ' number of ice categories jpl = ', jpl
331	WRITE(numout,*) ' number of ice layers nlay_i = ', nlay_i
332	WRITE(numout,*) ' number of snow layers nlay_s = ', nlay_s
333	WRITE(numout,*) ' virtual ITD param for jpl=1 (T) or not (F) ln_virtual_itd = ', ln_virtual_itd
334	WRITE(numout,*) ' Ice dynamics (T) or not (F) ln_icedyn = ', ln_icedyn
335	WRITE(numout,*) ' Ice thermodynamics (T) or not (F) ln_icethd = ', ln_icethd
336	WRITE(numout,*) ' maximum ice concentration for NH = ', rn_amax_n
337	WRITE(numout,*) ' maximum ice concentration for SH = ', rn_amax_s
338	ENDIF
339	! !--- change max ice concentration for roundoff errors
340	rn_amax_n = MIN( rn_amax_n, 1._wp - epsi10 )
341	rn_amax_s = MIN( rn_amax_s, 1._wp - epsi10 )
342	! !--- check consistency
343	IF ( jpl > 1 .AND. ln_virtual_itd ) THEN
344	ln_virtual_itd = .FALSE.
345	IF(lwp) WRITE(numout,*)
346	IF(lwp) WRITE(numout,*) ' ln_virtual_itd forced to false as jpl>1, no need with multiple categories to emulate them'
347	ENDIF
348	!
349	IF( ln_cpl .AND. nn_cats_cpl /= 1 .AND. nn_cats_cpl /= jpl ) THEN
350	CALL ctl_stop( 'STOP', 'par_init: in coupled mode, nn_cats_cpl should be either 1 or jpl' )
351	ENDIF
352	!
353	rDt_ice = REAL(nn_fsbc) * rn_Dt !--- sea-ice timestep and its inverse
354	r1_Dt_ice = 1._wp / rDt_ice
355	IF(lwp) WRITE(numout,*)
356	IF(lwp) WRITE(numout,) ' ice timestep rDt_ice = nn_fsbcrn_Dt = ', rDt_ice
357	!
358	r1_nlay_i = 1._wp / REAL( nlay_i, wp ) !--- inverse of nlay_i and nlay_s
359	r1_nlay_s = 1._wp / REAL( nlay_s, wp )
360	!
361	END SUBROUTINE par_init
362
363
364	SUBROUTINE store_fields
365	!!----------------------------------------------------------------------
366	!! * ROUTINE store_fields *
367	!!
368	!! ** purpose : store ice variables at "before" time step
369	!!----------------------------------------------------------------------
370	INTEGER :: ji, jj, jl ! dummy loop index
371	!!----------------------------------------------------------------------
372	!
373	a_i_b (:,:,:) = a_i (:,:,:) ! ice area
374	v_i_b (:,:,:) = v_i (:,:,:) ! ice volume
375	v_s_b (:,:,:) = v_s (:,:,:) ! snow volume
376	v_ip_b(:,:,:) = v_ip(:,:,:) ! pond volume
377	v_il_b(:,:,:) = v_il(:,:,:) ! pond lid volume
378	sv_i_b(:,:,:) = sv_i(:,:,:) ! salt content
379	e_s_b (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy
380	e_i_b (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy
381	WHERE( a_i_b(:,:,:) >= epsi20 )
382	h_i_b(:,:,:) = v_i_b(:,:,:) / a_i_b(:,:,:) ! ice thickness
383	h_s_b(:,:,:) = v_s_b(:,:,:) / a_i_b(:,:,:) ! snw thickness
384	ELSEWHERE
385	h_i_b(:,:,:) = 0._wp
386	h_s_b(:,:,:) = 0._wp
387	END WHERE
388	!
389	! ice velocities & total concentration
390	at_i_b(:,:) = SUM( a_i_b(:,:,:), dim=3 )
391	u_ice_b(:,:) = u_ice(:,:)
392	v_ice_b(:,:) = v_ice(:,:)
393	!
394	END SUBROUTINE store_fields
395
396
397	SUBROUTINE diag_set0
398	!!----------------------------------------------------------------------
399	!! * ROUTINE diag_set0 *
400	!!
401	!! ** purpose : set ice-ocean and ice-atm. fluxes to zeros at the beggining
402	!! of the time step
403	!!----------------------------------------------------------------------
404	INTEGER :: ji, jj, jl ! dummy loop index
405	!!----------------------------------------------------------------------
406
407	DO_2D( 1, 1, 1, 1 )
408	sfx (ji,jj) = 0._wp ;
409	sfx_bri(ji,jj) = 0._wp ; sfx_lam(ji,jj) = 0._wp
410	sfx_sni(ji,jj) = 0._wp ; sfx_opw(ji,jj) = 0._wp
411	sfx_bog(ji,jj) = 0._wp ; sfx_dyn(ji,jj) = 0._wp
412	sfx_bom(ji,jj) = 0._wp ; sfx_sum(ji,jj) = 0._wp
413	sfx_res(ji,jj) = 0._wp ; sfx_sub(ji,jj) = 0._wp
414	!
415	wfx_snw(ji,jj) = 0._wp ; wfx_ice(ji,jj) = 0._wp
416	wfx_sni(ji,jj) = 0._wp ; wfx_opw(ji,jj) = 0._wp
417	wfx_bog(ji,jj) = 0._wp ; wfx_dyn(ji,jj) = 0._wp
418	wfx_bom(ji,jj) = 0._wp ; wfx_sum(ji,jj) = 0._wp
419	wfx_res(ji,jj) = 0._wp ; wfx_sub(ji,jj) = 0._wp
420	wfx_spr(ji,jj) = 0._wp ; wfx_lam(ji,jj) = 0._wp
421	wfx_snw_dyn(ji,jj) = 0._wp ; wfx_snw_sum(ji,jj) = 0._wp
422	wfx_snw_sub(ji,jj) = 0._wp ; wfx_ice_sub(ji,jj) = 0._wp
423	wfx_snw_sni(ji,jj) = 0._wp
424	wfx_pnd(ji,jj) = 0._wp
425
426	hfx_thd(ji,jj) = 0._wp ;
427	hfx_snw(ji,jj) = 0._wp ; hfx_opw(ji,jj) = 0._wp
428	hfx_bog(ji,jj) = 0._wp ; hfx_dyn(ji,jj) = 0._wp
429	hfx_bom(ji,jj) = 0._wp ; hfx_sum(ji,jj) = 0._wp
430	hfx_res(ji,jj) = 0._wp ; hfx_sub(ji,jj) = 0._wp
431	hfx_spr(ji,jj) = 0._wp ; hfx_dif(ji,jj) = 0._wp
432	hfx_err_dif(ji,jj) = 0._wp
433	wfx_err_sub(ji,jj) = 0._wp
434	!
435	diag_heat(ji,jj) = 0._wp ; diag_sice(ji,jj) = 0._wp
436	diag_vice(ji,jj) = 0._wp ; diag_vsnw(ji,jj) = 0._wp
437	diag_aice(ji,jj) = 0._wp ; diag_vpnd(ji,jj) = 0._wp
438
439	tau_icebfr (ji,jj) = 0._wp ! landfast ice param only (clem: important to keep the init here)
440	qsb_ice_bot(ji,jj) = 0._wp ! (needed if ln_icethd=F)
441
442	fhld(ji,jj) = 0._wp ! needed if ln_icethd=F
443
444	! for control checks (ln_icediachk)
445	diag_trp_vi(ji,jj) = 0._wp ; diag_trp_vs(ji,jj) = 0._wp
446	diag_trp_ei(ji,jj) = 0._wp ; diag_trp_es(ji,jj) = 0._wp
447	diag_trp_sv(ji,jj) = 0._wp
448	!
449	diag_adv_mass(ji,jj) = 0._wp
450	diag_adv_salt(ji,jj) = 0._wp
451	diag_adv_heat(ji,jj) = 0._wp
452	END_2D
453
454	DO jl = 1, jpl
455	DO_2D( 1, 1, 1, 1 )
456	! SIMIP diagnostics
457	t_si (ji,jj,jl) = rt0 ! temp at the ice-snow interface
458	qcn_ice_bot(ji,jj,jl) = 0._wp
459	qcn_ice_top(ji,jj,jl) = 0._wp ! conductive fluxes
460	cnd_ice (ji,jj,jl) = 0._wp ! effective conductivity at the top of ice/snow (ln_cndflx=T)
461	qcn_ice (ji,jj,jl) = 0._wp ! conductive flux (ln_cndflx=T & ln_cndemule=T)
462	qtr_ice_bot(ji,jj,jl) = 0._wp ! part of solar radiation transmitted through the ice needed at least for outputs
463	qml_ice (ji,jj,jl) = 0._wp ! surface melt heat flux
464	! Melt pond surface melt diagnostics (mv - more efficient: grouped into one water volume flux)
465	dh_i_sum_2d(ji,jj,jl) = 0._wp
466	dh_s_mlt_2d(ji,jj,jl) = 0._wp
467	END_2D
468	ENDDO
469
470	END SUBROUTINE diag_set0
471
472
473	SUBROUTINE diag_trends( kn )
474	!!----------------------------------------------------------------------
475	!! * ROUTINE diag_trends *
476	!!
477	!! ** purpose : diagnostics of the trends. Used for conservation purposes
478	!! and outputs
479	!!----------------------------------------------------------------------
480	INTEGER, INTENT(in) :: kn ! 1 = after dyn ; 2 = after thermo
481	!!----------------------------------------------------------------------
482	!
483	! --- trends of heat, salt, mass (used for conservation controls)
484	IF( ln_icediachk .OR. iom_use('hfxdhc') ) THEN
485	!
486	diag_heat(:,:) = diag_heat(:,:) &
487	& - SUM(SUM( e_i (:,:,1:nlay_i,:) - e_i_b (:,:,1:nlay_i,:), dim=4 ), dim=3 ) * r1_Dt_ice &
488	& - SUM(SUM( e_s (:,:,1:nlay_s,:) - e_s_b (:,:,1:nlay_s,:), dim=4 ), dim=3 ) * r1_Dt_ice
489	diag_sice(:,:) = diag_sice(:,:) &
490	& + SUM( sv_i(:,:,:) - sv_i_b(:,:,:) , dim=3 ) * r1_Dt_ice * rhoi
491	diag_vice(:,:) = diag_vice(:,:) &
492	& + SUM( v_i (:,:,:) - v_i_b (:,:,:) , dim=3 ) * r1_Dt_ice * rhoi
493	diag_vsnw(:,:) = diag_vsnw(:,:) &
494	& + SUM( v_s (:,:,:) - v_s_b (:,:,:) , dim=3 ) * r1_Dt_ice * rhos
495	diag_vpnd(:,:) = diag_vpnd(:,:) &
496	& + SUM( v_ip + v_il - v_ip_b - v_il_b , dim=3 ) * r1_Dt_ice * rhow
497	!
498	IF( kn == 2 ) CALL iom_put ( 'hfxdhc' , diag_heat ) ! output of heat trend
499	!
500	ENDIF
501	!
502	! --- trends of concentration (used for simip outputs)
503	IF( iom_use('afxdyn') .OR. iom_use('afxthd') .OR. iom_use('afxtot') ) THEN
504	!
505	diag_aice(:,:) = diag_aice(:,:) + SUM( a_i(:,:,:) - a_i_b(:,:,:), dim=3 ) * r1_Dt_ice
506	!
507	IF( kn == 1 ) CALL iom_put( 'afxdyn' , diag_aice ) ! dyn trend
508	IF( kn == 2 ) CALL iom_put( 'afxthd' , SUM( a_i(:,:,:) - a_i_b(:,:,:), dim=3 ) * r1_Dt_ice ) ! thermo trend
509	IF( kn == 2 ) CALL iom_put( 'afxtot' , diag_aice ) ! total trend
510	!
511	ENDIF
512	!
513	END SUBROUTINE diag_trends
514
515	#else
516	!!----------------------------------------------------------------------
517	!! Default option Dummy module NO SI3 sea-ice model
518	!!----------------------------------------------------------------------
519	CONTAINS
520	SUBROUTINE ice_stp ( kt, ksbc ) ! Dummy routine
521	INTEGER, INTENT(in) :: kt, ksbc
522	WRITE(,) 'ice_stp: You should not have seen this print! error?', kt
523	END SUBROUTINE ice_stp
524	SUBROUTINE ice_init ! Dummy routine
525	END SUBROUTINE ice_init
526	#endif
527
528	!!======================================================================
529	END MODULE icestp

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/ICE/icestp.F90 @ 15648

Download in other formats: