| 1 | MODULE bdylib |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE bdylib *** |
|---|
| 4 | !! Unstructured Open Boundary Cond. : Library module of generic boundary algorithms. |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.6 ! 2013 (D. Storkey) original code |
|---|
| 7 | !! 4.0 ! 2014 (T. Lovato) Generalize OBC structure |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | !! bdy_orlanski_2d |
|---|
| 11 | !! bdy_orlanski_3d |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | USE bdy_oce ! ocean open boundary conditions |
|---|
| 16 | USE phycst ! physical constants |
|---|
| 17 | USE bdyini |
|---|
| 18 | ! |
|---|
| 19 | USE in_out_manager ! |
|---|
| 20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 21 | USE lib_mpp, ONLY: ctl_stop |
|---|
| 22 | |
|---|
| 23 | IMPLICIT NONE |
|---|
| 24 | PRIVATE |
|---|
| 25 | |
|---|
| 26 | PUBLIC bdy_frs, bdy_spe, bdy_nmn, bdy_orl |
|---|
| 27 | PUBLIC bdy_orlanski_2d |
|---|
| 28 | PUBLIC bdy_orlanski_3d |
|---|
| 29 | |
|---|
| 30 | !!---------------------------------------------------------------------- |
|---|
| 31 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 32 | !! $Id$ |
|---|
| 33 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | # include "single_precision_substitute.h90" |
|---|
| 36 | CONTAINS |
|---|
| 37 | |
|---|
| 38 | SUBROUTINE bdy_frs( idx, phia, dta ) |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | !! *** SUBROUTINE bdy_frs *** |
|---|
| 41 | !! |
|---|
| 42 | !! ** Purpose : Apply the Flow Relaxation Scheme for tracers at open boundaries. |
|---|
| 43 | !! |
|---|
| 44 | !! Reference : Engedahl H., 1995, Tellus, 365-382. |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | TYPE(OBC_INDEX), INTENT(in) :: idx ! OBC indices |
|---|
| 47 | REAL(dp), DIMENSION(:,:), POINTER, INTENT(in) :: dta ! OBC external data |
|---|
| 48 | REAL(dp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: phia ! tracer trend |
|---|
| 49 | !! |
|---|
| 50 | REAL(dp) :: zwgt ! boundary weight |
|---|
| 51 | INTEGER :: ib, ik, igrd ! dummy loop indices |
|---|
| 52 | INTEGER :: ii, ij ! 2D addresses |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | ! |
|---|
| 55 | igrd = 1 ! Everything is at T-points here |
|---|
| 56 | DO ib = 1, idx%nblen(igrd) |
|---|
| 57 | DO ik = 1, jpkm1 |
|---|
| 58 | ii = idx%nbi(ib,igrd) |
|---|
| 59 | ij = idx%nbj(ib,igrd) |
|---|
| 60 | zwgt = idx%nbw(ib,igrd) |
|---|
| 61 | phia(ii,ij,ik) = ( phia(ii,ij,ik) + zwgt * (dta(ib,ik) - phia(ii,ij,ik) ) ) * tmask(ii,ij,ik) |
|---|
| 62 | END DO |
|---|
| 63 | END DO |
|---|
| 64 | ! |
|---|
| 65 | END SUBROUTINE bdy_frs |
|---|
| 66 | |
|---|
| 67 | |
|---|
| 68 | SUBROUTINE bdy_spe( idx, phia, dta ) |
|---|
| 69 | !!---------------------------------------------------------------------- |
|---|
| 70 | !! *** SUBROUTINE bdy_spe *** |
|---|
| 71 | !! |
|---|
| 72 | !! ** Purpose : Apply a specified value for tracers at open boundaries. |
|---|
| 73 | !! |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | TYPE(OBC_INDEX), INTENT(in) :: idx ! OBC indices |
|---|
| 76 | REAL(dp), DIMENSION(:,:), POINTER, INTENT(in) :: dta ! OBC external data |
|---|
| 77 | REAL(dp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: phia ! tracer trend |
|---|
| 78 | !! |
|---|
| 79 | INTEGER :: ib, ik, igrd ! dummy loop indices |
|---|
| 80 | INTEGER :: ii, ij ! 2D addresses |
|---|
| 81 | !!---------------------------------------------------------------------- |
|---|
| 82 | ! |
|---|
| 83 | igrd = 1 ! Everything is at T-points here |
|---|
| 84 | DO ib = 1, idx%nblenrim(igrd) |
|---|
| 85 | ii = idx%nbi(ib,igrd) |
|---|
| 86 | ij = idx%nbj(ib,igrd) |
|---|
| 87 | DO ik = 1, jpkm1 |
|---|
| 88 | phia(ii,ij,ik) = dta(ib,ik) * tmask(ii,ij,ik) |
|---|
| 89 | END DO |
|---|
| 90 | END DO |
|---|
| 91 | ! |
|---|
| 92 | END SUBROUTINE bdy_spe |
|---|
| 93 | |
|---|
| 94 | |
|---|
| 95 | SUBROUTINE bdy_orl( idx, phib, phia, dta, lrim0, ll_npo ) |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | !! *** SUBROUTINE bdy_orl *** |
|---|
| 98 | !! |
|---|
| 99 | !! ** Purpose : Apply Orlanski radiation for tracers at open boundaries. |
|---|
| 100 | !! This is a wrapper routine for bdy_orlanski_3d below |
|---|
| 101 | !! |
|---|
| 102 | !!---------------------------------------------------------------------- |
|---|
| 103 | TYPE(OBC_INDEX), INTENT(in ) :: idx ! OBC indices |
|---|
| 104 | REAL(dp), DIMENSION(:,:), POINTER, INTENT(in ) :: dta ! OBC external data |
|---|
| 105 | REAL(dp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: phib ! before tracer field |
|---|
| 106 | REAL(dp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: phia ! tracer trend |
|---|
| 107 | LOGICAL , INTENT(in ) :: lrim0 ! indicate if rim 0 is treated |
|---|
| 108 | LOGICAL , INTENT(in ) :: ll_npo ! switch for NPO version |
|---|
| 109 | !! |
|---|
| 110 | INTEGER :: igrd ! grid index |
|---|
| 111 | !!---------------------------------------------------------------------- |
|---|
| 112 | ! |
|---|
| 113 | igrd = 1 ! Everything is at T-points here |
|---|
| 114 | ! |
|---|
| 115 | CALL bdy_orlanski_3d( idx, igrd, REAL(phib(:,:,:), dp), phia(:,:,:), dta, lrim0, ll_npo ) |
|---|
| 116 | ! |
|---|
| 117 | END SUBROUTINE bdy_orl |
|---|
| 118 | |
|---|
| 119 | |
|---|
| 120 | SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext, lrim0, ll_npo ) |
|---|
| 121 | !!---------------------------------------------------------------------- |
|---|
| 122 | !! *** SUBROUTINE bdy_orlanski_2d *** |
|---|
| 123 | !! |
|---|
| 124 | !! - Apply Orlanski radiation condition adaptively to 2D fields: |
|---|
| 125 | !! - radiation plus weak nudging at outflow points |
|---|
| 126 | !! - no radiation and strong nudging at inflow points |
|---|
| 127 | !! |
|---|
| 128 | !! |
|---|
| 129 | !! References: Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001) |
|---|
| 130 | !!---------------------------------------------------------------------- |
|---|
| 131 | TYPE(OBC_INDEX), INTENT(in ) :: idx ! BDY indices |
|---|
| 132 | INTEGER , INTENT(in ) :: igrd ! grid index |
|---|
| 133 | REAL(dp), DIMENSION(:,:), INTENT(in ) :: phib ! model before 2D field |
|---|
| 134 | REAL(dp), DIMENSION(:,:), INTENT(inout) :: phia ! model after 2D field (to be updated) |
|---|
| 135 | REAL(dp), DIMENSION(: ), POINTER, INTENT(in ) :: phi_ext ! external forcing data |
|---|
| 136 | LOGICAL , INTENT(in ) :: lrim0 ! indicate if rim 0 is treated |
|---|
| 137 | LOGICAL , INTENT(in ) :: ll_npo ! switch for NPO version |
|---|
| 138 | ! |
|---|
| 139 | INTEGER :: jb ! dummy loop indices |
|---|
| 140 | INTEGER :: ii, ij, iibm1, iibm2, ijbm1, ijbm2 ! 2D addresses |
|---|
| 141 | INTEGER :: iijm1, iijp1, ijjm1, ijjp1 ! 2D addresses |
|---|
| 142 | INTEGER :: iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses |
|---|
| 143 | INTEGER :: ii_offset, ij_offset ! offsets for mask indices |
|---|
| 144 | INTEGER :: flagu, flagv ! short cuts |
|---|
| 145 | INTEGER :: ibeg, iend ! length of rim to be treated (rim 0 or rim 1 or both) |
|---|
| 146 | REAL(dp) :: zmask_x, zmask_y1, zmask_y2 |
|---|
| 147 | REAL(dp) :: zex1, zex2, zey, zey1, zey2 |
|---|
| 148 | REAL(dp) :: zdt, zdx, zdy, znor2, zrx, zry ! intermediate calculations |
|---|
| 149 | REAL(dp) :: zout, zwgt, zdy_centred |
|---|
| 150 | REAL(dp) :: zdy_1, zdy_2, zsign_ups |
|---|
| 151 | REAL(dp), PARAMETER :: zepsilon = 1.e-30 ! local small value |
|---|
| 152 | REAL(dp), POINTER, DIMENSION(:,:) :: zmask ! land/sea mask for field |
|---|
| 153 | REAL(dp), POINTER, DIMENSION(:,:) :: zmask_xdif ! land/sea mask for x-derivatives |
|---|
| 154 | REAL(dp), POINTER, DIMENSION(:,:) :: zmask_ydif ! land/sea mask for y-derivatives |
|---|
| 155 | REAL(dp), POINTER, DIMENSION(:,:) :: pe_xdif ! scale factors for x-derivatives |
|---|
| 156 | REAL(dp), POINTER, DIMENSION(:,:) :: pe_ydif ! scale factors for y-derivatives |
|---|
| 157 | !!---------------------------------------------------------------------- |
|---|
| 158 | ! |
|---|
| 159 | ! ----------------------------------! |
|---|
| 160 | ! Orlanski boundary conditions :! |
|---|
| 161 | ! ----------------------------------! |
|---|
| 162 | |
|---|
| 163 | SELECT CASE(igrd) |
|---|
| 164 | CASE(1) |
|---|
| 165 | zmask => tmask(:,:,1) |
|---|
| 166 | zmask_xdif => umask(:,:,1) |
|---|
| 167 | zmask_ydif => vmask(:,:,1) |
|---|
| 168 | pe_xdif => e1u(:,:) |
|---|
| 169 | pe_ydif => e2v(:,:) |
|---|
| 170 | ii_offset = 0 |
|---|
| 171 | ij_offset = 0 |
|---|
| 172 | CASE(2) |
|---|
| 173 | zmask => umask(:,:,1) |
|---|
| 174 | zmask_xdif => tmask(:,:,1) |
|---|
| 175 | zmask_ydif => fmask(:,:,1) |
|---|
| 176 | pe_xdif => e1t(:,:) |
|---|
| 177 | pe_ydif => e2f(:,:) |
|---|
| 178 | ii_offset = 1 |
|---|
| 179 | ij_offset = 0 |
|---|
| 180 | CASE(3) |
|---|
| 181 | zmask => vmask(:,:,1) |
|---|
| 182 | zmask_xdif => fmask(:,:,1) |
|---|
| 183 | zmask_ydif => tmask(:,:,1) |
|---|
| 184 | pe_xdif => e1f(:,:) |
|---|
| 185 | pe_ydif => e2t(:,:) |
|---|
| 186 | ii_offset = 0 |
|---|
| 187 | ij_offset = 1 |
|---|
| 188 | CASE DEFAULT ; CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' ) |
|---|
| 189 | END SELECT |
|---|
| 190 | ! |
|---|
| 191 | IF( lrim0 ) THEN ; ibeg = 1 ; iend = idx%nblenrim0(igrd) ! rim 0 |
|---|
| 192 | ELSE ; ibeg = idx%nblenrim0(igrd)+1 ; iend = idx%nblenrim(igrd) ! rim 1 |
|---|
| 193 | ENDIF |
|---|
| 194 | ! |
|---|
| 195 | DO jb = ibeg, iend |
|---|
| 196 | ii = idx%nbi(jb,igrd) |
|---|
| 197 | ij = idx%nbj(jb,igrd) |
|---|
| 198 | IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj ) CYCLE |
|---|
| 199 | flagu = int( idx%flagu(jb,igrd) ) |
|---|
| 200 | flagv = int( idx%flagv(jb,igrd) ) |
|---|
| 201 | ! |
|---|
| 202 | ! Calculate positions of b-1 and b-2 points for this rim point |
|---|
| 203 | ! also (b-1,j-1) and (b-1,j+1) points |
|---|
| 204 | iibm1 = ii + flagu ; iibm2 = ii + 2*flagu |
|---|
| 205 | ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv |
|---|
| 206 | ! |
|---|
| 207 | iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) |
|---|
| 208 | ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu) |
|---|
| 209 | ! |
|---|
| 210 | iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) |
|---|
| 211 | ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) |
|---|
| 212 | ! |
|---|
| 213 | ! Calculate scale factors for calculation of spatial derivatives. |
|---|
| 214 | zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1 +ii_offset,ijbm1 ) & |
|---|
| 215 | & + abs(ijbm1-ijbm2) * pe_ydif(iibm1 ,ijbm1 +ij_offset) ) |
|---|
| 216 | zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2 +ii_offset,ijbm2 ) & |
|---|
| 217 | & + abs(ijbm1-ijbm2) * pe_ydif(iibm2 ,ijbm2 +ij_offset) ) |
|---|
| 218 | zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1 ) & |
|---|
| 219 | & + (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1 ,ijbm1jm1+ij_offset) ) |
|---|
| 220 | zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1 +ii_offset,ijbm1 ) & |
|---|
| 221 | & + (ijbm1jp1-ijbm1) * pe_ydif(iibm1 ,ijbm1 +ij_offset) ) |
|---|
| 222 | ! make sure scale factors are nonzero |
|---|
| 223 | if( zey1 .lt. rsmall ) zey1 = zey2 |
|---|
| 224 | if( zey2 .lt. rsmall ) zey2 = zey1 |
|---|
| 225 | zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall) |
|---|
| 226 | zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); |
|---|
| 227 | ! |
|---|
| 228 | ! Calculate masks for calculation of spatial derivatives. |
|---|
| 229 | zmask_x = ( abs(iibm1-iibm2) * zmask_xdif(iibm2 +ii_offset,ijbm2 ) & |
|---|
| 230 | & + abs(ijbm1-ijbm2) * zmask_ydif(iibm2 ,ijbm2 +ij_offset) ) |
|---|
| 231 | zmask_y1 = ( (iibm1-iibm1jm1) * zmask_xdif(iibm1jm1+ii_offset,ijbm1jm1 ) & |
|---|
| 232 | & + (ijbm1-ijbm1jm1) * zmask_ydif(iibm1jm1 ,ijbm1jm1+ij_offset) ) |
|---|
| 233 | zmask_y2 = ( (iibm1jp1-iibm1) * zmask_xdif(iibm1 +ii_offset,ijbm1 ) & |
|---|
| 234 | & + (ijbm1jp1-ijbm1) * zmask_ydif(iibm1 ,ijbm1 +ij_offset) ) |
|---|
| 235 | |
|---|
| 236 | ! Calculation of terms required for both versions of the scheme. |
|---|
| 237 | ! Mask derivatives to ensure correct land boundary conditions for each variable. |
|---|
| 238 | ! Centred derivative is calculated as average of "left" and "right" derivatives for |
|---|
| 239 | ! this reason. |
|---|
| 240 | ! Note no rn_Dt factor in expression for zdt because it cancels in the expressions for |
|---|
| 241 | ! zrx and zry. |
|---|
| 242 | zdt = phia(iibm1 ,ijbm1 ) - phib(iibm1 ,ijbm1 ) |
|---|
| 243 | zdx = ( ( phia(iibm1 ,ijbm1 ) - phia(iibm2 ,ijbm2 ) ) / zex2 ) * zmask_x |
|---|
| 244 | zdy_1 = ( ( phib(iibm1 ,ijbm1 ) - phib(iibm1jm1,ijbm1jm1) ) / zey1 ) * zmask_y1 |
|---|
| 245 | zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1) - phib(iibm1 ,ijbm1 ) ) / zey2 ) * zmask_y2 |
|---|
| 246 | zdy_centred = 0.5 * ( zdy_1 + zdy_2 ) |
|---|
| 247 | !!$ zdy_centred = phib(iibm1jp1,ijbm1jp1) - phib(iibm1jm1,ijbm1jm1) |
|---|
| 248 | ! upstream differencing for tangential derivatives |
|---|
| 249 | zsign_ups = sign( 1.0_wp, zdt * zdy_centred ) |
|---|
| 250 | zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) ) |
|---|
| 251 | zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2 |
|---|
| 252 | znor2 = zdx * zdx + zdy * zdy |
|---|
| 253 | znor2 = max(znor2,zepsilon) |
|---|
| 254 | ! |
|---|
| 255 | zrx = zdt * zdx / ( zex1 * znor2 ) |
|---|
| 256 | !!$ zrx = min(zrx,2.0_wp) |
|---|
| 257 | zout = sign( 1.0_wp, zrx ) |
|---|
| 258 | zout = 0.5*( zout + abs(zout) ) |
|---|
| 259 | zwgt = 2.*rn_Dt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) ) |
|---|
| 260 | ! only apply radiation on outflow points |
|---|
| 261 | if( ll_npo ) then !! NPO version !! |
|---|
| 262 | phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) & |
|---|
| 263 | & + zout * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1) & |
|---|
| 264 | & + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) |
|---|
| 265 | else !! full oblique radiation !! |
|---|
| 266 | zsign_ups = sign( 1.0_wp, zdt * zdy ) |
|---|
| 267 | zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) ) |
|---|
| 268 | zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 |
|---|
| 269 | zry = zdt * zdy / ( zey * znor2 ) |
|---|
| 270 | phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) & |
|---|
| 271 | & + zout * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1) & |
|---|
| 272 | & - zsign_ups * zry * ( phib(ii ,ij ) - phib(iijm1,ijjm1 ) ) & |
|---|
| 273 | & - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1) - phib(ii ,ij ) ) & |
|---|
| 274 | & + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) |
|---|
| 275 | endif |
|---|
| 276 | phia(ii,ij) = phia(ii,ij) * zmask(ii,ij) |
|---|
| 277 | END DO |
|---|
| 278 | ! |
|---|
| 279 | END SUBROUTINE bdy_orlanski_2d |
|---|
| 280 | |
|---|
| 281 | |
|---|
| 282 | SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext, lrim0, ll_npo ) |
|---|
| 283 | !!---------------------------------------------------------------------- |
|---|
| 284 | !! *** SUBROUTINE bdy_orlanski_3d *** |
|---|
| 285 | !! |
|---|
| 286 | !! - Apply Orlanski radiation condition adaptively to 3D fields: |
|---|
| 287 | !! - radiation plus weak nudging at outflow points |
|---|
| 288 | !! - no radiation and strong nudging at inflow points |
|---|
| 289 | !! |
|---|
| 290 | !! |
|---|
| 291 | !! References: Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001) |
|---|
| 292 | !!---------------------------------------------------------------------- |
|---|
| 293 | TYPE(OBC_INDEX), INTENT(in ) :: idx ! BDY indices |
|---|
| 294 | INTEGER , INTENT(in ) :: igrd ! grid index |
|---|
| 295 | REAL(dp), DIMENSION(:,:,:), INTENT(in ) :: phib ! model before 3D field |
|---|
| 296 | REAL(dp), DIMENSION(:,:,:), INTENT(inout) :: phia ! model after 3D field (to be updated) |
|---|
| 297 | REAL(dp), DIMENSION(:,: ), POINTER, INTENT(in ) :: phi_ext ! external forcing data |
|---|
| 298 | LOGICAL , INTENT(in ) :: lrim0 ! indicate if rim 0 is treated |
|---|
| 299 | LOGICAL , INTENT(in ) :: ll_npo ! switch for NPO version |
|---|
| 300 | ! |
|---|
| 301 | INTEGER :: jb, jk ! dummy loop indices |
|---|
| 302 | INTEGER :: ii, ij, iibm1, iibm2, ijbm1, ijbm2 ! 2D addresses |
|---|
| 303 | INTEGER :: iijm1, iijp1, ijjm1, ijjp1 ! 2D addresses |
|---|
| 304 | INTEGER :: iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses |
|---|
| 305 | INTEGER :: ii_offset, ij_offset ! offsets for mask indices |
|---|
| 306 | INTEGER :: flagu, flagv ! short cuts |
|---|
| 307 | INTEGER :: ibeg, iend ! length of rim to be treated (rim 0 or rim 1 or both) |
|---|
| 308 | REAL(dp) :: zmask_x, zmask_y1, zmask_y2 |
|---|
| 309 | REAL(dp) :: zex1, zex2, zey, zey1, zey2 |
|---|
| 310 | REAL(dp) :: zdt, zdx, zdy, znor2, zrx, zry ! intermediate calculations |
|---|
| 311 | REAL(dp) :: zout, zwgt, zdy_centred |
|---|
| 312 | REAL(dp) :: zdy_1, zdy_2, zsign_ups |
|---|
| 313 | REAL(dp), PARAMETER :: zepsilon = 1.e-30 ! local small value |
|---|
| 314 | REAL(dp), POINTER, DIMENSION(:,:,:) :: zmask ! land/sea mask for field |
|---|
| 315 | REAL(dp), POINTER, DIMENSION(:,:,:) :: zmask_xdif ! land/sea mask for x-derivatives |
|---|
| 316 | REAL(dp), POINTER, DIMENSION(:,:,:) :: zmask_ydif ! land/sea mask for y-derivatives |
|---|
| 317 | REAL(dp), POINTER, DIMENSION(:,:) :: pe_xdif ! scale factors for x-derivatives |
|---|
| 318 | REAL(dp), POINTER, DIMENSION(:,:) :: pe_ydif ! scale factors for y-derivatives |
|---|
| 319 | !!---------------------------------------------------------------------- |
|---|
| 320 | ! |
|---|
| 321 | ! ----------------------------------! |
|---|
| 322 | ! Orlanski boundary conditions :! |
|---|
| 323 | ! ----------------------------------! |
|---|
| 324 | ! |
|---|
| 325 | SELECT CASE(igrd) |
|---|
| 326 | CASE(1) |
|---|
| 327 | zmask => tmask(:,:,:) |
|---|
| 328 | zmask_xdif => umask(:,:,:) |
|---|
| 329 | zmask_ydif => vmask(:,:,:) |
|---|
| 330 | pe_xdif => e1u(:,:) |
|---|
| 331 | pe_ydif => e2v(:,:) |
|---|
| 332 | ii_offset = 0 |
|---|
| 333 | ij_offset = 0 |
|---|
| 334 | CASE(2) |
|---|
| 335 | zmask => umask(:,:,:) |
|---|
| 336 | zmask_xdif => tmask(:,:,:) |
|---|
| 337 | zmask_ydif => fmask(:,:,:) |
|---|
| 338 | pe_xdif => e1t(:,:) |
|---|
| 339 | pe_ydif => e2f(:,:) |
|---|
| 340 | ii_offset = 1 |
|---|
| 341 | ij_offset = 0 |
|---|
| 342 | CASE(3) |
|---|
| 343 | zmask => vmask(:,:,:) |
|---|
| 344 | zmask_xdif => fmask(:,:,:) |
|---|
| 345 | zmask_ydif => tmask(:,:,:) |
|---|
| 346 | pe_xdif => e1f(:,:) |
|---|
| 347 | pe_ydif => e2t(:,:) |
|---|
| 348 | ii_offset = 0 |
|---|
| 349 | ij_offset = 1 |
|---|
| 350 | CASE DEFAULT ; CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' ) |
|---|
| 351 | END SELECT |
|---|
| 352 | ! |
|---|
| 353 | IF( lrim0 ) THEN ; ibeg = 1 ; iend = idx%nblenrim0(igrd) ! rim 0 |
|---|
| 354 | ELSE ; ibeg = idx%nblenrim0(igrd)+1 ; iend = idx%nblenrim(igrd) ! rim 1 |
|---|
| 355 | ENDIF |
|---|
| 356 | ! |
|---|
| 357 | DO jk = 1, jpk |
|---|
| 358 | ! |
|---|
| 359 | DO jb = ibeg, iend |
|---|
| 360 | ii = idx%nbi(jb,igrd) |
|---|
| 361 | ij = idx%nbj(jb,igrd) |
|---|
| 362 | IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj ) CYCLE |
|---|
| 363 | flagu = int( idx%flagu(jb,igrd) ) |
|---|
| 364 | flagv = int( idx%flagv(jb,igrd) ) |
|---|
| 365 | ! |
|---|
| 366 | ! calculate positions of b-1 and b-2 points for this rim point |
|---|
| 367 | ! also (b-1,j-1) and (b-1,j+1) points |
|---|
| 368 | iibm1 = ii + flagu ; iibm2 = ii + 2*flagu |
|---|
| 369 | ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv |
|---|
| 370 | ! |
|---|
| 371 | iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) |
|---|
| 372 | ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu) |
|---|
| 373 | ! |
|---|
| 374 | iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) |
|---|
| 375 | ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) |
|---|
| 376 | ! |
|---|
| 377 | ! Calculate scale factors for calculation of spatial derivatives. |
|---|
| 378 | zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1 +ii_offset,ijbm1 ) & |
|---|
| 379 | & + abs(ijbm1-ijbm2) * pe_ydif(iibm1 ,ijbm1+ij_offset ) ) |
|---|
| 380 | zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2 +ii_offset,ijbm2 ) & |
|---|
| 381 | & + abs(ijbm1-ijbm2) * pe_ydif(iibm2 ,ijbm2+ij_offset ) ) |
|---|
| 382 | zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1 ) & |
|---|
| 383 | & + (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1 ,ijbm1jm1+ij_offset) ) |
|---|
| 384 | zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1 +ii_offset,ijbm1 ) & |
|---|
| 385 | & + (ijbm1jp1-ijbm1) * pe_ydif(iibm1 ,ijbm1+ij_offset ) ) |
|---|
| 386 | ! make sure scale factors are nonzero |
|---|
| 387 | if( zey1 .lt. rsmall ) zey1 = zey2 |
|---|
| 388 | if( zey2 .lt. rsmall ) zey2 = zey1 |
|---|
| 389 | zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall); |
|---|
| 390 | zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); |
|---|
| 391 | ! |
|---|
| 392 | ! Calculate masks for calculation of spatial derivatives. |
|---|
| 393 | zmask_x = ( abs(iibm1-iibm2) * zmask_xdif(iibm2 +ii_offset,ijbm2 ,jk) & |
|---|
| 394 | & + abs(ijbm1-ijbm2) * zmask_ydif(iibm2 ,ijbm2 +ij_offset,jk) ) |
|---|
| 395 | zmask_y1 = ( (iibm1-iibm1jm1) * zmask_xdif(iibm1jm1+ii_offset,ijbm1jm1 ,jk) & |
|---|
| 396 | & + (ijbm1-ijbm1jm1) * zmask_ydif(iibm1jm1 ,ijbm1jm1+ij_offset,jk) ) |
|---|
| 397 | zmask_y2 = ( (iibm1jp1-iibm1) * zmask_xdif(iibm1 +ii_offset,ijbm1 ,jk) & |
|---|
| 398 | & + (ijbm1jp1-ijbm1) * zmask_ydif(iibm1 ,ijbm1 +ij_offset,jk) ) |
|---|
| 399 | ! |
|---|
| 400 | ! Calculate normal (zrx) and tangential (zry) components of radiation velocities. |
|---|
| 401 | ! Mask derivatives to ensure correct land boundary conditions for each variable. |
|---|
| 402 | ! Centred derivative is calculated as average of "left" and "right" derivatives for |
|---|
| 403 | ! this reason. |
|---|
| 404 | zdt = phia(iibm1 ,ijbm1 ,jk) - phib(iibm1 ,ijbm1 ,jk) |
|---|
| 405 | zdx = ( ( phia(iibm1 ,ijbm1 ,jk) - phia(iibm2 ,ijbm2 ,jk) ) / zex2 ) * zmask_x |
|---|
| 406 | zdy_1 = ( ( phib(iibm1 ,ijbm1 ,jk) - phib(iibm1jm1,ijbm1jm1,jk) ) / zey1 ) * zmask_y1 |
|---|
| 407 | zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1 ,ijbm1 ,jk) ) / zey2 ) * zmask_y2 |
|---|
| 408 | zdy_centred = 0.5 * ( zdy_1 + zdy_2 ) |
|---|
| 409 | !!$ zdy_centred = phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1jm1,ijbm1jm1,jk) |
|---|
| 410 | ! upstream differencing for tangential derivatives |
|---|
| 411 | zsign_ups = sign( 1.0_wp, zdt * zdy_centred ) |
|---|
| 412 | zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) ) |
|---|
| 413 | zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2 |
|---|
| 414 | znor2 = zdx * zdx + zdy * zdy |
|---|
| 415 | znor2 = max(znor2,zepsilon) |
|---|
| 416 | ! |
|---|
| 417 | ! update boundary value: |
|---|
| 418 | zrx = zdt * zdx / ( zex1 * znor2 ) |
|---|
| 419 | !!$ zrx = min(zrx,2.0_wp) |
|---|
| 420 | zout = sign( 1.0_wp, zrx ) |
|---|
| 421 | zout = 0.5*( zout + abs(zout) ) |
|---|
| 422 | zwgt = 2.*rn_Dt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) ) |
|---|
| 423 | ! only apply radiation on outflow points |
|---|
| 424 | if( ll_npo ) then !! NPO version !! |
|---|
| 425 | phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) & |
|---|
| 426 | & + zout * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk) & |
|---|
| 427 | & + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) |
|---|
| 428 | else !! full oblique radiation !! |
|---|
| 429 | zsign_ups = sign( 1.0_wp, zdt * zdy ) |
|---|
| 430 | zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) ) |
|---|
| 431 | zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 |
|---|
| 432 | zry = zdt * zdy / ( zey * znor2 ) |
|---|
| 433 | phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) & |
|---|
| 434 | & + zout * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk) & |
|---|
| 435 | & - zsign_ups * zry * ( phib(ii ,ij ,jk) - phib(iijm1,ijjm1,jk) ) & |
|---|
| 436 | & - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1,jk) - phib(ii ,ij ,jk) ) & |
|---|
| 437 | & + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) |
|---|
| 438 | endif |
|---|
| 439 | phia(ii,ij,jk) = phia(ii,ij,jk) * zmask(ii,ij,jk) |
|---|
| 440 | END DO |
|---|
| 441 | ! |
|---|
| 442 | END DO |
|---|
| 443 | ! |
|---|
| 444 | END SUBROUTINE bdy_orlanski_3d |
|---|
| 445 | |
|---|
| 446 | SUBROUTINE bdy_nmn( idx, igrd, phia, lrim0 ) |
|---|
| 447 | !!---------------------------------------------------------------------- |
|---|
| 448 | !! *** SUBROUTINE bdy_nmn *** |
|---|
| 449 | !! |
|---|
| 450 | !! ** Purpose : Duplicate the value at open boundaries, zero gradient. |
|---|
| 451 | !! |
|---|
| 452 | !! |
|---|
| 453 | !! ** Method : - take the average of free ocean neighbours |
|---|
| 454 | !! |
|---|
| 455 | !! ___ ! |_____| ! ___| ! __|x o ! |_ _| ! | |
|---|
| 456 | !! __|x ! x ! x o ! o ! |_| ! |x o |
|---|
| 457 | !! o ! o ! o ! ! o x o ! |x_x_ |
|---|
| 458 | !! ! o |
|---|
| 459 | !!---------------------------------------------------------------------- |
|---|
| 460 | INTEGER, INTENT(in ) :: igrd ! grid index |
|---|
| 461 | REAL(dp), DIMENSION(:,:,:), INTENT(inout) :: phia ! model after 3D field (to be updated), must be masked |
|---|
| 462 | TYPE(OBC_INDEX), INTENT(in ) :: idx ! OBC indices |
|---|
| 463 | LOGICAL , INTENT(in ) :: lrim0 ! indicate if rim 0 is treated |
|---|
| 464 | !! |
|---|
| 465 | REAL(dp) :: zweight |
|---|
| 466 | REAL(dp), POINTER, DIMENSION(:,:,:) :: zmask ! land/sea mask for field |
|---|
| 467 | INTEGER :: ib, ik ! dummy loop indices |
|---|
| 468 | INTEGER :: ii, ij ! 2D addresses |
|---|
| 469 | INTEGER :: ipkm1 ! size of phia third dimension minus 1 |
|---|
| 470 | INTEGER :: ibeg, iend ! length of rim to be treated (rim 0 or rim 1 or both) |
|---|
| 471 | INTEGER :: ii1, ii2, ii3, ij1, ij2, ij3, itreat |
|---|
| 472 | !!---------------------------------------------------------------------- |
|---|
| 473 | ! |
|---|
| 474 | ipkm1 = MAX( SIZE(phia,3) - 1, 1 ) |
|---|
| 475 | ! |
|---|
| 476 | SELECT CASE(igrd) |
|---|
| 477 | CASE(1) ; zmask => tmask(:,:,:) |
|---|
| 478 | CASE(2) ; zmask => umask(:,:,:) |
|---|
| 479 | CASE(3) ; zmask => vmask(:,:,:) |
|---|
| 480 | CASE DEFAULT ; CALL ctl_stop( 'unrecognised value for igrd in bdy_nmn' ) |
|---|
| 481 | END SELECT |
|---|
| 482 | ! |
|---|
| 483 | IF( lrim0 ) THEN ; ibeg = 1 ; iend = idx%nblenrim0(igrd) ! rim 0 |
|---|
| 484 | ELSE ; ibeg = idx%nblenrim0(igrd)+1 ; iend = idx%nblenrim(igrd) ! rim 1 |
|---|
| 485 | ENDIF |
|---|
| 486 | ! |
|---|
| 487 | DO ib = ibeg, iend |
|---|
| 488 | ii = idx%nbi(ib,igrd) |
|---|
| 489 | ij = idx%nbj(ib,igrd) |
|---|
| 490 | itreat = idx%ntreat(ib,igrd) |
|---|
| 491 | CALL find_neib( ii, ij, itreat, ii1, ij1, ii2, ij2, ii3, ij3 ) ! find free ocean neighbours |
|---|
| 492 | SELECT CASE( itreat ) |
|---|
| 493 | CASE( 1:8 ) |
|---|
| 494 | IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj ) CYCLE |
|---|
| 495 | DO ik = 1, ipkm1 |
|---|
| 496 | IF( zmask(ii1,ij1,ik) /= 0. ) phia(ii,ij,ik) = phia(ii1,ij1,ik) |
|---|
| 497 | END DO |
|---|
| 498 | CASE( 9:12 ) |
|---|
| 499 | IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj ) CYCLE |
|---|
| 500 | IF( ii2 < 1 .OR. ii2 > jpi .OR. ij2 < 1 .OR. ij2 > jpj ) CYCLE |
|---|
| 501 | DO ik = 1, ipkm1 |
|---|
| 502 | zweight = zmask(ii1,ij1,ik) + zmask(ii2,ij2,ik) |
|---|
| 503 | IF( zweight /= 0. ) phia(ii,ij,ik) = ( phia(ii1,ij1,ik) + phia(ii2,ij2,ik) ) / zweight |
|---|
| 504 | END DO |
|---|
| 505 | CASE( 13:16 ) |
|---|
| 506 | IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj ) CYCLE |
|---|
| 507 | IF( ii2 < 1 .OR. ii2 > jpi .OR. ij2 < 1 .OR. ij2 > jpj ) CYCLE |
|---|
| 508 | IF( ii3 < 1 .OR. ii3 > jpi .OR. ij3 < 1 .OR. ij3 > jpj ) CYCLE |
|---|
| 509 | DO ik = 1, ipkm1 |
|---|
| 510 | zweight = zmask(ii1,ij1,ik) + zmask(ii2,ij2,ik) + zmask(ii3,ij3,ik) |
|---|
| 511 | IF( zweight /= 0. ) phia(ii,ij,ik) = ( phia(ii1,ij1,ik) + phia(ii2,ij2,ik) + phia(ii3,ij3,ik) ) / zweight |
|---|
| 512 | END DO |
|---|
| 513 | END SELECT |
|---|
| 514 | END DO |
|---|
| 515 | ! |
|---|
| 516 | END SUBROUTINE bdy_nmn |
|---|
| 517 | |
|---|
| 518 | !!====================================================================== |
|---|
| 519 | END MODULE bdylib |
|---|
