| 1 | MODULE domqco |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE domqco *** |
|---|
| 4 | !! Ocean : |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 2.0 ! 2006-06 (B. Levier, L. Marie) original code |
|---|
| 7 | !! 3.1 ! 2009-02 (G. Madec, M. Leclair, R. Benshila) pure z* coordinate |
|---|
| 8 | !! 3.3 ! 2011-10 (M. Leclair) totally rewrote domvvl: vvl option includes z_star and z_tilde coordinates |
|---|
| 9 | !! 3.6 ! 2014-11 (P. Mathiot) add ice shelf capability |
|---|
| 10 | !! 4.1 ! 2019-08 (A. Coward, D. Storkey) add time level indices for prognostic variables |
|---|
| 11 | !! - ! 2020-02 (S. Techene, G. Madec) quasi-eulerian coordinate (z* or s*) |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! dom_qco_init : define initial vertical scale factors, depths and column thickness |
|---|
| 16 | !! dom_qco_zgr : Set ssh/h_0 ratio at t |
|---|
| 17 | !! dom_qco_r3c : Compute ssh/h_0 ratio at t-, u-, v-, and optionally f-points |
|---|
| 18 | !! qco_ctl : Check the vvl options |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE oce ! ocean dynamics and tracers |
|---|
| 21 | USE phycst ! physical constant |
|---|
| 22 | USE dom_oce ! ocean space and time domain |
|---|
| 23 | USE dynadv , ONLY : ln_dynadv_vec |
|---|
| 24 | USE isf_oce ! iceshelf cavities |
|---|
| 25 | USE sbc_oce ! ocean surface boundary condition |
|---|
| 26 | USE wet_dry ! wetting and drying |
|---|
| 27 | USE usrdef_istate ! user defined initial state (wad only) |
|---|
| 28 | USE restart ! ocean restart |
|---|
| 29 | ! |
|---|
| 30 | USE in_out_manager ! I/O manager |
|---|
| 31 | USE iom ! I/O manager library |
|---|
| 32 | USE lib_mpp ! distributed memory computing library |
|---|
| 33 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 34 | USE timing ! Timing |
|---|
| 35 | |
|---|
| 36 | IMPLICIT NONE |
|---|
| 37 | PRIVATE |
|---|
| 38 | |
|---|
| 39 | PUBLIC dom_qco_init ! called by domain.F90 |
|---|
| 40 | PUBLIC dom_qco_zgr ! called by isfcpl.F90 |
|---|
| 41 | PUBLIC dom_qco_r3c ! called by steplf.F90 |
|---|
| 42 | |
|---|
| 43 | ! !!* Namelist nam_vvl |
|---|
| 44 | LOGICAL , PUBLIC :: ln_vvl_zstar = .FALSE. ! zstar vertical coordinate |
|---|
| 45 | LOGICAL , PUBLIC :: ln_vvl_ztilde = .FALSE. ! ztilde vertical coordinate |
|---|
| 46 | LOGICAL , PUBLIC :: ln_vvl_layer = .FALSE. ! level vertical coordinate |
|---|
| 47 | LOGICAL , PUBLIC :: ln_vvl_ztilde_as_zstar = .FALSE. ! ztilde vertical coordinate |
|---|
| 48 | LOGICAL , PUBLIC :: ln_vvl_zstar_at_eqtor = .FALSE. ! ztilde vertical coordinate |
|---|
| 49 | LOGICAL , PUBLIC :: ln_vvl_kepe = .FALSE. ! kinetic/potential energy transfer |
|---|
| 50 | ! ! conservation: not used yet |
|---|
| 51 | REAL(wp) :: rn_ahe3 ! thickness diffusion coefficient |
|---|
| 52 | REAL(wp) :: rn_rst_e3t ! ztilde to zstar restoration timescale [days] |
|---|
| 53 | REAL(wp) :: rn_lf_cutoff ! cutoff frequency for low-pass filter [days] |
|---|
| 54 | REAL(wp) :: rn_zdef_max ! maximum fractional e3t deformation |
|---|
| 55 | LOGICAL , PUBLIC :: ln_vvl_dbg = .FALSE. ! debug control prints |
|---|
| 56 | |
|---|
| 57 | !! * Substitutions |
|---|
| 58 | # include "do_loop_substitute.h90" |
|---|
| 59 | # include "single_precision_substitute.h90" |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 62 | !! $Id: domvvl.F90 12377 2020-02-12 14:39:06Z acc $ |
|---|
| 63 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | CONTAINS |
|---|
| 66 | |
|---|
| 67 | SUBROUTINE dom_qco_init( Kbb, Kmm, Kaa ) |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | !! *** ROUTINE dom_qco_init *** |
|---|
| 70 | !! |
|---|
| 71 | !! ** Purpose : Initialization of all ssh. to h._0 ratio |
|---|
| 72 | !! |
|---|
| 73 | !! ** Method : - use restart file and/or initialize |
|---|
| 74 | !! - compute ssh. to h._0 ratio |
|---|
| 75 | !! |
|---|
| 76 | !! ** Action : - r3(t/u/v)_b |
|---|
| 77 | !! - r3(t/u/v/f)_n |
|---|
| 78 | !! |
|---|
| 79 | !!---------------------------------------------------------------------- |
|---|
| 80 | INTEGER, INTENT(in) :: Kbb, Kmm, Kaa ! time level indices |
|---|
| 81 | !!---------------------------------------------------------------------- |
|---|
| 82 | ! |
|---|
| 83 | IF(lwp) WRITE(numout,*) |
|---|
| 84 | IF(lwp) WRITE(numout,*) 'dom_qco_init : Variable volume activated' |
|---|
| 85 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 86 | ! |
|---|
| 87 | CALL qco_ctl ! choose vertical coordinate (z_star, z_tilde or layer) |
|---|
| 88 | ! |
|---|
| 89 | CALL dom_qco_zgr( Kbb, Kmm ) ! interpolation scale factor, depth and water column |
|---|
| 90 | ! |
|---|
| 91 | #if defined key_agrif |
|---|
| 92 | ! We need to define r3[tuv](Kaa) for AGRIF initialisation (should not be a |
|---|
| 93 | ! problem for the restartability...) |
|---|
| 94 | r3t(:,:,Kaa) = r3t(:,:,Kmm) |
|---|
| 95 | r3u(:,:,Kaa) = r3u(:,:,Kmm) |
|---|
| 96 | r3v(:,:,Kaa) = r3v(:,:,Kmm) |
|---|
| 97 | #endif |
|---|
| 98 | ! |
|---|
| 99 | END SUBROUTINE dom_qco_init |
|---|
| 100 | |
|---|
| 101 | |
|---|
| 102 | SUBROUTINE dom_qco_zgr( Kbb, Kmm ) |
|---|
| 103 | !!---------------------------------------------------------------------- |
|---|
| 104 | !! *** ROUTINE dom_qco_init *** |
|---|
| 105 | !! |
|---|
| 106 | !! ** Purpose : Initialization of all r3. = ssh./h._0 ratios |
|---|
| 107 | !! |
|---|
| 108 | !! ** Method : Call domqco using Kbb and Kmm |
|---|
| 109 | !! NB: dom_qco_zgr is called by dom_qco_init it uses ssh from ssh_init |
|---|
| 110 | !! |
|---|
| 111 | !! ** Action : - r3(t/u/v)(Kbb) |
|---|
| 112 | !! - r3(t/u/v/f)(Kmm) |
|---|
| 113 | !!---------------------------------------------------------------------- |
|---|
| 114 | INTEGER, INTENT(in) :: Kbb, Kmm ! time level indices |
|---|
| 115 | !!---------------------------------------------------------------------- |
|---|
| 116 | ! |
|---|
| 117 | ! !== Set of all other vertical scale factors ==! (now and before) |
|---|
| 118 | ! ! Horizontal interpolation of e3t |
|---|
| 119 | #if defined key_RK3 |
|---|
| 120 | CALL dom_qco_r3c( ssh(:,:,Kbb), r3t(:,:,Kbb), r3u(:,:,Kbb), r3v(:,:,Kbb), r3f(:,:) ) |
|---|
| 121 | CALL dom_qco_r3c( ssh(:,:,Kmm), r3t(:,:,Kmm), r3u(:,:,Kmm), r3v(:,:,Kmm) ) |
|---|
| 122 | #else |
|---|
| 123 | CALL dom_qco_r3c( ssh(:,:,Kbb), r3t(:,:,Kbb), r3u(:,:,Kbb), r3v(:,:,Kbb) ) |
|---|
| 124 | CALL dom_qco_r3c( ssh(:,:,Kmm), r3t(:,:,Kmm), r3u(:,:,Kmm), r3v(:,:,Kmm), r3f(:,:) ) |
|---|
| 125 | #endif |
|---|
| 126 | ! dom_qco_r3c defines over [nn_hls, nn_hls-1, nn_hls, nn_hls-1] |
|---|
| 127 | IF( nn_hls == 2 ) CALL lbc_lnk( 'dom_qco_zgr', r3u(:,:,Kbb), 'U', 1._wp, r3v(:,:,Kbb), 'V', 1._wp, & |
|---|
| 128 | & r3u(:,:,Kmm), 'U', 1._wp, r3v(:,:,Kmm), 'V', 1._wp ) |
|---|
| 129 | ! |
|---|
| 130 | END SUBROUTINE dom_qco_zgr |
|---|
| 131 | |
|---|
| 132 | |
|---|
| 133 | SUBROUTINE dom_qco_r3c( pssh, pr3t, pr3u, pr3v, pr3f ) |
|---|
| 134 | !!--------------------------------------------------------------------- |
|---|
| 135 | !! *** ROUTINE r3c *** |
|---|
| 136 | !! |
|---|
| 137 | !! ** Purpose : compute the filtered ratio ssh/h_0 at t-,u-,v-,f-points |
|---|
| 138 | !! |
|---|
| 139 | !! ** Method : - compute the ssh at u- and v-points (f-point optional) |
|---|
| 140 | !! Vector Form : surface weighted averaging |
|---|
| 141 | !! Flux Form : simple averaging |
|---|
| 142 | !! - compute the ratio ssh/h_0 at t-,u-,v-pts, (f-pt optional) |
|---|
| 143 | !!---------------------------------------------------------------------- |
|---|
| 144 | REAL(dp), DIMENSION(:,:) , INTENT(in ) :: pssh ! sea surface height [m] |
|---|
| 145 | REAL(dp), DIMENSION(:,:) , INTENT( out) :: pr3t, pr3u, pr3v ! ssh/h0 ratio at t-, u-, v-,points [-] |
|---|
| 146 | REAL(dp), DIMENSION(:,:), OPTIONAL, INTENT( out) :: pr3f ! ssh/h0 ratio at f-point [-] |
|---|
| 147 | ! |
|---|
| 148 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 149 | !!---------------------------------------------------------------------- |
|---|
| 150 | ! |
|---|
| 151 | ! |
|---|
| 152 | DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls ) |
|---|
| 153 | pr3t(ji,jj) = pssh(ji,jj) * r1_ht_0(ji,jj) !== ratio at t-point ==! |
|---|
| 154 | END_2D |
|---|
| 155 | ! |
|---|
| 156 | ! |
|---|
| 157 | ! !== ratio at u-,v-point ==! |
|---|
| 158 | ! |
|---|
| 159 | !!st IF( ln_dynadv_vec ) THEN !- Vector Form (thickness weighted averaging) |
|---|
| 160 | #if ! defined key_qcoTest_FluxForm |
|---|
| 161 | ! ! no 'key_qcoTest_FluxForm' : surface weighted ssh average |
|---|
| 162 | DO_2D_OVR( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) |
|---|
| 163 | pr3u(ji,jj) = 0.5_wp * ( e1e2t(ji ,jj) * pssh(ji ,jj) & |
|---|
| 164 | & + e1e2t(ji+1,jj) * pssh(ji+1,jj) ) * r1_hu_0(ji,jj) * r1_e1e2u(ji,jj) |
|---|
| 165 | pr3v(ji,jj) = 0.5_wp * ( e1e2t(ji,jj ) * pssh(ji,jj ) & |
|---|
| 166 | & + e1e2t(ji,jj+1) * pssh(ji,jj+1) ) * r1_hv_0(ji,jj) * r1_e1e2v(ji,jj) |
|---|
| 167 | END_2D |
|---|
| 168 | !!st ELSE !- Flux Form (simple averaging) |
|---|
| 169 | #else |
|---|
| 170 | DO_2D_OVR( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) |
|---|
| 171 | pr3u(ji,jj) = 0.5_wp * ( pssh(ji,jj) + pssh(ji+1,jj ) ) * r1_hu_0(ji,jj) |
|---|
| 172 | pr3v(ji,jj) = 0.5_wp * ( pssh(ji,jj) + pssh(ji ,jj+1) ) * r1_hv_0(ji,jj) |
|---|
| 173 | END_2D |
|---|
| 174 | !!st ENDIF |
|---|
| 175 | #endif |
|---|
| 176 | ! |
|---|
| 177 | IF( .NOT.PRESENT( pr3f ) ) THEN !- lbc on ratio at u-, v-points only |
|---|
| 178 | IF (nn_hls==1) CALL lbc_lnk( 'dom_qco_r3c', pr3u, 'U', 1._wp, pr3v, 'V', 1._wp ) |
|---|
| 179 | ! |
|---|
| 180 | ! |
|---|
| 181 | ELSE !== ratio at f-point ==! |
|---|
| 182 | ! |
|---|
| 183 | !!st IF( ln_dynadv_vec ) THEN !- Vector Form (thickness weighted averaging) |
|---|
| 184 | #if ! defined key_qcoTest_FluxForm |
|---|
| 185 | ! ! no 'key_qcoTest_FluxForm' : surface weighted ssh average |
|---|
| 186 | |
|---|
| 187 | DO_2D_OVR( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) ! start from 1 since lbc_lnk('F') doesn't update the 1st row/line |
|---|
| 188 | ! round brackets added to fix the order of floating point operations |
|---|
| 189 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 190 | pr3f(ji,jj) = 0.25_wp * ( ( e1e2t(ji ,jj ) * pssh(ji ,jj ) & |
|---|
| 191 | & + e1e2t(ji+1,jj ) * pssh(ji+1,jj ) & |
|---|
| 192 | & ) & ! bracket for halo 1 - halo 2 compatibility |
|---|
| 193 | & + ( e1e2t(ji ,jj+1) * pssh(ji ,jj+1) & |
|---|
| 194 | & + e1e2t(ji+1,jj+1) * pssh(ji+1,jj+1) & |
|---|
| 195 | & ) & ! bracket for halo 1 - halo 2 compatibility |
|---|
| 196 | & ) * r1_hf_0(ji,jj) * r1_e1e2f(ji,jj) |
|---|
| 197 | END_2D |
|---|
| 198 | !!st ELSE !- Flux Form (simple averaging) |
|---|
| 199 | #else |
|---|
| 200 | DO_2D_OVR( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) |
|---|
| 201 | ! round brackets added to fix the order of floating point operations |
|---|
| 202 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 203 | pr3f(ji,jj) = 0.25_wp * ( ( pssh(ji,jj ) + pssh(ji+1,jj ) ) & |
|---|
| 204 | & + ( pssh(ji,jj+1) + pssh(ji+1,jj+1) & |
|---|
| 205 | & ) & ! bracket for halo 1 - halo 2 compatibility |
|---|
| 206 | & ) * r1_hf_0(ji,jj) |
|---|
| 207 | END_2D |
|---|
| 208 | !!st ENDIF |
|---|
| 209 | #endif |
|---|
| 210 | ! ! lbc on ratio at u-,v-,f-points |
|---|
| 211 | IF (nn_hls==1) CALL lbc_lnk( 'dom_qco_r3c', pr3u, 'U', 1._wp, pr3v, 'V', 1._wp, pr3f, 'F', 1._wp ) |
|---|
| 212 | ! |
|---|
| 213 | ENDIF |
|---|
| 214 | ! |
|---|
| 215 | END SUBROUTINE dom_qco_r3c |
|---|
| 216 | |
|---|
| 217 | |
|---|
| 218 | SUBROUTINE qco_ctl |
|---|
| 219 | !!--------------------------------------------------------------------- |
|---|
| 220 | !! *** ROUTINE qco_ctl *** |
|---|
| 221 | !! |
|---|
| 222 | !! ** Purpose : Control the consistency between namelist options |
|---|
| 223 | !! for vertical coordinate |
|---|
| 224 | !!---------------------------------------------------------------------- |
|---|
| 225 | INTEGER :: ioptio, ios |
|---|
| 226 | !! |
|---|
| 227 | NAMELIST/nam_vvl/ ln_vvl_zstar, ln_vvl_ztilde, ln_vvl_layer, ln_vvl_ztilde_as_zstar, & |
|---|
| 228 | & ln_vvl_zstar_at_eqtor , rn_ahe3 , rn_rst_e3t , & |
|---|
| 229 | & rn_lf_cutoff , rn_zdef_max , ln_vvl_dbg ! not yet implemented: ln_vvl_kepe |
|---|
| 230 | !!---------------------------------------------------------------------- |
|---|
| 231 | ! |
|---|
| 232 | READ ( numnam_ref, nam_vvl, IOSTAT = ios, ERR = 901) |
|---|
| 233 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nam_vvl in reference namelist' ) |
|---|
| 234 | READ ( numnam_cfg, nam_vvl, IOSTAT = ios, ERR = 902 ) |
|---|
| 235 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'nam_vvl in configuration namelist' ) |
|---|
| 236 | IF(lwm) WRITE ( numond, nam_vvl ) |
|---|
| 237 | ! |
|---|
| 238 | IF(lwp) THEN ! Namelist print |
|---|
| 239 | WRITE(numout,*) |
|---|
| 240 | WRITE(numout,*) 'qco_ctl : choice/control of the variable vertical coordinate' |
|---|
| 241 | WRITE(numout,*) '~~~~~~~~' |
|---|
| 242 | WRITE(numout,*) ' Namelist nam_vvl : chose a vertical coordinate' |
|---|
| 243 | WRITE(numout,*) ' zstar ln_vvl_zstar = ', ln_vvl_zstar |
|---|
| 244 | WRITE(numout,*) ' ztilde ln_vvl_ztilde = ', ln_vvl_ztilde |
|---|
| 245 | WRITE(numout,*) ' layer ln_vvl_layer = ', ln_vvl_layer |
|---|
| 246 | WRITE(numout,*) ' ztilde as zstar ln_vvl_ztilde_as_zstar = ', ln_vvl_ztilde_as_zstar |
|---|
| 247 | WRITE(numout,*) ' ztilde near the equator ln_vvl_zstar_at_eqtor = ', ln_vvl_zstar_at_eqtor |
|---|
| 248 | WRITE(numout,*) ' !' |
|---|
| 249 | WRITE(numout,*) ' thickness diffusion coefficient rn_ahe3 = ', rn_ahe3 |
|---|
| 250 | WRITE(numout,*) ' maximum e3t deformation fractional change rn_zdef_max = ', rn_zdef_max |
|---|
| 251 | IF( ln_vvl_ztilde_as_zstar ) THEN |
|---|
| 252 | WRITE(numout,*) ' ztilde running in zstar emulation mode (ln_vvl_ztilde_as_zstar=T) ' |
|---|
| 253 | WRITE(numout,*) ' ignoring namelist timescale parameters and using:' |
|---|
| 254 | WRITE(numout,*) ' hard-wired : z-tilde to zstar restoration timescale (days)' |
|---|
| 255 | WRITE(numout,*) ' rn_rst_e3t = 0.e0' |
|---|
| 256 | WRITE(numout,*) ' hard-wired : z-tilde cutoff frequency of low-pass filter (days)' |
|---|
| 257 | WRITE(numout,*) ' rn_lf_cutoff = 1.0/rn_Dt' |
|---|
| 258 | ELSE |
|---|
| 259 | WRITE(numout,*) ' z-tilde to zstar restoration timescale (days) rn_rst_e3t = ', rn_rst_e3t |
|---|
| 260 | WRITE(numout,*) ' z-tilde cutoff frequency of low-pass filter (days) rn_lf_cutoff = ', rn_lf_cutoff |
|---|
| 261 | ENDIF |
|---|
| 262 | WRITE(numout,*) ' debug prints flag ln_vvl_dbg = ', ln_vvl_dbg |
|---|
| 263 | ENDIF |
|---|
| 264 | ! |
|---|
| 265 | ioptio = 0 ! Parameter control |
|---|
| 266 | IF( ln_vvl_ztilde_as_zstar ) ln_vvl_ztilde = .true. |
|---|
| 267 | IF( ln_vvl_zstar ) ioptio = ioptio + 1 |
|---|
| 268 | IF( ln_vvl_ztilde ) ioptio = ioptio + 1 |
|---|
| 269 | IF( ln_vvl_layer ) ioptio = ioptio + 1 |
|---|
| 270 | ! |
|---|
| 271 | IF( ioptio /= 1 ) CALL ctl_stop( 'Choose ONE vertical coordinate in namelist nam_vvl' ) |
|---|
| 272 | ! |
|---|
| 273 | IF(lwp) THEN ! Print the choice |
|---|
| 274 | WRITE(numout,*) |
|---|
| 275 | IF( ln_vvl_zstar ) WRITE(numout,*) ' ==>>> zstar vertical coordinate is used' |
|---|
| 276 | IF( ln_vvl_ztilde ) WRITE(numout,*) ' ==>>> ztilde vertical coordinate is used' |
|---|
| 277 | IF( ln_vvl_layer ) WRITE(numout,*) ' ==>>> layer vertical coordinate is used' |
|---|
| 278 | IF( ln_vvl_ztilde_as_zstar ) WRITE(numout,*) ' ==>>> to emulate a zstar coordinate' |
|---|
| 279 | ENDIF |
|---|
| 280 | ! |
|---|
| 281 | #if defined key_agrif |
|---|
| 282 | IF( (.NOT.Agrif_Root()).AND.(.NOT.ln_vvl_zstar) ) CALL ctl_stop( 'AGRIF is implemented with zstar coordinate only' ) |
|---|
| 283 | #endif |
|---|
| 284 | ! |
|---|
| 285 | END SUBROUTINE qco_ctl |
|---|
| 286 | |
|---|
| 287 | !!====================================================================== |
|---|
| 288 | END MODULE domqco |
|---|
